home *** CD-ROM | disk | FTP | other *** search
/ Fujiology Archive / fujiology_archive_v1_0.iso / !FALCON / LINEOUT / DELTA.ZIP / DELTASRC.ZIP / DELTA.SRC / STARFISH.SO < prev    next >
Text File  |  2003-01-04  |  27KB  |  1,292 lines
  1. ; Dying starfish. A screen for delta. Uses the ufly engine.
  2.  
  3. ;======= OBJECT EQUATES ====================================================
  4.  
  5. ; Change these to suit your needs.
  6. Starfish.DEPTH:        =    60
  7. Starfish.TOPDEPTH:    =    3*Starfish.DEPTH/2
  8. Starfish.ARMLENGTH:    =    1200
  9. Starfish.LE:        =    Starfish.ARMLENGTH/10
  10. Starfish.MAX_BEND:    =    2500
  11. Starfish.ARMS:        =    5            ; >=3
  12. Starfish.RINGPOINTS:    =    6            ; even and >=4
  13. Starfish.RINGS:        =    5            ; >=1
  14.  
  15. ; Do not change..
  16. Starfish.ARMPOINTS:    =    Starfish.RINGS*Starfish.RINGPOINTS+1
  17. Starfish.BINDPOINT1:    =    Starfish.ARMPOINTS*Starfish.ARMS
  18. Starfish.BINDPOINT2:    =    Starfish.ARMPOINTS*Starfish.ARMS+1
  19. Starfish.POINTS:    =    2+Starfish.ARMPOINTS*Starfish.ARMS
  20. Starfish.ARMPOLYS:    =    Starfish.RINGS*Starfish.RINGPOINTS
  21. Starfish.OUTPOLYS:    =    Starfish.ARMPOLYS*Starfish.ARMS
  22. Starfish.BINDPOLYS:    =    Starfish.RINGPOINTS*Starfish.ARMS    ; tris only
  23. Starfish.POLYS:        =    Starfish.BINDPOLYS+Starfish.OUTPOLYS
  24.  
  25.             RSRESET
  26. Starfish.object:    RS.W    8192
  27. Starfish.armAngleTable:    RS.W    Starfish.ARMS*(Starfish.RINGS+1)
  28. Starfish.background:    RS.W    320*200
  29. Starfish.shadowTable:    RS.W    1+4*2*500
  30. Starfish.shadowTable2:    RS.W    1+4*2*500
  31. Starfish.shadowTable3:    RS.W    1+4*2*500
  32. Starfish.shadowTable4:    RS.W    1+4*2*500
  33. Starfish.shadowTable5:    RS.W    1+4*2*500
  34. Starfish.shadowTable6:    RS.W    1+4*2*500
  35. Starfish.BLOCK_SIZE:    RS.B    0
  36.  
  37.  
  38. ;======= OBJECT TABLE ======================================================
  39.  
  40. ; Must be first in object!!
  41. Starfish.table:
  42.     DC.L    Starfish.mainLoop
  43.     DC.L    Starfish.init
  44.     DC.L    rts
  45.     DC.L    Starfish.incField
  46.     DC.L    Starfish.decField
  47.     DC.L    Starfish.invField
  48.     DC.L    Starfish.drop
  49.     DC.L    Starfish.setZoom
  50.     DC.L    0
  51.  
  52.     IFND    DEMO_SYSTEM
  53.     INCLUDE    SFLY_DSP.S
  54.     TEXT
  55.     ENDC
  56.  
  57. ;======= INIT SUBROUTINE ===================================================
  58.  
  59. ; OUTPUT:
  60. ; d0.l: 0   = All clear, neg = Error! Not initialized!
  61. Starfish.init:
  62.     move.l    #Starfish.BLOCK_SIZE,d0
  63.     bsr.l    Mem.register
  64.  
  65.     lea    sine_tbl,a1
  66.     bsr.l    Matrix.init
  67.  
  68. .success:
  69.     moveq    #0,d0
  70.     rts
  71. .error:    moveq    #-1,d0
  72.     rts
  73.  
  74. ;======= REALTIME INIT SUBROUTINE ==========================================
  75.  
  76. Starfish.realtimeInit:
  77.     move.l    #rts,vbl_gfx
  78.  
  79.     bsr.l    Mem.getBlock
  80.  
  81.     move.l    d0,d1
  82.     addi.l    #Starfish.object,d1
  83.     move.l    d1,Starfish.objAdr
  84.     move.l    d0,d1
  85.     addi.l    #Starfish.armAngleTable,d1
  86.     move.l    d1,Starfish.angleTableAdr
  87.     move.l    d0,d1
  88.     addi.l    #Starfish.background,d1
  89.     move.l    d1,Starfish.backAdr
  90.  
  91.     lea    Starfish.shadowAdr,a0
  92.     move.l    d0,a1
  93.     adda.l    #Starfish.shadowTable,a1
  94.     clr.l    (a1)
  95.     move.l    a1,(a0)+
  96.     move.l    d0,a1
  97.     adda.l    #Starfish.shadowTable2,a1
  98.     clr.l    (a1)
  99.     move.l    a1,(a0)+
  100.     move.l    d0,a1
  101.     adda.l    #Starfish.shadowTable3,a1
  102.     clr.l    (a1)
  103.     move.l    a1,(a0)+
  104.  
  105.     lea    Starfish.shadowAdr2,a0
  106.     move.l    d0,a1
  107.     adda.l    #Starfish.shadowTable4,a1
  108.     clr.l    (a1)
  109.     move.l    a1,(a0)+
  110.     move.l    d0,a1
  111.     adda.l    #Starfish.shadowTable5,a1
  112.     clr.l    (a1)
  113.     move.l    a1,(a0)+
  114.     move.l    d0,a1
  115.     adda.l    #Starfish.shadowTable6,a1
  116.     clr.l    (a1)
  117.     move.l    a1,(a0)+
  118.  
  119.     bsr.l    HumanFly.init
  120.  
  121.     lea    Viewport.settingsTable,a0
  122.     move.w    #320,Viewport.XSCREEN(a0)
  123.     move.w    #200,Viewport.YSCREEN(a0)
  124.     move.w    #0,Viewport.XSTART(a0)
  125.     move.w    #0,Viewport.YSTART(a0)
  126.     move.w    #320,Viewport.XEND(a0)
  127.     move.w    #200,Viewport.YEND(a0)
  128.     move.w    #160,Viewport.XCENTER(a0)
  129.     move.w    #100,Viewport.YCENTER(a0)
  130.     move.w    #256+32,Viewport.ASPECT(a0)
  131.     move.w    #$100,Viewport.FOCAL(a0)
  132.     bsr.l    Viewport.update
  133.  
  134.     lea    Starfish.textureTable,a0
  135.     bsr.l    Polygon.init
  136.  
  137.     movea.l    Starfish.backAdr,a0
  138.     bsr.l    Primitive.setScreenbuffer
  139.  
  140.     move.w    #320,d6
  141.     move.w    #200,d7
  142.     movea.l    Starfish.backAdr,a0
  143.     bsr.w    Starfish.genMarble
  144.  
  145.     movea.l    Starfish.backAdr,a0
  146.     lea    Texture.sandPal,a1
  147.     move.w    #320*200-1,d7
  148.     clr.l    d0
  149. .convloop:
  150.     move.w    (a0),d0
  151.     move.w    (a1,d0.l*4),(a0)+
  152.     dbf    d7,.convloop
  153.  
  154.     bsr.l    ObjectRegistry.clear
  155.  
  156.     lea    Starfish.fixArmAngleTable,a1
  157.     movea.l    Starfish.objAdr,a0
  158.     bsr.w    Starfish.calcBendedObject
  159.  
  160. ; d0.l=size of generated object
  161.     movea.l    Starfish.objAdr,a0
  162.     bsr.l    ObjectRegistry.set
  163.  
  164.     move.w    #-1000,d0
  165.     move.w    #-0500,d1
  166.     move.w    #+3000,d2
  167.     clr.w    d3
  168.     clr.w    d4
  169.     clr.w    d5
  170.     bsr.w    Starfish.paint
  171.  
  172.     movea.l    Starfish.rectAddressTable,a0
  173.     bsr.l    PrimitiveMesh.paint
  174.  
  175.     move.w    $4BC.w,Starfish.startTime
  176.     bsr.w    Starfish.drop
  177.  
  178.     move.w    monitormode,d0
  179.     cmpi.w    #vga60,d0
  180.     beq.s    .vga60
  181.     cmpi.w    #vga100,d0
  182.     beq.s    .vga100
  183.     cmpi.w    #rgb50,d0
  184.     beq.s    .rgb50
  185. .vga60:    move.l    #vga60_16bit_320_200,Starfish.resRout
  186.     rts
  187. .vga100:move.l    #vga100_16bit_320_200,Starfish.resRout
  188.     rts
  189. .rgb50:    move.l    #rgb50_16bit_320_200,Starfish.resRout
  190.     rts
  191.  
  192. ;======= SCREENINIT SUBROUTINE =============================================
  193.  
  194. Starfish.initScreen:
  195.     movea.l    scr,a0
  196.     movea.l    Starfish.backAdr,a1
  197.     bsr.l    COPY_PIC32020016
  198.     rts
  199.  
  200. ;======= MAINLOOP SUBROUTINE ===============================================
  201.  
  202. Starfish.mainLoop:
  203.     move.l    frmcnt,d0
  204.     sub.l    lastframecount,d0
  205.     bne.s    .end_realtime_init
  206.     move.l    d0,-(sp)
  207.     bsr.w    Starfish.realtimeInit
  208.     move.l    (sp)+,d0
  209. .end_realtime_init:
  210.     cmpi.l    #3,d0
  211.     bhs.s    .end_screeninit
  212.     bsr.w    Starfish.initScreen
  213. .end_screeninit:
  214.  
  215.     tst.w    Starfish.zooming
  216.     bne.s    .zoom_it
  217.     bsr.w    Starfish.paintScene
  218.     bra.s    .end_paint
  219. .zoom_it:
  220.     bsr.w    Starfish.zoom
  221. .end_paint:
  222.  
  223.     lea    scr,a0
  224.     move.l    (a0)+,d0
  225.     move.l    (a0)+,d1
  226.     move.l    (a0),-4(a0)
  227.     move.l    d0,(a0)
  228.     move.l    d1,-8(a0)
  229.  
  230.     movea.l    Starfish.resRout,a0
  231.     suba.l    a1,a1
  232.     movea.l    d0,a2
  233. .again:    bsr.l    Screen.requestUpdate
  234.     tst.l    d0
  235.     bmi.s    .again
  236.     clr.l    Starfish.resRout
  237.  
  238.     rts
  239.  
  240. ;======= OBJECT SUBROUTINES ================================================
  241.  
  242. Starfish.incField:
  243.     addi.w    #$0020,Starfish.fieldStrength
  244.     rts
  245.  
  246. Starfish.decField:
  247.     subi.w    #$0020,Starfish.fieldStrength
  248.     rts
  249.  
  250. Starfish.invField:
  251.     neg.w    Starfish.fieldStrength
  252.     rts
  253.  
  254. Starfish.drop:
  255.     st    Starfish.falling
  256.     clr.w    Starfish.zooming
  257.     rts
  258.  
  259. Starfish.setZoom:
  260. ; Copy current screen to background-buffer.
  261.     movea.l    scr+8,a1
  262.     movea.l    Starfish.backAdr,a0
  263.     bsr.l    COPY_PIC32020016
  264.  
  265.     st    Starfish.zooming
  266.     move.w    $04BC.w,Starfish.zoomStart
  267.     rts
  268.  
  269. ; Very small and nice 'marble' texture generator.
  270. ; Ripped from lost 4ktro by lucky/inter.
  271. ; INPUT:
  272. ; d6.w=width (w)
  273. ; d7.w=height (w)
  274. ; a0: dst buffer (w*h words)
  275. Starfish.genMarble:
  276. ; Make a row of noise...
  277.     move.w      D6,D0
  278.     bra.s       .marmor_w6
  279. .marmor_l0:
  280.     move.w      D1,(A0)+
  281. .marmor_w6:
  282.     rol.l       #5,D5
  283.     eori.l      #$3551462F,D5
  284.     addq.l      #1,D5
  285.     move.w      D5,D2
  286.     and.w       #7,D2
  287.     cmp.w       #7,D2
  288.     bne.s       .marmor_w4
  289.     moveq       #6,D2
  290. .marmor_w4:
  291.     add.w       D2,D1
  292.     subq.w      #3,D1
  293.     bpl.s       .marmor_w0
  294.     moveq       #0,D1
  295. .marmor_w0:
  296.     cmp.w       #$27,D1
  297.     ble.s       .marmor_w1
  298.     moveq       #$27,D1
  299. .marmor_w1:
  300.     dbra        D0,.marmor_l0
  301.  
  302. ; Back to rowstart...
  303.     move.w      D6,D0
  304.     neg.w       D0
  305.     lsl.w       #1,D0
  306.     lea         0(A0,D0.w),A1
  307.  
  308. ; Average and add a pass of noise to the whole texture (?).
  309. ; a1,a2,a3 lag behind a0, so output hights are 'recycled' for averaging.
  310. ; Nice trick. Very fast.
  311.     lea         2(A1),A2
  312.     lea         4(A2),A3
  313.     move.w      D7,D0
  314.     subq.w      #1,D0
  315.     mulu.w      D6,D0                ; d0.w=w*(h-1)
  316.     subq.w      #1,D0
  317. .marmor_l1:
  318.     move.w      (A2)+,D1
  319.     add.w       D1,D1
  320.     add.w       (A1)+,D1
  321.     add.w       (A3)+,D1
  322.     lsr.w       #2,D1
  323.     move.l    d5,d2
  324.     rol.l       #5,D5
  325.     eori.l      #-$3A5E8A3B,D5
  326.     addq.l      #7,D5
  327.     move.w      D5,D2
  328.     and.w       #7,D2
  329.     cmp.w       #7,D2
  330.     bne.s       .marmor_w5
  331.     moveq       #6,D2
  332. .marmor_w5:
  333.     add.w       D2,D1
  334.     subq.w      #3,D1
  335.     bpl.s       .marmor_w2
  336.     moveq       #0,D1
  337. .marmor_w2:
  338.     cmp.w       #39,D1
  339.     ble.s       .marmor_w3
  340.     moveq       #39,D1
  341. .marmor_w3:
  342.     move.w      D1,(A0)+
  343.     dbf    D0,.marmor_l1
  344.  
  345.     rts         
  346.  
  347. ; Update all arms of starfish according to a stream (a simple field).
  348. ; INPUT:
  349. ; d0.w=rot-offset
  350. ; a0: armtable
  351. Starfish.update:
  352.     moveq    #Starfish.ARMS-1,d7
  353.     move.w    d0,.rot
  354.  
  355. .loop:    move.w    Starfish.fieldStrength,d1
  356.     move.w    d7,d0
  357.     mulu.w    #sintbllen/Starfish.ARMS,d0
  358.     add.w    .rot(pc),d0
  359.     Do_SinModulo    d0
  360.     move.w    d0,(a0)                ; Store baseangle.
  361.     move.w    d7,-(sp)
  362.     bsr    Starfish.updateArm
  363.     move.w    (sp)+,d7
  364. ; a0: next armtable    
  365.     dbf    d7,.loop    
  366.     rts
  367.  
  368. .rot:    DC.W    0
  369.  
  370. ; Updates bent arm. Modelled as a string of massless nodes with some
  371. ; elastic properties..
  372. ;
  373. ; Seems to work, even if it neglect mass, friction of several kinds, etc..
  374. ; Abstraction (cheating) rules! =:-)
  375. ;
  376. ; theta[k, t+1] = theta[k, t] + d_theta[k, t]
  377. ;
  378. ;                             p
  379. ; d_theta[k+1]=(1-theta[k]/pi) *cos(sumtheta[k])*F
  380. ;
  381. ; sumtheta[k]=theta[0]+theta[1]+...+theta[k] (angle from armaxis)
  382. ;
  383. ; F=applied force
  384. ; p=power term used to limit big angle changes
  385. ;
  386. ; btw. p=32 gives reasonably stable results. (quite sick i know!)
  387. ; 
  388. ; INPUT:
  389. ; d1.w=force in pos y direction (F) (8:8)
  390. ; a0: arm angletable
  391. ; OUTPUT:
  392. ; a0: end of angletable
  393. Starfish.updateArm:
  394.     lea    sine_tbl,a1
  395.     moveq    #Starfish.RINGS-1,d7
  396.     move.w    (a0)+,d2            ; d2.w=startangle
  397.  
  398. .loop:    move.w    (a0),d0
  399.     lsr.w    #5,d0
  400.  
  401.     Do_SinModulo    d0            ; d0.w=theta[k, t]
  402.     add.w    d0,d2
  403.     Do_SinModulo    d2            ; d2.w=sumtheta[k, t]
  404.     Get_Cos    a1,d2,d3            ; d3.w=cos(sumtheta[k, t])
  405.     move.w    #sintbllen/2-1,d4
  406.     sub.w    d0,d4
  407.     Do_SinModulo    d4
  408.     mulu.w    #$10000/sintbllen,d4        ; d4.w=1-theta[k, t]/pi (sgn frac)
  409.     REPT    5
  410.     muls.w    d4,d4
  411.     add.l    d4,d4
  412.     swap    d4
  413.     ENDR
  414.     muls.w    d4,d3
  415.     add.l    d3,d3
  416.     swap    d3                ; d3.w=(1-theta[k, t]/pi)*cos(sumtheta[k, t])
  417.     muls.w    d1,d3
  418.  
  419.     tst.w    d3
  420.     swap    d3
  421.     bpl.s    .end_round
  422.     addq.w    #1,d3
  423. .end_round:
  424.  
  425. ; Neglect minute angle differences..
  426.     move.w    d3,d4
  427.     bpl.s    .pos1
  428.     neg.w    d4
  429. .pos1:    cmpi.w    #5,d4
  430.     bgt.s    .diff_ok
  431.     clr.w    d3
  432. .diff_ok:
  433.  
  434. ; Update angle..
  435. ; d3.w=F*(1-theta[k, t]/pi)*cos(sumtheta[k, t])
  436. ; d3.w=theta[k, t+1]
  437.     add.w    (a0),d3
  438.     move.w    d3,d4
  439.     bpl.s    .pos
  440.     neg.w    d3
  441. .pos:    cmpi.w    #Starfish.MAX_BEND,d3
  442.     blt.s    .value_in_range
  443.     move.w    #Starfish.MAX_BEND,d3
  444. .value_in_range:
  445.     tst.w    d4
  446.     bpl.s    .ok
  447.     neg.w    d3
  448. .ok:    move.w    d3,(a0)+            ; Store new theta[k].
  449.     dbf    d7,.loop    
  450.     rts
  451.  
  452.     IFNE    0
  453. ; Paints a wireframe respresentation of the massless string model starfish.
  454. ; 
  455. ;               [cos(sumtheta[k])]
  456. ; p[k+1]=p[k]+L*[                ] 
  457. ;               [sin(sumtheta[k])]
  458. ;
  459. Starfish.paintWF:
  460.     movea.l    Starfish.angleTableAdr,a0
  461.     moveq    #Starfish.ARMS-1,d7
  462.  
  463. .arm_loop:
  464.     moveq    #Starfish.RINGS-1,d6
  465.     movea.w    #160,a1
  466.     movea.w    #100,a2
  467.     move.w    (a0)+,d0            ; d0.w=startangle
  468.  
  469. .point_loop:
  470.     move.w    (a0)+,d1
  471.     lsr.w    #5,d1
  472.     add.w    d1,d0
  473.     Do_SinModulo    d0
  474.     move.w    d0,-(sp)
  475.     Get_SinCos    sine_tbl,d0,d1,d2
  476.     muls.w    #20*2,d1
  477.     muls.w    #20*2,d2
  478.     swap    d1
  479.     swap    d2
  480.     move.l    a1,d0
  481.     adda.w    d1,a1
  482.     move.l    a2,d1
  483.     adda.w    d2,a2
  484.     move.l    a1,d2
  485.     move.l    a2,d3
  486.     movem.l    d6-a2,-(sp)
  487.     bsr.l    Line.paintFlatshaded
  488.     movem.l    (sp)+,d6-a2
  489.     move.w    (sp)+,d0
  490.     dbf    d6,.point_loop
  491.  
  492.     dbf    d7,.arm_loop
  493.     rts
  494.     ENDC
  495.  
  496. ; Generates a starfish that can have bended arms.
  497. ; Not the best possible model for normal-based shading. It needs patching.
  498. ; todo: skewed normals on arms.. patched normals close to binder!
  499. ;
  500. ; parametrisation:
  501. ;
  502. ; 0<=alpha<2pi,         0<=beta<2pi,    0<=t<=1, l=AL*t
  503. ; controls pos in ring, controls armnr, controls pos in arm (ringnumber)
  504. ;
  505. ; AL=*armlength*
  506. ;
  507. ;      A
  508. ;  _________
  509. ;  \b  |  c/
  510. ;   \ L|  /
  511. ;  B \ | / B
  512. ;     \|/
  513. ;      a
  514. ;
  515. ; L=AL/(#rings+1), a=2pi/#arms
  516. ;
  517. ; tan(a/2)=tan(pi/#arms)=(A/2)/C=A/2L
  518. ;
  519. ; =>
  520. ;
  521. ;                         2*AL*tan(pi/#arms)
  522. ; A = 2L*tan(pi/#arms) = -------------------- = *armwidth*
  523. ;                            (#rings+1)
  524. ; 
  525. ;---------------------------------------------------------------------------
  526. ;
  527. ; Parametrisation of bended arms:
  528. ;
  529. ; su=cos(alpha)(1-t)A/2, sv=sin(alpha)(1-t)A/2 (scalars of u, v)
  530. ;                                                          -  -
  531. ; d is direction vector of arm, |d| = 1, d.z=0
  532. ; -                              -
  533. ; c is center vector. c[t+1]=c[t]+sd[t], c[0]=0
  534. ; -                   -      -    --     -    -
  535. ;
  536. ;                      [cos(sumtheta[t]+beta)]
  537. ; sd[t] = ll*d[t] = ll*[sin(sumtheta[t]+beta)]
  538. ; --                   [        0            ]
  539. ;
  540. ; a = c + su*u+sv*v
  541. ; -   -      -    -
  542. ;
  543. ; a.x   c.x -su*d.y
  544. ; a.y = c.y +su*d.x
  545. ; a.z   c.z +sv
  546. ;
  547. ; u . d = v . d = u . v = 0 & |d| = 1 & d.z = 0
  548. ; -   -   -   -   -   -        -
  549. ;
  550. ; =>
  551. ;
  552. ;     [-d.y]       [ 0 ]
  553. ; u = [+d.x] , v = [ 0 ]
  554. ; -   [ 0  ]   -   [ 1 ]
  555. ;
  556. ;---------------------------------------------------------------------------
  557. ;
  558. ; normals given by biasing (0,0,1),
  559. ; rotation around x-axis alpha degrees,
  560. ; rotation around z-axis beta degrees.
  561. ;
  562. ; n.x          1       [+A*cos(beta)+AL*sin(alpha)*cin(beta)]
  563. ; n.y = -------------- [-A*sin(beta)+AL*sin(alpha)*cos(beta)]
  564. ; n.z   sqrt(A^2+AL^2) [+AL*cos(alpha)                      ]
  565. ;
  566. ;       [+A'*cos(beta)+AL'*sin(alpha)*sin(beta)]
  567. ;     = [-A'*sin(beta)+AL'*sin(alpha)*cos(beta)]
  568. ;       [+AL'*cos(alpha)                       ]
  569. ;
  570. ; A' =A/sqrt(A^2+AL^2)
  571. ; AL'=AL/sqrt(A^2+AL^2)
  572. ;
  573. ;---------------------------------------------------------------------------
  574. ;
  575. ; INPUT:
  576. ; a0: dst object
  577. ; a1: arm angletables
  578. ; OUTPUT:
  579. ; d0.l=size of object
  580. Starfish.calcBendedObject:
  581.     movea.l    a0,a6                ; a6: dst object
  582.     movea.l    a1,a2                ; a2: armangle tables
  583.  
  584. ; Output vertices..
  585.     move.w    #2*Starfish.POINTS,(a0)+    ; Store #vertices+#normals.
  586.     move.w    #Starfish.POINTS,(a0)+        ; Store #normals.
  587.     lea    Starfish.POINTS*Vertex.SIZE(a0),a3
  588.     lea    sine_tbl,a1
  589.     moveq    #Starfish.ARMS-1,d7
  590.  
  591. ; Calc A/2..
  592.     move.w    #sintbllen/(2*Starfish.ARMS),d0
  593.     Get_SinCos    a1,d0,d0,d1
  594. ; 0<=bla<=pi/4  =>  0<=sin(bla)<=1
  595.     subq.w    #1,d0
  596.     swap    d0
  597.     clr.w    d0
  598.     divu.w    d1,d0
  599. ; d0.w=tan(pi/#arms) (frac)
  600.     mulu.w    #Starfish.LE,d0
  601.     move.l    d0,d1
  602.     tst.w    d0
  603.     swap    d0
  604.     bpl.s    .end_round_a
  605.     addq.w    #1,d0
  606. .end_round_a:
  607.     move.w    d0,.a_div_2
  608. ; .a_div_2.w=A/2=L*tan(pi/#arms) (int)
  609.  
  610. ; calc A', AL'
  611.     move.w    #Starfish.ARMLENGTH,d0
  612.     mulu.w    d0,d0                    ; d0.l=AL*AL
  613.     add.l    d1,d1
  614.     move.l    d1,d4
  615.     swap    d1
  616.     mulu.w    d1,d1                    ; d1.l=A*A
  617.     add.l    d0,d1                    ; d1.l=AL^2+A^2
  618.     bsr.l    Math.sqrt                ; d0.l=sqrt(A^2+AL^2) (16:16)
  619.     swap    d0                    ; d0.w=sqrt(A^2+AL^2) (int)
  620.     clr.l    d3
  621.     move.w    #Starfish.ARMLENGTH,d3
  622.     swap    d3
  623.     lsr.l    d3                    ; for signed crap
  624.     divu.w    d0,d3
  625.     move.w    d3,.al_t
  626.     lsr.l    d4
  627.     divu.w    d0,d4                    ; for signed crap
  628.     move.w    d4,.a_t
  629.  
  630. .arm_pointloop:
  631.     swap    d7
  632.     move.w    #Starfish.RINGS,d7
  633.  
  634.     move.w    (a2)+,d0
  635.     move.w    d0,.sum_theta
  636. ; d0.w=beta
  637.  
  638. ; Reset c, calc d[0].
  639. ;       -       -
  640.     Do_SinModulo    d0
  641.     Get_SinCos    a1,d0,d0,d1
  642. ; d0.w=d.x, d1.w=d.y
  643.     move.w    d0,.dx
  644.     move.w    d1,.dy
  645.     muls.w    #49*Starfish.LE*2/50,d0
  646.     muls.w    #49*Starfish.LE*2/50,d1
  647.     swap    d0
  648.     swap    d1
  649.     move.w    d0,.cx
  650.     move.w    d1,.cy
  651.  
  652. .ring_pointloop:
  653.     moveq    #Starfish.RINGPOINTS-1,d6
  654.  
  655. ; Calc 1-t.
  656.     move.w    d7,d0
  657.     mulu.w    #$7FFF/Starfish.RINGS,d0
  658.     move.w    d0,.one_min_t
  659. ; .one_min_t.w=1-t (sgn frac)
  660.  
  661. ; Calc points in ring...
  662. .pointloop:
  663.     move.w    d6,d0
  664.     mulu.w    #sintbllen/Starfish.RINGPOINTS,d0    ; d0.w=alpha
  665.     Get_SinCos    a1,d0,d0,d1
  666. ; d0.w=sin(alpha), d1.w=cos(alpha) (sgn frac)
  667.     exg.l    d0,d1
  668.     movem.w    d0-d1,.sin_alpha
  669.  
  670. ; Calc su, sv.
  671.     move.w    .a_div_2(pc),d2            ; d2.w=A/2
  672.     mulu.w    .one_min_t(pc),d2
  673.     add.l    d2,d2
  674.     tst.w    d2
  675.     swap    d2
  676.     bpl.s    .end_round_ta
  677.     addq.w    #1,d2
  678. .end_round_ta:
  679.     move.w    d2,d3
  680. ; d2.w=d3.w=(1-t)A/2 (sgn frac)
  681.     
  682.     muls.w    d0,d2
  683.     add.l    d2,d2
  684.     tst.w    d2
  685.     swap    d2
  686.     bpl.s    .end_round_su
  687.     addq.w    #1,d2
  688. .end_round_su:
  689.     move.w    d2,.su
  690.  
  691.     move.w    d0,d4                ; d4.w=cos(alpha)
  692.     move.w    d1,d5                ; d5.w=sin(alpha)
  693.  
  694. ; Todo: apply scale to this!
  695.     muls.w    d1,d3
  696.     add.l    d3,d3
  697.     tst.w    d3
  698.     swap    d3
  699.     bpl.s    .end_round_sv
  700.     addq.w    #1,d3
  701. .end_round_sv:
  702.     move.w    d3,.sv
  703.  
  704. ; a.x = c.x -su*d.y
  705.     move.w    .su(pc),d0
  706.     muls.w    .dy(pc),d0
  707.     add.l    d0,d0
  708.     swap    d0
  709.     move.w    .cx(pc),d1
  710.     sub.w    d0,d1
  711.     move.w    d1,(a0)+            ; Store x.
  712.  
  713. ; y negated for backface elend
  714. ; a.y = c.y +su*d.x
  715.     move.w    .su(pc),d0
  716.     muls.w    .dx(pc),d0
  717.     add.l    d0,d0
  718.     swap    d0
  719.     add.w    .cy(pc),d0
  720.     neg.w    d0
  721.     move.w    d0,(a0)+            ; Store y.
  722.  
  723. ; a.z = +sv
  724.     move.w    .sv(pc),(a0)+            ; Store z.
  725.  
  726. ;     [+A'*cos(beta)+AL'*sin(alpha)*sin(beta)]
  727. ; n = [-A'*sin(beta)+AL'*sin(alpha)*cos(beta)]
  728. ; -   [+AL'*cos(alpha)                       ]
  729.     IFNE    0
  730.     move.w    .dx(pc),d0            ; d0.w=cos(beta)
  731.     move.w    .dy(pc),d1            ; d1.w=sin(beta)
  732.     move.w    d0,d2                ; d2.w=cos(beta)
  733.     move.w    d1,d3                ; d3.w=sin(beta)
  734.  
  735. ; Calculate n.x.
  736.     muls.w    .a_t(pc),d0            ; d0.l=A'*cos(beta)/2
  737.     muls.w    .al_t(pc),d1            ; d1.l=AL'*sin(beta)/2
  738.     add.l    d1,d1
  739.     swap    d1
  740.     muls.w    .sin_alpha(pc),d1        ; d1.l=AL'*sin(alpha)*sin(beta)/2
  741.     add.l    d1,d0
  742.     add.l    d0,d0                ; d0.l=n.x (16:16)
  743.     swap    d0
  744.     muls.w    #$E0,d0
  745.     swap    d0
  746.     move.w    d0,Vertex.X(a3)            ; Store n.x.
  747.     
  748. ; Calculate n.y.
  749.     muls.w    .a_t(pc),d3            ; d3.l=A'*sin(beta)/2
  750.     muls.w    .al_t(pc),d2            ; d2.l=AL'*cos(beta)/2    
  751.     add.l    d2,d2
  752.     swap    d2
  753.     muls.w    .sin_alpha(pc),d2        ; d2.l=AL'*sin(alpha)*cos(beta)/2
  754.     sub.l    d3,d2
  755.     add.l    d2,d2                ; d2.l=n.y (16:16)
  756.     swap    d2
  757.     muls.w    #$E0,d2
  758.     swap    d2
  759.     move.w    d2,Vertex.Y(a3)            ; Store n.y.
  760.  
  761. ; Calculate n.z.
  762.     move.w    .al_t(pc),d0            ; d0.w=AL'
  763.     muls.w    .cos_alpha(pc),d0        ; d0.l=AL'*cos(alpha)/2
  764.     add.l    d0,d0                ; d0.l=AL'*cos(alpha)
  765.     swap    d0                ; d0.w=AL'*cos(alpha)=n.z
  766.     muls.w    #$E0,d0
  767.     swap    d0
  768.     move.w    d0,Vertex.Z(a3)            ; Store n.z.
  769.  
  770.     addq    #Vertex.SIZE,a3
  771.  
  772.     ELSE
  773. ; old, unbiased normal..
  774.     move.w    d4,d2
  775.     muls.w    .dy(pc),d2
  776.     add.l    d2,d2
  777.     swap    d2
  778.     neg.w    d2
  779.     asr.w    #8,d2
  780.     move.w    d2,(a3)+            ; Store n.x.
  781.     move.w    d4,d2
  782.     muls.w    .dx(pc),d2
  783.     add.l    d2,d2
  784.     swap    d2
  785.     neg.w    d2
  786.     asr.w    #8,d2
  787.     move.w    d2,(a3)+            ; Store n.y
  788.     asr.w    #8,d5
  789.     move.w    d5,(a3)+            ; Store n.z.
  790.     ENDC
  791.  
  792.     dbf    d6,.pointloop
  793.  
  794.  
  795.     move.w    (a2)+,d0            ; d0.w=theta[t+1]<<5
  796.     lsr.w    #5,d0                ; d0.w=theta[t+1]
  797.     add.w    d0,.sum_theta            ; d0.w=sumtheta[t+1]
  798.  
  799. ; Calc c[t+1] = c[t] + d[t]
  800. ;      -        -      -
  801.     move.w    .sum_theta(pc),d0
  802.     Do_SinModulo    d0
  803.     Get_SinCos    a1,d0,d0,d1
  804. ; d0.w=d.x, d1.w=d.y
  805.     move.w    d0,.dx
  806.     move.w    d1,.dy
  807.     muls.w    #Starfish.ARMLENGTH*2/Starfish.RINGS,d0
  808.     muls.w    #Starfish.ARMLENGTH*2/Starfish.RINGS,d1
  809.     swap    d0
  810.     swap    d1
  811. ; d0.w=sd.x, d1.w=sd.y
  812.     add.w    d0,.cx
  813.     add.w    d1,.cy
  814.  
  815.     subq.w    #1,d7
  816.     bgt    .ring_pointloop
  817.  
  818.     move.w    .cx(pc),(a0)+            ; Store x.
  819.     move.w    .cy(pc),d0
  820.     neg.w    d0
  821.     move.w    d0,(a0)+            ; Store y.
  822.     clr.w    (a0)+                ; Store z.
  823.  
  824.     move.w    .dx(pc),d0
  825.     asr.w    #8,d0
  826.     cmpi.w    #$FF80,d0
  827.     bgt.s    .ok
  828.     move.w    #$FF81,d0
  829. .ok:    move.w    d0,(a3)+            ; Store n.x.
  830.     move.w    .dy(pc),d0
  831.     asr.w    #8,d0
  832.     neg.w    d0
  833.     cmpi.w    #$FF80,d0
  834.     bgt.s    .ok2
  835.     move.w    #$FF81,d0
  836. .ok2:    move.w    d0,(a3)+            ; Store n.y.
  837.     clr.w    (a3)+                ; Store n.z.
  838.  
  839.     swap    d7
  840.     dbf    d7,.arm_pointloop
  841.  
  842. ; Store binder vertices..
  843.     clr.l    (a0)+                ; Store (x,y)
  844.     move.w    #+Starfish.TOPDEPTH,(a0)+
  845.     clr.l    (a0)+                ; Store (x,y)
  846.     move.w    #-Starfish.TOPDEPTH,(a0)+
  847.     clr.l    (a3)+
  848.     move.w    #+127,(a3)+
  849.     clr.l    (a3)+
  850.     move.w    #-127,(a3)+
  851.  
  852.     movea.l    a3,a0                ; a0: end of vertices/normals
  853.  
  854. ; texels
  855.     clr.w    (a0)+
  856.  
  857. ; polys
  858. ; arm polys
  859. ; todo: fuck this around cos of changed spikepoint position!
  860.     move.w    #Starfish.POLYS,(a0)+
  861.     clr.w    d2
  862.     moveq    #Starfish.ARMS-1,d7
  863.  
  864. .poly_armloop:
  865.  
  866. ; Output spike triangles in arm..
  867.     moveq    #Starfish.RINGPOINTS-1,d5
  868.  
  869. .spike_polyloop:
  870. ; Output polyhead.
  871.     move.w    #Polygon.TRI|Polygon.ENVMAPPED|0,(a0)+
  872.  
  873.     clr.l    d0
  874.     move.w    d5,d0
  875.     addq.w    #1,d0
  876.     divu.w    #Starfish.RINGPOINTS,d0
  877.     swap    d0
  878.     addi.w    #Starfish.ARMPOINTS-1-Starfish.RINGPOINTS,d0
  879.     add.w    d2,d0
  880.     move.w    d0,(a0)+
  881.  
  882.     move.w    #Starfish.ARMPOINTS-1,d0
  883.     add.w    d2,d0
  884.     move.w    d0,(a0)+            ; Store spikeref.
  885.  
  886.     move.w    d5,d0
  887.     addi.w    #Starfish.ARMPOINTS-1-Starfish.RINGPOINTS,d0
  888.     add.w    d2,d0
  889.     move.w    d0,(a0)+
  890.  
  891. ; Store normal-refs..
  892.     REPT    3
  893.     move.w    -6(a0),d0
  894.     addi.w    #Starfish.POINTS,d0
  895.     move.w    d0,(a0)+
  896.     ENDR
  897.  
  898.     dbf    d5,.spike_polyloop
  899.  
  900.     moveq    #Starfish.RINGS-2,d6
  901. .poly_ringloop:
  902.  
  903.     moveq    #Starfish.RINGPOINTS-1,d5
  904. .polyloop:
  905. ; Output polyhead.
  906.     move.w    #Polygon.QUAD|Polygon.ENVMAPPED|0,(a0)+
  907.  
  908.     move.w    d6,d0
  909.     mulu.w    #Starfish.RINGPOINTS,d0
  910.     add.w    d2,d0
  911. ; row*n + i
  912.     move.w    d0,d1
  913.     add.w    d5,d1
  914.     move.w    d1,(a0)+
  915. ; row*n + [(i+1) mod n]
  916.     clr.l    d1
  917.     move.w    d5,d1
  918.     addq.w    #1,d1
  919.     divu.w    #Starfish.RINGPOINTS,d1
  920.     swap    d1
  921.     add.w    d0,d1
  922.     move.w    d1,(a0)+
  923. ; row*(n+1) + [(i+1) mod n]
  924.     addi.w    #Starfish.RINGPOINTS,d1
  925.     move.w    d1,(a0)+
  926. ; row*(n+1) + i
  927.     move.w    d0,d1
  928.     add.w    d5,d1
  929.     addi.w    #Starfish.RINGPOINTS,d1
  930.     move.w    d1,(a0)+
  931.  
  932. ; Store normal-refs..
  933.     REPT    4
  934.     move.w    -8(a0),d0
  935.     addi.w    #Starfish.POINTS,d0
  936.     move.w    d0,(a0)+
  937.     ENDR
  938.     
  939.     dbf    d5,.polyloop
  940.  
  941.     dbf    d6,.poly_ringloop
  942.  
  943.     addi.w    #Starfish.ARMPOINTS,d2
  944.     dbf    d7,.poly_armloop
  945.  
  946. ; binder polys
  947.     clr.w    d2
  948.     moveq    #Starfish.ARMS-1,d7
  949.  
  950. .bindpoly_armloop:
  951.     moveq    #Starfish.RINGPOINTS-1,d6
  952.  
  953. .bindpoly_ringloop:
  954. ; Output polyhead.
  955.     move.w    #Polygon.TRI|Polygon.ENVMAPPED|0,(a0)+
  956.  
  957.     move.w    #Starfish.RINGPOINTS-2,d0
  958.     cmpi.w    #Starfish.RINGPOINTS-1,d6
  959.     bne.s    .no_adj
  960.     move.w    #Starfish.RINGPOINTS-1,d0
  961.     bra.s    .end_adj
  962. .no_adj:sub.w    d6,d0
  963. .end_adj:
  964.     add.w    d2,d0
  965.     move.w    d0,(a0)+
  966.  
  967.     cmpi.w    #Starfish.RINGPOINTS/2,d6
  968.     bhs.s    .oki
  969.     move.w    #Starfish.BINDPOINT1,(a0)+
  970.     bra.s    .end_store_bindpoint
  971. .oki:    move.w    #Starfish.BINDPOINT2,(a0)+
  972. .end_store_bindpoint:
  973.  
  974.     move.w    #Starfish.RINGPOINTS-1,d0
  975.     sub.w    d6,d0
  976.     add.w    d2,d0
  977.     move.w    d0,(a0)+
  978.  
  979. ; Store normal-refs..
  980.     REPT    3
  981.     move.w    -6(a0),d0
  982.     addi.w    #Starfish.POINTS,d0
  983.     move.w    d0,(a0)+
  984.     ENDR
  985.  
  986.     dbf    d6,.bindpoly_ringloop
  987.  
  988.     addi.w    #Starfish.ARMPOINTS,d2
  989.     dbf    d7,.bindpoly_armloop
  990.  
  991. ; Calc size of object..
  992.     move.l    a0,d0
  993.     sub.l    a6,d0
  994.     rts
  995.  
  996. .cx:    DC.W    0
  997. .cy:    DC.W    0
  998. .dx:    DC.W    0
  999. .dy:    DC.W    0
  1000. .sin_alpha:
  1001.     DC.W    0
  1002. .cos_alpha:
  1003.     DC.W    0
  1004. .a_t:    DC.W    0
  1005. .al_t:    DC.W    0
  1006. .a_div_2:
  1007.     DC.W    0
  1008. .one_min_t:
  1009.     DC.W    0
  1010. .su:    DC.W    0
  1011. .sv:    DC.W    0
  1012. .sum_theta:
  1013.     DC.W    0
  1014.  
  1015. ; INPUT:
  1016. ; d0.w=x offset
  1017. ; d1.w=y offset
  1018. ; d2.w=z offset
  1019. ; d3.w=xrot
  1020. ; d4.w=yrot
  1021. ; d5.w=zrot
  1022. Starfish.paint:
  1023.     movem.w    d0-d2,-(sp)
  1024.     movem.w    d3-d5,-(sp)
  1025.  
  1026.     movea.l    Starfish.shadowAdrAdr,a0    ; a0: log table adrs
  1027.     movea.l    (a0),a0                ; a0: current log table
  1028.     bsr.l    PrimitiveMesh.newShadowed
  1029.  
  1030.     movem.w    (sp)+,d0-d2
  1031.     bsr.l    Matrix.generate
  1032.  
  1033.     movem.w    (sp)+,d0-d2
  1034.     bsr.l    Matrix.translate
  1035.     bsr.l    Matrix.push
  1036.     moveq    #TransformObject.BACKFACE_CULLING|TransformObject.PERSPECTIVATE,d0
  1037.     moveq    #0,d1
  1038.     bsr.l    TransformObject.transform
  1039.     bsr.l    Matrix.pop
  1040.  
  1041.     bsr.l    PrimitiveMesh.sortZ
  1042.  
  1043.     bsr.l    PrimitiveMesh.complete
  1044.  
  1045.     rts
  1046.  
  1047. Starfish.paintScene:
  1048.     movea.l    scr,a0
  1049.     bsr.l    Primitive.setScreenbuffer
  1050.  
  1051.     bsr.l    ObjectRegistry.clear
  1052.  
  1053.     movea.l    Starfish.angleTableAdr,a1
  1054.     movea.l    Starfish.objAdr,a0
  1055.     bsr.w    Starfish.calcBendedObject
  1056.  
  1057. ; d0.l=size of generated object
  1058.     movea.l    Starfish.objAdr,a0
  1059.     bsr.l    ObjectRegistry.set
  1060.  
  1061.     move.w    #+0600,d0
  1062.     move.w    #+0100,d1
  1063.     move.w    #+3000,d2
  1064.     tst.w    Starfish.falling
  1065.     beq.s    .not_falling
  1066.     move.w    $04BC.w,d2
  1067.     sub.w    Starfish.startTime,d2
  1068.     add.w    d2,d2
  1069.  
  1070. ; Use a squareroot for the movement.
  1071.     movem.w    d0-d1,-(sp)
  1072.     clr.l    d1
  1073.     move.w    d2,d1
  1074.     lsl.l    #8,d1
  1075.     lsl.l    #3,d1
  1076.     bsr.l    Math.sqrt
  1077.     move.l    d0,d2
  1078.     swap    d2
  1079.     movem.w    (sp)+,d0-d1
  1080.  
  1081.     cmpi.w    #+3000,d2
  1082.     blt.s    .depth_ok
  1083.     move.w    #+3000,d2
  1084.     clr.w    Starfish.falling
  1085. .not_falling:
  1086.     clr.w    d3
  1087.     clr.w    d4
  1088.     clr.w    d5
  1089. ;    bra.s    .paint
  1090. .depth_ok:
  1091.     clr.w    d3
  1092.     move.w    $04BC.w,d4
  1093.     sub.w    Starfish.startTime,d4
  1094.     lsl.w    #2,d4
  1095.     Do_SinModulo    d4
  1096.     Get_Sin    sine_tbl,d4,d4
  1097.  
  1098. ; Recycle the squareroot movement for the 'swing' amplitude.
  1099.     move.w    #3000,d6
  1100.     sub.w    d2,d6
  1101.     muls.w    d6,d4
  1102.     swap    d4
  1103.     asr.w    #2,d4
  1104.  
  1105.     clr.w    d5
  1106. .paint:    bsr.w    Starfish.paint
  1107.  
  1108. ;- parallel shit -----------------------------------------------------------
  1109.     movea.l    Starfish.angleTableAdr,a0
  1110.     
  1111.     move.w    Starfish.oldRot,d0
  1112.     tst.w    Starfish.falling
  1113.     beq.s    .rot_calced
  1114.     move.w    $04BC.w,d0
  1115.     sub.w    Starfish.startTime,d0
  1116.     lsr.w    #2,d0
  1117.     addi.w    #$200,d0
  1118.     move.w    d0,Starfish.oldRot
  1119. .rot_calced:
  1120.     bsr.w    Starfish.update
  1121.  
  1122.     IFNE    1
  1123. ; Restore shadow..
  1124.     movea.l    Starfish.backAdr,a0
  1125.     movea.l    Starfish.shadowAdrAdr+4,a1    ; a1: phys table adrs
  1126.     movea.l    (a1),a1                ; a1: current phys table
  1127.     bsr.l    Polygon.restoreShadows
  1128.     ELSE
  1129.     movea.l    scr,a0
  1130.     movea.l    Starfish.backAdr,a1
  1131.     bsr.l    COPY_PIC32020016
  1132.     ENDC
  1133.  
  1134. ;- end of parallel shit ----------------------------------------------------
  1135.  
  1136.     movea.l    Starfish.rectAddressTable,a0
  1137.     bsr.l    PrimitiveMesh.paint
  1138.  
  1139.     lea    Starfish.rectAddressTable,a0
  1140.      move.l    (a0)+,d0
  1141.     move.l    (a0)+,d1
  1142.     move.l    (a0),-(a0)
  1143.     move.l    d0,4(a0)
  1144.     move.l    d1,-(a0)
  1145.  
  1146. ;= shadow swapping =
  1147.  
  1148.     movea.l    Starfish.shadowAdrAdr,a0
  1149.      move.l    (a0)+,d0
  1150.     move.l    (a0)+,d1
  1151.     move.l    (a0),-(a0)
  1152.     move.l    d0,4(a0)
  1153.     move.l    d1,-(a0)
  1154.  
  1155.     movea.l    Starfish.shadowAdrAdr+4,a0
  1156.      move.l    (a0)+,d0
  1157.     move.l    (a0)+,d1
  1158.     move.l    (a0),-(a0)
  1159.     move.l    d0,4(a0)
  1160.     move.l    d1,-(a0)
  1161.  
  1162.     move.w    .swapcount(pc),d0
  1163.     addq.w    #1,d0
  1164.     cmpi.w    #3,d0
  1165.     blt.s    .end_swapcount
  1166.  
  1167. ; Clear count and swap phys/log shadow tables..
  1168.     clr.w    d0
  1169.     lea    Starfish.shadowAdrAdr,a0
  1170.     move.l    (a0),d1
  1171.     move.l    4(a0),(a0)+
  1172.     move.l    d1,(a0)
  1173.  
  1174. .end_swapcount:
  1175.     move.w    d0,.swapcount
  1176.  
  1177. ;= end shadow swapping =
  1178.  
  1179.     rts
  1180.  
  1181. .swapcount:
  1182.     DC.W    0
  1183.  
  1184. Starfish.zoom:
  1185.     movea.l    scr,a0
  1186.     move.w    $04BC.w,d0
  1187.     sub.w    Starfish.zoomStart,d0
  1188.     cmpi.w    #$0100,d0
  1189.     bcs.s    .clipped
  1190.     move.w    #$0100,d0
  1191. .clipped:
  1192.     move.w    d0,d1
  1193.     move.w    d0,d2
  1194.     mulu.w    #80,d1                ; d1.l=x_offset<<8
  1195.     mulu.w    #50,d2                ; d2.l=y_offset<<8
  1196.     lsr.l    #8,d1                ; d1.l=x_offset
  1197.     lsr.l    #8,d2                ; d2.l=y_offset
  1198.     mulu.w    #320,d2
  1199.     add.l    d1,d2
  1200.     movea.l    Starfish.backAdr,a1
  1201.     lea    (a1,d2.l*2),a1
  1202.     movea.l    a1,a2                ; a2: src backup
  1203.     lsr.w    #1,d0
  1204.     move.w    #$0100,d1
  1205.     sub.w    d0,d1                ; d1.w=step (8:8)
  1206.     ext.l    d1
  1207.     lsl.l    #8,d1                ; d1.l=step (16:16)
  1208.     move.l    d1,d2                ; d2.l=step (16:16)
  1209.     clr.l    d3                ; d3.l=y_pos (16:16)
  1210.     swap    d1                ; d1.l=ssSS (16:16)
  1211.     move.w    #200-1,d7
  1212.  
  1213. .yloop:    moveq    #320/16-1,d6
  1214.     sub.l    d0,d0                ; Clear count and clear carry.
  1215.  
  1216. .xloop:
  1217.     REPT    16
  1218.     move.w    (a1,d0.w*2),(a0)+
  1219.     addx.l    d1,d0
  1220.     ENDR
  1221.     dbf    d6,.xloop
  1222.  
  1223.     add.l    d2,d3                ; d3.l=next y_pos (16:16)
  1224.     move.l    d3,d4
  1225.     swap    d4                ; d4.w=next y_pos (int)
  1226.     mulu.w    #320,d4                ; d4.l=next y_offset (int)
  1227.     lea    (a2,d4.l*2),a1            ; a1: next src line
  1228.     dbf    d7,.yloop
  1229.     
  1230.     rts
  1231.  
  1232. ;======= OBJECT DATA =======================================================
  1233.  
  1234.     DATA
  1235.  
  1236. Starfish.textureTable:
  1237.     DC.L    FlareGen.redBuffer
  1238.     DC.L    0
  1239.  
  1240. Starfish.rectAddressTable:
  1241.     DC.L    Starfish.rectangleTable
  1242.     DC.L    Starfish.rectangleTable2
  1243.     DC.L    Starfish.rectangleTable3
  1244.  
  1245. Starfish.fieldStrength:
  1246.     DC.W    $0080
  1247.  
  1248. ; Only works with 5 arms, 5 rings..
  1249. Starfish.fixArmAngleTable:
  1250.     INCBIN    ARMS.DAT            ; idiocy, but it works
  1251.  
  1252. Starfish.shadowAdrAdr:
  1253.     DC.L    Starfish.shadowAdr
  1254.     DC.L    Starfish.shadowAdr2
  1255.  
  1256. ;======= OBJECT RESERVES ===================================================
  1257.  
  1258.     BSS
  1259.  
  1260. Starfish.resRout:
  1261.     DS.L    1
  1262.  
  1263. Starfish.rectangleTable:
  1264.     DS.W    4*10
  1265. Starfish.rectangleTable2:
  1266.     DS.W    4*10
  1267. Starfish.rectangleTable3:
  1268.     DS.W    4*10
  1269.  
  1270. Starfish.startTime:
  1271.     DS.W    1
  1272. Starfish.falling:
  1273.     DS.W    1
  1274. Starfish.oldRot:
  1275.     DS.W    1
  1276. Starfish.zooming:
  1277.     DS.W    1
  1278. Starfish.zoomStart:
  1279.     DS.W    1
  1280.  
  1281. Starfish.objAdr:
  1282.     DS.L    1
  1283. Starfish.angleTableAdr:
  1284.     DS.L    1
  1285. Starfish.backAdr:
  1286.     DS.L    1
  1287.  
  1288. Starfish.shadowAdr:
  1289.     DS.L    3
  1290. Starfish.shadowAdr2:
  1291.     DS.L    3
  1292.