home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS 1992 December / simtel1292_SIMTEL_1292_Walnut_Creek.iso / msdos / pcmag / pp704.arc / ITOA.ASM next >
Assembly Source File  |  1987-12-15  |  2KB  |  66 lines
  1.         name    itoa
  2.         title   ITOA - integer to ASCII
  3.         page    55,132
  4.  
  5. ;
  6. ; ITOA.ASM --- Convert 16-bit integer to ASCII
  7. ;
  8. ; Copyright (c) 1987 Ziff Communications Co.
  9. ; Ray Duncan
  10. ;
  11. ; Call with:    AX    = 16-bit integer
  12. ;               DS:SI = buffer to receive string,
  13. ;                       must be at least 6 bytes long
  14. ;               CX    = radix
  15. ;
  16. ; Returns:      DS:SI = address of converted string
  17. ;               AX    = length of string
  18. ; 
  19. ; Since test for value = zero is made after a digit
  20. ; has been stored, the resulting string will always
  21. ; contain at least one significant digit.
  22.  
  23. _TEXT   segment word public 'CODE'
  24.  
  25.         assume  cs:_TEXT
  26.  
  27.         public  itoa            ; make ITOA available to Linker
  28.  
  29. itoa    proc    near            ; convert long int to ASCII.
  30.  
  31.         add     si,6            ; advance to end of buffer
  32.         push    si              ; and save that address.
  33.         or      ax,ax           ; test sign of 16-bit value,
  34.         pushf                   ; and save sign on stack.
  35.         jns     itoa1           ; jump if value was positive.
  36.         neg     ax              ; find absolute value.
  37.  
  38. itoa1:  cwd                     ; divide value by radix to extract
  39.         div     cx              ; next digit for forming string.
  40.  
  41.         add     dl,'0'          ; convert remainder to ASCII digit
  42.         cmp     dl,'9'          ; in case converting to hex ASCII,
  43.         jle     itoa2           ; jump if in range 0-9,
  44.         add     dl,'A'-'9'-1    ; correct digit if in range A-F.
  45.  
  46. itoa2:  dec     si              ; back up through buffer
  47.         mov     [si],dl         ; store this character into string.
  48.         or      ax,ax
  49.         jnz     itoa1           ; no, convert another digit.
  50.  
  51.         popf                    ; was original value negative?
  52.         jns     itoa3           ; no, jump
  53.  
  54.         dec     si              ; yes,store sign into output string.
  55.         mov     byte ptr [si],'-'
  56.  
  57. itoa3:  pop     ax              ; calculate length of string
  58.         sub     ax,si
  59.         ret                     ; back to caller.
  60.  
  61. itoa    endp
  62.  
  63. _TEXT   ends
  64.  
  65.         end
  66.