home *** CD-ROM | disk | FTP | other *** search
/ Frozen Fish 1: Amiga / FrozenFish-Apr94.iso / bbs / alib / d3xx / d358 / scaniff.lha / ScanIFF / ScanIFF.asm < prev    next >
Assembly Source File  |  1990-06-12  |  10KB  |  254 lines
  1. ;
  2. ;   IFFscan - IFF file scanner - Jim Butterfield.  January 12/90.
  3.  
  4. ; Exec library calls
  5. _LVOOpenLibrary       EQU -$228
  6. _LVOCloseLibrary      EQU -$19E
  7. _LVOSetSignal         EQU -$132
  8. ; DOS library calls
  9. _LVOSeek              EQU -$42
  10. _LVOOutput            EQU -$3C
  11. _LVOWrite             EQU -$30
  12. _LVORead              EQU -$2A
  13. _LVOClose             EQU -$24
  14. _LVOOpen              EQU -$1E
  15. ;
  16. BufSize EQU 10
  17. ;-- Initial setup:
  18. Startup     move.l a0,a4       ; Remember ptr to argument line. cf MOVEA
  19.             move.b #0,-$1(a0,d0.W)   ; binary zero at end
  20.             lea    dosname(pc),a1    ; Name 'dos.library'.
  21.             clr.l  d0                ;   Any version (0)
  22.             move.l $4,a6             ;   Using Exec library
  23.             jsr    _LVOOpenLibrary(a6)  ;   Open Dos library.
  24.             move.l d0,a6             ; Remember DosBase ptr.
  25.             tst.l  d0                ; Check for error (d0=0 means
  26.             beq.s  StartupQuit       ;      dos not opened)
  27.             bsr.s  DOSinit
  28.             move.l a6,a1             ;-Specify Dos library in a1;
  29.             move.l $4,a6             ;   then using Exec library,
  30.             jsr    _LVOCloseLibrary(a6)    ;   close Dos library.
  31. StartupQuit rts                      ; End of Program
  32. ;
  33. ;-- Get CLI outhandle:
  34. DOSinit     jsr    _LVOOutput(a6)    ;   get CLI outhandle,
  35.             move.l d0,d7             ;   & then remember it.
  36. ;
  37. ; -- Skin leading spaces:
  38. skipspc     move.l a4,d1             ; filename start
  39.             cmp.b  #$20,(a4)+        ; space?
  40.             beq.s  skipspc
  41.             move.l #1005,d2          ; MODE_OLDFILE (for reading)
  42.             jsr    _LVOOpen(a6)
  43.             move.l d0,d6             ; file inhandle
  44.             beq.s  FileNot           ; no good, quit
  45.             link   a5,#-$1C
  46.             bsr.s  ScanFile          ; the main job
  47.             unlk   a5
  48.             move.l d6,d1             ; use the handle..
  49.             jsr    _LVOClose(a6)     ; to close the file
  50. DOSquit     rts                      ;   exit program.
  51. FileNot     move.l d7,d1             ; handle
  52.             lea    FNF.MSG(pc),a0 
  53.             move.l a0,d2     
  54.             moveq  #FNFlen,d3
  55.             jmp    _LVOWrite(a6)
  56. ;
  57. ; DOS is open and we have our in/out handles.
  58. ; Global stack definitions
  59. FileP   EQU -$4
  60. DosBase EQU -$8
  61. Type    EQU -$C
  62. Abort   EQU -$10
  63. String  EQU -$1C     ; 12 byte work area
  64. ; Look for 'FORM' or other drawer types
  65. ScanFile:   move.l a6,DosBase(a5)
  66.             moveq  #1,d4             ; start at Level 1
  67.             moveq  #0,d0
  68.             move.l d0,Abort(a5)      ; Ctrl-C trap
  69.             move.l d0,FileP(a5)      ; file position=start
  70.             bsr    ReadType
  71.             tst.l  d5                ; is it a drawer?
  72.             bne.s  GotDrawer         ; yes, exit
  73. ; First four characters are not valid type.  Give up.
  74.             move.l d7,d1             ;output handle
  75.             lea    NotIFF.MSG(pc),a0  ;message to
  76.             move.l a0,d2             ;       buffer
  77.             moveq  #NotIFFlen,d3     ;length
  78.             jsr    _LVOWrite(a6)
  79.             bra.s  SFexit
  80. ;
  81. GotDrawer   bsr.s  DoBlock           ; recursive analysis job
  82.             tst.l  Abort(a5)
  83.             beq.s  SFexit
  84.             move.l d7,d1             ;output handle
  85.             lea    CtrlCMess(pc),a0  ;message to
  86.             move.l a0,d2             ;       buffer
  87.             moveq  #3,d3             ;length
  88.             jsr    _LVOWrite(a6)
  89. SFexit      rts                       ; job complete
  90. ; D4=Recursion level      D5=Drawer Flag
  91. ; D6=Inhandle (file)      D7=Outhandle (screen)
  92. ; A4=Local Stack Frame
  93. ; A5=Global Stack Frame   A6=DosLibrary
  94. ; 
  95. BSize       EQU     -4
  96. CSize       EQU     -8
  97. FileF       EQU     -12
  98. XType       EQU     -$10
  99. DoBlock     link    a4,#-$10          ; local variables
  100. ; read Size of this block
  101.             move.l d6,d1             ; input file handle
  102.             lea    BSize(a4),a2      ; input buff (stack) address
  103.             move.l a2,d2             ; .. to D2 for read
  104.             moveq  #4,d3             ; read 4 characters
  105.             add.l  d3,FileP(a5)      ; record file position
  106.             jsr    _LVORead(a6)      ; read 'em
  107.             move.l (a2),d0           ; take raw size
  108.             addq.l #1,d0             ; round up to even value
  109.             and.b  #$fe,d0
  110.             move.l d0,CSize(a4)      ; store rounded value
  111.             move.l FileP(a5),d1      ; start point this chunk
  112.             add.l  d1,d0             ; log end point this chunk
  113.             move.l d0,FileF(a4)
  114.             tst.w  d5                ; a drawer?
  115.             beq.s  NotDraw1
  116. ; read subType of the drawer
  117.             move.l d6,d1             ; input file handle
  118.             lea    XType(a4),a0      ; input buff (stack) address
  119.             move.l a0,d2             ; .. to D2 for read
  120.             moveq  #4,d3             ; read 4 characters
  121.             add.l  d3,FileP(a5)      ; record file position
  122.             jsr    _LVORead(a6)      ; read 'em
  123. ; print <indent> drawer Type <space> subType <newline>
  124.             bsr    ShowType
  125.             move.l d7,d1             ;output handle
  126.             lea    Spaces(PC),a0     ;message to
  127.             move.l a0,d2             ;       buffer
  128.             moveq  #1,d3             ;length=1 space
  129.             jsr    _LVOWrite(a6)
  130.             move.l d7,d1             ;output handle
  131.             lea    XType(a4),a0      ;message to
  132.             move.l a0,d2             ;       buffer
  133.             moveq  #4,d3             ;length
  134.             jsr    _LVOWrite(a6)
  135.             move.l d7,d1             ;output handle
  136.             lea    NewLine(PC),a0    ;message to
  137.             move.l a0,d2             ;       buffer
  138.             moveq  #1,d3             ;length=1 char
  139.             jsr    _LVOWrite(a6)
  140. ; Scan through size of drawer.  First, Check CTL-C
  141. NotDraw1    move.l 4,a6              ; set Exec libr
  142.             moveq  #0,d0
  143.             move.l #$1000,d1
  144.             jsr    _LVOSetSignal(a6) ;test CTRL-C
  145.             move.l DosBase(a5),a6    ;restore DOS libr
  146.             and.l  #$1000,d0
  147.             or.l   d0,Abort(a5)
  148.             tst.l  Abort(a5)
  149.             bne.s  EndSect
  150.             move.l FileP(a5),d0
  151.             cmp.l  FileF(a4),d0
  152.             bcc.s  EndSect
  153.             tst.w  d5                ; a drawer?
  154.             beq.s  NotDraw2
  155. ; Analyze drawer for sub elements - get Type!
  156.             bsr.s  ReadType
  157. ; recurse .. look inside outer drawer
  158.             addq   #1,d4
  159.             bsr    DoBlock
  160.             subq   #1,d4
  161.             moveq  #1,d5             ; restore old drawer type!
  162.             bra.s  NotDraw1
  163. ; found a non-drawer .. report it and position
  164. ; print <indent> Type <newline>
  165. NotDraw2    bsr.s  ShowType
  166.             move.l d7,d1             ;output handle
  167.             lea    NewLine(PC),a0    ;message to
  168.             move.l a0,d2             ;       buffer
  169.             moveq  #1,d3             ;length=1 char
  170.             jsr    _LVOWrite(a6)
  171. ; now position to FileP(a5)+CSize(a4)
  172.             move.l d6,d1             ;input handle
  173.             move.l FileF(a4),d2      ;new position
  174.             move.l d2,FileP(a5)      ; synchronize
  175.             moveq  #-1,d3            ;offset from start.file
  176.             jsr    _LVOSeek(a6)
  177.             bra.s  NotDraw1
  178. EndSect     unlk    a4
  179.             rts
  180. ; read Type and identify if drawer
  181. ReadType    move.l d6,d1             ; input file handle
  182.             lea    Type(a5),a2       ; input buff (stack) address
  183.             move.l a2,d2             ; .. to D2 for read
  184.             moveq  #4,d3             ; read 4 characters
  185.             add.l  d3,FileP(a5)      ; record file position
  186.             jsr    _LVORead(a6)      ; read 'em
  187. ; Look for 'FORM' or other drawer types
  188.             moveq  #1,d5             ; drawer?
  189.             moveq  #0,d0             ; zero table count
  190.             lea    Ttab,a0           ; start of table
  191.             move.l (a2),d1
  192. RTloop      cmp.l  0(a0,d0.w),d1     ; is it drawer?
  193.             beq.s  DrawerGot         ; yes, exit
  194.             addq.w #4,d0             ; try next type
  195.             cmp.w  #Ttlen,d0         ; any more?
  196.             bne.s  RTloop            ; yes, try it
  197.             moveq  #0,d5             ; not a drawer
  198. DrawerGot   rts
  199.  
  200. ; print <indent> Type..
  201. ShowType    move.l d7,d1             ;output handle
  202.             lea    Spaces(PC),a0     ;message to
  203.             move.l a0,d2             ;       buffer
  204.             move.l d4,d3             ; (Level) number of spaces
  205.             jsr    _LVOWrite(a6)
  206.             move.l d7,d1             ;output handle
  207.             lea    Type(a5),a0       ;message to
  208.             move.l a0,d2             ;       buffer
  209.             moveq  #4,d3             ;length
  210.             jsr    _LVOWrite(a6)
  211.             move.l BSize(a4),d0      ; size of block
  212. ; MakeAscii
  213.             lea    String(a5),a1     ; Address of string
  214.             moveq  #11,d2            ; size of string
  215. DigLoop     swap   d0                ; hi/lo swap
  216.             moveq  #0,d1
  217.             move.w d0,d1
  218.             beq.s  Skipper
  219.             divu   #10,d1
  220. Skipper     move.w d1,d0
  221.             swap   d0
  222.             move.w d0,d1
  223.             divu   #10,d1
  224.             move.w d1,d0
  225.             swap   d1
  226.             or.b   #$30,d1
  227.             move.b d1,0(a1,d2.w)
  228.             tst.l  d0
  229.             dbeq   d2,DigLoop
  230.             lea    0(a1,d2.w),a0
  231.             move.b #$20,-(a0)
  232.             move.l d7,d1             ; outhandle
  233.             moveq  #13,d3            ; max string size
  234.             sub.b  d2,d3             ; less unused
  235.             move.l a0,d2             ; num string address
  236. ; d2 string position, d3 length
  237.             jsr _LVOWrite(a6)
  238.             rts
  239.  
  240. Ttab        dc.b 'FORM'
  241.             dc.b 'CAT '
  242.             dc.b 'LIST'
  243.             dc.b 'PROP'
  244. Ttlen       EQU  *-Ttab
  245. FNF.MSG     dc.b 'File not found.',$a
  246. FNFlen      EQU  *-FNF.MSG
  247. NotIFF.MSG  dc.b 'Not an IFF file!',$a
  248. NotIFFlen   EQU  *-NotIFF.MSG
  249. Spaces      dc.b '                        '
  250. dosname     dc.b 'dos.library',0
  251. CtrlCMess   dc.b '^C'
  252. NewLine     dc.b $0a
  253.             end
  254.