5 POKE53280,.:POKE53281,.:PRINT"[147]";
6 REM CHANGES ERROR MESSAGES
7 DATA 42101,44277,43884,42086,48579
8 FOR X=1 TO 5:READ V(X):NEXT
10 IF PEEK(40964)=65 THEN 50
20 FOR X=828 TO X+24:READ D:POKEX,D:NEXT
22 SYS 828:REM MOVE BASIC ROM TO RAM
25 DATA 169,0,133,251,169,160,133,252
26 DATA 160,0,162,32,177,251,145,251,200
27 DATA 208,249,230,252,202,208,244,96
30 POKE1,PEEK(1) AND254:POKE40964,65:POKE49153,192:POKE 49152,2
50 DEF FNH(DE)=INT(DE/256)
52 DEF FNL(DN)=DN-FNH(DN)*256
60 M=PEEK(49153)*256+PEEK(49152)
65 POKE 808,239 :REM DISABLE STOP KEY
200 PRINTCHR$(147)
205 PRINT"I WILL LIST ERROR MESSAGES"
210 PRINT"PRESS F7 TO CHANGE MESSAGE"
212 PRINT"PRESS F1 TO END PROGRAM"
215 PRINT"PRESS ANY OTHER KEY TO CONTINUE LISTING":PRINT:PRINT
500 FOR Z=41768 TO 41824 STEP2
505 N=N+1:PRINT N;
510 LB=PEEK(Z):HB=PEEK(Z+1):LC=256*HB+LB
530 PK=PEEK(LC):IF PK>128 THEN PRINTCHR$(PK-128);:GOTO550
535 LC=LC+1:PRINTCHR$(PK);:GOTO530
550 GOSUB1000:IF F THEN GOSUB950
590 NEXT
800 FOR W=1 TO 5
805 Z=V(W):GOSUB900
810 GOSUB1000:IF F=0 THEN NEXT:GOTO1050
815 GOSUB950:NEXT:GOTO1050
820 POKEZ,FNL(M):POKEZ+2,FNH(M)
825 IF N=30 THEN POKEM,13:M=M+1
830 FORX=1 TO LEN(M$):C$=MID$(M$,X,1):POKEM,ASC(C$):M=M+1:NEXT
835 IF N>29 AND N<33 THEN POKEM,13:M=M+1
840 POKEM,0:M=M+1
850 RETURN
900 LB=PEEK(Z):HB=PEEK(Z+2):LC=256*HB+LB
915 N=N+1:PRINT N;
920 PK=PEEK(LC):IF PK>0THEN PRINT CHR$(PK);:LC=LC+1:GOTO920
930 RETURN
950 M$="":PRINT"CHANGE TO WHAT?":PRINT
964 POKE631,34:POKE632,34:POKE633,20:POKE198,3
965 INPUT M$:IF M$=""THEN RETURN
966 IF N>29 THEN 820
967 POKEZ,FNL(M):POKEZ+1,FNH(M)
970 FORX=1 TO LEN(M$)-1:C$=MID$(M$,X,1):POKEM,ASC(C$):M=M+1:NEXT
975 POKEM,ASC(RIGHT$(M$,1))+128:M=M+1
980 PRINT:RETURN
1000 GETK$:IFK$=""THEN 1000
1002 PRINT
1020 F=0:IF K$=CHR$(136)THEN F=1
1030 IF K$<>CHR$(133)THEN RETURN
1050 POKE 49153,FNH(M):POKE 49152,FNL(M)
1060 POKE 808,237 :REM ENABLE STOP KEY
1070 PRINT:PRINTCHR$(18)"PROGRAM OVER.. GOOD BYE":END
2000 FOR X=43 TO 46:PRINT"POKE";X;",";PEEK(X):PRINT:PRINT:NEXT:PRINT
2030 POKE43,0:POKE44,160:POKE45,PEEK(49152):POKE46,PEEK(49153)
2040 PRINT"SAVE MESSAGES THEN ENTER ABOVE POKES"