1 REM MEDTAX.03
2 REM 11/14/86
3 REM BY MICHAEL REICH
4 REM WITH INSTRUCTION LOADER
8 REM 04/05/87
9 POKE53280,6:POKE53281,1
10 IF A=0 THEN A=1:GOSUB 10030:REM PRINT SCREEN
11 IF B=0 THEN B=1:LD$="SEQ READER.EXE":GOTO 7500
12 IF B=1 THEN B=2:LD$="LPTR RTN":GOTO 7500
13 GOSUB 210
15 REM **********
16 REM * INIT.  *
17 REM **********
20 T$="[205]EDICAL-[212]AX [198]ILE":RV$=CHR$(18):RO$=CHR$(146):TS$="MEDTAX.DAT":SC$=CHR$(147)
25 DEF FNR(Z)=INT(Z*100+.5)/100
30 CL$="                                       ":DN$=""
40 LO$=DN$+CL$+DN$:C1$=CHR$(154):C2$=CHR$(152):PC=.85:REM COPAY
50 M=100:NF=6:PE=5:TY=5:DIM EN$(M),A$(NF),SL(NF),LE(NF),PE$(9)
55 FORI=1TOPE:READPE$(I):NEXT:REM FAMILY NAMES
60 DATA MIKE,NANCY,SARA,AMANDA,JAKE
65 FORI=1TOTY:READTY$(I):NEXT:REM EXPENSE TYPES
70 DATA "[205][196]","[196][196][211]","[200]OSP","[210][216]","[207]THER"
75 EN$(0)="..................................":REM LEN=34
80 FORI=1TONF:READFI$(I),SL(I),LE(I):NEXT:FI$(0)="[210]ECORD #"
82 DATA"[196]ATE      ",1,8,"[212]YPE      ",9,1,"[197]XPENSE   ",10,7,"[210]EIMBURSE.",17,7
84 DATA"[208]ROVIDER  ",24,10,"[208]ATIENT   ",34,1
85 NO=9:DIM MO$(NO):FORI=1TONO:READMO$(I):NEXT
87 DATA"[205]ODIFY [210]ECORD","[208]RINT [198]ILE","[193]DD [210]ECORD"
88 DATA"[204]OAD [198]ILE","[211]AVE [198]ILE","[195]ALCULATE [207]UTSTANDING [195]LAIMS"
89 DATA"[197]DIT [198]AMILY [205]EMBERS' [206]AMES","[201]NSTRUCTIONS","[197]XIT"
95 GOTO500
100 REM **********
102 REM * SCREEN *
104 REM **********
110 PRINTSC$;MO;MO$(MO):IFMO=2THENIFZ<=PETHENPRINTTAB(25)"[145]"RV$PE$(Z)
115 PRINT"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]":RETURN
120 GOSUB100:PRINTLEFT$(DN$,6);
130 FORI=1TONF:PRINTI;RV$;FI$(I)
140 NEXT: RETURN
200 REM **********
202 REM * DELAY  *
204 REM **********
210 FORT=1TO500:NEXT
220 FORT=1TO500:NEXT:RETURN
255 REM **********
256 REM *KEYPRESS*
257 REM **********
260 GETC$:IFC$=""THEN260
270 RETURN
280 IFMO=1THENPRINTLO$TAB(16)"[145] [201][146]NDEX,"
282 PRINTLO$"            [195][146]ONTINUE OR [197][146]XIT";
285 GOSUB 260: REM GET KBD INPUT
286 IF (C$="C") OR (C$="E") OR (C$="I") THEN 290
287 IF (C$<>"[195]") AND (C$<>"[197]") AND (C$<>"[201]") THEN 285
290 RETURN
300 REM **********
302 REM *DISASEMB*
304 REM **********
310 FORI=1TONF:A$(I)=MID$(EN$(0),SL(I),LE(I)):NEXT:RETURN
320 FORI=1TONF:A$(I)=MID$(EN$(CR),SL(I),LE(I)):NEXT:RETURN
340 REM **********
342 REM *PRINT A$*
344 REM **********
350 PRINTLEFT$(DN$,5)FI$(0)CR:FORI=1TONF    :PRINTTAB(15)A$(I)
360 IFMO=1THENX$(I)=A$(I)
370 NEXT: RETURN
400 REM **********
402 REM * SELECT *
404 REM **********
410 PRINTLO$"[145][145][145][145]"
420 PRINT"[215]HICH [208]ERSON:"
425 PRINTC2$0;C1$"[193]LL",;
430 FORP=1TOPE:PRINT"[152]"P"[154]"PE$(P),;:NEXT
450 GOSUB260:C=VAL(C$):IF C>PE THEN450
460 PRINTLO$"[145][145][145]"CL$CL$CL$" ":RETURN
500 REM **********
502 REM * MENU   *
504 REM **********
510 MO=0:GOSUB10000
512 PRINTLEFT$(DN$,24)SPC(9)"";LR;"[157] [146]"C2$" [210]ECORDS IN [205]EMORY"C1$:PRINT
515 FORI=1TONO:PRINT:PRINTTAB(5)I;MO$(I):NEXT:PRINT
520 PRINTTAB(12)"[211]ELECTION? [163][145][157][157] ";
530 GOSUB260:MO$=C$
540 MO=VAL(MO$):IFMO<1ORMO>NO THEN510
550 PRINTC2$MO$C1$:IF MO=NO THEN SYS (8*4096)+4
560 IFMO=4 OR MO=8OR MO=7 OR LR>0THEN580
570 PRINTLO$RV$SPC(9)"[150]  [206]O [198]ILE IN [205]EMORY  "
575 PRINTSPC(12)"[154][206]EW [198]ILE? <Y/N>";:GOSUB 260: NE$=C$: IFNE$="Y"THENGOTO580
576 GOTO590
580 ONMOGOSUB1000,42000,3000,5000,6000,9000,43000,30000
590 GOTO510
1000 REM **********
1002 REM * MODIFY *
1004 REM **********
1020 GOSUB100:GOSUB280
1030 IFC$<>"C"ANDC$<>"I"ANDC$<>"E"THEN1020
1050 IFC$="E"THEN1999
1060 IFC$="I"THENGOSUB1800:GOTO1000
1100 PRINTLO$"[145]"CL$LO$"[197]NTER [210]ECORD [206]UMBER TO [205]ODIFY -> ";:BS$="[157] [157]":MAX=3
1110 GOSUB 30200:CR=VAL(TE$)
1120 IFCR<1ORCR>LRTHENPRINTLO$"         [201]NVALID [210]ECORD [206]UMBER"C1$:GOSUB200:GOTO1000
1130 GOSUB120:GOSUB320:GOSUB350
1170 PRINTLO$"[205]ODIFY [215]HICH [198]IELD (1-"NF"OR 0=EXIT) ";:GOSUB260:PRINTC$;
1174 I=VAL(C$):IFI=0THEN1000
1175 IFI<>4 THEN 1180
1176 PRINTLO$"[193]UTOMATIC CALC. <[217]> ";:DE$="[157] [157]"
1177 GOSUB 30200:IF TE$="Y" OR TE$="[217]" OR TE$="" THEN 1240
1180 IFI>NFTHENPRINTLO$"[201]NVALID [198]IELD [206]UMBER"C1$:GOSUB200:GOTO1000
1190 GOSUB3600:GOSUB3740:IFY$<>"Y"THEN1170
1230 A$(I)=X$:EN$(CR)="":FORX=1TONF:EN$(CR)=EN$(CR)+A$(X):NEXT:GOTO1170
1235 :
1240 IFI=4THENZ=.85*VAL(A$(3)):Z=FNR(Z):Z$=LEFT$(STR$(Z)+EN$(0),LE(I))
1250 A$(I)=MID$(Z$,2)+".":EN$(CR)="":FORX=1TONF:EN$(CR)=EN$(CR)+A$(X):NEXT
1260 GOTO1130
1800 :
1802 REM INDEX
1804 :
1810 GOSUB1890:FORCR=1TOLR:X1$=MID$(EN$(CR),1,8):X2$=MID$(EN$(CR),34,1)
1820 X2=VAL(X2$):X3$=MID$(EN$(CR),9,1):X3=VAL(X3$)
1830 PRINTCR;TAB(5)X1$TAB(15)PE$(X2)TAB(30)TY$(X3):LN=LN+1
1840 IFLN>19THENGOSUB1870
1850 NEXT:GOSUB2850:RETURN
1870 GOSUB2850
1890 PRINTSC$TAB(16)RV$" [201]NDEX ":PRINTA$(0)
1900 PRINT"[210]EC"TAB(5)"[196]ATE"TAB(15)"[208]ERSON"TAB(30)"[212]YPE":PRINTA$(0):LN=3
1999 RETURN
2000 REM **********
2002 REM * VIEW   *
2004 REM **********
2010 PRINTLO$"       [214]IEW "RV$"[193]"RO$"LL OR "RV$"[210]"RO$"ANGE OR ";
2015 PRINTRV$"[197]"RO$"XIT"
2020 GOSUB260:IFC$<>"A"ANDC$<>"R"ANDC$<>"E"THEN2020
2030 IFC$="E"THENRETURN
2040 UR=0:IFC$="A"THENF=1:L=LR:GOTO2100
2050 PRINTLO$"[145]"CL$" [197]NTER [198]IRST [210]ECORD: ";:BS$="[157] [157]":MAX=3:GOSUB 30200
2055 F=VAL(TE$):IF F<1 OR F>LR THEN 2010
2060 PRINTLO$"[197]NTER [204]AST [210]ECORD: ";:GOSUB 30200:L=VAL(TE$):IFL<FTHEN2010
2070 IFL>LRTHENL=LR
2100 Z=0:GOSUB 110:GOSUB400:Z=C:IFMO=6THENRETURN
2120 GOSUB2900:FORCR=FTOL
2140 GOSUB320:IFZ=0THEN2160
2150 IFVAL(A$(6))<>ZTHEN2310
2160 PRINTA$(1)SPC(4)A$(3)SPC(4);:           IFLEFT$(A$(5),1)="."THENPRINT
2170 IFLEFT$(A$(5),1)<>"."THENPRINTA$(5)
2180 PRINT" "TY$(VAL(A$(2)))TAB(12)A$(4)SPC(4);:IFLEFT$(A$(6),1)="."THENPRINT
2190 IFLEFT$(A$(6),1)<>"."THENPRINTPE$(VAL(A$(6)))
2200 U1=VAL(A$(3))-VAL(A$(4))
2220 UR=UR+U1:UR$=STR$(UR):U1$=STR$(U1):     IFU1<1THENU1$=LEFT$(U1$,4)
2230 PRINTC2$"^[210]EC."CR"[157] [213]NREIM:"U1$" [212]OTAL :"UR$C1$
2300 LN=LN+3:IFLN>18THENGOSUB2850
2310 NEXT
2320 GOSUB2850:RETURN
2850 PRINTLO$"       [208]RESS <[211]PACE> TO [195]ONTINUE"
2860 GOSUB260:IFC$<>" "THEN2860
2870 IFCR>=L THENRETURN
2900 GOSUB100
2920 FORI=1TONFSTEP2:PRINTRV$"[152]"FI$(I)RO$" ";:NEXT:PRINT
2930 FORI=2TO NFSTEP2:PRINTRV$FI$(I)RO$" ";:NEXT:PRINT"[154]":LN=4:RETURN
3000 REM **********
3002 REM * ADD    *
3004 REM **********
3010 FL=1:BS$="[157][154].[157]":GOSUB100:GOSUB280:IFC$="E"THENRETURN
3100 GOSUB120:CR=LR+1
3110 IFCR>MTHENPRINT"[198]ILE [212]OO [204]ARGE -[154] [211]AVE [196]ATA":GOSUB210:GOSUB210:RETURN
3130 GOSUB300:GOSUB350
3150 FORI=1TONF:X$(I)=A$(I):GOSUB3600:       A$(I)=X$:NEXT
3170 GOSUB3740:IFY$<>"Y"THEN3000
3190 LR=CR:FORI=1TONF:EN$(LR)=EN$(LR)+A$(I):NEXT:GOTO3000
3600 :
3602 REM INPUT FOR CURRENT RECORD
3604 :
3610 PO$=LEFT$(DN$,5+I):PRINTLO$
3620 PRINTPO$TAB(15)X$(I):X$="": MAX=6
3625 IF I=1 THEN MAX=8:PRINTLO$SPC(16)"[205][205]/[196][196]/[217][217]"
3630 IF I=2 THEN MAX=1: PRINTLO$;:FOR P=1 TO TY: PRINT""P"[154]"TY$(P);: NEXT
3640 IFI=4THENPRINTLO$" [197]NTER AMOUNT REIMBURSED BY INSURANCE"
3650 IF I=5 THEN MAX=10: PRINTLO$" ENTER MD/DDS/HOSP NAME [OPTIONAL]"
3670 IF I=6 THEN MAX=1: PRINTLO$"[145]";: FOR P=1 TO PE:PRINT""P"[154]"PE$(P),;:NEXT
3680 PRINT PO$ TAB(15)"";: IF (I=3) OR (I=4) THEN PRINT"[157]$";
3685 GOSUB 30200:X$=TE$+LEFT$(EN$(0),LE(I)-LEN(TE$))
3686 PRINT PO$ TAB(13)" "
3687 IF I<>1 OR LEN(TE$)=8 THEN 3690
3688 IF MID$(X$,2,1)="/" THEN X$=LEFT$("0"+X$,8)
3689 IF LEN(TE$)<8 THENIF MID$(X$,5,1)="/" THEN X$=LEFT$(X$,3)+"0"+RIGHT$(TE$,4)
3690 IF I=6 THEN IF (X$<"1") OR (X$>MID$(STR$(PE),2,1)) THEN 3610
3720 PRINT LO$:X$(I)=X$: RETURN
3730 :
3740 PRINTLO$"[145]"CL$"               [193]CCEPT <[217]>";:DE$="Y":GOSUB 41000
3750 PRINTLO$:RETURN
4000 REM **********
4002 REM * PRINT  *
4004 REM **********
4005 REM PRINTER VARIABLES
4010 LF$=CHR$(10):ES$=CHR$(27):FF$=CHR$(12):RI$=ES$+CHR$(98):PA=0
4020 TS$=ES$+CHR$(68)+CHR$(5)+CHR$(10)+CHR$(19)+CHR$(30)+CHR$(40)+CHR$(50)
4030 TS$=TS$+CHR$(61)+CHR$(73)+CHR$(0)
4040 UI$=ES$+"-"+CHR$(1):UO$=ES$+"-"+CHR$(0):REM UNDERLINE
4050 GOSUB110:Z=0:GOSUB400:Z=C:X$="[193]LL":IF Z<>0 THEN X$=PE$(Z)
4060 FORI=1TO79:SP$=SP$+CHR$(32):NEXT:SP$=UI$+SP$+UO$
4070 FORI=1TOPE:TP(I)=0:NEXT:FORI=1TOTY:TY(I)=0:NEXT:REM RESET COUNTERS
4090 PRINTLO$"             [210]EADY TO [208]RINT":GOSUB200
4100 PRINTLO$"             [208]RESS <[210][197][212][213][210][206]>":GOSUB260:PRINTLO$
4200 POKE 780,4:REM CHANNEL#
4205 POKE 782,8:REM SECONDARY ADDRESS (L/C, NO LINEFEEDS)
4207 SYS 828:IF PEEK(783) AND 1 THEN CLOSE 4:GOSUB 4500:GOTO 4000
4210 GOSUB4900:FORCR=1TOLR:GOSUB320
4212 A1=VAL(A$(6)):IFZ<>0THENIFA1<>ZTHEN4300
4215 A2=VAL(A$(2)):X=VAL(A$(3))-VAL(A$(4)):IFX<0THENX=0
4220 TP(A1)=TP(A1)+X:TY(A2)=TY(A2)+X:TP(A1)=FNR(TP(A1)):TY(A2)=FNR(TY(A2))
4225 IFZ=0THEN4240
4230 IFVAL(A$(6))<>ZTHEN4300
4240 PRINT#4,""SPC(4);CR;:X=2:X$=STR$(CR):GOSUB 4600:PRINT#4,A$(1);
4242 X=3:X$=A$(1):GOSUB 4600:PRINT#4,TY$(A2);:X=4:X$=TY$(A2):GOSUB 4600:PRINT#4,A$(3);
4244 X=5:X$=A$(3):GOSUB 4600:PRINT#4,A$(4);:X=6:X$=A$(4):GOSUB 4600:PRINT#4,A$(5);
4250 X=7:X$=A$(5):GOSUB 4600:PRINT#4,PE$(A1);LF$
4260 LN=LN+1
4270 IFLN>55THENPRINT#4,FF$:GOSUB4900
4300 NEXTCR:IFLN>45THENPRINT#4,FF$
4310 PRINT#4,LF$;SP$;LF$
4320 PRINT#4,""SPC(10);"[213]NREIMBURSED [212]OTALS:";LF$;LF$:T1=0:T2=0:IFZ<>0THEN4340
4330 FORI=1TOPE:PRINT#4,""SPC(19);PE$(I);""SPC(11-LEN(PE$(I)));"$";TP(I);LF$
4331 T1=T1+TP(I)
4332 T1=FNR(T1)
4335 NEXT:PRINT#4,LF$:PRINT#4,""SPC(19);"[212]OTAL:";""SPC(5);"$";T1;LF$;LF$
4340 FORI=1TOTY:PRINT#4,""SPC(19);TY$(I);""SPC(11-LEN(TY$(I)));"$";TY(I);LF$
4342 T2=T2+TY(I):T2=FNR(T2)
4345 NEXT:PRINT#4,LF$:PRINT#4,""SPC(19);"[212]OTAL:";""SPC(5);"$";T2;LF$
4360 PRINT#4:CLOSE4:GOSUB200:RETURN
4500 PRINTLO$"        [206]O [208]RINTER![154]  [200]IT [193]NY KEY"
4510 GET A$:IF A$="" THEN 4510
4520 RETURN
4600 LX=LEN(X$)
4605 IF X$=FI$(0) THEN PRINT#4,""SPC(2);:RETURN
4610 PRINT#4,""SPC(TB(X)-LX);
4620 RETURN
4900 PA=PA+1:IFPA=1THENPRINT#4,TS$
4905 TB(1)=5:TB(2)=5:TB(3)=9:TB(4)=11:TB(5)=10:TB(6)=10:TB(7)=11:TB(8)=12
4910 PRINT#4,LF$;SP$;LF$;LF$
4920 PRINT#4,RI$;CHR$(24);UI$;"[213]NREIMBURSED [205]EDICAL [197]XPENSES";UO$;LF$;LF$
4930 PRINT#4,RI$;CHR$(32);"[210]ECORDS  1 TO ";LR,"PAGE:";PA;LF$;LF$
4940 PRINT#4,RI$;CHR$(32);"[198]OR: ";UI$;X$;UO$;LF$;SP$;LF$:LN=9
4950 PRINT#4,"     [210]EC  [196]ATE     [212]YPE       [197]XPENSE   [210]EIMBURS  [208]ROVIDER";
4955 PRINT#4,"   [208]ATIENT"
4960 PRINT#4,SP$;LF$;LF$:LN=11
4999 RETURN
5000 REM **********
5002 REM * LOAD   *
5004 REM **********
5010 GOSUB110:GOSUB 280:IF C$="E" THEN RETURN
5050 OPEN15,8,15,"I0":OPEN2,8,2,"0:"+TS$+",S,R":GOSUB7000:IFERTHEN5999
5060 INPUT#2,PE:IF PE=0 THEN 5100
5065 FOR I=1 TO PE
5070 INPUT#2,PE$(I):NEXT
5100 INPUT#2,LR$:LR=VAL(LR$):PRINTLO$"[210]EADING [210]ECORD #"
5120 FORI=1TOLR:INPUT#2,EN$(I):              PRINTDN$TAB(17)I
5130 IFST=0THENNEXT
5140 CLOSE2:CLOSE15:Q9=1
5999 RETURN
6000 REM **********
6002 REM * SAVE   *
6004 REM **********
6010 GOSUB 110:IFLR<1THENRETURN
6015 GOSUB 280:GOSUB 8000
6020 TS$="MEDTAX.DAT"
6040 IFC$="E"THENRETURN
6050 OPEN15,8,15,"I0":OPEN2,8,2,"0:"+TS$+",S,W":GOSUB7000:IF ER=63 THEN 6050
6060 PRINT#2,PE:IF PE=0 THEN 6100
6065 FOR I=1 TO PE
6070 PRINT#2,PE$(I):NEXT
6100 LR$=STR$(LR):PRINT#2,LR$:PRINTLO$"[215]RITING [210]ECORD #"
6120 FORI=1TOLR:PRINT#2,EN$(I):              PRINTDN$TAB(17)I:NEXT
6140 CLOSE2:CLOSE15
6150 RETURN
7000 REM **********
7002 REM *DISK ERR*
7004 REM **********
7010 INPUT#15,ER,ER$:IFER=0THEN7100
7020 IFMO=4THENIFER=62THENPRINTLO$TS$" "ER$
7030 IFMO=5THENIFER=63THENPRINTLO$"[211]CRATCHING "TS$:PRINT#15,"S0:"+TS$
7080 TS=TI+120
7085 IFTI<TSTHEN7085
7090 CLOSE2:CLOSE15:PRINTLO$
7100 RETURN
7500 OPEN 15,8,15,"I0"
7510 OPEN 2,8,2,"0:"+LD$+",P,R"
7515 INPUT#15,ER:CLOSE2:CLOSE 15
7520 IF ER=0 THEN LOAD"0:"+LD$,8,1
7530 PRINT"[147]               [196]ISK [197]RROR![154]"
7540 PRINT"       [212][146]RY AGAIN, [209][146]UIT TO [213]P[212]IME"
7550 GET A$:IF A$="T" THEN 7500
7560 IF A$="Q" THEN SYS (8*4096)+4
7570 GOTO 7550
8000 REM **********
8002 REM * SORT   *
8004 REM **********
8010 PRINTLO$"                [211]ORT <[206]>";:DE$="N":GOSUB 41000:IFY$="N"THENRETURN
8020 K=0:FORI=1TOLR-1:K1$=LEFT$(EN$(I),8):K2$=LEFT$(EN$(I+1),8)
8040 IFK1$<=K2$THEN8060
8050 K=1:K3$=EN$(I):EN$(I)=EN$(I+1):         EN$(I+1)=K3$
8060 IFK=1THEN8020
8070 NEXT:RETURN
9000 REM **********
9002 REM * CALC   *
9004 REM **********
9010 GOSUB 110:GOSUB 280:SU=0:C$="A":GOSUB2040
9020 REM START AT END OF FILE AND WORK BACK UNTIL A REIMBURSED
9040 REM EXPENSE IS FOUND
9100 FOR CR=LTOF STEP-1:GOSUB320:IFZ=0 THEN 9120
9110 IFVAL(A$(6))<>ZTHEN9200
9120 REMIFVAL(A$(4))<>0THENCR=F:GOTO9200
9180 SU=SU+(VAL(A$(3))-VAL(A$(4))):REM EXPENSE
9190 REM PRINTA$(1),A$(3),A$(4),A$(6):REM TEST
9200 PRINT"[145][197]XAMINED [210]ECORD      [157][157][157][157]"CR
9210 NEXT:PRINT"[145][145]":GOSUB110
9220 PRINT"[212]OTAL [193]MOUNT [207]UTSTANDING FOR ";
9230 IFZ=0 THENPRINT"[193]LL":GOTO9250
9240 PRINTPE$(Z)
9250 PRINT"   IS $"SU
9260 GOSUB115:PRINT"[208]RESS [193]NY [203]EY [212]O [195]ONTINUE"
9270 GET A$:IF A$="" THEN 9270
9280 RETURN
10000 REM **********
10002 REM * TITLE  *
10004 REM **********
10010 PRINTSC$CHR$(8)CHR$(14):IFMOTHENPRINTMO;MO$(MO)
10020 PRINTSPC(12)T$: PRINT: RETURN
10030 GOSUB 30150: PRINT"[150]                                      "
10035 PRINT" [193] [198]ILE TO [212]RACK [205]EDICAL [197]XPENSES AND "
10040 PRINT"    [210]EIMBURSEMENTS FOR [212]AX [208]URPOSES   "
10045 PRINT"                                      "
10050 PRINTSPC(8)"[154]([195])1987 BY [205]ICHAEL [210]EICH"
10060 PRINTSPC(10)"[193]LL [210]IGHTS [210]ESERVED"
10070 PRINT" [208]UBLISHED BY [211]OFTDISK [208]UBLISHING, [201]NC.":RETURN
30000 REM DISPLAY INSTRUCTIONS
30010 :
30020 CLOSE15:OPEN15,8,15,"I0"
30030 OPEN4,8,4,"0:MEDTAX.DOC,S,R":           INPUT#15,ER,ER$
30040 IF NOT ER THEN 30050
30042 PRINTLO$"[196]ISK [197]RROR: [154]"ER$
30045 GET A$:IF A$="" THEN 30045
30048 GOTO 30100
30050 PAG=0
30060 GOSUB 30130: SYS 49152: REM *** PRINT A PAGE OF TEXT ***
30080 GOSUB 30110: IF KEY$="" THEN GOTO 30100
30090 IF (PEEK(2)AND64) = 0 THEN GOTO 30060
30100 CLOSE4: CLOSE15: RETURN
30110 PRINT: PRINTSPC(8)" [208]RESS ANY [203]EY FOR [205]ORE "
30115 PRINTSPC(12)" [195][212][210][204] E TO [197][216][201][212] [154]"
30120 POKE198,0: WAIT198,1: GET KEY$:         POKE198,0: RETURN
30130 PAG=PAG+1: PRINT"[147]    [201]NSTRUCTIONS  [208]AGE"PAG"[157] OF 10     [152]"CHR$(14)
30140 RETURN
30150 PRINT"[147]"CHR$(8)CHR$(14):IFMOTHENPRINTMO;MO$(MO)
30151 PRINTSPC(17)"[154]      "
30152 PRINTSPC(17)"      "
30154 PRINTSPC(17)"      "
30156 PRINTSPC(11)"                  "
30158 PRINTSPC(11)" [205]EDICAL-[212]AX [198]ILE "
30160 PRINTSPC(11)"                  "
30162 PRINTSPC(17)"      "
30164 PRINTSPC(17)"      "
30166 PRINTSPC(17)"      "
30168 RETURN
30200 CT=0: TE$=""
30210 GET K$: IF K$="" THEN 30210
30220 IF K$=CHR$(13) THEN 30340
30230 IF K$<>CHR$(20) THEN 30270
30240 IF CT=0 THEN 30210
30250 CT=CT-1: TE$=LEFT$(TE$,CT)
30260 PRINT BS$;: GOTO 30210
30270 IF CT=MAX THEN 30210
30280 IF FL THEN IF (I=2) OR (I=6) THEN 30310
30288 IF (K$>=" ") THEN 30330
30290 IF (K$>="A") AND (K$<="Z") THEN 30330
30300 IF (K$>="[193]") AND (K$<="[218]") THEN 30330
30310 IF ((K$>="0") AND (K$<="9")) OR (K$=".") OR (K$="/") THEN 30330
30320 GOTO 30210
30330 TE$=TE$+K$: CT=CT+1: PRINTK$;: GOTO 30210
30340 PRINT"[154]": RETURN
41000 GET Y$
41010 IF Y$="N" OR Y$="[206]" THEN PRINT"[157][157][157] [206]O":Y$="N":RETURN
41020 IF Y$="Y" OR Y$="[217]" THEN PRINT"[157][157][157] [217]ES":Y$="Y":RETURN
41025 IF Y$=CHR$(13) THEN Y$=DE$:RETURN
41030 GOTO 41000
42000 GOSUB 110
42005 PRINTLO$"        [154][211][146]CREEN, [208][146]RINTER, OR [197][146]XIT"
42010 GET Y$:PRINT"[154]";
42020 IF Y$="S" OR Y$="[211]" THEN 2000
42030 IF Y$="P" OR Y$="[208]" THEN 4000
42035 IF Y$="E" OR Y$="[197]" THEN RETURN
42040 GOTO42010
43000 GOSUB 110:FL=0:BS$="[157] [157]"
43010 IF PE=0 THEN 43050
43020 FOR I=1 TO PE
43030 PRINTI;PE$(I)
43040 NEXT:PRINT
43050 PRINTLEFT$(DN$,15)"   1 [193]DD NAME"
43060 PRINT"   2 [195]HANGE NAME"
43070 PRINT"   3 [196]ELETE NAME"
43080 PRINT"   4 [209]UIT"
43090 GET Y$
43100 IF Y$="1" THEN 43200
43110 IF Y$="2" THEN 43300
43120 IF Y$="3" THEN 43400
43130 IF Y$="4" THEN RETURN
43140 GOTO 43090
43200 IF PE=7 THEN 43000
43205 PRINT"[197]NTER NAME"
43210 PRINT"> ";:MAX=6:GOSUB 30200
43220 IF TE$="" THEN 43000
43230 PE=PE+1:PE$(PE)=TE$
43240 GOTO 43000
43300 PRINT"[215]HICH NUMBER"
43310 PRINT"> ";:MAX=1:GOSUB 30200
43320 IF TE$="" THEN 43000
43330 I=VAL(TE$):IF I=0 THEN 43000
43340 PRINT"[145][145][197]NTER [206]AME   "
43350 PRINT">          [157][157][157][157][157][157][157][157][157]";:MAX=6:GOSUB 30200
43360 IF TE$="" THEN 43000
43370 PE$(I)=TE$
43380 GOTO 43000
43400 PRINT"[215]HICH NUMBER"
43410 PRINT"> ";:MAX=1:GOSUB 30200
43420 IF VAL(TE$)=0 THEN 43000
43430 IF VAL(TE$)>PE THEN 43000
43440 FOR I=VAL(TE$) TO PE
43450 PE$(I)=PE$(I+1):NEXT
43460 PE$(PE)="":PE=PE-1
43470 GOTO 43000