0 REM SYSTEM-V V3.1 VON INGOLF LANGE
1 REM (C)1990 MARKT&TECHNIK VERLAG
2 GOTO170
3 PRINT"[146]";P$;LEFT$(L$,40-LEN(P$));"";P$;LEFT$(L$,40-LEN(P$));:RETURN
4 PRINTH$;"[146]";P$;LEFT$(L$,40-LEN(P$));"";P$;LEFT$(L$,39-LEN(P$))"[145][145]";:RETURN
5 POKE53280,F(0):POKE646,F(2):POKE53281,F(1):PRINT"[147]";:SYS FI,55296,56296,F(2)
6 PRINT"[146]";:POKE646,F(3):P$=" [196]:"+D$+"."+RIGHT$(" "+STR$(EX),3)
7 P$=P$+"  "+W$(W,0)+"    .  0":GOSUB3:POKE646,F(2)
8 PRINT LEFT$(H$,20);:P$=LEFT$(M$,40):GOSUB3:P$=MID$(M$,41,40):GOSUB3
9 P$="  [211]TOP-[212]ASTE ZUM [193]NW[HLEN DER [194]EFEHLE":GOSUB4:PRINT"":RETURN
10 :
20 PP$=P$:M=0:X1=PEEK(211):Y1=PEEK(214):POKE646,F(2)
30 P$="     [195]URSOR+[210]ETURN ODER [194]UCHSTABEN":GOSUB4
40 SYS FI,56056,56296,F(2)
50 SYS FI,56056+M(M,0),56056+M(M,1),F(4):SYS FI,56096+M(M,0),56096+M(M,1),F(4)
60 GETI$:IFI$=""THEN60
70 IF(I$=""ORI$=" ")ANDM<MM THENM=M+1:GOTO40
80 IF(I$="[157]"ORI$="[160]")ANDM>0  THENM=M-1:GOTO40
90 IF I$=CHR$(13) THEN I$=CHR$(PEEK(49913+M(M,0))):GOTO140
100 IFI$=X$ THEN140
110 IFASC(I$)<65ORASC(I$)>95 THEN60
120 A$=CHR$(128+ASC(I$)):FORI=1TOLEN(M$):IFMID$(M$,I,1)=A$ THEN140
130 NEXTI:GOTO60
140 SYS FI,56056,56296,F(2):P$="":GOSUB4:P$=PP$:POKE211,X1:POKE214,Y1:SYS58640
150 RETURN
160 :
170 POKE788,52:POKE55,209:POKE56,81:CLR
180 DA=20945:VA=23410:IN=50176:FI=50368:P1=50432:P2=P1+5:FO=50624:DI=50704
190 T1=50848:T2=50934:KO=51024:CT=51200:C2=51456:V=53248
200 OPEN5,8,15
210 GA=4:SA=7:FORI=0TO255:POKEC2+I,I:NEXTI
220 LB=72:RO=5:RU=5:RL=10
230 F(0)=0:F(1)=13:F(2)=0:F(3)=5:F(4)=2
240 OPEN6,8,2,"STATUS,S,R"
250 INPUT#5,E,E$,E1,E2:IFE<>0 THEN300
260 FORI=0TO4:INPUT#6,F(I):NEXTI
270 INPUT#6,GA:INPUT#6,SA:INPUT#6,LB:INPUT#6,RO:INPUT#6,RU:INPUT#6,RL
280 INPUT#6,CO$:INPUT#6,LI$:INPUT#6,RE$
290 FORI=0TO255:GET#6,P$:POKEC2+I,ASC(P$+" "):NEXTI
300 CLOSE6
310 X=0:Y=0:Z=0:R=0:Z=0:I=0:S=0:EX=0:M=0:N=0:H=0:P=0:Q=0
320 IN$="":I$="":T$="":A$="":B$=""
330 L$="                    ":L$=L$+L$
340 H$=""
350 D$="            "
360 VM=224:L=38:L1=78:L2=39
370 DIM AO$(5,5),O(5),W$(4,1),M(8,1),SP$(1),MO$(1),WI$(1),WE$(5)  :X$=CHR$(3)
380 SYS IN,40960,40960
390 SYS FI,DA,40960,0
400 SYS FI,1024,1024+VM,0
410 SYS FI,49152,50152,32:SYS FI,55296,56296,0
420 FORW=0TO4:FORI=0TO1:READW$(W,I):NEXTI,W:FORI=0TO5:READWE$(I):NEXTI
430 SP$(0)="L":SP$(1)="R"
440 MO$(0)="M]NDLICH":MO$(1)="SCHRIFTL"
450 AN$(0)="N":AN$(1)="J"
460 WI=0:LK=0:SP=0:MO=0
470 PRINT CHR$(14);CHR$(8):POKE650,128
480 POKE648,192:POKE56576,148:POKE53272,11:POKE53265,27
490 :
500 :
510 REM OPTIONEN
520 :
530 M$=" [210]AND [211]CHRIFT [200]INTERGRUND [194]ALKEN [195]URSOR  [198]ARBSPEICHERUNG"
540 M(0,0)= 0:M(0,1)= 6:M(1,0)= 5:M(1,1)=14:M(2,0)=13:M(2,1)=26
550 M(3,0)=25:M(3,1)=33:M(4,0)=32:M(4,1)=40:M(5,0)=80:M(5,1)=97 :MM=5
560 W=0:GOSUB5
570 P$=" [211]YSTEM-[214]  [214]3.1":GOSUB3
580 P$=" [195]OPYRIGHT ([195])1990 [205]ARKT&[212]ECHNIK [214]ERLAG":GOSUB3
590 P$="":GOSUB3:FORS=1TO4
600 P$="               "+W$(S,1)+"            ":GOSUB3
610 NEXTS:W=1
620 :
630 POKE646,F(4)
640 PRINTLEFT$(H$,6+2*W)TAB(13)"[146]  "W$(W,1)"  ";TAB(53)"  "W$(W,1)"  [145][145]"
650 GETI$:IFI$=""THEN650
660 POKE646,F(2):PRINTTAB(13)"[146]  "W$(W,1)"  ";TAB(53)"  "W$(W,1)"  [145][145]"
670 IFI$=X$ THENGOSUB20:IFI$<>X$ THEN730
680 IFI$=""THENW=((W)AND3)+1
690 IFI$="[145]"THENW=((W-2)AND3)+1
700 IFI$=CHR$(13)THENONWGOTO860,1720,3110,4760
710 GOTO630
720 :
730 IFI$="R" THENP$="          [210]ANDFARBE":Z=0
740 IFI$="S" THENP$="        [211]CHIFTFARBE":Z=1
750 IFI$="H" THENP$="   [200]INTERGRUNDFARBE":Z=2
760 IFI$="B" THENP$="        [194]ALKENFARBE":Z=3
770 IFI$="C" THENP$="        [195]URSORFARBE":Z=4
780 IFI$="F" THENGOSUB4790:GOTO560
790 GOSUB4
800 IY=11:IX=20:IM=2:IN$=STR$(F(Z)):GOSUB2850:IF I$=X$ THEN530
810 F(Z)=VAL(IN$):GOTO560
820 :
830 :
840 REM LERNEN
850 :
860 IFEX>0 THEN880
870 P$="     [203]EIN [215]ORTSCHATZ IM [211]PEICHER.":GOSUB4900:GOTO630
880 V%=0:R%=0:VR=0
890 M$=" [211]PALTE:"+SP$(SP)+" [205]ODUS:"+MO$(MO)+" [215]IEDERHOLUNG:"+AN$(WI)
900 M$=M$+"  [204]EERZEICHENKONTROLLE:"+AN$(LK)+" [193]USGANG":IF V%>0 THEN RETURN
910 M(0,0)= 0:M(0,1)=10:M(1,0)= 9:M(1,1)=25:M(2,0)=24:M(2,1)=40
920 M(3,0)=80:M(3,1)=104:M(4,0)=103:M(4,1)=112:MM=4:GOSUB5
930 P$="":PRINTLEFT$(H$,14);:GOSUB3
940 IFVR=0THENVR=EX:SYS FI,1024,1024+VM+2,0:IFV%>0AND MO=1 THEN1470
950 SYS FO,1024,INT(RND(1)*VR)
960 N=PEEK(251)+256*PEEK(252):POKE N,1
970 N=N-1024:VR=VR-1:V%=V%+1
980 PRINT"":P$=" [199]ETESTET:"+STR$(V%-1)+"   [206]OCH ZU TESTEN:"+STR$(VR+1):GOSUB3
990 PRINT"";:P$=LEFT$(L$,L):SYS T2,VA+N*L1+(1-SP)*L2:P$=" "+P$:GOSUB3
1000 P$=LEFT$(L$,L):GOSUB3:PRINT"[145][145]";
1010 SYS T2,VA+N*L1+SP*L2:B$=P$
1020 SYS P2,N+1
1030 IF MO=1 THEN 1120
1040 :
1050 GETI$:IFI$=""THEN1050
1060 IFI$=X$ THENG=1:GOTO1610
1070 P$=" "+B$:GOSUB3:R%=R%+1
1080 GETI$:IFI$=""THEN1080
1090 IFI$=X$ THENG=2:GOTO1610
1100 GOTO930
1110 :
1120 IN$="[183]"+B$:I=1:AA=-1
1130 K$=MID$(IN$,I,1):I=I+1:P$=""
1140 I$=MID$(IN$,I,1):IFI$=" "ANDLK=0 THEN I=I+1:GOTO1140
1150 IFI$<>"[183]"ANDI$<>"[184]"ANDI$<>"" THENP$=P$+I$:I=I+1:GOTO1140
1160 IFK$="[183]"THENAA=AA+1:O(AA)=0:AO$(AA,O(AA))=P$:GOTO1130
1170 IFK$="[184]"THENO(AA)=O(AA)+1:AO$(AA,O(AA))=P$:GOTO1130
1180 PRINTLEFT$(H$,16);:P$=LEFT$(" [183][183][183][183][183][183][183][183]",AA+1):GOSUB3
1190 :
1200 IY=5:IX=1:IM=38:GOSUB2840:IFI$=X$ THENG=3:GOTO1610
1210 IFLEFT$(IN$,1)=" " THEN IN$=RIGHT$(IN$,LEN(IN$)-1):GOTO1210
1220 IFRIGHT$(IN$,1)=" " THEN IN$=LEFT$(IN$,LEN(IN$)-1):GOTO1220
1230 FORA=0TOAA:OK(A)=0:NEXTA
1240 IN$="[183]"+IN$:I=1
1250 K$=MID$(IN$,I,1):I=I+1:P$=""
1260 I$=MID$(IN$,I,1):IFI$=" "ANDLK=0 THENI=I+1:GOTO1260
1270 IFI$<>"[183]"ANDI$<>"[184]"ANDI$<>""THENP$=P$+I$:I=I+1:GOTO1260
1280 IFK$<>"[183]"THEN1320
1290 FORA=0TOAA:FORO=0TOO(A):IFAO$(A,O)=P$ THEN OK(A)=1:A2=A
1300 NEXTO,A:IFOK(A2)=0 THEN 1400
1310 GOTO1250
1320 IFK$<>"[184]"THEN1360
1330 OK=0:FORO=0TOO(A2):IFAO$(A2,O)=P$ THEN OK=1
1340 NEXTO:IFOK=0 THEN 1400
1350 GOTO1250
1360 OK=1:FORA=0TOAA:IFOK(A)=0 THEN OK=0
1370 NEXTA:IF OK=0 THEN 1400
1380 R%=R%+1:GOTO930
1390 :
1400 PRINT LEFT$(H$,14);:POKE646,F(4):P$=" "+B$:GOSUB3:POKE646,F(2)
1410 P$="       [198]ALSCH. [194]ITTE VERGLEICHEN!":GOSUB4
1420 POKE198,0
1430 GETI$:IFI$=""THEN1430
1440 IFWI=1 THENPOKE1024+N,0:VR=VR+1
1450 P$="":GOSUB4:GOTO930
1460 :
1470 PRINT LEFT$(H$,7);:POKE646,F(4)
1480 A$="":P$=A$+LEFT$(L$,30)+A$:GOSUB3
1490 P=INT(R%/(V%-(V%=0))*100+.5)
1500 WE=INT((1-P/100)^.47712*5.999)
1510 P$=A$+"              RICHTIG FALSCH  "+A$:GOSUB3
1520 P$=A$+"  [193]BSOLUT   :"+RIGHT$(L$+STR$(R%),7)+RIGHT$(L$+STR$(V%-R%),7)+"   "
1530 P$=P$+A$:GOSUB3
1540 P$=A$+"  [208]ROZENTUAL:"+RIGHT$(L$+STR$(P),7)+RIGHT$(L$+STR$(100-P),7)+"   "
1550 P$=P$+A$:GOSUB3
1560 P$=A$+"  [215]ERTUNG   : "+WE$(WE)+"    "+A$:GOSUB3
1570 P$=A$+LEFT$(L$,30)+A$:GOSUB3
1580 GETI$:IFI$=""THEN1580
1590 POKE646,F(2):GOTO880
1600 :
1610 GOSUB20
1620 IFI$="W" THENWI=1-WI:GOSUB890:GOSUB8
1630 IFI$="L" THENLK=1-LK:GOSUB890:GOSUB8
1640 IFI$="S" THENSP=1-SP:GOTO880
1650 IFI$="M" THENMO=1-MO:GOTO880
1660 IFI$="A" THEN530
1670 ON G GOTO 1050,1080,1200
1680 :
1690 :
1700 REM EINGEBEN
1710 :
1720 M$=" [198]ELDL\SCHEN [218]EILENL\SCHEN [197]INF]GEN      [211]PEICHERL\SCHEN [199]EHEZU [193]USGANG"
1730 M(0,0)=0 :M(0,1)=13:M(1,0)=12:M(1,1)=27:M(2,0)=26:M(2,1)=36
1740 M(3,0)=80:M(3,1)=97:M(4,0)=96:M(4,1)=104:M(5,0)=103:M(5,1)=112 :MM=5
1750 GOSUB5
1760 H=0:X=0:Y=0:R=0:T=1:S=1
1770 GOSUB8:PRINT"":P$=LEFT$(L$,L):FORI=HTOH+7
1780 SYS T2,VA+I*L1:I$=P$
1790 SYS T2,VA+I*L1+L2
1800 PRINT"[146] "MID$(I$+L$,1,18)"[182][181]"MID$(P$+L$,1,18)" ";
1810 PRINT" "MID$(I$+L$,1,18)"[182][181]"MID$(P$+L$,1,18)" ";
1820 NEXTI
1830 PRINTLEFT$(H$,2*Y+2);
1840 Z=H+Y:SYS T2,VA+Z*L1+R*L2:SYS P2,Z+1:GOTO1880
1850 A$=MID$(P$,X+1,1):IFA$=","ORA$="[161]"ORA$="[162]"ORA$="[163]"THENGOSUB2190
1860 P$=LEFT$(P$,X)+I$+RIGHT$(P$,LEN(P$)-1-X)
1870 IFI<160ORI>163 THENX=X+1:S=S-(S<X-16)
1880 PRINT"[146]"TAB(T)MID$(P$+L$,S,18);""TAB(T+40)MID$(P$+L$,S,18)"[145][145]"
1890 A=55338+80*Y+20*R+X-S:POKEA,F(4):POKEA+40,F(4)
1900 GETI$:IFI$=""THEN1900
1910 POKEA,F(2):POKEA+40,F(2)
1920 IFI$=X$ THENGOSUB20:IFI$<>X$ THEN2340
1930 I=PEEK(CT+ASC(I$)):I$=CHR$(I):POKEA,F(2):POKEA+40,F(2)
1940 IFI>31AND(I<127ORI>159)ANDX<L THEN1850
1950 IFI=17THENIFH+Y<VM-1THENSYS T1,VA+Z*L1+R*L2:GOTO2100
1960 IFI=145THENIFH+Y>0THENSYS T1,VA+Z*L1+R*L2:GOTO2140
1970 IFI=29ANDX<L THENX=X+1:S=S-(S<X-16):GOTO1880
1980 IFI=157ANDX>0THENX=X-1:S=S+(S>X+1):GOTO1880
1990 IFI=20ANDX>0 THENX=X-1:S=S+(S>X+1):P$=LEFT$(P$,X)+RIGHT$(P$,L-X-1)+" "
2000 IFI=148ANDX<L THENP$=LEFT$(P$,X)+" "+MID$(P$,X+1,L-X-1)
2010 IFI=13THENSYS T1,VA+Z*L1+R*L2:GOTO2050
2020 GOTO1880
2030 :
2040 :
2050 PRINTTAB(T)LEFT$(P$+L$,18);TAB(T+40)""LEFT$(P$+L$,18)"[145][145]"
2060 X=0:S=1:R=1-R:T=22-T:IFR=1ORZ=VM-1THENP$=LEFT$(L$,L):SYS T2,VA+Z*L1+R*L2
2070 IFR=1ORZ=VM-1 THEN1880
2080 GOTO2110
2090 :
2100 I$=LEFT$(P$+L$,18):PRINTTAB(T)I$;TAB(T+40)""I$"[145][145]"
2110 X=X-S+1:S=1:Y=Y+1:IFY<8THENPRINT"":GOTO1840
2120 Y=7-6:H=H+1+6:GOTO1770
2130 :
2140 I$=LEFT$(P$+L$,18):PRINTTAB(T)I$;TAB(T+40)""I$"[145][145]"
2150 X=X-S+1:S=1:Y=Y-1:IFY>-1THENPRINT"[145][145][145]":GOTO1840
2160 Y=0+6:H=H-1-6:GOTO1770
2170 :
2180 :
2190 IFA$="[161]"ANDI$="E"THENI$="[164]":RETURN
2200 IFA$="[161]"ANDI$="[162]"THENI$="[163]":RETURN
2210 IFA$="[162]"ANDI$="A"THENI$="[165]":RETURN
2220 IFA$="[162]"ANDI$="E"THENI$="[166]":RETURN
2230 IFA$="[162]"ANDI$="U"THENI$="[167]":RETURN
2240 IFA$="[162]"ANDI$="[161]"THENI$="[163]":RETURN
2250 IFA$="[163]"ANDI$="A"THENI$="[168]":RETURN
2260 IFA$="[163]"ANDI$="E"THENI$="[169]":RETURN
2270 IFA$="[163]"ANDI$="I"THENI$="[170]":RETURN
2280 IFA$="[163]"ANDI$="O"THENI$="[171]":RETURN
2290 IFA$="[163]"ANDI$="U"THENI$="[172]":RETURN
2300 IFA$=","ANDI$="C"THENI$="[177]":RETURN
2310 IFA$=","ANDI$="[195]"THENI$="[179]":RETURN
2320 RETURN
2330 :
2340 SYS T1,VA+Z*L1+R*L2
2350 IFI$="F" THEN2430
2360 IFI$="Z" THEN2450
2370 IFI$="E" THEN2560
2380 IFI$="S" THEN2700
2390 IFI$="G" THEN2750
2400 IFI$="A" THEN2800
2410 GOTO1890
2420 :
2430 P$=LEFT$(L$,L):X=0:S=1:GOTO1880
2440 :
2450 P$=" [204]\SCHEN  [193]B [218]EILE:    [193]NZAHL:":GOSUB4
2460 IN$=STR$(Z+1):IY=11:IX=19:IM=3:GOSUB2850
2470 P=VAL(IN$):IF I$=X$ OR P<1 OR P>VM THEN2670
2480 IN$="1":IX=30:GOSUB2860:IFI$=X$ THEN2670
2490 Q=VAL(IN$):IFQ<1ORP+Q>VM+1 THEN2670
2500 P$=LEFT$(L$,L):FORZ=P-1TOVM-1
2510 SYS T2,VA+(Z+Q)*L1:SYS T1,VA+Z*L1
2520 SYS T2,VA+(Z+Q)*L1+L2:SYS T1,VA+Z*L1+L2
2530 NEXTZ:P$=""
2540 FORZ=VM-QTOVM-1:SYST1,VA+Z*L1:SYST1,VA+Z*L1+L2:NEXTZ:GOTO1770
2550 :
2560 P$=" [197]INF]GEN  [193]B [218]EILE:    [193]NZAHL:":GOSUB4
2570 IN$=STR$(Z+1):IY=11:IX=20:IM=3:GOSUB2850
2580 P=VAL(IN$):IF I$=X$ OR P<1 OR P>VM THEN2670
2590 IN$="1":IX=31:GOSUB2860:IFI$=X$ THEN2670
2600 Q=VAL(IN$):IFQ<1ORP+Q>VM+1 THEN2670
2610 P$=LEFT$(L$,L):FORZ=VM-Q-1TOP-1STEP-1
2620 SYS T2,VA+Z*L1:SYS T1,VA+(Z+Q)*L1
2630 SYS T2,VA+Z*L1+L2:SYS T1,VA+(Z+Q)*L1+L2
2640 NEXTZ:P$=""
2650 FORZ=P-1TOP-1+Q-1:SYS T1,VA+Z*L1:SYS T1,VA+Z*L1+L2:NEXTZ:GOTO1770
2660 :
2670 IF I$<>X$ THEN P$="             [206]ICHT M\GLICH!":GOSUB4900
2680 GOTO1770
2690 :
2700 GOSUB4940:IFI<>13 THEN1890
2710 P$="           [204]\SCHE [211]PEICHER...":GOSUB4
2720 P$="":FORZ=0TOVM-1:SYS T1,VA+Z*L1:SYS T1,VA+Z*L1+L2:SYS P2,Z+1:NEXTZ
2730 D$="            ":EX=0:GOTO1750
2740 :
2750 P$=" [199]EHE ZU [218]EILE:":GOSUB4
2760 IN$=STR$(Z+1):IY=11:IX=15:IM=3:GOSUB2850
2770 P=VAL(IN$):IF I$=X$ OR P<1 OR P>VM THEN2670
2780 P=P-1:H=INT(P/7)*7:Y=P-H:P$="":GOSUB4:GOTO1770
2790 :
2800 PRINT H$;:P$="          [211]UCHE [204]EERFELD...":GOSUB4 : EX=0
2810 IFPEEK(VA+EX*L1)<>0 THENEX=EX+1:SYS P1,EX:GOTO2810
2820 GOTO530
2830 :
2840 IN$=""
2850 IFLEFT$(IN$,1)=" " THENIN$=RIGHT$(IN$,LEN(IN$)-1)
2860 IP=0:GOTO2910
2870 IFIP>=LEN(IN$)THENIN$=IN$+LEFT$(L$,IP-LEN(IN$))+I$:GOTO2900
2880 A$=MID$(IN$,IP+1,1):IFA$=","ORA$="[161]"ORA$="[162]"ORA$="[163]"THENGOSUB2190
2890 IN$=LEFT$(IN$,IP)+I$+RIGHT$(IN$,LEN(IN$)-1-IP)
2900 IFI<160ORI>163 THENIP=IP+1
2910 P$=MID$(IN$+L$,1,IM)
2920 PRINTLEFT$(H$,2*IY+2)TAB(IX)"[146]"P$;TAB(40+IX)""P$"[145][145]"
2930 A=55336+80*IY+IX+IP:POKEA,F(4):POKEA+40,F(4)
2940 GETI$:IFI$=""THEN2940
2950 POKEA,PEEK(646):POKEA+40,PEEK(646)
2960 I=PEEK(CT+ASC(I$)):I$=CHR$(I)
2970 IFI>31AND(I<127ORI>159)ANDIP<IM THEN2870
2980 IFI=29ANDIP<IMTHENIP=IP+1:GOTO2910
2990 IFI=157ANDIP>0THENIP=IP-1:GOTO2910
3000 IFI=20ANDIP>0ANDIP=<LEN(IN$)ANDLEN(IN$)>0 THEN3050
3010 IFI=148ANDIP<LEN(IN$) THEN3060
3020 IFI=147THENIN$="":IP=0:GOTO2910
3030 IFI=13 ORI$=X$ THENRETURN
3040 GOTO2930
3050 IN$=LEFT$(IN$,IP-1)+MID$(IN$,IP+1,LEN(IN$)-IP):IP=IP-1:GOTO2910
3060 IN$=LEFT$(IN$,IP)+" "+MID$(IN$,IP+1,LEN(IN$)-IP+(LEN(IN$)=IM)):GOTO2910
3070 :
3080 :
3090 REM UEBERTRAGEN
3100 :
3110 DD=0:H=0:Y=0
3120 M$=" [211]PEICHERN [204]ADEN [201]NHALTSVERZEICHNIS      [198]LOPPYBEFEHL [196]RUCKEN [193]USGANG"
3130 M(0,0)= 0:M(0,1)=11:M(1,0)=10:M(1,1)=17:M(2,0)=16:M(2,1)=36
3140 M(3,0)=80:M(3,1)=94:M(4,0)=93:M(4,1)=102:M(5,0)=101:M(5,1)=110 :MM=5
3150 GOSUB5
3160 PRINT"":IFDD=0THENIN$="":GOTO3260
3170 FORD=0TO7:P$=LEFT$(L$,16):A=DA+17*(H+D):SYS T2,A:P$=LEFT$(P$,PEEK(A))
3180 IFH+D<DD THENP$="           "+CHR$(34)+P$+CHR$(34):GOSUB3
3190 IFH+D>=DD THENP$="":GOSUB3
3200 NEXTD:GOTO3220
3210 GOSUB6
3220 IFDD=0 THEN3260
3230 SYS P2,H+Y+1:P$=LEFT$(L$,16):A=DA+17*(H+Y):SYS T2,A:IN$=LEFT$(P$,PEEK(A))
3240 PRINTLEFT$(H$,2+2*Y);:P$=CHR$(34)+IN$+CHR$(34)
3250 POKE646,F(4):PRINTTAB(11)"[146]"P$;TAB(51)""P$"[145][145]"
3260 GETI$:IFI$=""THEN3260
3270 I=ASC(I$):IFI$=X$ THENGOSUB20:IFI$<>X$ THEN3360
3280 IFDD=0 THEN3220
3290 POKE646,F(2):PRINTTAB(11)"[146]"P$;TAB(51)""P$"[145][145]"
3300 IFI$<>""ORH+Y+1=DDTHEN3330
3310 Y=Y+1:IFY<8 THEN3220
3320 Y=7-6:H=H+1+6:GOTO3160
3330 IFI$<>"[145]"ORH+Y=0THEN3220
3340 Y=Y-1:IFY>-1 THEN3220
3350 Y=0+6:H=H-1-6:GOTO3160
3360 IFI$="S" AND EX>0 THEN3670
3370 IFI$="L" THEN3490
3380 IFI$="I" THEN3800
3390 IFI$="F" THEN3430
3400 IFI$="D" THEN3840
3410 IFI$="A" THEN530
3420 GOTO3220
3430 P$="":GOSUB4
3440 IY=11:IX=1:IM=38:GOSUB2840:IFI$=X$ OR IN$="" THEN3220
3450 PRINT#5,"I":GOSUB4880:IFE<>0 THEN3210
3460 PRINT#5,(IN$):GOSUB4880:IFE<>0 THEN3210
3470 GOTO3210
3480 :
3490 IY=8:IX=3:IM=12:IN$=LEFT$(IN$,12):POKE646,F(3):GOSUB2860:POKE646,F(2)
3500 IFI$=X$ORIN$="" THEN3210
3510 IN$=LEFT$(IN$+L$,12)
3520 P$="        [204]ADEN ODER [196]AZULADEN?":GOSUB4
3530 GETI$:IFI$<>"L"ANDI$<>"D" ANDI$<>X$ THEN3530
3540 IFI$=X$ THEN3210
3550 IFI$="L" THEN EX=0
3560 PRINT#5,"I"
3570 OPEN6,8,2,(IN$+".*,S,R"):GET#6,I$
3580 : GOSUB4880:IFE<>0 THEN3210
3590 INPUT#6,A$:AV=VAL(A$):I=EX
3600 IFI-EX<AVANDI<VM THENINPUT#6,P$:SYST1,VA+I*L1:INPUT#6,P$:SYST1,VA+I*L1+L2
3610 IFI-EX<AVANDI<VM THENI=I+1:SYSP1,I:GOTO3600
3620 CLOSE6:EX=I:D$=IN$
3630 IFI<VM THENP$="         [204]\SCHE [210]ESTSPEICHER...":GOSUB4
3640 IFI<VM THENP$="":FORZ=ITOVM-1:SYST1,VA+Z*L1:SYST1,VA+Z*L1+L2:SYSP2,Z+1:NEXTZ
3650 GOTO3210
3660 :
3670 IY=8:IX=3:IM=12:IN$=D$:POKE646,F(3):GOSUB2860:POKE646,F(2)
3680 IFI$=X$ OR IN$="" THEN3210
3690 D$=LEFT$(IN$+L$,12)
3700 PRINT#5,"I":PRINT#5,("S0:"+LEFT$(D$,12)+"*")
3710 OPEN6,8,2,(D$+"."+RIGHT$(" "+STR$(EX),3)+",S,W")
3720 : GOSUB4880:IFE<>0 THEN3210
3730 PRINT#6,(STR$(EX)):I=0
3740 B$=CHR$(34):P$=LEFT$(L$,L)
3750 SYS T2,VA+I*L1:PRINT#6,(B$+LEFT$(P$,PEEK(VA+I*L1))+B$)
3760 SYS T2,VA+I*L1+L2:PRINT#6,(B$+LEFT$(P$,PEEK(VA+I*L1+L2))+B$)
3770 I=I+1:SYS P2,I:IFI<EX THEN3750
3780 CLOSE6:GOTO3210
3790 :
3800 PRINT#5,"I":GOSUB4880:IFE<>0 THEN3110
3810 SYS DI,DA
3820 DD=PEEK(828):H=0:Y=0:GOTO3150
3830 :
3840 POKE53280,F(0):POKE646,F(2):POKE53281,F(1):PRINT"[147]":SYS FI,55296,56296,F(2)
3850 P$=" [196]RUCKERCODES [NDERN OD. [210]ETURN DR]CKEN":GOSUB3:P$="":GOSUB3
3860 PRINT"";:P$="  [218]EICHEN(CODE):    [196]RUCKERCODE:":GOSUB3
3870 IX=16:IY=1:IM=3:GOSUB2840:IFI$=X$ THEN3150
3880 IFIN$="" THEN3930
3890 IFLEN(IN$)>1 THENP=VAL(IN$):IFP<0 ORP>255 THEN3860
3900 IFLEN(IN$)=1 THENP=ASC(IN$)
3910 IN$=STR$(PEEK(C2+P)):IX=32:IY=1:IM=3:GOSUB2850:IFI$=X$THEN3150
3920 POKEC2+P,VAL(IN$):GOTO3860
3930 PRINTLEFT$(H$,6);:P$=" [196]RUCKERCODES ZUR [211]CHRIFTEINSTELLUNG:":GOSUB3
3940 P$="  [201]NIT    :":GOSUB3
3950 IX=11:IY=3:IM=28:IN$=CO$:GOSUB2860:IFI$=X$ THEN3150
3960 CO$=IN$:A=C2+256:GOSUB4310:IFOK=0 THEN3950
3970 PRINTLEFT$(H$,10);:P$="  [211]PALTE 1:":GOSUB3
3980 IY=4:IN$=LI$:GOSUB2860:IFI$=X$ THEN3150
3990 LI$=IN$:A=C2+256+21:GOSUB4310:IFOK=0 THEN3980
4000 PRINTLEFT$(H$,12);:P$="  [211]PALTE 2:":GOSUB3
4010 IY=5:IN$=RE$:GOSUB2860:IFI$=X$ THEN3150
4020 RE$=IN$:A=C2+256+42:GOSUB4310:IFOK=0 THEN4010
4030 :
4040 PRINTLEFT$(H$,14);:P$=" [194]LATTBEGRENZUNGEN IN [218]EICHEN/[218]EILEN:":GOSUB3
4050 P$="  [194]LATTL[NGE   :     [204]INKER [210]AND  :":GOSUB3
4060 IX=16:IY=7:IM=3:IN$=STR$(LB):GOSUB2850:IFI$=X$ THEN3150
4070 LB=VAL(IN$):IFLB<1 THEN4060
4080 IX=35:IN$=STR$(RL):GOSUB2850:IFI$=X$ THEN3150
4090 RL=VAL(IN$):IFRL<0ORRL>121 THEN4080
4100 PRINTLEFT$(H$,18);:P$="  [207]BERER [210]AND  :     [213]NTERER [210]AND :":GOSUB3
4110 IX=16:IY=8:IN$=STR$(RO):GOSUB2850:IFI$=X$ THEN3150
4120 RO=VAL(IN$):IFRO<0OR1+RO>LB THEN4110
4130 IX=35:IY=8:IN$=STR$(RU):GOSUB2850:IFI$=X$ THEN3150
4140 RU=VAL(IN$):IFRU<0OR1+RO+RU>LB THEN4130
4150 PRINTLEFT$(H$,20);:P$=" [196]RUCKER:":GOSUB3
4160 P$="  [199]ER[TEADRESSE:     [211]EKUND[RADR. :":GOSUB3
4170 IX=16:IY=10:IN$=STR$(GA):GOSUB2850:IFI$=X$ THEN3150
4180 GA=VAL(IN$):IFGA<0ORGA>15 THEN4170
4190 IX=35:IN$=STR$(SA):GOSUB2850:IFI$=X$ THEN3150
4200 SA=VAL(IN$):IFSA<0ORSA>255 THEN4190
4210 P$="        [208]ARAMETER SPEICHERN?":GOSUB4
4220 IX=29:IY=11:IM=1:GOSUB2840:IFI$=X$ THEN3150
4230 IFIN$="J" THENGOSUB4790:IFE<>0 THEN4210
4240 P$="          [210]ETURN ZUM [196]RUCKEN":GOSUB4
4250 GETI$:IFI$<>CHR$(13)ANDI$<>X$ THEN4250
4260 E=0:P=PEEK(768):IFI$=X$ THEN3150
4270 PRINT"":OPEN7,GA,SA:POKE768,185:PRINT#7,"";:CLOSE7:POKE768,P
4280 IFST=-128 THENP$="         [196]RUCKER NICHT AKTIV!":GOSUB4:GOSUB4900:GOTO4240
4290 E=E+1:ON E GOTO4270,4270,4400
4300 :
4310 IFRIGHT$(IN$,1)=" " THENIN$=LEFT$(IN$,LEN(IN$)-1):GOTO4310
4320 A$=IN$+",":I=1:P=1:Q=0
4330 IFMID$(A$,I,1)<>","ORI=P THEN4370
4340 X=VAL(MID$(A$,P,I-P)):P=I+1:Q=Q+1
4350 IFX<0ORX>255 THENOK=0:RETURN
4360 POKE A+Q,X
4370 IFI<LEN(A$) THENI=I+1:GOTO4330
4380 POKE A,Q:OK=1:RETURN
4390 :
4400 OPEN 7,GA,SA
4410 Z=0:I=0
4420 IFI<PEEK(C2+256) THENI=I+1:PRINT#7,CHR$(PEEK(C2+256+I));:GOTO4420
4430 A$=D$:B$="":GOSUB4620
4440 A$="":B$="":GOSUB4620
4450 P=0
4460 P$=LEFT$(L$,L):A2$="":B2$=""
4470 SYS T2,VA+P*L1:A$=LEFT$(P$,29)
4480 I=30:IF PEEK(VA+P*L1)<30 THEN4510
4490 I=I-1:IFMID$(P$,I,1)<>"[183]"ANDMID$(P$,I,1)<>"[184]"ANDMID$(P$,I,1)<>" "ANDI>10THEN4490
4500 A$=LEFT$(P$,I):A2$=" "+MID$(P$,I+1,28)
4510 SYS T2,VA+P*L1+L2:B$=LEFT$(P$,29)
4520 I=30:IF PEEK(VA+P*L1+L2)<30 THEN4550
4530 I=I-1:IFMID$(P$,I,1)<>"[183]"ANDMID$(P$,I,1)<>"[184]"ANDMID$(P$,I,1)<>" "ANDI>10THEN4530
4540 B$=LEFT$(P$,I):B2$=" "+MID$(P$,I+1,28)
4550 GOSUB4620
4560 IFA2$<>""ORB2$<>"" THENA$=A2$:B$=B2$:GOSUB4620
4570 GETI$:IFI$=X$ THEN4600
4580 P=P+1:IFP<EX THEN4460
4590 IFZ<LB THENZ=Z+1:PRINT#7,CHR$(PEEK(C2+32)):GOTO4590
4600 CLOSE7:GOTO3150
4610 :
4620 IFZ<RO THENZ=Z+1:PRINT#7,CHR$(PEEK(C2+32)):GOTO4620
4630 IFZ>=LB-RU AND Z<LB THENZ=Z+1:PRINT#7,CHR$(PEEK(C2+32)):GOTO4630
4640 IFZ=LB THENZ=0:GOTO4620
4650 Z=Z+1:I=0
4660 IFI<PEEK(C2+277) THENI=I+1:PRINT#7,CHR$(PEEK(C2+277+I));:GOTO4660
4670 P$=LEFT$(L$,RL)+LEFT$(A$+L$,29):SYS KO:PRINT#7,P$;
4680 I=0
4690 IFI<PEEK(C2+298) THENI=I+1:PRINT#7,CHR$(PEEK(C2+298+I));:GOTO4690
4700 P$="  "+LEFT$(B$+L$,29):SYS KO:PRINT#7,P$
4710 RETURN
4720 :
4730 :
4740 REM EXIT
4750 :
4760 GOSUB4940:IFI<>13 THEN630
4770 SYS64738
4780 :
4790 PRINT#5,"I":PRINT#5,"S0:STATUS"
4800 OPEN6,8,2,"STATUS,S,W"
4810 GOSUB4880:IF E<>0 THENRETURN
4820 FORI=0TO4:PRINT#6,F(I):NEXTI
4830 PRINT#6,GA:PRINT#6,SA:PRINT#6,LB:PRINT#6,RO:PRINT#6,RU:PRINT#6,RL
4840 B$=CHR$(34):PRINT#6,B$+CO$+B$:PRINT#6,B$+LI$+B$:PRINT#6,B$+RE$+B$
4850 FORI=0TO255:PRINT#6,CHR$(PEEK(C2+I));:NEXTI
4860 CLOSE6:RETURN
4870 :
4880 INPUT#5,E,E$,E1,E2:IFE=0 THENRETURN
4890 CLOSE6:P$=" [190][191]"+STR$(E)+" "+E$+";"+STR$(E1)+STR$(E2)
4900 GOSUB4:I=180:POKE198,0
4910 IFPEEK(198)=0ANDI>0 THENI=I-1:GOTO4910
4920 P$="":GOSUB4:RETURN
4930 :
4940 PP$=P$:X1=PEEK(211):Y1=PEEK(214):POKE646,F(2)
4950 P$="        [205]IT [210]ETURN BEST[TIGEN!"
4960 GOSUB4900
4970 GET I$:I=ASC(I$+" ")
4980 POKE211,X1:POKE214,Y1:SYS58640:P$=PP$:RETURN
4990 :
5000 OPEN1,8,15,"S0:PROGRAM":CLOSE1
5010 SAVE"PROGRAM",8:VERIFY"PROGRAM",8
5020 :
5030 DATA"[207]PTIONEN  ",
5040 DATA"[204]ERNEN    ","  [204]ERNEN  "
5050 DATA"[197]INGEBEN  "," [197]INGEBEN "
5060 DATA"[221]BERTRAGEN","[221]BERTRAGEN"
5070 DATA"[197]XIT      ","   [197]XIT   "
5080 :
5090 DATA"SEHR GUT    "
5100 DATA"GUT         "
5110 DATA"BEFRIEDIGEND"
5120 DATA"AUSREICHEND "
5130 DATA"MANGELHAFT  "
5140 DATA"UNGEN]GEND  "