home *** CD-ROM | disk | FTP | other *** search
/ Gold Fish 1 / GoldFishApril1994_CD2.img / d4xx / d420 / winman / arg.asm < prev    next >
Assembly Source File  |  1990-12-20  |  9KB  |  377 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * Adapted by Jorrit Tyberghein
  4. * 
  5. * Use the following command line to make the cli/workbench startup
  6. * asm -iINCLUDE: Arg.asm
  7. *
  8. * Use the following command line to make the resident startup
  9. * asm -dRESIDENT -iINCLUDE: -oArgR.o Arg.asm
  10. *
  11. * Use the following command line to make the cli startup
  12. * asm -dCLI -iINCLUDE: Arg.asm
  13. *
  14.     INCLUDE    "exec/types.i"
  15.     INCLUDE    "exec/alerts.i"
  16.     INCLUDE    "exec/nodes.i"
  17.     INCLUDE    "exec/lists.i"
  18.     INCLUDE    "exec/ports.i"
  19.     INCLUDE    "exec/libraries.i"
  20.     INCLUDE    "exec/tasks.i"
  21.     INCLUDE    "exec/memory.i"
  22.     INCLUDE    "exec/execbase.i"
  23.     INCLUDE    "libraries/dos.i"
  24.     INCLUDE    "libraries/dosextens.i"
  25.     INCLUDE    "workbench/startup.i"
  26.     INCLUDE    "exec/funcdef.i"
  27.     INCLUDE    "exec/exec_lib.i"
  28.     INCLUDE    "libraries/dos_lib.i"
  29.  
  30. MEMFLAGS            EQU    MEMF_CLEAR+MEMF_PUBLIC
  31. AbsExecBase        EQU    4
  32.  
  33. * some usefull macros:
  34.  
  35. callsys    macro
  36.             CALLLIB _LVO\1
  37.             endm
  38.     
  39.         xdef        _XCEXIT                * exit(code) is standard way to leave C.
  40.         xdef        _@XCEXIT
  41.     
  42.         xref        _LinkerDB            * linker defined base value
  43.         xref        __BSSBAS                * linker defined base of BSS
  44.         xref        __BSSLEN                * linker defined length of BSS
  45.     IFD RESIDENT
  46.         xref        _RESLEN
  47.         xref        _RESBASE
  48.         xref        _NEWDATAL
  49.         xref        __stack
  50.     ENDC
  51.     
  52. *       library references
  53.  
  54.         section text,code
  55.  
  56.         xref        _argmain                * Name of C program to start with.
  57.     
  58. start:
  59.         movem.l d1-d6/a0-a6,-(a7)
  60.  
  61.         move.l    a0,a2                    * save command pointer
  62.         move.l    d0,d2                    * and command length
  63.         lea        _LinkerDB,a4        * load base register
  64.         move.l    AbsExecBase.W,a6
  65.  
  66.     IFND RESIDENT
  67. ;We do not have to clear BSS because AmigaDOS 2.0 does this for us.
  68. ;        lea        __BSSBAS,a3            * get base of BSS
  69. ;        moveq        #0,d1
  70. ;        move.l    #__BSSLEN,d0        * get length of BSS in longwords
  71. ;        bra.s        clr_lp                * and clear for length given
  72. ;clr_bss:
  73. ;        move.l    d1,(a3)+
  74. ;clr_lp:
  75. ;        dbf        d0,clr_bss
  76.         move.l    a7,__StackPtr(A4)    * Save stack ptr
  77.         move.l    a6,_SysBase(A4)
  78.     ENDC
  79.     
  80.  
  81.     IFD RESIDENT
  82.         movem.l    d2,-(a7)
  83.         movem.l    a0-a2,-(a7)
  84.  
  85. *------ get the size of the stack,    if CLI use cli_DefaultStack
  86. *------                                        if WB use a7 - TC_SPLOWER
  87.         move.l    ThisTask(a6),A3
  88.         move.l    pr_CLI(A3),d1
  89.     IFND CLI
  90.         beq.s        fromwb
  91.     ENDC
  92.         lsl.l        #2,d1
  93.         move.l    d1,a0
  94.         move.l    cli_DefaultStack(a0),d1
  95.         lsl.l        #2,d1                    * # longwords -> # bytes
  96.     IFND CLI
  97.         bra.s        dostack
  98. fromwb:
  99.         move.l    a7,d1             
  100.         sub.l        TC_SPLOWER(a3),d1     
  101.     ENDC
  102. dostack:
  103.         moveq        #0,d2                    * use d2 as flag for newstack or not
  104.         move.l    #_RESLEN,d0
  105.         cmp.l        __stack(a4),d1        * This a4 is in the original 
  106.                     * set of data
  107.         bcc.s        nochange    
  108.         move.l    __stack(a4),d1
  109.         add.l        d1,d0                    * increase size of mem for new stack
  110.         moveq        #1,d2                    * set flag
  111.         
  112. nochange:
  113.         move.l    d1,a3                    * save stacksize to set up stack checking
  114.         move.l    #MEMFLAGS,d1
  115.         callsys    AllocMem
  116.         tst.l        d0
  117.         bne.s        ok1
  118.         movem.l    (a7)+,d2/a0-a2
  119.         rts
  120.  
  121. ok1:    move.l    d0,a0
  122.         move.l    d0,a2
  123.  
  124. ;a2 now has difference
  125.         move.l    d0,a1
  126.         move.l    #_NEWDATAL,d0
  127.         sub.l        #_RESBASE,a4
  128. ;copy data over
  129. cpy:
  130.         move.l    (a4)+,(a0)+
  131.         subq.l    #1,d0
  132.         bne.s        cpy
  133. ;a4 now points at number of relocs
  134.         move.l    (a4)+,d0
  135. reloc:
  136.         beq.s        nreloc
  137.         move.l    a1,a0
  138.         add.l        (a4)+,a0                * a0 now has add of reloc
  139.         add.l        (a0),a2
  140.         move.l    a2,(a0) 
  141.         move.l    a1,a2                    * restore offset
  142.         subq.l    #1,d0
  143.         bra.s        reloc
  144.  
  145. nreloc:
  146.         move.l    a1,a4                    * set up new base register
  147.         add.l        #_RESBASE,a4
  148.  
  149.         move.l    #_RESLEN,realdatasize(a4)
  150.         movem.l    (a7)+,a0-a2
  151.  
  152.         move.l    a6,_SysBase(A4)
  153.         tst.b        d2
  154.         movem.l    (a7)+,d2                * restore d2 
  155.         movem.l    a7,__StackPtr(A4)    * Save stack ptr (movem doesn't
  156.                                             * change flags)
  157.         beq.s        nochg2
  158.  
  159. *------ set up new stack
  160.         move.l    a4,d0
  161.         sub.l        #_RESBASE,d0
  162.         add.l        #_RESLEN,d0
  163.         add.l        __stack(a4),d0        * here a4 will be pointing at the
  164.                                             * new data, but _stack will be the
  165.                                             * same if all goes well
  166.  
  167.         sub.l        #128,d0                * 128 down for good measure
  168.         move.l    d0,a7
  169.         move.l    __stack(a4),d0
  170.         move.l    d0,4(a7)                * fill in size of new stack    
  171.         add.l        d0,realdatasize(a4)* need to know how much to free later
  172.  
  173. nochg2:
  174.  
  175.     ENDC
  176.  
  177. clrwb:
  178.     IFND CLI
  179.         clr.l        _WBenchMsg(A4)
  180.     ENDC
  181.  
  182. *-----  clear any pending signals
  183.         moveq        #0,d0
  184.         move.l    #$00003000,d1
  185.         callsys    SetSignal
  186.     
  187. *------ attempt to open DOS library:
  188.         lea        DOSName(PC),A1
  189.         moveq.l    #0,D0
  190.         callsys    OpenLibrary
  191.         move.l    D0,_DOSBase(A4)
  192.         bne.s        ok2
  193.         moveq.l    #100,d0
  194.         bra.w        exit2
  195.  
  196. ok2:
  197. *------ are we running as a son of Workbench?
  198.         move.l    ThisTask(a6),A3
  199.     IFND CLI
  200.         tst.l        pr_CLI(A3)
  201.         beq.s        fromWorkbench
  202.     ENDC
  203.     
  204. *=======================================================================
  205. *====== CLI Startup Code ===============================================
  206. *=======================================================================
  207. *
  208. * Entry: D2 = command length
  209. *            A2 = Command pointer
  210. fromCLI:
  211.     
  212. *------ find command name:
  213.         move.l    pr_CLI(a3),a0
  214.         add.l        a0,a0                    * bcpl pointer conversion
  215.         add.l        a0,a0
  216.         move.l    cli_CommandName(a0),a1
  217.         add.l        a1,a1                    * bcpl pointer conversion
  218.         add.l        a1,a1
  219.  
  220. *------ collect parameters:
  221.         move.l    d2,d0                    * get command line length
  222.         moveq.l    #0,d1
  223.         move.b    (a1)+,d1
  224.         move.l    a1,_ProgramName(A4)
  225.         add.l        d1,d0                    * add length of command name
  226.         addq.l    #1,d0                    * allow for space after command 
  227.  
  228.         clr.w        -(A7)                    * set null terminator for command line
  229.         addq.l    #3,D0                    * force to longword alligned number of bytes
  230.         andi.w    #$fffc,D0            * (round up)
  231.         addq.l    #2,d0                    * one extra word
  232.         sub.l        D0,A7                    * make room on stack for command line
  233.         subq.l    #6,D0
  234.         clr.l        0(A7,D0)
  235.  
  236. *------ copy command line onto stack
  237.         move.l    d2,d0                    * get command line length
  238.         subq.l    #1,d0
  239.         add.l        d1,d2
  240.  
  241. copy_line:
  242.         move.b    0(A2,D0.W),0(A7,D2.W)    * copy command line to stack
  243.         subq.l    #1,d2
  244.         dbf        d0,copy_line
  245.         move.b    #' ',0(a7,d2.w)    * add space between command and parms
  246.         subq.l    #1,d2
  247.  
  248. copy_cmd:
  249.         move.b    0(a1,d2.w),0(a7,d2.w)    * copy command name to stack
  250.         dbf        d2,copy_cmd
  251.         move.l    A7,A1
  252.         move.l    A1,-(A7)                * push command line address
  253.     IFND CLI
  254.         bra.s        main                    * call C entrypoint
  255.  
  256. *=======================================================================
  257. *====== Workbench Startup Code =========================================
  258. *=======================================================================
  259.  
  260. fromWorkbench:
  261.  
  262. *------ we are now set up.  wait for a message from our starter
  263.         lea        pr_MsgPort(A3),a0    * our process base
  264.         callsys    WaitPort
  265.         lea        pr_MsgPort(A3),a0    * our process base
  266.         callsys    GetMsg
  267.         move.l    d0,_WBenchMsg(a4)
  268.         move.l    d0,-(SP)
  269. *
  270.         move.l    d0,a2                    * get first argument
  271.         move.l    sm_ArgList(a2),d0
  272.         beq.s        do_cons
  273.         move.l    _DOSBase(a4),a6
  274.         move.l    d0,a0
  275.         move.l    wa_Lock(a0),d1
  276.         callsys    CurrentDir
  277. do_cons:
  278.         move.l    sm_ToolWindow(a2),d1    * get the window argument
  279.         beq.s        do_main
  280.         move.l    #MODE_OLDFILE,d2
  281.         callsys    Open
  282.         move.l    d0,stdin(a4)
  283.         beq.s        do_main
  284.         lsl.l        #2,d0
  285.         move.l    d0,a0
  286.         move.l    fh_Type(a0),pr_ConsoleTask(A3)
  287. do_main:
  288.         move.l    _WBenchMsg(A4),a0    * get address of workbench message
  289.         move.l    a0,-(a7)                * push argv
  290.         moveq        #0,d0
  291.         move.l    d0,-(a7)                * push argc
  292.         move.l    sm_ArgList(a0),a0    * get address of arguments
  293.         move.l    wa_Name(a0),_ProgramName(A4)    * get name of program
  294.     ENDC
  295.  
  296. *=============================================
  297. *------ common code --------
  298. *=============================================
  299.  
  300. main
  301.         jsr        _argmain(PC)        * call C entrypoint
  302.         moveq.l    #0,d0                    * set successful status
  303.         bra.s        exit2
  304. *
  305.  
  306. _XCEXIT:
  307.         move.l    4(SP),d0                * extract return code
  308. _@XCEXIT:
  309. exit2:
  310.         move.l    d0,-(a7)
  311.         move.l    AbsExecBase.W,a6
  312.         move.l    _DOSBase(A4),a1
  313.         callsys    CloseLibrary        * close Dos library
  314.  
  315. done_1c:
  316. *------ if we ran from CLI, skip workbench cleanup:
  317.     IFND CLI
  318.         tst.l        _WBenchMsg(A4)
  319.         beq.s        exitToDOS
  320.         move.l    stdin(a4),d1
  321.         beq.s        done_4
  322.         callsys    Close
  323. done_4:
  324.  
  325. *------ return the startup message to our parent
  326. *       we forbid so workbench can't UnLoadSeg() us
  327. *       before we are done:
  328.         move.l    AbsExecBase.W,A6
  329.         callsys    Forbid
  330.         move.l    _WBenchMsg(a4),a1
  331.         callsys    ReplyMsg
  332.     ENDC
  333.  
  334. *------ this rts sends us back to DOS:
  335. exitToDOS:
  336.     IFD RESIDENT
  337.         move.l    realdatasize(a4),d0
  338.         move.l    a4,a1
  339.         sub.l        #_RESBASE,a1
  340.         move.l    AbsExecBase.W,a6
  341.         move.l    (A7)+,d6
  342.         movea.l    __StackPtr(a4),a5
  343.         callsys    FreeMem
  344.         move.l    d6,d0
  345.         movea.l    a5,sp
  346.     ELSE
  347.         move.l    (A7)+,D0
  348.         movea.l    __StackPtr(a4),SP    * restore stack ptr
  349.     ENDC
  350.  
  351.         movem.l    (a7)+,d1-d6/a0-a6
  352.         rts
  353.  
  354.  
  355. DOSName
  356.         dc.b        'dos.library',0
  357.  
  358.         section __MERGED,BSS
  359. *
  360.         xdef        _SysBase,_WBenchMsg
  361.         xdef        _ProgramName,__StackPtr,_DOSBase
  362.  
  363. *
  364.     ifd RESIDENT
  365. realdatasize
  366.         ds.b        4                        * size of memory allocated for data +
  367.                                             * possible stack
  368.     endc
  369.  
  370. _SysBase            ds.b    4
  371. _WBenchMsg        ds.b    4
  372. __StackPtr        ds.b    4
  373. stdin                ds.b    4
  374. _DOSBase            ds.b    4
  375. _ProgramName    ds.b    4
  376.         END
  377.