Maclife 12/MACLIFE12-No-92-1996.ISO.7z/MACLIFE12-No-92.ISO/CD-ROM MACLIFE12/Programming/Simple Document Construction

Text File | 1996-02-11 | 1.4 KB | 53 lines | [TEXT/ToyS]

tell application "QuarkXPress 3.3 Demo"
    activate
    make new document at beginning

    tell first document
        set view scale to fit page in window

        tell page 1
            make new text box at beginning
            tell first text box
                set bounds to {"2 cm", "5 cm", "8 cm", "19 cm"}
                set vertical justification to bottom justified
                tell first story
                    set contents of it to "Sample Text"
                    set font to "Osaka"
                    set size of first word to 30
                    set style of first word to all caps
                    set size of second word to 120
                    set style of second word to italic
                end tell
            end tell

            make new text box at end
            tell second text box
                set bounds to {"8.5 cm", "5 cm", "28.5 cm", "18 cm"}
                set first story to (choose file with prompt "TEXTファイルを選択してください")
                tell first story
                    set size to 12
                    set justification to fully justified
                    set font to "Osaka"
                end tell
            end tell

            make new picture box at beginning
            tell first picture box
                set bounds to {"10 cm", "20 cm", "20 cm", "32 cm"}
                set first image to (choose file with prompt "TIFFファイルを選択してください")
                tell first image
                    set scale to {"150", "150"}
                end tell
            end tell

            make new line box at end
            tell first line box
                set left point to {"8.2 cm", "2 cm"}
                set right point to {"8.2 cm", "32 cm"}
                set width to 3
                set style to dotted line
            end tell
        end tell
    end tell
end tell