home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS 1992 June / SIMTEL_0692.cdr / msdos / pctech / pctj1188.arc / SCREENOR.ASM < prev    next >
Assembly Source File  |  1988-09-06  |  7KB  |  156 lines
  1. ; Microsoft C: 
  2. ; 
  3. ;       void ScreenOrigin( x, y ); 
  4. ;               int     x, y;           /* pixel x,y coordinates */ 
  5. ; 
  6.  
  7. _TEXT           SEGMENT byte public 'CODE' 
  8.                 ASSUME  cs:_TEXT 
  9.  
  10.                 PUBLIC  _ScreenOrigin 
  11. _ScreenOrigin   PROC    near 
  12.  
  13.                 push    bp              ; preserve caller registers 
  14.                 mov     bp,sp 
  15.  
  16. ; setup for pixel x-coordinate: 
  17. ;       - determine 8 or 9 bits per pixel by examining bit 0 in 
  18. ;            Sequencer Clocking Mode register 
  19. ;       - compute value for Attribute Controller Horizontal Pel Pan register 
  20.  
  21.                 mov     dx,3C4h         ; DX = port for Sequencer index register 
  22.                 mov     al,1 
  23.                 cli                     ; disable interrupts 
  24.                 out     dx,al           ; select Sequencer Clocking Mode reg 
  25.                 jmp     $+2             ; wait for Sequencer to respond 
  26.  
  27.                 inc     dx 
  28.                 in      al,dx 
  29.                 sti                     ; set interrupts 
  30.                 and     al,1            ; isolate low-order bit 
  31.                 mov     cl,9 
  32.                 sub     cl,al           ; CL = 8 or 9 (number of pixels/byte) 
  33.  
  34.                 mov     ax,[bp+4]       ; AX = pixel x-coordinate 
  35.                 div     cl              ; AH = bit offset in byte 
  36.                                         ; AL = byte offset in row 
  37.                 cmp     cl,8 
  38.                 je      L01             ; jump if 8 pixels/byte 
  39.  
  40.                 dec     ah              ; AH = -1, 0-7 
  41.                 jns     L01             ; if AH = -1 ... 
  42.                 mov     ah,8            ; ... set AH = 8 
  43.  
  44. L01:            mov     cl,ah           ; CL = Horizontal Pel Pan value 
  45.                 mov     bl,al 
  46.                 xor     bh,bh           ; BX = byte offset in row 
  47.  
  48. ; setup for pixel y-coordinate: 
  49. ;       - use value in CRTC Max Scan Line register to compute value for 
  50. ;            CRTC Preset Row Scan register 
  51. ;       - read CRTC Offset register to determine logical width of video buffer; 
  52. ;            use this to compute value for CRTC Start Address registers 
  53.  
  54.                 mov     ax,40h 
  55.                 mov     es,ax           ; ES -> video BIOS data segment 
  56.  
  57.                 mov     dx,es:[63h]     ; DX = port for CTRC index reg 
  58.                 mov     al,9            ; AL = Max Scan Line reg number 
  59.                 cli 
  60.                 out     dx,al 
  61.  
  62.                 push    bx              ; preserve BX (byte offset in row) 
  63.                 push    dx              ; preserve DX (CRTC index reg port) 
  64.  
  65.                 inc     dx 
  66.                 in      al,dx           ; AL = Max Scan Line value 
  67.                 sti 
  68.  
  69.                 and     ax,1Fh          ; AX = value from bits 0-4 
  70.                 inc     ax 
  71.                 mov     bx,ax           ; DX = scan lines per character 
  72.  
  73.                 xor     dx,dx 
  74.                 mov     ax,[bp+6]       ; AX = pixel y-coordinate 
  75.                 div     bx              ; AX = character row 
  76.                                         ; DL = value for Preset Row Scan reg 
  77.                 mov     ch,dl           ; save in CH 
  78.                 mov     bx,ax           ; save character row in BX 
  79.  
  80.                 pop     dx              ; DX = port for CRTC index reg 
  81.                 push    dx 
  82.                 mov     al,13h          ; AL = Offset reg number 
  83.                 cli                     ; disable interrupts 
  84.                 out     dx,al 
  85.                 jmp     $+2 
  86.  
  87.                 inc     dx 
  88.                 in      al,dx           ; AL = Offset reg value 
  89.                 sti                     ; enable interrupts 
  90.  
  91.                 xor     ah,ah 
  92.                 mul     bx              ; AX = word offset of start of row 
  93.                 shl     ax,1            ; AX = byte offset of start of row 
  94.  
  95.                 pop     dx              ; DX = port for CRTC index reg 
  96.                 pop     bx              ; BX = byte offset in row 
  97.                 add     bx,ax           ; BX = buffer offset 
  98.  
  99.                 add     dl,6            ; video status port (3BAH or 3DAH) 
  100.  
  101. ; update CRTC Start Address registers 
  102.  
  103. L02:            in      al,dx           ; wait for start of vertical retrace 
  104.                 test    al,8 
  105.                 jz      L02 
  106.  
  107. L03:            in      al,dx           ; wait for end of vertical retrace 
  108.                 test    al,8 
  109.                 jnz     L03 
  110.  
  111.                 cli                     ; disable interrupts 
  112.                 sub     dl,6            ; DX = 3B4H or 3D4H 
  113.  
  114.                 mov     ah,bh           ; AH = value for Start Address High 
  115.                 mov     al,0Ch          ; AL = Start Address High reg number 
  116.                 out     dx,ax           ; update this register 
  117.  
  118.                 mov     ah,bl           ; AH = value for Start Address Low 
  119.                 inc     al              ; AL = Start Address Low reg number 
  120.                 out     dx,ax           ; update this register 
  121.                 sti                     ; enable interrupts 
  122.  
  123. ; update CRTC Preset Row Scan and 
  124. ;  Attribute Controller Horizontal Pel Pan registers 
  125.  
  126.                 add     dl,6            ; DX = video status port 
  127.  
  128. L04:            in      al,dx           ; wait for start of vertical retrace 
  129.                 test    al,8 
  130.                 jz      L04 
  131.  
  132.                 cli                     ; disable interrupts 
  133.                 sub     dl,6            ; DX = 3B4H or 3D4H 
  134.                 mov     ah,ch           ; AH = value for Preset Row Scan reg 
  135.                 mov     al,8            ; AL = Preset Row Scan reg number 
  136.                 out     dx,ax           ; update this register 
  137.  
  138.                 mov     dl,0C0h         ; DX = 3C0h (Attribute Controller port) 
  139.                 mov     al,13h OR 20h   ; AL bit 0-4 = Horiz Pel Pan reg number 
  140.                                         ; AL bit 5 = 1 
  141.                 out     dx,al           ; write Attribute Controller Address reg 
  142.                                         ;  (The Attribute Controller address 
  143.                                         ;    flip-flop has been reset by the 
  144.                                         ;    IN at L04.) 
  145.                 mov     al,cl           ; AL = value for Horiz Pel Pan reg 
  146.                 out     dx,al           ; update this register 
  147.                 sti                     ; re-enable interrupts 
  148.  
  149.                 mov     sp,bp 
  150.                 pop     bp 
  151.                 ret 
  152.  
  153. _ScreenOrigin   ENDP 
  154.  
  155. _TEXT           ENDS 
  156.