home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / eispack-1.0-src.tgz / tar.out / contrib / eispack / htribk.f < prev    next >
Text File  |  1996-09-28  |  3KB  |  92 lines
  1.       subroutine htribk(nm,n,ar,ai,tau,m,zr,zi)
  2. c
  3.       integer i,j,k,l,m,n,nm
  4.       double precision ar(nm,n),ai(nm,n),tau(2,n),zr(nm,m),zi(nm,m)
  5.       double precision h,s,si
  6. c
  7. c     this subroutine is a translation of a complex analogue of
  8. c     the algol procedure trbak1, num. math. 11, 181-195(1968)
  9. c     by martin, reinsch, and wilkinson.
  10. c     handbook for auto. comp., vol.ii-linear algebra, 212-226(1971).
  11. c
  12. c     this subroutine forms the eigenvectors of a complex hermitian
  13. c     matrix by back transforming those of the corresponding
  14. c     real symmetric tridiagonal matrix determined by  htridi.
  15. c
  16. c     on input
  17. c
  18. c        nm must be set to the row dimension of two-dimensional
  19. c          array parameters as declared in the calling program
  20. c          dimension statement.
  21. c
  22. c        n is the order of the matrix.
  23. c
  24. c        ar and ai contain information about the unitary trans-
  25. c          formations used in the reduction by  htridi  in their
  26. c          full lower triangles except for the diagonal of ar.
  27. c
  28. c        tau contains further information about the transformations.
  29. c
  30. c        m is the number of eigenvectors to be back transformed.
  31. c
  32. c        zr contains the eigenvectors to be back transformed
  33. c          in its first m columns.
  34. c
  35. c     on output
  36. c
  37. c        zr and zi contain the real and imaginary parts,
  38. c          respectively, of the transformed eigenvectors
  39. c          in their first m columns.
  40. c
  41. c     note that the last component of each returned vector
  42. c     is real and that vector euclidean norms are preserved.
  43. c
  44. c     questions and comments should be directed to burton s. garbow,
  45. c     mathematics and computer science div, argonne national laboratory
  46. c
  47. c     this version dated august 1983.
  48. c
  49. c     ------------------------------------------------------------------
  50. c
  51.       if (m .eq. 0) go to 200
  52. c     .......... transform the eigenvectors of the real symmetric
  53. c                tridiagonal matrix to those of the hermitian
  54. c                tridiagonal matrix. ..........
  55.       do 50 k = 1, n
  56. c
  57.          do 50 j = 1, m
  58.             zi(k,j) = -zr(k,j) * tau(2,k)
  59.             zr(k,j) = zr(k,j) * tau(1,k)
  60.    50 continue
  61. c
  62.       if (n .eq. 1) go to 200
  63. c     .......... recover and apply the householder matrices ..........
  64.       do 140 i = 2, n
  65.          l = i - 1
  66.          h = ai(i,i)
  67.          if (h .eq. 0.0d0) go to 140
  68. c
  69.          do 130 j = 1, m
  70.             s = 0.0d0
  71.             si = 0.0d0
  72. c
  73.             do 110 k = 1, l
  74.                s = s + ar(i,k) * zr(k,j) - ai(i,k) * zi(k,j)
  75.                si = si + ar(i,k) * zi(k,j) + ai(i,k) * zr(k,j)
  76.   110       continue
  77. c     .......... double divisions avoid possible underflow ..........
  78.             s = (s / h) / h
  79.             si = (si / h) / h
  80. c
  81.             do 120 k = 1, l
  82.                zr(k,j) = zr(k,j) - s * ar(i,k) - si * ai(i,k)
  83.                zi(k,j) = zi(k,j) - si * ar(i,k) + s * ai(i,k)
  84.   120       continue
  85. c
  86.   130    continue
  87. c
  88.   140 continue
  89. c
  90.   200 return
  91.       end
  92.