Gold Fish 2/goldfish_vol2_cd1.bin/files/comm/fido/spot/rexx/afmpe.rexx

OS/2 REXX Batch file | 1994-01-15 | 5KB | 187 lines

/* AreaFixMan.prefs.rexx © 1993 PSR Software
 * $VER: AreaFixMan.prefs v1.0 (08-01-93)
 *  See AreaFixMan.prefs documentation
 * FOR AREAFIXMAN PREFS VERSIONS 2.6+
 * Will update old formats to enable use of ANNOUNCE
 * feature.
 */

PREF='AreaFixMan.prefs'
FILE='Env:'
FILESAVE='EnvArc:'

FF='0c'x

Say ""
Say "AreafixMan prefs editor v1.0 © 1993 PSR Software"
Say "For use with AreaFixMan Spot script."
If ~Exists(FILE || PREF) Then Do
   Say "Cannot find prefs file" FILE || PREF
   Say "Use AreaFixMan.spot script to create new prefs file"
   Exit
End
If ~Open('prefs',FILE || PREF,'r') Then Do
   Say " Cannot open prefs file"
   Exit
End
FORMAT=ReadLn('prefs')
If ~(FORMAT='FORMAT 2.6') Then Do
  Say "Prefs file is not compatible.  Delete prefs and start again."
  Call Close('prefs')
End

COUNT=0
Do Until Eof('prefs')
   DUMMY='dummy'
   AREA=Strip(ReadLn('prefs'),'L')
   If ~(Length(AREA)=0) Then Do
      ADDRESS=Strip(ReadLn('prefs'),'L')
      PASS=Strip(ReadLn('prefs'),'L')
      AREAFIX=Strip(ReadLn('prefs'),'L')
      COMMENT=Strip(ReadLn('prefs'),'L')
      If Length(COMMENT)=0 Then Do
         COMMENT='Options'
      End
      Else Do
         ANNOUNCE=Strip(ReadLn('prefs'),'L')
         If Length(ANNOUNCE)=0 Then Do
            ANNOUNCE='No Announce'
            DUMMY=''
         End
         Else Do
            /* Any new prefs will be inserted here */
            Do Until Length(DUMMY)=0
               DUMMY=ReadLn('prefs')
            End
         End
      End
      AREA.count=AREA
      ADDRESS.count=ADDRESS
      PASS.count=PASS
      AREAFIX.count=AREAFIX
      COMMENT.count=COMMENT
      ANNOUNCE.count=ANNOUNCE
      ERASED.count=0
      COUNT=COUNT+1
   End
End
Call Close('prefs')
TOTAL=COUNT-1
COUNT=0

Do Forever
   Say ""
   Say "This is record" COUNT+1 "of" TOTAL+1
   If ERASED.count Then Do
      Say "  Marked for deletion"
   End
   Else Do
      Say ""
   End
   Say "_________________________________________________"
   Say " NET NAME:" AREA.count
   Say "  ADDRESS:" ADDRESS.count
   Say " PASSWORD:" PASS.count
   Say "  AREAFIX:" AREAFIX.count
   Say "  COMMENT:" COMMENT.count
   Say " ANNOUNCE:" ANNOUNCE.count
   Say "¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯"
   Say "   Next Previous  Delete Edit  Last  Save Use Cancel"
   Say "   ¯    ¯         ¯      ¯     ¯     ¯    ¯   ¯"
   WriteCh('STDOUT'," Select: ")
   Pull SELECT
   If SELECT='N' Then Do
      Say FF
      COUNT=COUNT+1
      If COUNT>TOTAL Then COUNT=TOTAL
   End
   If SELECT='P' Then Do
      Say FF
      COUNT=COUNT-1
      If COUNT<0 Then COUNT=0
   End
   If SELECT='D' Then Do
      Say FF
      If ERASED.count=0 Then Do
         ERASED.count=1
      End
      Else Do
         ERASED.count=0
      End
   End
   If SELECT='E' Then Do
      Say FF
      Say "Simply hit RETURN for previous settings"
      Say ""

      Say " NET NAME:" AREA.count
      WriteCh('STDOUT',' NET NAME: ')
      Parse Pull AREA
      If Length(AREA)>0 Then AREA.count=AREA

      Say "  ADDRESS:" ADDRESS.count
      WriteCh('STDOUT','  ADDRESS: ')
      Parse Pull ADDRESS
      If Length(ADDRESS)>0 Then ADDRESS.count=ADDRESS

      Say " PASSWORD:" PASS.count
      WriteCh('STDOUT',' PASSWORD: ')
      Parse Pull PASS
      If Length(PASS)>0 Then PASS.count=PASS

      Say "  AREAFIX:" AREAFIX.count
      WriteCh('STDOUT','  AREAFIX: ')
      Parse Pull AREAFIX
      If Length(AREAFIX)>0 Then AREAFIX.count=AREAFIX

      Say "   COMMENT:" COMMENT.count
      WriteCh('STDOUT','   COMMENT: ')
      Parse Pull COMMENT
      If Length(COMMENT)>0 Then COMMENT.count=COMMENT

      If ANNOUNCE.count='Announce' Then Do
         Say " ANNOUNCE: On"
      End
      Else Do
         Say " ANNOUNCE: Off"
      End
      WriteCh('STDOUT',' ANNOUNCE: ')
      Pull ANNOUNCE
      If ANNOUNCE='ON' Then ANNOUNCE.count='Announce'
      If ANNOUNCE='OFF' Then ANNOUNCE.count='No Announce'
      Say FF
   End
   If SELECT='L' Then Do
      Address Command 'Copy "'FILESAVE || PREF'" To "'FILE || PREF'"'
      Exit
   End
   If (SELECT='S') | (SELECT='U') Then Do
      If Open('prefs',FILE || PREF,'w') Then Do
         Call WriteLn('prefs','FORMAT 2.6')
         Do COUNT=0 to TOTAL
            If ~ERASED.count Then Do
               Call WriteLn('prefs',AREA.count)
               Call WriteLn('prefs',ADDRESS.count)
               Call WriteLn('prefs',PASS.count)
               Call WriteLn('prefs',AREAFIX.count)
               Call WriteLn('prefs',COMMENT.count)
               Call WriteLn('prefs',ANNOUNCE.count)
               Call WriteLn('prefs','')
            End
         End
         Call Close('prefs')
      End
      Else Do
         Say " Cannot open prefs file"
         Pull dummy
      End
      Say FF
      If SELECT='S' Then Address Command 'Copy "'FILE || PREF'" To "'FILESAVE || PREF'"'
      Exit
   End
   If SELECT='C' Then Do
      Say FF
      Exit
   End
End