10 POKE53280,0:POKE53281,0:PRINT"[147][196][212][202]-[194][194][211] [196]ATE [208]RESETTER [197]XAMPLE"
20 PRINT"[212]HIS PROGRAM SHOWS YOU HOW TO SET THE"
30 PRINT"DATE AND TIME BEFORE YOU LOAD THE"
40 PRINT"[196][212][202]-[194][194][211]."
50 PRINT"[212]O MODIFY THIS PROGRAM TO USE A"
60 PRINT"HARDWARE DATE/TIME DEVICE, MODIFY LINES"
70 PRINT"1000 AND HIGHER TO READ THE DATE AND"
80 PRINT"TIME INTO THE APPROPRIATE VARIABLES."
90 GOSUB 1000:REM      GET DATE/TIME
100 POKE2041,123:REM   DATE-SET FLAG
110 POKE2042,YE:REM    YEAR
120 POKE2043,MO:REM    MONTH
130 POKE2044,DA:REM    DAY
140 POKE56331,HO:REM   HOUR (BCD)
150 POKE56330,MI:REM   MINUTE (BCD)
160 POKE56329,SE:REM   SECONDS (BCD)
170 POKE56328,0:REM    START CLOCK
180 LOAD"BBS",8,1:REM  LOAD BBS
990 END
1000 REM  ----------------------------
1010 REM  THIS ROUTINE GETS THE DATE
1020 REM  AND TIME.  VARIABLES ARE:
1030 REM   YE = YEAR
1040 REM   MO = MONTH
1050 REM   DA = DAY
1060 REM   HO = HOURS (24 HOUR)
1070 REM   MI = MINUTES
1080 REM   SE = SECONDS
1090 REM  ----------------------------
1100 INPUT "   [217]EAR";YE
1110 INPUT "  [205]ONTH";MO
1120 INPUT "    [196]AY";DA
1130 INPUT "  [200]OURS (24 HOUR MILITARY TIME)";HO
1140 INPUT "[205]INUTES";MI
1150 INPUT "[211]ECONDS  0[157][157][157]";SE
1160 REM  ----------------------------
1170 REM  MAKE SURE YEAR IS 2 DIGITS
1180 YE=INT(100*(YE/100-INT(YE/100))+.5)
1190 REM  ----------------------------
1200 REM  CONVERT TIME TO BCD AM/PM
1210 IFHO>23THENHO=HO-24
1220 I=0:IFHO>11THENHO=HO-12:I=128
1230 HO=16*INT(HO/10)+(HO-10*INT(HO/10))+I
1240 MI=16*INT(MI/10)+(MI-10*INT(MI/10))
1250 SE=16*INT(SE/10)+(SE-10*INT(SE/10))
1260 RETURN
9000 REM  ---* CORRECTED 9/11/89 *----