home *** CD-ROM | disk | FTP | other *** search
/ Fujiology Archive / fujiology_archive_v1_0.iso / !FALCON / LINEOUT / DELTA.ZIP / DELTASRC.ZIP / DELTA.SRC / DEMO.S < prev    next >
Text File  |  2003-01-04  |  16KB  |  884 lines
  1. ;                        //==========================\\
  2. ;                       //|  demo part handler 1.0   |\\
  3. ;                       \\|    24-08-2002 by earx    |//
  4. ;                        \\==========================//
  5. ;
  6. ;                                falcon030 only
  7. ; 
  8. ; beware: only 3 screenbuffers
  9.  
  10. ;======= GLOBAL EQUATES ========
  11.  
  12. DEMO_SYSTEM:                    ; Indicates demosystem is active.
  13. testmode:    =    0            ; debug mode
  14.  
  15. MAX_SCREENSIZE:    =    320*200*2
  16.  
  17. ; monitormode-equates
  18. autodetect:    =    0
  19. rgb50:        =    1            ; RGB/TV, 50Hz
  20. vga60:        =    2            ; VGA, 60, noninterlaced
  21. vga100:        =    3            ; VGA, 100Hz, interlaced
  22. ; monitormode selector ( =autodetect ) or force mode ( >0 )
  23. monitorequ:    =    autodetect
  24.  
  25. Part.INIT:    =    0
  26. Part.START:    =    4
  27. Part.STOP:    =    8
  28.  
  29. ;======= ASM OPTIONS AND PATHS ========
  30.  
  31.     COMMENT    HEAD=%111
  32.     OPT    P=68030
  33.     IFEQ    testmode
  34.     OPT    D-
  35.     ENDC
  36.  
  37. ;======= INCLUDES ========
  38.  
  39.     bra.l    START
  40.  
  41.     INCLUDE    SYS.I
  42.     TEXT
  43.     INCLUDE    MEM.I
  44.     TEXT
  45.     INCLUDE    MATH.I
  46.     TEXT
  47.     INCLUDE    DEPACK35.S
  48.     INCLUDE    FSCR2.I
  49.     TEXT
  50.     INCLUDE    DSP_FIX.S
  51.     TEXT
  52. ;    INCLUDE    DSP.I
  53.     INCLUDE    TEXTURE.I
  54.     TEXT
  55.     INCLUDE    EARXPLAO.S
  56.     TEXT
  57.     INCLUDE    SFLY_DSP.S            ; Include the CPU-DSP engine.
  58.     TEXT
  59.     INCLUDE    OBJECT3D.I
  60.     TEXT
  61.     INCLUDE    TUNNEL.I
  62.     TEXT
  63.     INCLUDE    FONT.I
  64.     TEXT
  65.  
  66. ;======= INITIALISING ========
  67.  
  68. START:
  69. ; Give back some mem to the system..
  70.     move.l    $04(sp),a5            ; mshrink
  71.     move.l    $0C(a5),d0
  72.     add.l    $14(a5),d0
  73.     add.l    $1C(a5),d0
  74.     addi.l    #$00001000,d0
  75.     move.l    a5,d1
  76.     add.l    d0,d1
  77.     andi.b    #%11111110,d1            ; even address
  78.     move.l    d1,sp
  79.     move.l    d0,-(sp)
  80.     move.l    a5,-(sp)
  81.     move.w    d0,-(sp)
  82.     move.w    #$4a,-(sp)
  83.     trap    #1
  84.     lea    12(sp),sp
  85.  
  86. ; mxalloc - Reserve stram ONLY for screens.
  87.     move.w    #0,-(sp)
  88.     move.l    #MAX_SCREENSIZE*3+256,-(sp)    ; size of screens..
  89.     move.w    #$44,-(sp)
  90.     trap    #1
  91.     addq    #8,sp
  92.     tst.l    d0                ; Check if there is ST-RAM enough.
  93.     bgt.s    .ramok
  94. ; Not enough ST-RAM free :(
  95.     clr.w    -(sp)
  96.     trap    #1
  97.  
  98. ; Initialize screenaddresses..
  99. .ramok    lea    scr,a0
  100.     addi.l    #15,d0                ; / long even
  101.     andi.b    #%11110000,d0            ; \ address..
  102.     move.l    d0,(a0)+
  103.     addi.l    #MAX_SCREENSIZE,d0
  104.     move.l    d0,(a0)+
  105.     addi.l    #MAX_SCREENSIZE,d0
  106.     move.l    d0,(a0)+
  107.  
  108. ; Calculate sine table.
  109.     lea    sine_tbl,a0
  110.     Init_SineTable
  111.  
  112.     IFNE    monitorequ-autodetect
  113.     move.w    #monitorequ,monitormode
  114.     ELSE
  115.     bsr.l    getSettings
  116.     tst.w    d0
  117.     bmi.l    exit
  118.     ENDC
  119.  
  120. ; Set supervisormode and save old stackpointer..
  121.     clr.l    -(sp)
  122.     move.w    #32,-(sp)
  123.     trap    #1
  124.     addq    #6,sp
  125.     move.l    d0,oldsp
  126.     move.l    #ustk,sp            ; Install own stack..
  127.  
  128. ; Save old screenaddress..
  129.     move.w    #2,-(sp)
  130.     trap    #14
  131.     addq    #2,sp
  132.     move.l    d0,oldscr
  133.  
  134. ; Falcon check..
  135.     move.l    $05A0.w,a0
  136.     tst.l    a0
  137.     beq.l    exit
  138. .fndmch    cmpi.l    #"_MCH",(a0)
  139.     beq.s    .found
  140.     addq    #8,a0
  141.     bra.s    .fndmch
  142. .found    cmpi.w    #3,4(a0)
  143.     bne.l    exit
  144.  
  145. ; Initialize libs..
  146.     bsr.l    System.init
  147.     bsr    setDot
  148.     bsr.l    Mem.init
  149.     bsr    setDot
  150.     bsr.l    Tunnel.genOffsetMap
  151.     bsr    setDot
  152.     bsr.l    Tunnel.calcFlareOctant
  153.     bsr    setDot
  154.     bsr.l    FlareGen.init
  155.     bsr    setDot
  156.     bsr.l    Texture.makeDefaults
  157.     bsr    setDot
  158.     bsr.l    Font.init
  159.     bsr    setDot
  160.  
  161. ; Call parts to initialize all their screens..
  162.     bsr.l    initParts
  163.     tst.l    d0
  164.     bmi.l    exit
  165.     bsr    setDot
  166.  
  167. ; Initialize intro..
  168.     movea.l    Intro.table+4,a1
  169.     jsr    (a1)
  170.     tst.l    d0
  171.     bmi.l    exit
  172.     bsr    setDot
  173. ; Initialize menuscreen..
  174.     movea.l    Menu.table+4,a1
  175.     jsr    (a1)
  176.     tst.l    d0
  177.     bmi.l    exit
  178.     bsr    setDot
  179.  
  180. ; Reserve enough mem for all fx.
  181.     bsr.l    Mem.take
  182.     tst.l    d0
  183.     beq.l    exit
  184.  
  185. ; Save and install nasty interrupts..
  186.     IFEQ    testmode
  187.     move.b    $0484.w,old484
  188.     clr.b    $0484.w
  189. ; Save falcon-pallette..
  190.     bsr.l    SAVE_FALCPAL
  191. ; Save resolution..
  192.     bsr.l    SAVE_FV
  193. ; Install own vbl-routine..
  194.     move    #$2700,sr
  195.     move.l    $0070.w,oldvbl
  196.     move.l    #NEWVBL,$70.w
  197.     move    #$2300,sr
  198.  
  199. ; Initialize mod-player.
  200.     moveq    #2,d0                ; 33KHz
  201. ;    moveq    #1,d0                ; 49KHz
  202.     bsr.l    EarxPlay.init
  203.     tst.l    d0
  204.     bmi.l    return2tos
  205.  
  206. ; Black out palette..
  207.     lea    $FFFF9800.w,a0
  208.     clr.l    d0
  209.     clr.b    d1
  210. .loop:    move.l    d0,(a0)+
  211.     addq.b    #1,d1
  212.     bne.s    .loop
  213.     ENDC                    ; IFEQ testmode
  214.  
  215. ; Show intro..
  216.     bsr.l    showIntro
  217.  
  218. ; Show menu, request part...
  219. showMenu:
  220.     bsr.l    showActualMenu
  221.     move.w    d0,partNum
  222.  
  223. ; Set the demo to selected part.
  224.     move.w    partNum,d0
  225.     bsr.l    setPart
  226.  
  227. ; Reset framecounters, timers.
  228.     clr.l    d0
  229.     move.l    d0,frmcnt
  230.     move.l    d0,lastframecount
  231.     move.l    $04BA.w,starttime
  232.  
  233. mainloopcycle:
  234.  
  235.     IFNE    0
  236.  
  237. ; Test if a key is pressed.
  238.     move.w    #$B,-(sp)
  239.     trap    #1
  240.     addq    #2,sp
  241.     tst.w    d0
  242.     beq.s    .key_done
  243. ; Read the waiting char.
  244.     move.w    #1,-(sp)
  245.     trap    #1
  246.     addq    #2,sp
  247.     swap    d0
  248.  
  249.     ELSE
  250.  
  251.     move.b    $FFFFFC02.w,d0
  252.  
  253.     ENDC
  254.  
  255.     cmpi.b    #$39,d0
  256.     beq.l    showMenu
  257.     cmpi.b    #$72,d0
  258.     bne.s    .no_skip
  259.     bsr.l    EarxPlay.nextPos
  260. .no_skip:
  261.  
  262. .key_done:
  263.     movea.l    actScreenAdr,a0
  264.     tst.l    a0
  265.     beq.s    .do
  266.     movea.l    (a0),a1
  267.     jsr    (a1)                ; execute main-rout of screen
  268. .do:    addq.l    #1,frmcnt
  269.     bsr.l    handleDemoEvents
  270.     bra.s    mainloopcycle
  271.  
  272. setDot:    move.w    #".",-(sp)
  273.     move.w    #2,-(sp)
  274.     trap    #1
  275.     addq    #4,sp
  276.     rts
  277.  
  278. ;======= INCLUDED PARTS ========
  279.  
  280. partTable:
  281.     DC.L    alphaRoutTable
  282.     DC.L    betaRoutTable
  283.     DC.L    gammaRoutTable
  284.     DC.L    0
  285.  
  286. alphaRoutTable:
  287.     INCLUDE    ALPHA_P.S
  288.     TEXT
  289. betaRoutTable:
  290.     INCLUDE    BETA_P.S
  291.     TEXT
  292. gammaRoutTable:
  293.     INCLUDE    GAMMA_P.S
  294.     TEXT
  295.  
  296. ; A dark intermezzo.
  297.     INCLUDE    BLACK.SO
  298.     INCLUDE    INTRO.SO
  299.     TEXT
  300.     INCLUDE    MENU2.SO
  301.     TEXT
  302.  
  303. ;======= EXITTING CODE ========
  304.  
  305. return2tos:
  306. OUT:
  307.     IFEQ    testmode
  308.  
  309. ; Stop current part..
  310. ;    move.w    partNum,d0
  311. ;    movea.l    (partTable,d0.w*4),a0
  312. ;    movea.l    Part.STOP(a0),a0
  313. ;    jsr    (a0)
  314.  
  315. exitMenu:
  316.     bsr.l    EarxPlay.stop
  317.     bsr.l    EarxPlay.deinit
  318.  
  319. ; Restore interrupts..
  320.     move.l    oldvbl,$70.w
  321.  
  322. ; Restore video..
  323.     lea    save_fv,a0
  324.     bsr.l    CHANGE_FVFAST
  325.     bsr.l    RESTORE_FALCPAL
  326.  
  327. ; Restore screen..
  328.     move.l    oldscr,d0
  329.     move.l    d0,d1
  330.     lsr.w    #8,d0
  331.     move.l    d0,$ffff8200.w
  332.     move.b    d1,$ffff820d.w
  333.  
  334. ; Restore keyboard sound..
  335.     move.b    old484,$0484.w
  336.  
  337.     ENDC                    ; IFEQ testmode
  338.  
  339.     bsr.l    dsp_load_bootstrap
  340.  
  341. exit:    clr.w    -(sp)
  342.     trap    #1
  343.  
  344. ;======= DEMO-OS SUBROUTINES ========
  345.  
  346.         RSRESET
  347. Option.XPOS:    RS.B    1
  348. Option.YPOS:    RS.B    1
  349. Option.CHAR:    RS.B    1
  350.  
  351. Keycode.ESCAPE:    =    27        ; escape
  352. Keycode.RGB_50:    =    "1"
  353. Keycode.VGA_100:=    "2"
  354. Keycode.VGA_60:    =    "3"
  355. Keycode.DETAIL:    =    "d"
  356.  
  357. ; OUTPUT:
  358. ; d0.w:    0=Run demo, -1=Exit demo
  359. getSettings:
  360.     bsr    paintSelector
  361.  
  362. .repaint:
  363.     tst.w    detail
  364.     beq.s    .set_wtext
  365.     pea    .detailb_txt(pc)
  366.     bra.s    .paint_detail
  367. .set_wtext:
  368.     pea    .detailw_txt(pc)
  369. .paint_detail:
  370.     move.w    #9,-(sp)
  371.     trap    #1
  372.     addq    #6,sp
  373.  
  374. ; Read a key from the console into d0.
  375. .get_newkey:
  376.     move.w    #8,-(sp)
  377.     trap    #1
  378.     addq    #2,sp
  379. ; d0.b: result keycode
  380.  
  381.     cmpi.b    #Keycode.ESCAPE,d0
  382.     beq.s    .exit
  383.     cmpi.b    #Keycode.RGB_50,d0
  384.     beq.s    .set_rgb50
  385.     cmpi.b    #Keycode.VGA_100,d0
  386.     beq.s    .set_vga100
  387.     cmpi.b    #Keycode.VGA_60,d0
  388.     beq.s    .set_vga60
  389.     cmpi.b    #Keycode.DETAIL,d0
  390.     beq.s    .switch_detail
  391.     bra.s    .get_newkey
  392.  
  393. .set_rgb50:
  394.     move.w    #rgb50,monitormode
  395.     bra.s    .proceed
  396. .set_vga100:
  397.     move.w    #vga100,monitormode
  398.     bra.s    .proceed
  399. .set_vga60:
  400.     move.w    #vga60,monitormode
  401.     bra.s    .proceed
  402. .switch_detail:
  403.     not.w    detail
  404.     bra.s    .repaint
  405.  
  406. .proceed:
  407.     moveq    #0,d0
  408.     rts
  409. .exit:    moveq    #-1,d0
  410.     rts
  411.  
  412. .detailw_txt:
  413.     DC.B    27,89,32+11,32+18,"detail",27,89,32+13,32+15,0
  414. .detailb_txt:
  415.     DC.B    27,89,32+11,32+18,27,112,"detail",27,113,27,89,32+13,32+15,0
  416.     EVEN
  417.  
  418. paintSelector:
  419.     pea    selector_txt
  420.     move.w    #9,-(sp)
  421.     trap    #1
  422.     addq    #6,sp
  423.     rts
  424.  
  425. ; Run the intro..
  426. showIntro:
  427.     clr.l    d0
  428.     move.l    d0,frmcnt
  429.     move.l    d0,lastframecount
  430.     move.l    $04BA.w,starttime
  431.  
  432. .intro_loop:
  433. ; Test if a key is pressed.
  434.     move.w    #$B,-(sp)
  435.     trap    #1
  436.     addq    #2,sp
  437.     tst.w    d0
  438.     beq.s    .no_introkey_waiting
  439.  
  440. ; Read the waiting char.
  441.     move.w    #7,-(sp)
  442.     trap    #1
  443.     addq    #2,sp
  444.  
  445.     cmpi.b    #' ',d0
  446.     beq    .intro_done
  447.  
  448. .no_introkey_waiting:
  449.     move.l    $04BA.w,d0
  450.     sub.l    starttime,d0
  451.     cmpi.l    #100,d0
  452.     blt.s    .intro_events_done
  453.     cmpi.l    #700+400,d0
  454.     blt.s    .try_crew_logo
  455.     cmpi.l    #1300+400,d0
  456.     blt.s    .try_presents
  457.     cmpi.l    #2000+400,d0
  458.     bge.s    .intro_done
  459.  
  460. .try_delta:
  461.     tst.w    .delta_shown(pc)
  462.     bne.s    .intro_events_done
  463.     st    .delta_shown
  464.     movea.l    Intro.table+4*5,a1
  465.     jsr    (a1)
  466.     bra.s    .intro_events_done
  467.  
  468. .try_presents:
  469.     tst.w    .presents_shown(pc)
  470.     bne.s    .intro_events_done
  471.     st    .presents_shown
  472.     movea.l    Intro.table+4*4,a1
  473.     jsr    (a1)
  474.     bra.s    .intro_events_done
  475.  
  476. .try_crew_logo:
  477.     tst.w    .crew_shown(pc)
  478.     bne.s    .intro_events_done
  479.     st    .crew_shown
  480.     movea.l    Intro.table+4*3,a1
  481.     jsr    (a1)
  482.  
  483. .intro_events_done:
  484.     movea.l    Intro.table,a1
  485.     jsr    (a1)
  486.     addq.l    #1,frmcnt
  487.     bra    .intro_loop
  488.  
  489. .intro_done:
  490.     rts
  491.  
  492. .crew_shown:
  493.     DC.W    0
  494. .presents_shown:
  495.     DC.W    0
  496. .delta_shown:
  497.     DC.W    0
  498.  
  499. ; Shows a nice graphic delta menu..
  500. ; OUPUT:
  501. ; d0.w= partnumber
  502. showActualMenu:
  503.     bsr.l    EarxPlay.stop
  504.     clr.l    d0
  505.     move.w    d0,.options_shown
  506.     move.w    d0,.logo_shown
  507.     move.l    d0,frmcnt
  508.     move.l    d0,lastframecount
  509.     move.l    $04BA.w,starttime
  510.  
  511. .menu_loop:
  512. ; Test if a key is pressed.
  513.     move.w    #$B,-(sp)
  514.     trap    #1
  515.     addq    #2,sp
  516.     tst.w    d0
  517.     beq.s    .no_char_waiting
  518.  
  519. ; Read the waiting char.
  520.     move.w    #7,-(sp)
  521.     trap    #1
  522.     addq    #2,sp
  523.  
  524.     cmpi.b    #27,d0                ; escape
  525.     beq    exitMenu
  526.     ori.b    #$20,d0
  527.     cmpi.b    #'a',d0
  528.     beq.s    .a_key
  529.     cmpi.b    #'b',d0
  530.     beq.s    .b_key
  531.     cmpi.b    #'c',d0
  532.     beq.s    .c
  533.  
  534. .no_char_waiting:
  535.     move.l    $04BA.w,d0
  536.     sub.l    starttime,d0
  537.     cmpi.l    #400,d0
  538.     blt.s    .end_menu_event
  539.     tst.w    .logo_shown(pc)
  540.     bne.s    .end_logo_stuff
  541.     st    .logo_shown
  542.     movea.l    Menu.table+4*3,a1
  543.     jsr    (a1)
  544.     bra.s    .end_menu_event
  545. .end_logo_stuff:
  546.     cmpi.l    #600,d0
  547.     blt.s    .end_menu_event
  548.     tst.w    .options_shown(pc)
  549.     bne.s    .end_options_stuff
  550.     st    .options_shown
  551.     movea.l    Menu.table+4*5,a1
  552.     jsr    (a1)
  553. .end_options_stuff:
  554. .end_menu_event:
  555.  
  556.     movea.l    Menu.table,a1
  557.     jsr    (a1)
  558.     addq.l    #1,frmcnt
  559.     bra.w    .menu_loop
  560.  
  561. .a_key:    moveq    #0,d0
  562.     bra.s    .blink_it
  563. .b_key:    moveq    #1,d0
  564.     bra.s    .blink_it
  565. .c:    moveq    #2,d0
  566. ;    bra.s    .blink_it
  567. .blink_it:
  568.     move.w    d0,-(sp)
  569.     bsr.l    Menu.setBlinking
  570.     move.w    (sp)+,d0
  571.     rts
  572.  
  573. .logo_shown:
  574.     DC.W    0
  575. .options_shown:
  576.     DC.W    0
  577.  
  578. ; Initializes all parts.
  579. ; OUTPUT:
  580. ; d0.l: =0: success, <0: error
  581. initParts:
  582.     lea    partTable,a0
  583.     lea    partInfoTable,a2
  584.     clr.w    numParts
  585.  
  586. .loop:    movea.l    (a0)+,a1
  587.     tst.l    a1
  588.     beq.s    .end
  589. ; a1: part's rout table
  590.     movea.l    Part.INIT(a1),a1        ; a1: part's init rout
  591.     movem.l    a0/a2,-(sp)
  592.     jsr    (a1)
  593.     move.l    a0,d1
  594.     move.l    a1,d2
  595.     movem.l    (sp)+,a0/a2
  596.     tst.l    d0
  597.     bmi.s    .abort
  598.     move.l    d1,(a2)+
  599.     move.l    d2,(a2)+
  600.     addq.w    #1,numParts
  601.     bra.s    .loop
  602.  
  603. .end:    clr.l    d0
  604. .abort:    rts
  605.  
  606. ; Initializes a part's screens.
  607. ; INPUT:
  608. ; a0: part's screentable
  609. ; OUTPUT:
  610. ; d0.l: =0: success, <0: error
  611. initScreens:
  612.     addq    #4,a0                ; a0: first object-pointer
  613.  
  614. ; Count screens..
  615.     movea.l    a0,a6
  616.       moveq    #-1,d0
  617. .countloop:
  618.     addq.w    #1,d0
  619.     tst.l    (a6)+
  620.     bne.s    .countloop
  621.  
  622. ; If 0 screens in part, abort.
  623.     tst.w    d0
  624.     beq.s    .abort
  625.  
  626. ; Initialize screens.
  627.     clr.l    d0                ; d0.w: screencounter
  628.  
  629. .loop:    ;cmpi.b    #$39,$FFFFFC02.w
  630.     ;beq    .abort
  631.  
  632.     movea.l    (a0)+,a1            ; a1: screen's rout-table
  633.     tst.l    a1
  634.     beq.s    .end
  635.     move.l    4(a1),a1            ; a1: screen's init-rout
  636.  
  637.     move.w    d0,-(sp)
  638.     move.l    a0,-(sp)
  639.     jsr    (a1)                ; Execute to screen's initialization.
  640.     move.l    d0,d1
  641.     movea.l    (sp)+,a0
  642.     move.w    (sp)+,d0
  643.     tst.l    d1                ; Screen init failed?
  644.     bmi.s    .abort
  645.  
  646.     addq.w    #1,d0                ; Increase counter.
  647.     bra.s    .loop
  648.  
  649. .end:    rts
  650.  
  651. .abort:    moveq    #-1,d0
  652.     rts
  653.  
  654. ; Counts a part's event-subroutines for every screen.
  655. ; INPUT:
  656. ; a0: part's screentable
  657. ; a1: dst. subevent count table
  658. countSubFx:
  659.     addq    #1,a1
  660.     lea    4(a0),a2
  661.  
  662. .countloop:
  663.     movea.l    (a2)+,a3
  664.     tst.l    a3
  665.     beq.s    .endcounting
  666.     moveq    #-1,d1
  667.  
  668. .incountloop:
  669.     addq.w    #1,d1
  670.     tst.l    (a3)+
  671.     bne.s    .incountloop
  672.  
  673.     move.b    d1,(a1)+
  674.     bra.s    .countloop
  675.  
  676. .endcounting:
  677.     rts
  678.  
  679. ; Sets the demo to a specified part.
  680. ; INPUT:
  681. ; d0.w= part number
  682. setPart:cmp.w    numParts,d0
  683.     blt.s    .ok
  684.     move.l    #showMenu,(sp)            ; If last part done, return to menu.
  685.     rts
  686.  
  687. .ok:    move.w    d0,partNum            ; If it's a legal part, set it.
  688.  
  689. ; Temporary blindness.
  690.     move.l    #Darkness.table,actScreenAdr
  691.     move.l    frmcnt,lastframecount
  692.  
  693. ; Start the part.
  694.     lea    partInfoTable,a0
  695.     move.l    (a0,d0.w*8),actPartAdr
  696.     move.l    4(a0,d0.w*8),subEffectTableAdr
  697.     movea.l    (partTable,d0.w*4),a0
  698.     movea.l    Part.START(a0),a0
  699.     jsr    (a0)
  700.     move.w    d0,screenCount
  701.     bmi    return2tos
  702.     rts
  703.  
  704. ; Processes one new event from the eventlist.
  705. ; PRE:
  706. ; - subeffects_tbl contains number of routs for each fx.
  707. ; - screenCount = number of fx in table
  708. handleDemoEvents:
  709.  
  710. .loop:
  711. ; Get command from modplayer..
  712.     bsr.l    EarxPlay.getSyncInfo
  713.  
  714.     cmpi.b    #255,d0
  715.     beq    .end                ; no new command -> do nothing
  716.  
  717.     tst.b    d0
  718.     beq.s    .next_part            ; end command -> next part
  719.  
  720.     btst    #7,d0                ; test intern indicator
  721.     bne.s    .intern
  722.  
  723. ; Activate new effect.
  724.     movea.l    actPartAdr,a1
  725.     andi.w    #$007F,d0
  726.     cmp.w    screenCount,d0
  727.     bgt    .end                ; fx-index >= #fx, error
  728.     move.w    d0,actScreenNum            ; Set fx-number.
  729.     move.l    (a1,d0.w*4),actScreenAdr    ; Set new fx-base.
  730.     move.l    frmcnt,lastframecount        ; Store time of this fx-change.
  731.  
  732.     bra.s    .loop
  733.  
  734. ; Call a routine in the current effect.
  735. .intern:andi.w    #$007F,d0            ; Mask out indicator, d0.w=fx index
  736.     movea.l    subEffectTableAdr,a2
  737.     move.w    actScreenNum,d1
  738.     move.b    (a2,d1.w),d1            ; d1.w=#fx-routs
  739.     cmp.w    d1,d0
  740.     bge.s    .end                ; fx-rout-index >= #fx-routs, error
  741.     movea.l    actScreenAdr,a0
  742.     movea.l    (a0,d0.w*4),a0
  743.     jsr    (a0)                ; Call fx-subroutine.
  744.  
  745.     bra.s    .loop
  746.  
  747. ; Start the next part, if any.
  748. ; pre: a part is running.
  749. .next_part:
  750.     move.w    partNum,d0
  751.     addq.w    #1,d0
  752.     bsr.w    setPart
  753.  
  754. .end:    rts
  755.  
  756. ; INPUT:
  757. ; a0: filename
  758. playMod:
  759. ; fopen
  760.     clr.w    -(sp)
  761.     move.l    a0,-(sp)
  762.     move.w    #$3D,-(sp)
  763.     trap    #1
  764.     addq    #8,sp
  765.  
  766.     tst.l    d0
  767.     blt.s    .fin                ; d0.w=handle
  768.     move.l    d0,d6
  769.  
  770. ; fread
  771.     pea    mod
  772.     move.l    #-1,-(sp)
  773.     move.w    d6,-(sp)
  774.     move.w    #$3F,-(sp)
  775.     trap    #1
  776.     lea    12(sp),sp
  777.  
  778. ; fclose
  779.     move.w    d6,-(sp)
  780.     move.w    #$3E,-(sp)
  781.     trap    #1
  782.     addq    #4,sp
  783.  
  784. ; Decrunch the file using atomik. If not packed nothing happens.
  785.     lea    mod,a0
  786.     bsr.l    depack
  787.  
  788.     IFEQ    testmode
  789.     lea    mod,a0
  790.     bsr.l    EarxPlay.play
  791.     ENDC
  792.  
  793. .fin:    rts                    ; d0.l=resultcode
  794.  
  795. ;======= INTERRUPTS ========
  796.  
  797. NEWVBL:    addq.l    #1,$0466.w
  798.     movem.l    d0-a6,-(sp)
  799.     bsr.l    Screen.update
  800.     move.l    vbl_gfx(pc),a0
  801.     jsr    (a0)
  802.     movem.l    (sp)+,d0-a6
  803.     rte
  804.  
  805. vbl_gfx:DC.L    rts
  806.  
  807. rts:    rts
  808.  
  809. ;======= DATA + INCBINS ========
  810.  
  811.     DATA
  812.  
  813. selector_txt:
  814.     DC.B    27,72
  815.     DC.B    "........................................",$a,$d
  816.     DC.B    "|                                      |",$a,$d
  817.     DC.B    "|      . .   //\                       |",$a,$d
  818.     DC.B    "|           //  \                      |",$a,$d
  819.     DC.B    "|        . //    \                     |",$a,$d
  820.     DC.B    "|    .  . //______\..e..l..t..a.. .    |",$a,$d
  821.     DC.B    "|                                      |",$a,$d
  822.     DC.B    "|   ..b..y.....l..i..n..e..o..u..t..   |",$a,$d
  823.     DC.B    "|                                      |",$a,$d
  824.     DC.B    "|   1.rgb50 2.vga100 3.vga60 esc.exit  |",$a,$d
  825.     DC.B    "|                                      |",$a,$d
  826.     DC.B    "|               d.detail               |",$a,$d    ; 19,11, len=6
  827.     DC.B    "|                                      |",$a,$d
  828.     DC.B    "!.............[          ].............!",$a,$d
  829.     DC.B    0
  830.     EVEN
  831.  
  832. ;======= RESERVES ========
  833.  
  834.     BSS
  835.  
  836. ; Init-data
  837.     DS.L    256
  838. ustk:    DS.L    1
  839. oldsp:    DS.L    1
  840. oldscr:    DS.L    1
  841. oldvbl:    DS.L    1
  842. old484:    DS.W    1
  843. old468:    DS.W    1
  844. fvbuf:    DS.W    24
  845.  
  846. sine_tbl:
  847.     DS.L    sintbllen
  848.  
  849. ; Stats shit
  850. monitormode:
  851.     DS.W    1
  852. detail:    DS.W    1
  853.  
  854. ; Object handling
  855. numParts:
  856.     DS.W    1                    ; #parts in demo
  857. partNum:DS.W    1                    ; current part
  858. screenCount:
  859.     DS.W    1                    ; #screens in current part
  860. actScreenNum:
  861.     DS.W    1                    ; selected screen
  862. actScreenAdr:
  863.     DS.L    1                    ; Points to current screen.
  864. actPartAdr:
  865.     DS.L    1                    ; Points to current part.
  866. subEffectTableAdr:
  867.     DS.L    1                    ; Points to current part's sub-effect counttable
  868. partInfoTable:
  869.     DS.L    2*3                    ; 3 parts (screentbl ptr, counttable ptr)
  870.  
  871. ; Counter and timer shit
  872. frmcnt:    DS.L    1                    ; #frames animated
  873. lastframecount:
  874.     DS.L    1                    ; #frames animated when current screen started
  875. starttime:
  876.     DS.L    1
  877.  
  878. ; Key vars.
  879. keycode:DS.W    1
  880.  
  881. ; Scr-stuff
  882. scr:    DS.L    3
  883.  
  884. mod:    DS.B    530000                    ; max(mod1,mod2,mod3)