10 PRINT"[147]":POKE53280,0:POKE53281,0
25 REM PET CONVERSION BY JOHN O'HARE
50 LS$="YOU'RE LOST IN A CLOUD OF ORANGE SMOKE  YOU'D BETTER 'LOOK'"
100 PRINT"[147]":PRINTTAB(7);"THE HOUSE OF SEVEN GABLES":PRINT:PRINTTAB(12);"BY GREG HASSETT"
110 A$="I DON'T SEE IT HERE.":R$="DON'T BE REDICULOUS!":Y$="I DON'T KNOW THAT WORD.":H$="I'M NOT HOLDING IT.":CP=2:GOTO2630
120 GOTO2530
130 IFINT(RND(1)*100)=50ANDZZ>2THEN2110
140 IFINT(RND(1)*40)=1ANDCP<>2ANDCP<>5ANDCP<>21ANDCP<>41THEN2200
150 GOSUB2310:T=T+1:IFT=50THENOB$(27)="A TARNISHED OLD COMPASS"
160 IFNO>40THENNO=NO-40
170 IFVB<>25ANDVB>10ANDNO$=""THENINPUT"GIVE ME AN OBJECT";NO$:GOSUB2480
180 IFNO$<>""ANDNO=0ANDVB=1THENPRINT"WHAT?":GOTO150
190 IFT>175THENMI=-10
200 IFT>225THENMI=-15
210 IFNO=0ANDNO$<>""THENPRINTY$:GOTO150
220 IFVB<>1THEN370
230 IFVB=1ANDNO$=""THENINPUT"WHERE ?";NO$:GOSUB2480
240 IFNO>40THENNO=NO-40
250 IFNO<7THEN290
260 AB%=OB(NO,0)
270 IF(AB%>10ANDAB%<18)ORABS(CP-ABB%)>3ORCP=2ORAB%=0THENPRINTY$:GOTO150
280 CP=AB%:GOTO120
290 IFOB(27,0)<>-1THENPRINT"I DON'T HAVE A COMPASS!":GOTO150
300 IFP(CP,NO-1)=0THENPRINT"I CAN'T GO THAT WAY!":GOTO150
310 IFCP=2ANDNO=2THENPRINT"IT'S LOCKED.":GOTO150
320 IFCP=6ANDNO=3ANDDF=0THENPRINT"THE DOOR IS CLOSED.":GOTO150
330 IFCP=9ANDOB(9,0)=9ANDNO=1THENPRINT"HE WON'T LET ME!":GOTO150
340 IFCP=38ANDNO=6ANDOB(18,0)<>0THENP(5,0)=2
350 IFCP=5ANDFF=1ANDP(5,0)=2ANDNO=1THENPRINT"[147]":PRINT"YOU MADE IT !!":GOTO2260
360 CP=P(CP,NO-1):GOTO120
370 IFVB<>2THEN520
380 IFNO$=""THENINPUT"GET WHAT";NO$:GOSUB2480
390 IFOB(NO,0)=-1THENPRINT"I'VE ALREADY GOT IT!":GOTO150
400 IFNO=7ANDCP=2THENPRINT"IT'S IMPOSSIBLE TO REMOVE.":GOTO150
410 IFNO=0THENPRINTY$:GOTO150
420 IFOB(NO,0)<>CPTHENPRINTA$:GOTO150
430 IFNO=31THENPRINTR$:GOTO150
440 IFNO=9THENPRINTR$:GOTO150
450 IFNO=40THENPRINT"I CAN'T PULL IT OUT OF IT'S SOCKET.":GOTO150
460 IFNO=14THENPRINT"IT'S TO HEAVY.":GOTO150
470 IFNO=16THENPRINT"IT'S IN A BIG POT THAT I CAN'T LIFT.":GOTO150
480 IFNO=22THENPRINTR$:GOTO150
490 IFZZ>5THENPRINT"I CAN'T CARRY ANY MORE!":GOTO150
500 ZZ=ZZ+1
510 OB(NO,0)=-1:PRINT"YOU GOT IT.":GOTO150
520 IFVB=3THEN120
530 IFVB<>4THEN570
540 ZZ=0:PRINT"I'M CARRYING:":FORI=8TO39:IFOB(I,0)=-1THENPRINTOB$(I):ZZ=ZZ+1
550 NEXTI:IFZZ=0THENPRINT"NOTHING AT ALL!"
560 GOTO150
570 IFVB<>5THEN610
580 J=0:FORI=1TOLO:IFOB(I,0)=5THENJ=J+OB(I,1)
590 NEXTI:J=J+MI
600 PRINT"YOU HAVE "J" OUT OF 160 POINTS.":GOTO150
610 IFVB<>6THEN650
620 IFNO$=""THENINPUT"DROP WHAT";NO$:GOSUB2480
630 IFOB(NO,0)<>-1THEN2860
640 PRINT"OK":ZZ=ZZ-1:OB(NO,0)=CP:GOTO150
650 IFVB=7THENPRINT"SORRY, I CAN'T.":GOTO150
660 IFVB<>8THEN720
670 INPUT"HIT RETURN WHEN READY";XX$:PRINT"SAVING":FORXX=8TO39:IFOB$(XX)=""THEN690
680 QQ(XX)=OB(XX,0)
690 NEXTXX
700 QQ(1)=CP:QQ(2)=FF:QQ(3)=ZZ:QQ(4)=T:QQ(5)=P(5,0):QQ(6)=DF
710 SAVEQQ:GOTO150
720 IFVB<>9THEN780
730 INPUT"HIT RETURN WHEN READY";XX$:PRINT"LOADING"
740 LOADQQ:FORI=8TOLO:IFOB$(I)=""THEN760
750 OB(I,0)=QQ(I)
760 NEXTI
770 CP=QQ(1):FF=QQ(2):ZZ=QQ(3):T=QQ(4):P(5,0)=QQ(5):DF=QQ(6):GOTO120
780 IFVB<>10THEN820
790 INPUT"ARE YOU SURE?";QN$
800 QN$=LEFT$(QN$,1):IFQN$="N"THEN150
810 GOTO2260
820 IFVB<>11THEN890
830 IFOB$(NO)=""ANDNO<>7THENPRINTR$:GOTO150
840 IFNO=7THEN870
850 IFOB(NO,0)<>-1THENPRINTA$:GOTO150
860 IFNO<>7THENPRINT"I CAN'T RING ";OB$(NO);"!!":GOTO150
870 IFCP<>2THENPRINTA$:GOTO150
880 PRINT"THE DOOR OPENS AND I'M SWEPT INSIDE.    IT THEN VANISHES!":FF=1:CP=5:GOTO150
890 IFVB<>12THEN960
900 IFNO=8ANDOB(10,0)<>0THENPRINT"IT IS ALREADY FULL.":GOTO150
910 IFOB(NO,0)<>-1THEN2860
920 IFNO<>8ANDNO<>29THENPRINT"I CAN'T FILL THAT!":GOTO150
930 IFCP<>3THENPRINT"HOW?":GOTO150
940 IFNO=29THENPRINT"NO, I VALUE MY LIFE. THAT FLUID MIGHT   REACT WITH THE WATER!":GOTO150
950 IFNO=8THENPRINT"YOUR BUCKET IS NOW FULL.":OB(8,0)=0:OB(10,0)=-1:GOTO150
960 IFVB<>13THEN1020
970 IFNO<>27ANDNO<>26ANDNO<>9ANDNO<>13ANDNO<>31THENPRINT"IT ISN'T ALIVE !":GOTO150
980 IFOB(NO,0)<>CPTHENPRINTA$:GOTO150
990 IFNO=9THENPRINT"IT DOESN'T APPROVE.":GOTO150
1000 IFNO=27THENPRINT"IT DOESN'T LIKE THE IDEA.":GOTO150
1010 PRINT"BE MORE SPECIFIC.":GOTO150
1020 IFVB<>14THEN1080
1030 IFNO=0THENPRINT"THROW WHAT ?":GOTO150
1040 IFOB(NO,0)<>-1THEN2860
1050 IFNO<>24ANDNO<>10THEN630
1060 IFCP=38ANDNO=10THENPRINT"SHE VANISHED BUT THE HAT REMAINS!":OB(18,0)=38:OB(31,0)=0:OB(10,0)=0:OB(8,0)=-1:GOTO150
1070 GOTO630
1080 IFVB<>15THEN1140
1090 IFNO=0THENPRINT"SHOW WHAT ?":GOTO150
1100 IFOB(NO,0)<>-1THEN2860
1110 IFNO<>11OROB(9,0)<>25THENPRINT"NOTHING HAPPENED.":GOTO150
1120 IFOB(9,0)<>25THENPRINT"NOTHING HAPPENED.":GOTO150
1130 PRINT"HE RUNS OFF SAYING 'I'LL RETURN!'":OB(9,0)=9:GOTO150
1140 IFVB<>16THEN1210
1150 IFNO<>9ANDNO<>13ANDNO<>31THENPRINTR$:GOTO150
1160 IFOB(NO,0)<>CPTHENPRINTA$:GOTO150
1170 IFOB(23,0)<>-1THEN2860
1180 IFNO=9ANDOB(23,0)<>-1THENPRINT"HE ONLY LIKES BANANAS.":GOTO150
1190 IFNO=9THENPRINT"HE GULPS DOWN THE BANANA, PEEL AND ALL!":OB(23,0)=0:GOTO150
1200 PRINT"SHE THROWS IT INTO THE BREW!":OB(23,0)=0:GOTO150
1210 IFVB<>17THEN1270
1220 IFOB(NO,0)<>-1ANDOB(NO,0)<>CPTHENPRINTA$:GOTO150
1230 IFNO=11THENPRINTR$:GOTO150
1240 IFNO<>12ANDNO<>23THENPRINTR$:GOTO150
1250 IFOB(NO,0)<>-1THEN2860
1260 PRINT"MUNCH MUNCH MUNCH. GOOD.":OB(23,0)=0:OB(24,0)=-1:GOTO150
1270 IFVB<>18THEN1390
1280 IFNO=0THENPRINT"I DON'T UNDERSTAND.":GOTO150
1290 IFNO<>14ANDNO<>22ANDNO<>33THENPRINT"I CAN'T DO THAT!":GOTO150
1300 IFCP<>25ANDNO=14THENPRINTA$:GOTO150
1310 IFCP=25ANDOB(9,0)=CPANDNO=14THENPRINT"THE VAMPIRE WON'T LET ME!":GOTO150
1320 IFNO=14ANDCP=25THENPRINT"THE COFFIN IS OPEN":CF=1:IFOB(35,0)=0THENOB(35,0)=25:GOTO150
1330 IFNO<>22THEN1370
1340 IFCP=2THENPRINT"IT'S LOCKED. TRY RINGING THE BELL.":GOTO150
1350 IFCP=6THENPRINT"I CAN'T. THERE'S NO DOORKNOB OR KEYHOLE":GOTO150
1360 PRINT"I SEE NO DOOR HERE.":GOTO150
1370 IFOB(33,0)=-1THENPRINT"TRY UNFOLDING THE AIRPLANE.":GOTO150
1380 IFOB(33,0)<>-1THENPRINT"I HAVE NO AIRPLANE.":GOTO150
1390 IFVB<>20THEN1480
1400 IFNO=22AND(CP=2ORCP=6)THEN1430
1410 IFNO=0THENPRINT"CHOP WHAT?":GOTO150
1420 IFOB(NO,0)<>CPTHENPRINTA$:GOTO150
1430 IFOB(39,0)<>-1THENINPUT"WITH WHAT, MY BARE HANDS";BH$:IFLEFT$(BH$,1)="Y"THENPRINT"I DON'T KNOW KARATE!":GOTO150
1440 IFOB(39,0)<>-1THENPRINT"ALL RIGHT THEN!":GOTO150
1450 IFNO<>22THENPRINT"THAT IS BEYOND MY POWER.":GOTO150
1460 IFCP<>2ANDCP<>6THENPRINT"I SEE NO DOOR HERE.":GOTO150
1470 PRINT"THE DOOR IS CHOPPED TO PIECES.":DF=1:GOTO150
1480 IFVB<>19THEN1560
1490 IFNO<>22ANDNO<>38ANDNO<>14THENPRINTR$:GOTO150
1500 IFNO=14ANDCP<>25THENPRINTA$:GOTO150
1510 IFNO=14ANDCP=25THENPRINT"THE COFFIN IS CLOSED.":CF=0:GOTO150
1520 IFNO=22ANDCP=6ANDDF=1THENPRINT"WHAT - A BUNCH OF SCRAPS?":GOTO150
1530 IFNO=22ANDCP=5THENPRINT"THE DOOR VANISHED, REMEMBER?":GOTO150
1540 IFNO=22ANDCP=2THENPRINT"IT IS ALREADY CLOSED.":GOTO150
1550 IFNO=22THENPRINTA$:GOTO150
1560 IFVB<>21THEN1610
1570 IFNO=0THENPRINTY$:GOTO150
1580 IFNO<>15THENPRINTR$:GOTO150
1590 IFOB(15,0)<>-1THENPRINT"I'M NOT HOLDING THEM !!":GOTO150
1600 PRINT"OKAY..":PRINT"    POOF!!":PRINT"THEY'RE NOW AN ORANGE BUBBLING LIQUID.":CF=1:GOTO150
1610 IFVB<>22THEN1750
1620 IFNO<>16ANDNO<>10ANDNO<>28ANDNO<>15THENPRINTR$:GOTO150
1630 IFNO=16ANDCP=38THENPRINT"THERE'S AN OLD SHOE IN IT!":GOTO150
1640 IFNO=10ANDOB(28,0)=-1THENPRINT"OKAY":OB(10,0)=0:OB(8,0)=-1:GOTO150
1650 IFNO=28ANDOB(28,0)=-1THENPRINT"ALLRIGHT..":PRINTTAB(15)"POOF!!":PRINT"OH OH!! - WHERE AM I? ALL OF MY POSSES- IONS WERE LOST IN THAT BLACK SMOKE!"
1660 IFNO<>28OROB(28,0)<>-1THEN1730
1670 FORI=8TOLO
1680 IFOB$(I)=""THEN1710
1690 IFOB(I,0)<>-1ANDOB(I,0)<>5THEN1710
1700 OB(I,0)=INT(RND(1)*38)
1710 NEXTI
1720 OB(27,0)=CP:OB(28,0)=0:OB(29,0)=-1:ZZ=1:GOTO150
1730 IFNO=15THENPRINTR$:GOTO150
1740 PRINT"I CAN'T.":GOTO150
1750 IFVB<>23THEN1810
1760 IFNO=22AND(CP=2ORCP=6)THEN1780
1770 IFOB(NO,0)<>-1ANDOB(NO,0)<>CPTHENPRINTA$:GOTO150
1780 IFNO<>9ANDNO<>13ANDNO<>31THENPRINT"I DON'T WANT TO HIT THE ";NO$;".":GOTO150
1790 IFNO=9THENPRINT"HIT HIM YOURSELF!":GOTO150
1800 PRINT"YUK! SHE'S TOO UGLY!":GOTO150
1810 IFVB=24THENPRINT"ALL RIGHT...";NO$:GOTO150
1820 IFVB=25THENPRINT"YOU HAVE USED "T" TURNS SO FAR.":GOTO150
1830 IFVB<>26THEN1890
1840 IFNO<>10ANDNO<>28ANDNO<>15THENPRINTR$:GOTO150
1850 IFNO=10ANDOB(10,0)=-1THENPRINT"IT'S EMPTY AND THE GROUND IS WET.":OB(10,0)=0:OB(8,0)=-1:GOTO150
1860 IFNO=28THENPRINT"YOU NOW HAVE AN EMPTY TEST TUBE.":OB(28,0)=0:OB(29,0)=-1:GOTO150
1870 IFNO=15ANDOB(15,0)=-1THENPRINTTAB(16)"POOF!!":PRINT:PRINTLS$:OB(15,0)=CP:CP=12:GOTO150
1880 PRINTH$:GOTO150
1890 IFVB=27THENPRINTR$:GOTO150
1900 IFVB<>29THEN1940
1910 IFNO<>33THENPRINTR$:GOTO150
1920 IFOB(33,0)<>-1THEN2860
1930 PRINT"O.K.":OB(33,0)=0:OB(34,0)=-1:GOTO150
1940 IFVB<>28THEN2010
1950 IFOB(NO,0)<>CPANDOB(NO,0)<>-1THENPRINTA$;" AND ";H$:GOTO150
1960 IFNO<>34ANDNO<>32ANDNO<>19THENPRINT"READ WHAT?":GOTO150
1970 IFOB(NO,0)<>-1THEN2860
1980 IFNO=32THENPRINT"IT SAYS: NOTTUB SSERP":GOTO150
1990 IFNO=34THENPRINT"'REMEMBER THE WIZARD OF OZ.'":GOTO150
2000 PRINT"IT'S IN WITCHISH!":GOTO150
2010 IFVB=30THENPRINT"TRY OPEN.":GOTO150
2020 IFVB<>31THEN2080
2030 IFOB(NO,0)<>CPTHENPRINTA$:GOTO150
2040 IFNO<>9ANDNO<>31THENPRINTR$:GOTO150
2050 IFOB(35,0)<>-1THEN2860
2060 IFNO=31THENPRINT"THE KNIFE VANISHES WHEN IT TOUCHES HER.":OB(35,0)=0:GOTO150
2070 PRINT"THE VAMPIRE DIES AND THEN VANISHES.":OB(9,0)=0:GOTO150
2080 IFNO<>40THENPRINTR$:GOTO150
2090 IFCP<>37THENPRINTA$:GOTO150
2100 CP=38:GOTO120
2110 PRINT"A GHOST APPEARS AND SAYS 'THROW ME SOME TREASURE!'":GOSUB2310
2120 IFVB<>16ORNO<>13THEN2150
2130 IFOB(23,0)=0THENPRINT"I HAVE NO FOOD.":GOTO2150
2140 PRINT"HE EATS THE BANANA AND VANISHES.":OB(23,0)=0:OB(24,0)=CP:GOTO150
2150 IFVB<>14THENPRINT"HE IS GETTING MAD!":GOSUB2310
2160 IFVB<>14THENPRINT"HE HAS KILLED ME !":GOTO2260
2170 IFOB(NO,0)<>-1THENPRINTH$:GOSUB2310:GOSUB2150
2180 IFOB(NO,1)=0THENPRINT"HE GROWLS 'NOT GOOD ENOUGH' AND THROWS  IT BACK.":GOSUB2310:GOSUB2150
2190 PRINT"HE GRABS IT AND RUNS.":ZZ=ZZ-1:OB(NO,0)=0:GOTO150
2200 PRINT"OH OH! A ONE EYED GHOUL!":INPUT"WHAT SHALL I DO?";CM$:GOSUB2380
2210 IFVB<>14ORNO<>15THEN2250
2220 IFOB(15,0)<>-1THENPRINT"I DON'T HAVE THEM!":GOTO2250
2230 IFCF=0THENPRINT"THEY WEREN'T MIXED!":GOTO2250
2240 PRINT"THE GHOUL MELTS TO NOTHING.":OB(15,0)=CP:ZZ=ZZ-1:GOTO150
2250 PRINT"THE GHOUL KILLS ME!":GOTO2260
2260 J=0:FORI=8TOLO:IFOB(I,0)=5THENJ=J+OB(I,1)
2270 NEXTI
2280 J=J+MI
2290 PRINT"OUT OF 160 POINTS, YOU SCORED "J"       POINTS USING "T" TURNS.":PRINT:INPUT"WANT TO TRY AGAIN?";AG$:AG$=LEFT$(AG$,1):IFAG$="Y"THENRUN
2300 END
2310 PRINT"WHAT SHOULD I DO --->";:CM$=""
2320 GETGT$:IFGT$=""THEN2320
2321 IFGT$=CHR$(13)ANDLEN(CM$)=0THEN2320
2325 IFGT$=CHR$(13)THEN2370
2330 IFASC(GT$)<>20THENCM$=CM$+GT$:GOTO2360
2340 IFLEN(CM$)<=1THENCM$="":GOTO2360
2350 CM$=LEFT$(CM$,LEN(CM$)-1)
2360 PRINTGT$;:GOTO2320
2370 PRINT
2380 NO$="":VB$="":VB=0:NO=0
2390 LC=LEN(CM$):FORI=1TOLC:IFMID$(CM$,I,1)<>" "THENVB$=VB$+MID$(CM$,I,1):NEXTI
2400 V1$=VB$
2410 VB$=LEFT$(VB$,3)
2420 FORI=1TONV:T$=MID$(V$,I*3-2,3):IFRIGHT$(T$,1)=" "THENT$=LEFT$(T$,2)
2430 IFVB$=T$THENVB=I:GOTO2460
2440 NEXTI
2450 VB=1:NO$=VB$:GOTO2480
2460 IFLEN(V1$)+1>=LEN(CM$)THENNO=0:RETURN
2470 NO$=RIGHT$(CM$,LEN(CM$)-1-LEN(V1$))
2480 NO$=LEFT$(NO$,3):FORI=1TONN:T$=MID$(N$,I*3-2,3):IFRIGHT$(T$,1)=" "THENT$=LEFT$(T$,1)
2490 IFNO$=T$THEN2520
2500 NEXTI
2510 NO=0:RETURN
2520 NO=I:RETURN
2530 PRINT"[147]"
2540 PRINTP$(CP)
2550 FORI=8TOLO:IFOB(I,0)=CPTHENPRINT"THERE IS ";OB$(I);" HERE."
2560 NEXTI
2570 FL=0:IFOB(27,0)<>-1THEN2610
2580 PRINT"I CAN GO --";:FORI=0TO5:IFP(CP,I)<>0THENPRINTMID$(N$,121+3*I,3);:FL=1
2590 NEXTI:IFFL=0THENPRINT"NOWHERE!":GOTO2610
2600 PRINT
2610 PRINT"---------------------------------------"
2620 GOTO130
2630 NN=46:LO=40:P=40:NV=32:DIMOB$(LO),OB(LO,1),QQ(46)
2640 DIMP$(P),P(P,5),VB$(NV)
2650 DATAI'M AT THE 2ND GABLE,0,4,0,0,0,0,I'M OUTSIDE A HOUSE WITH 7 G
ABLES. I SEE A DOOR WITH A BELL,0,5,0,0,0,0,I'M IN THE KITCHEN. THERE IS A SINK WITH A SPICKET HERE,0,6,0,0,0,0,I'M IN THE GUESTROOM,1,0,5,8,0,0
2660 DATAI'M IN THE LIVING ROOM,0,9,6,4,0,0,I'M IN THE DINING ROOM,3,0,7,5,0,0,I'M AT THE BOTTOM OF THE STAIRWELL,0,0,0,6,29,0,I'M AT THE 1ST GABLE,0,0,4,0,0,0,I'M AT THE TOP OF A STAIRCASE,5,0,0,10,0,20
2670 DATAI'M IN A CLOSET. A VOICE SAYS 'MIX EM',0,0,9,0,0,0,I'M IN A MAD SCIENTIST'S LAB,0,0,0,0,0,12,I'M IN A MAZE OF HALLWAYS,0,16,12,12,11,15,X,0,0,0,0,0,0,X,0,0,0,0,0,0,X,15,17,15,16,0,0,X,15,16,12,16,16,16
2680 DATAX,15,0,18,0,0,0,I'M AT THE WEST END OF THE HALLWAY,19,0,23,17,0,0
2690 DATA I'M IN A DUNGEON. A NOTE ON THE WALL    READS- 'YOU HAVE TO KILL THE WITCH TO   LEAVE,0,18,19,19,19,19,I'M AT THE BOTTOM OF A STAIRCASE,0,23,0,0,9,0,X,0,0,0,0,0,0,I'M IN A BARREN LIBRARY,0,24,0,0,0,0
2700 DATAI'M IN THE CENTER OF A LONG E/W HALLWAY,20,0,24,18,0,0,I'M AT THE EAST END OF THE HALLWAY,22,0,25,23,0,0,I'M IN DRACULA'S CHAMBER,0,0,0,24,0,0,I'M IN A BROOM CLOSET,0,0,27,0,0,0,I'M AT THE 4TH GABLE,28,0,0,26,0,0
2710 DATAI'M AT GABLE 5,0,27,29,0,0,0,X,0,0,0,28,0,32,I'M IN A BEDROOM,0,0,31,33,0,0,I'M IN A DUSTY BEDROOM,0,34,32,30,0,0,I'M AT THE 6TH GABLE,0,0,0,31,0,0,I'M AT THE 3RD GABLE,0,0,30,34,0,0,I'M AT THE END OF A HALLWAY,31,40,35,0,0,0
2720 DATAI'M IN THE MIDDLE OF A HALLWAY,0,0,36,34,0,0
2730 DATAX,32,0,37,35,0,0,I'M IN A ROOM WITH A PEDESTAL WITH A    LARGE BUTTON ON TOP,0,0,0,36,0,39,I'M IN THE WITCH'S CHAMBER,0,0,0,0,0,5,I'M AT THE 7TH GABLE,0,0,0,0,37,0,I'M IN A MAMMOTH ART GALLERY,34,0,0,0,0,0
2740 DATAAN EMPTY BUCKET,6,0,A MEAN LOOKING VAMPIRE,25,0,A BUCKET OF WATER,0,0,SOME FRESH GARLIC,3,0,X,0,0,X,0,0,A COFFIN,25,0,SOME CHEMICALS,11,0,A POT OF WITCHS' BREW,38,0,X,0,0,A BLACK HAT,0,50
2750 DATASOME VALUABLE RECIPIES,26,15,SOME SILVER CANDLESTICKS,6,10,X,0,0,X,0,0,A BANANA,3,0,A BANANA PEEL,0,0,A SPARKLING DIAMOND,39,15,X,0,0,A SHINY COMPASS,2,0,A TEST TUBE OF FLUID,33,0
2760 DATAAN EMPTY TEST TUBE,0,0,A BEAUTIFUL ROSE,29,10,AN UGLY WITCH,38,0,A BOOK OF WITCHCRAFT,22,0,A PAPER AIRPLANE,32,0,A PIECE OF PAPER WITH WRITING ON IT,0,0,SULTON'S DAGGER,0,35
2770 DATAA PRICELESS REMBRANDT,40,20,X,0,0,X,0,0,AN OLD RUSTY AXE,15,5
2780 FORI=1TOP:READP$(I):FORJ=0TO5:READP(I,J):NEXTJ,I
2790 P$(15)=P$(12):P$(16)=P$(12):P$(17)=P$(12):P$(29)=P$(9):P$(36)=P$(34)
2800 FORI=8TO39
2810 READOB$(I),OB(I,0),OB(I,1)
2820 NEXTI
2830 N$="NORSOUEASWESUP DOWBELBUCVAMWATGARFOOGHOCOFCHEBRECUPHATRECCANKEYDOOBANPEEDIACATCOMFLUTUBROSWITBOOAIRPAPDAGREMCAGGATAXEBUTN  S  E  W  U  D  "
2840 V$="GO GETLOOINVSCODROHELSAVLOAQUIRINFILKILTHRSHOFEEEATOPECLOCHOMIXDRIHITSAYTURDUMFIGREAUNFUNLSTAPRE"
2850 GOTO120
2860 PRINTH$:GOTO150
2870 PRINT"WHAZZAT ?":GOTO150