////////////////////////////
//
//	Clip-4-Win @ ... SAY definitions
//
//	Copyright (C) 1993 Skelton Software, Kendal Cottage, Hillam, Leeds, UK.
//	All Rights Reserved.
//
//	These #command's produce output that is automatically re-drawn
//	whenever necessary, as well as allowing you to specify exact
//	width/height in pixels, exact position, font to use, etc.
//
//	NOTE:	You need an empty array called SayList (rather like GetList),
//
//	e.g.	LOCAL	SayList := {}
//
//		@ 10,10 say "Using row,col positioning" color "b/g"
//		#define	BLUE	RGB(0,0,255)
//		#define	GREEN	RGB(0,255,0)
//		@ pixel 50,10 say "Using x,y positioning"	;
//			textcolor BLUE bkcolor GREEN
//
//
//	NOTE:  You can choose a font either using something like:
//
//		SET DEFAULT SAY FONT TO GetStockObject(ANSI_VAR_FONT)
//
//	which uses one of the pre-defined fonts, or use a font from
//	CreateFont() or ChooseFont().
//
//	You probably won't want to do this, but: you can define
//	SAY_IN_WINDOW if you want to keep Clipper's @ ... SAY as well.
//
////////////////////////////


#ifndef	C4W_SAY_CH
#define	C4W_SAY_CH


#command CLEAR SAYS                                                     ;
      => _ClearSays( SayList )                                          ;
       ; SayList := {}

#command SET DEFAULT SAY FONT TO <hFont>                                ;
      => SetSayFont( <hFont> )


#ifdef	SAY_IN_WINDOW

#command @ <row>,<col> SAY <xpr>                                        ;
                       [PICTURE <pic>]                                  ;
                       [COLOR <color>]                                  ;
                       [TEXTCOLOR <textrgb>]                            ;
                       [BKCOLOR <bkrgb>]                                ;
                       [STYLE <style>]                                  ;
                       [CHARWIDTH <wc>]                                 ;
                       [CHARHEIGHT <hc>]                                ;
                       [WIDTH <w>]                                      ;
                       [HEIGHT <h>]                                     ;
                       [FONT <font>]                                    ;
                       IN WINDOW <hWnd>                                 ;
      => AAdd( SayList,                                                 ;
               _SayWndRC( SayList,                                      ;
                          <hWnd>, <row>, <col>, <w>, <h>, <wc>, <hc>,   ;
                          <xpr>, <pic>, <color>,                        ;
                          <textrgb>, <bkrgb>, <font> [, <style>] )      ;
             )

#command @ PIXEL <x>,<y> SAY <xpr>                                      ;
                         [PICTURE <pic>]                                ;
                         [COLOR <color>]                                ;
                         [TEXTCOLOR <textrgb>]                          ;
                         [BKCOLOR <bkrgb>]                              ;
                         [STYLE <style>]                                ;
                         [WIDTH <w>]                                    ;
                         [HEIGHT <h>]                                   ;
                         [FONT <font>]                                  ;
                         IN WINDOW <hWnd>                               ;
      => AAdd( SayList,                                                 ;
               _SayWndXY( SayList,                                      ;
                          <hWnd>, <x>, <y>, <w>, <h>,                   ;
                          <xpr>, <pic>, <color>,                        ;
                          <textrgb>, <bkrgb>, <font> [, <style>] )      ;
             )


#else	// SAY_IN_WINDOW


#command @ <row>,<col> SAY <xpr>                                        ;
                       [PICTURE <pic>]                                  ;
                       [COLOR <color>]                                  ;
                       [TEXTCOLOR <textrgb>]                            ;
                       [BKCOLOR <bkrgb>]                                ;
                       [STYLE <style>]                                  ;
                       [CHARWIDTH <wc>]                                 ;
                       [CHARHEIGHT <hc>]                                ;
                       [WIDTH <w>]                                      ;
                       [HEIGHT <h>]                                     ;
                       [FONT <font>]                                    ;
                       [IN [WINDOW] <hWnd>]                             ;
      => AAdd( SayList,                                                 ;
               _SayWndRC( SayList,                                      ;
                          <hWnd>, <row>, <col>, <w>, <h>, <wc>, <hc>,   ;
                          <xpr>, <pic>, <color>,                        ;
                          <textrgb>, <bkrgb>, <font> [, <style>] )      ;
             )

#command @ PIXEL <x>,<y> SAY <xpr>                                      ;
                         [PICTURE <pic>]                                ;
                         [COLOR <color>]                                ;
                         [TEXTCOLOR <textrgb>]                          ;
                         [BKCOLOR <bkrgb>]                              ;
                         [STYLE <style>]                                ;
                         [WIDTH <w>]                                    ;
                         [HEIGHT <h>]                                   ;
                         [FONT <font>]                                  ;
                         [IN [WINDOW] <hWnd>]                           ;
      => AAdd( SayList,                                                 ;
               _SayWndXY( SayList,                                      ;
                          <hWnd>, <x>, <y>, <w>, <h>,                   ;
                          <xpr>, <pic>, <color>,                        ;
                          <textrgb>, <bkrgb>, <font> [, <style>] )      ;
             )

#endif	// SAY_IN_WINDOW


#endif	// C4W_SAY_CH