home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / emacs-19.28-src.tgz / tar.out / fsf / emacs / lisp / avoid.el < prev    next >
Lisp/Scheme  |  1996-09-28  |  14KB  |  357 lines
  1. ;;; avoid.el -- make mouse pointer stay out of the way of editing.
  2.  
  3. ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Boris Goldowsky <boris@cs.rochester.edu>
  6. ;; Keywords: mouse
  7. ;; Version: 1.10
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24.  
  25. ;;; Commentary:
  26. ;;;
  27. ;;; For those who are annoyed by the mouse pointer obscuring text,
  28. ;;; this mode moves the mouse pointer - either just a little out of
  29. ;;; the way, or all the way to the corner of the frame. 
  30. ;;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31. ;;; To set up permanently, put this file on your load-path and put the
  32. ;;; following in your .emacs: 
  33. ;;;
  34. ;;; (cond (window-system
  35. ;;;        (require 'avoid)
  36. ;;;        (mouse-avoidance-mode 'animate)))
  37. ;;;
  38. ;;; The 'animate can be 'jump or 'banish or 'exile or 'protean if you prefer.
  39. ;;; See the documentation for function `mouse-avoidance-mode' for
  40. ;;; details of the different modes.
  41. ;;;
  42. ;;; For added silliness, make the animatee animate...
  43. ;;; put something similar to the following into your .emacs:
  44. ;;;
  45. ;;; (cond (window-system
  46. ;;;       (setq x-pointer-shape 
  47. ;;;         (eval (nth (random 4)
  48. ;;;            '(x-pointer-man x-pointer-spider
  49. ;;;              x-pointer-gobbler x-pointer-gumby))))
  50. ;;;       (set-mouse-color (cdr (assoc 'mouse-color (frame-parameters))))))
  51. ;;;
  52. ;;; For completely random pointer shape, replace the setq above with:
  53. ;;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  54. ;;; 
  55. ;;; Bugs / Warnings / To-Do:
  56. ;;;
  57. ;;; - Using this code does slow emacs down.  "banish" mode shouldn't
  58. ;;;   ever be too bad though, and on my workstation even "animate" doesn't
  59. ;;;   seem to have a noticable effect during editing.
  60. ;;;
  61. ;;; - It should find out where any overlapping frames are and avoid them,
  62. ;;;   rather than always raising the frame.
  63.  
  64. ;;; Credits:
  65. ;;; This code was helped by all those who contributed suggestions, 
  66. ;;;   fixes, and additions
  67. ;;; Joe Harrington (and his advisor), for the original inspiration.
  68. ;;; Ken Manheimer, for dreaming up the Protean mode.
  69. ;;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  70. ;;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  71. ;;; Simon Marshall, and M.S. Ashton, for their feedback.
  72. ;;;
  73. ;;; Code:
  74.  
  75. (provide 'avoid)
  76.  
  77. (defvar mouse-avoidance-mode nil
  78.   "Value is t or a symbol if the mouse pointer should avoid the cursor.
  79. See function `mouse-avoidance-mode' for possible values.  Changing this
  80. variable is NOT the recommended way to change modes; use that function 
  81. instead.")
  82.  
  83. (defvar mouse-avoidance-nudge-dist 15
  84.   "*Average distance that mouse will be moved when approached by cursor.
  85. Only applies in mouse-avoidance-mode `jump' and its derivatives.
  86. For best results make this larger than `mouse-avoidance-threshold'.")
  87.  
  88. (defvar mouse-avoidance-nudge-var 10
  89.   "*Variability of `mouse-avoidance-nudge-dist' (which see).")
  90.  
  91. (defvar mouse-avoidance-animation-delay .01
  92.   "Delay between animation steps, in seconds.")
  93.  
  94. (defvar mouse-avoidance-threshold 5
  95.   "*Mouse-pointer's flight distance.
  96. If the cursor gets closer than this, the mouse pointer will move away.
  97. Only applies in mouse-avoidance-modes `animate' and `jump'.")
  98.  
  99. ;; Internal variables
  100. (defvar mouse-avoidance-state nil)
  101. (defvar mouse-avoidance-pointer-shapes nil)
  102. (defvar mouse-avoidance-n-pointer-shapes 0)
  103.  
  104. ;;; Functions:
  105.  
  106. (defun mouse-avoidance-point-position ()
  107.   "Return the position of point as (FRAME X . Y).
  108. Analogous to mouse-position."
  109.   (let* ((w (selected-window))
  110.      (edges (window-edges w))
  111.      (list 
  112.       (compute-motion (max (window-start w) (point-min))   ; start pos
  113.               ;; window-start can be < point-min if the
  114.               ;; latter has changed since the last redisplay 
  115.               '(0 . 0)                           ; start XY
  116.               (point)                           ; stop pos
  117.               (cons (window-width) (window-height)); stop XY: none
  118.               (1- (window-width))                  ; width
  119.               (cons (window-hscroll w) 0)          ; 0 may not be right?
  120.               (selected-window))))
  121.     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
  122.     ;; we want:               (frame hpos . vpos)
  123.     (cons (selected-frame)
  124.       (cons (+ (car edges)       (car (cdr list)))
  125.         (+ (car (cdr edges)) (car (cdr (cdr list))))))))
  126.  
  127. ;(defun mouse-avoidance-point-position-test ()
  128. ;  (interactive)
  129. ;  (message (format "point=%s mouse=%s" 
  130. ;           (cdr (mouse-avoidance-point-position))
  131. ;           (cdr (mouse-position)))))
  132.  
  133. (defun mouse-avoidance-set-mouse-position (pos)
  134.   ;; Carefully set mouse position to given position (X . Y)
  135.   ;; Ideally, should check if X,Y is in the current frame, and if not,
  136.   ;; leave the mouse where it was.  However, this is currently
  137.   ;; difficult to do, so we just raise the frame to avoid frame switches.
  138.   ;; Returns t if it moved the mouse.
  139.   (let ((f (selected-frame)))
  140.     (raise-frame f)
  141.     (set-mouse-position f (car pos) (cdr pos))
  142.     t))
  143.       
  144. (defun mouse-avoidance-too-close-p (mouse)
  145.   ;;  Return t if mouse pointer and point cursor are too close.
  146.   ;; Acceptable distance is defined by mouse-avoidance-threshold.
  147.   (let ((point (mouse-avoidance-point-position)))
  148.     (and (eq (car mouse) (car point))
  149.      (car (cdr mouse))
  150.      (< (abs (- (car (cdr mouse)) (car (cdr point))))
  151.         mouse-avoidance-threshold)
  152.      (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
  153.         mouse-avoidance-threshold))))
  154.  
  155. (defun mouse-avoidance-banish-destination ()
  156.   "The position to which mouse-avoidance-mode `banish' moves the mouse.
  157. You can redefine this if you want the mouse banished to a different corner."
  158.  (cons (1- (frame-width))
  159.        0))
  160.  
  161. (defun mouse-avoidance-banish-mouse ()
  162.   ;; Put the mouse pointer in the upper-right corner of the current frame.
  163.   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
  164.  
  165. (defsubst mouse-avoidance-delta (cur delta dist var min max)
  166.   ;; Decide how far to move in either dimension.
  167.   ;; Args are the CURRENT location, the desired DELTA for
  168.   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
  169.   ;; in distance allowed, and the MIN and MAX possible window positions.
  170.   ;; Returns something as close to DELTA as possible withing the constraints.
  171.   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
  172.     (R1                  (+ (- dist)    var ))
  173.     (L2                  (+    dist  (- var)))
  174.     (R2 (min (- max cur) (+    dist     var))))
  175.     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
  176.     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
  177.     (cond ((and L1 (< delta L1)) L1)
  178.       ((and R1 (< delta R1)) delta)
  179.       ((and R1 (< delta 0)) R1)
  180.       ((and L2 (< delta L2)) L2)
  181.       ((and R2 (< delta R2)) delta)
  182.       (R2)
  183.       ((or R1 L2))
  184.       (t 0))))
  185.  
  186. (defun mouse-avoidance-nudge-mouse () 
  187.   ;; Push the mouse a little way away, possibly animating the move
  188.   ;; For these modes, state keeps track of the total offset that we've
  189.   ;; accumulated, and tries to keep it close to zero.
  190.   (let* ((cur (mouse-position))
  191.      (cur-frame (car cur))
  192.      (cur-pos (cdr cur))
  193.      (deltax (mouse-avoidance-delta 
  194.           (car cur-pos) (- (random mouse-avoidance-nudge-var)
  195.                    (car mouse-avoidance-state))
  196.           mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
  197.           0 (frame-width)))
  198.      (deltay (mouse-avoidance-delta 
  199.           (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
  200.                    (cdr mouse-avoidance-state))
  201.           mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
  202.           0 (frame-height))))
  203.     (setq mouse-avoidance-state
  204.       (cons (+ (car mouse-avoidance-state) deltax)
  205.         (+ (cdr mouse-avoidance-state) deltay)))
  206.     (if (or (eq mouse-avoidance-mode 'animate) 
  207.         (eq mouse-avoidance-mode 'proteus))
  208.     (let ((i 0.0)
  209.           (color (cdr (assoc 'mouse-color (frame-parameters)))))
  210.       (while (<= i 1)
  211.         (mouse-avoidance-set-mouse-position 
  212.          (cons (+ (car cur-pos) (round (* i deltax)))
  213.            (+ (cdr cur-pos) (round (* i deltay)))))
  214.             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
  215.         (if (eq mouse-avoidance-mode 'proteus)
  216.         (progn
  217.           (setq x-pointer-shape (mouse-avoidance-random-shape))
  218.           (set-mouse-color color)))
  219.         (sit-for mouse-avoidance-animation-delay)))
  220.       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
  221.                         (+ (cdr (cdr cur)) deltay))))))
  222.  
  223. (defun mouse-avoidance-random-shape ()
  224.   "Return a random cursor shape.
  225. This assumes that any variable whose name begins with x-pointer- and
  226. has an integer value is a valid cursor shape.  You might want to
  227. redefine this function to suit your own tastes."
  228.   (if (null mouse-avoidance-pointer-shapes)
  229.       (progn
  230.     (setq mouse-avoidance-pointer-shapes
  231.           (mapcar '(lambda (x) (symbol-value (intern x)))
  232.               (all-completions "x-pointer-" obarray
  233.                        '(lambda (x) 
  234.                       (and (boundp x)
  235.                            (integerp (symbol-value x)))))))
  236.     (setq mouse-avoidance-n-pointer-shapes 
  237.           (length mouse-avoidance-pointer-shapes))))
  238.   (nth (random mouse-avoidance-n-pointer-shapes)
  239.        mouse-avoidance-pointer-shapes))
  240.  
  241. (defun mouse-avoidance-banish-hook ()
  242.   (if (and (not executing-kbd-macro)    ; don't check inside macro
  243.        (mouse-avoidance-kbd-command (this-command-keys)))
  244.       (mouse-avoidance-banish-mouse)))
  245.  
  246. (defun mouse-avoidance-exile-hook ()
  247.   ;; For exile mode, the state is nil when the mouse is in its normal
  248.   ;; position, and set to the old mouse-position when the mouse is in exile.
  249.   (if (and (not executing-kbd-macro)
  250.        (mouse-avoidance-kbd-command (this-command-keys)))
  251.       (let ((mp (mouse-position)))
  252.     (cond ((and (not mouse-avoidance-state)
  253.             (mouse-avoidance-too-close-p mp))
  254.            (setq mouse-avoidance-state mp)
  255.            (mouse-avoidance-banish-mouse))
  256.           ((and mouse-avoidance-state
  257.             (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
  258.            (if (and (eq (car mp) (selected-frame))
  259.             (equal (cdr mp) (mouse-avoidance-banish-destination)))
  260.            (mouse-avoidance-set-mouse-position
  261.             ;; move back only if user has not moved mouse
  262.             (cdr mouse-avoidance-state)))
  263.            ;; but clear state anyway, to be ready for another move
  264.            (setq mouse-avoidance-state nil))))))
  265.  
  266. (defun mouse-avoidance-fancy-hook ()
  267.   ;; Used for the "fancy" modes, ie jump et al.
  268.   (if (and (not executing-kbd-macro)    ; don't check inside macro
  269.        (mouse-avoidance-kbd-command (this-command-keys))
  270.        (mouse-avoidance-too-close-p (mouse-position)))
  271.       (let ((old-pos (mouse-position)))
  272.     (mouse-avoidance-nudge-mouse)
  273.     (if (not (eq (selected-frame) (car old-pos))) ; move went awry
  274.         (set-mouse-position old-pos (car old-pos) ; sigh..
  275.                 (car (cdr old-pos))
  276.                 (cdr (cdr old-pos)))))))
  277.  
  278. (defun mouse-avoidance-kbd-command (key)
  279.   "Return t if the KEYSEQENCE is composed of keyboard events only.
  280. Return nil if there are any lists in the key sequence."
  281.   (cond ((null key) nil)        ; Null event seems to be
  282.                     ; returned occasionally.
  283.     ((not (vectorp key)) t)        ; Strings are keyboard events.
  284.     ((catch 'done
  285.        (let ((i 0)
  286.          (l (length key)))
  287.          (while (< i l)
  288.            (if (listp (aref key i))
  289.            (throw 'done nil))
  290.            (setq i (1+ i))))
  291.        t))))
  292.  
  293. (defun mouse-avoidance-mode (&optional mode)
  294.   "Set cursor avoidance mode to MODE.
  295. MODE should be one of the symbols `banish', `exile', `jump', `animate',
  296. `cat-and-mouse', `proteus', or `none'.
  297.  
  298. If MODE is nil, toggle mouse avoidance between `none` and `banish'
  299. modes.  Positive numbers and symbols other than the above are treated
  300. as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
  301.  
  302. Effects of the different modes: 
  303.  * banish: Move the mouse to the upper-right corner on any keypress.
  304.  * exile: Move the mouse to the corner only if the cursor gets too close,
  305.      and allow it to return once the cursor is out of the way.
  306.  * jump: If the cursor gets too close to the mouse, displace the mouse
  307.      a random distance & direction.
  308.  * animate: As `jump', but shows steps along the way for illusion of motion.
  309.  * cat-and-mouse: Same as `animate'.
  310.  * proteus: As `animate', but changes the shape of the mouse pointer too.
  311.  
  312. Whenever the mouse is moved, the frame is also raised.
  313.  
  314. \(see `mouse-avoidance-threshold' for definition of \"too close\",
  315. and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
  316. definition of \"random distance\".)"
  317.   (interactive
  318.    (list (intern (completing-read
  319.           "Select cursor avoidance technique (SPACE for list): "
  320.           '(("banish") ("exile") ("jump") ("animate")
  321.             ("cat-and-mouse") ("proteus") ("none"))
  322.           nil t))))
  323.   (if (eq mode 'cat-and-mouse)
  324.       (setq mode 'animate))
  325.   (setq post-command-hook
  326.     (delete 'mouse-avoidance-banish-hook (append post-command-hook nil)))
  327.   (setq post-command-hook
  328.     (delete 'mouse-avoidance-exile-hook (append post-command-hook nil)))
  329.   (setq post-command-hook
  330.     (delete 'mouse-avoidance-fancy-hook (append post-command-hook nil)))
  331.   (cond    ((eq mode 'none)
  332.      (setq mouse-avoidance-mode nil))
  333.     ((or (eq mode 'jump)
  334.          (eq mode 'animate)
  335.          (eq mode 'proteus))
  336.      (add-hook 'post-command-hook 'mouse-avoidance-fancy-hook)
  337.      (setq mouse-avoidance-mode mode
  338.            mouse-avoidance-state (cons 0 0)))
  339.     ((eq mode 'exile)
  340.      (add-hook 'post-command-hook 'mouse-avoidance-exile-hook)
  341.      (setq mouse-avoidance-mode mode
  342.            mouse-avoidance-state nil))
  343.     ((or (eq mode 'banish) 
  344.          (eq mode t)
  345.          (and (null mode) (null mouse-avoidance-mode))
  346.          (and mode (> (prefix-numeric-value mode) 0)))
  347.      (add-hook 'post-command-hook 'mouse-avoidance-banish-hook)
  348.      (setq mouse-avoidance-mode 'banish))
  349.     (t (setq mouse-avoidance-mode nil)))
  350.   (force-mode-line-update))
  351.  
  352. (or (assq 'mouse-avoidance-mode minor-mode-alist)
  353.     (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
  354.                  minor-mode-alist)))
  355.  
  356. ;;; End of avoid.el
  357.