home *** CD-ROM | disk | FTP | other *** search
/ DP Tool Club 16 / CD_ASCQ_16_0994.iso / news / 4611 / fw16d.ins / INCLUDE / DIALOG.CH < prev    next >
Text File  |  1994-06-13  |  3KB  |  74 lines
  1. #ifndef _DIALOG_CH
  2. #define _DIALOG_CH
  3.  
  4. //----------------------------------------------------------------------------//
  5. // Microsoft 3D Look
  6.  
  7. #xcommand SET <look_3d: 3DLOOK, LOOK3D, LOOK 3D, 3D LOOK> <on:ON,OFF,&> => ;
  8.           Set3DLook( Upper(<(on)>) == "ON" )
  9.  
  10. //----------------------------------------------------------------------------//
  11. // Resources
  12.  
  13. #xcommand SET RESOURCES TO <cName1> [,<cName2>] ;
  14.        => ;
  15.           [ SetResources( <cName2> ); ] SetResources( <cName1> )
  16.  
  17. #xcommand SET RESOURCES TO => FreeResources()
  18.  
  19. //----------------------------------------------------------------------------//
  20.  
  21. #xcommand SET HELPFILE TO <cFile>    => SetHelpFile( <cFile> )
  22. #xcommand SET HELP TOPIC TO <cTopic> => HelpSetTopic( <cTopic> )
  23.  
  24. //----------------------------------------------------------------------------//
  25. // Loading strings/or other Types from Resources
  26.  
  27. #xcommand REDEFINE <uVar> ;
  28.              [ AS <type: CHARACTER, NUMERIC, LOGICAL, DATE> ] ;
  29.              [ <resource: RESOURCE, RESNAME, NAME> <nIdRes> ] ;
  30.        => ;
  31.           <uVar> := LoadValue( <nIdRes>, [Upper(<(type)>)], <uVar> )
  32.  
  33. //----------------------------------------------------------------------------//
  34.  
  35. #xcommand DEFINE DIALOG <oDlg> ;
  36.              [ <resource: NAME, RESNAME, RESOURCE> <cResName> ] ;
  37.              [ TITLE <cTitle> ] ;
  38.              [ FROM <nTop>, <nLeft> TO <nBottom>, <nRight> ] ;
  39.              [ <lib: LIBRARY, DLL> <hResources> ] ;
  40.              [ <vbx: VBX> ] ;
  41.              [ STYLE <nStyle> ] ;
  42.              [ <color: COLOR, COLORS> <nClrText> [,<nClrBack> ] ] ;
  43.              [ BRUSH <oBrush> ] ;
  44.              [ <of: WINDOW, DIALOG, OF> <oWnd> ] ;
  45.              [ <pixel: PIXEL> ] ;
  46.              [ ICON <oIco> ] ;
  47.        => ;
  48.           <oDlg> = TDialog():New( <nTop>, <nLeft>, <nBottom>, <nRight>,;
  49.                  <cTitle>, <cResName>, <hResources>, <.vbx.>, <nStyle>,;
  50.                  <nClrText>, <nClrBack>, <oBrush>, <oWnd>, <.pixel.>,;
  51.                  <oIco> )
  52.  
  53. #xcommand ACTIVATE DIALOG <oDlg> ;
  54.              [ ON LEFT CLICK <uClick> ] ;
  55.              [ ON MOVE <uMoved> ] ;
  56.              [ ON PAINT <uPaint> ] ;
  57.              [ <center: CENTER, CENTERED> ] ;
  58.              [ <NonModal: NOWAIT, NOMODAL> ] ;
  59.              [ WHEN <uWhen> ] ;
  60.              [ VALID <uValid> ] ;
  61.              [ ON INIT <uInit> ] ;
  62.              [ ON RIGHT CLICK <uRClicked> ] ;
  63.         => ;
  64.           <oDlg>:Activate( <oDlg>:bLClicked [ := <{uClick}> ], ;
  65.                            <oDlg>:bMoved    [ := <{uMoved}> ], ;
  66.                            <oDlg>:bPainted  [ := <{uPaint}> ], ;
  67.                            <.center.>, [{|Self|<uValid>}],;
  68.                            [ ! <.NonModal.> ], [{|Self|<uInit>}],;
  69.                            [ <{uRClicked}> ], [{|Self|<uWhen>}] )
  70.  
  71. //----------------------------------------------------------------------------//
  72.  
  73. #endif
  74.