home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / emacs-19.28-src.tgz / tar.out / fsf / emacs / lisp / mail-hist.el < prev    next >
Lisp/Scheme  |  1996-09-28  |  11KB  |  287 lines
  1. ;;; mail-hist.el --- Headers and message body history for outgoing mail.
  2. ;; Copyright (C) 1994 Free Software Foundation, Inc.
  3.  
  4. ;; Author: Karl Fogel <kfogel@cs.oberlin.edu>
  5. ;; Created: March, 1994
  6. ;; Version: 1.3
  7. ;; Keywords: mail, history
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;;; Commentary:
  22.  
  23. ;; You should have received a copy of the GNU General Public License
  24. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26.  
  27. ;; Thanks to Jim Blandy for mentioning ring.el.  It saved a lot of
  28. ;; time.
  29. ;;
  30. ;; To use this package, put it in a directory in your load-path, and
  31. ;; put this in your .emacs file:
  32. ;;
  33. ;; (load "mail-hist" nil t)
  34. ;;
  35. ;; Or you could do it with autoloads and hooks in your .emacs:
  36. ;;
  37. ;; (add-hook 'mail-mode-hook 'mail-hist-define-keys)
  38. ;; (add-hook 'mail-send-hook 'mail-hist-put-headers-into-history)
  39. ;; (add-hook 'vm-mail-mode-hook 'mail-hist-define-keys) ;or rmail, etc
  40. ;; (autoload 'mail-hist-define-keys "mail-hist")
  41. ;; (autoload 'mail-hist-put-headers-into-history "mail-hist")
  42. ;;
  43. ;; Once it's installed, use M-p and M-n from mail headers to recover
  44. ;; previous/next contents in the history for that header, or, in the
  45. ;; body of the message, to recover previous/next text of the message.
  46. ;; This only applies to outgoing mail -- mail-hist ignores received
  47. ;; messages.
  48. ;;
  49. ;; Although repeated history requests do clear out the text from the
  50. ;; previous request, an isolated request just inserts its text at
  51. ;; point, so that you can mix the histories of different messages
  52. ;; easily.  This might be confusing at times, but there should be no
  53. ;; problems that undo can't handle.
  54.  
  55. ;;; Code:
  56. (require 'ring)
  57.  
  58. ;;;###autoload
  59. (defun mail-hist-define-keys ()
  60.   "Define keys for accessing mail header history.  For use in hooks."
  61.   (local-set-key "\M-p" 'mail-hist-previous-input)
  62.   (local-set-key "\M-n" 'mail-hist-next-input))
  63.  
  64. ;;;###autoload
  65. (add-hook 'mail-mode-hook 'mail-hist-define-keys)
  66.  
  67. ;;;###autoload
  68. (add-hook 'vm-mail-mode-hook 'mail-hist-define-keys)
  69.  
  70. ;;;###autoload
  71. (add-hook 'mail-send-hook 'mail-hist-put-headers-into-history)
  72.  
  73. (defvar mail-hist-header-ring-alist nil
  74.   "Alist of form (header-name . history-ring).
  75. Used for knowing which history list to look in when the user asks for
  76. previous/next input.")
  77.  
  78. (defvar mail-hist-history-size (or kill-ring-max 1729)
  79.   "*The maximum number of elements in a mail field's history.
  80. Oldest elements are dumped first.")
  81.  
  82. ;;;###autoload
  83. (defvar mail-hist-keep-history t
  84.   "*Non-nil means keep a history for headers and text of outgoing mail.")
  85.  
  86. ;; For handling repeated history requests
  87. (defvar mail-hist-access-count 0)
  88.  
  89. (defvar mail-hist-last-bounds nil)
  90. ;; (start . end) A pair indicating the buffer positions delimiting the
  91. ;; last inserted history, so it can be replaced by a new input if the
  92. ;; command is repeated.
  93.  
  94. (defvar mail-hist-header-regexp "^[^:]*:"
  95.   "Regular expression for matching headers in a mail message.")
  96.  
  97. (defsubst mail-hist-current-header-name ()
  98.   "Get name of mail header point is currently in, without the colon.
  99. Returns nil if not in a header, implying that point is in the body of
  100. the message."
  101.   (if (save-excursion
  102.         (re-search-backward (concat "^" mail-header-separator) nil t))
  103.       nil ; then we are in the body of the message
  104.     (save-excursion
  105.       (let* ((body-start ; limit possibility of false headers
  106.               (save-excursion
  107.                 (re-search-forward (concat "^" mail-header-separator) nil t)))
  108.              (name-start
  109.               (re-search-backward mail-hist-header-regexp nil t))
  110.              (name-end
  111.               (prog2 (search-forward ":" body-start t) (1- (point)))))
  112.         (and
  113.          name-start
  114.          name-end
  115.          (downcase (buffer-substring name-start name-end)))))))
  116.  
  117. (defsubst mail-hist-forward-header (count)
  118.   "Move forward COUNT headers (backward if COUNT is negative).
  119. If last/first header is encountered first, stop there and returns
  120. nil.  
  121.  
  122. Places point on the first non-whitespace on the line following the
  123. colon after the header name, or on the second space following that if
  124. the header is empty."
  125.   (let ((boundary (save-excursion
  126.                 (re-search-forward (concat "^" mail-header-separator) nil t))))
  127.     (and
  128.      boundary
  129.      (let ((unstopped t))
  130.        (setq boundary (save-excursion
  131.                     (goto-char boundary)
  132.                     (beginning-of-line)
  133.                     (1- (point))))
  134.        (if (> count 0)
  135.            (while (> count 0)
  136.              (setq
  137.               unstopped
  138.               (re-search-forward mail-hist-header-regexp boundary t))
  139.              (setq count (1- count)))
  140.          ;; because the current header will match too.
  141.          (setq count (1- count))
  142.          ;; count is negative
  143.          (while (< count 0)
  144.            (setq
  145.             unstopped
  146.             (re-search-backward mail-hist-header-regexp nil t))
  147.            (setq count (1+ count)))
  148.          ;; we end up behind the header, so must move to the front
  149.          (re-search-forward mail-hist-header-regexp boundary t))
  150.        ;; Now we are right after the colon
  151.        (and (looking-at "\\s-") (forward-char 1))
  152.        ;; return nil if didn't go as far as asked, otherwise point
  153.        unstopped))))
  154.  
  155. (defsubst mail-hist-beginning-of-header ()
  156.   "Move to the start of the current header.
  157. The start of the current header is defined as one space after the
  158. colon, or just after the colon if it is not followed by whitespace."
  159.   ;; this is slick as all heck:
  160.   (if (mail-hist-forward-header -1)
  161.       (mail-hist-forward-header 1)
  162.     (mail-hist-forward-header 1)
  163.     (mail-hist-forward-header -1)))
  164.  
  165. (defsubst mail-hist-current-header-contents ()
  166.   "Get the contents of the mail header in which point is located."
  167.   (save-excursion
  168.     (mail-hist-beginning-of-header)
  169.     (let ((start (point)))
  170.       (or (mail-hist-forward-header 1)
  171.           (re-search-forward (concat "^" mail-header-separator)))
  172.       (beginning-of-line)
  173.       (buffer-substring start (1- (point))))))
  174.  
  175. (defsubst mail-hist-get-header-ring (header)
  176.   "Get HEADER's history ring, or nil if none.
  177. HEADER is a string without the colon."
  178.   (setq header (downcase header))
  179.   (cdr (assoc header mail-hist-header-ring-alist)))
  180.  
  181. (defsubst mail-hist-add-header-contents-to-ring (header &optional contents)
  182.   "Add the contents of HEADER to the header history ring.
  183. Optional argument CONTENTS is a string which will be the contents
  184. (instead of whatever's found in the header)."
  185.   (setq header (downcase header))
  186.   (let ((ring (cdr (assoc header mail-hist-header-ring-alist))))
  187.     (or ring
  188.         ;; If the ring doesn't exist, we'll have to make it and add it
  189.         ;; to the mail-header-ring-alist:
  190.         (prog1
  191.             (setq ring (make-ring mail-hist-history-size))
  192.           (setq mail-hist-header-ring-alist
  193.                 (cons (cons header ring) mail-hist-header-ring-alist))))
  194.     (ring-insert
  195.      ring
  196.      (or contents (mail-hist-current-header-contents)))))
  197.  
  198. ;;;###autoload
  199. (defun mail-hist-put-headers-into-history ()
  200.   "Put headers and contents of this message into mail header history. 
  201. Each header has its own independent history, as does the body of the
  202. message.
  203.  
  204. This function normally would be called when the message is sent." 
  205.   (and
  206.    mail-hist-keep-history
  207.    (progn
  208.      (goto-char (point-min))
  209.      (while (mail-hist-forward-header 1)
  210.        (mail-hist-add-header-contents-to-ring
  211.         (mail-hist-current-header-name)))
  212.      (let ((body-contents
  213.             (save-excursion
  214.             (goto-char (point-min))
  215.             (re-search-forward (concat "^" mail-header-separator) nil)
  216.             (forward-line 1)
  217.             (buffer-substring (point) (point-max)))))
  218.        (mail-hist-add-header-contents-to-ring "body" body-contents)))))
  219.  
  220. (defun mail-hist-previous-input (header)
  221.   "Insert the previous contents of this mail header or message body.
  222. Moves back through the history of sent mail messages.  Each header has
  223. its own independent history, as does the body of the message.
  224.  
  225. The history only contains the contents of outgoing messages, not
  226. received mail."
  227.   (interactive (list (or (mail-hist-current-header-name) "body")))
  228.   (setq header (downcase header))
  229.   (let* ((ring (cdr (assoc header mail-hist-header-ring-alist)))
  230.          (len (ring-length ring))
  231.          (repeat (eq last-command 'mail-hist-input-access)))
  232.     (if repeat
  233.         (setq mail-hist-access-count
  234.               (ring-plus1 mail-hist-access-count len))
  235.       (setq mail-hist-access-count 0))
  236.     (if (null ring)
  237.         (progn
  238.           (ding)
  239.           (message "No history for \"%s\"." header))
  240.       (if (ring-empty-p ring)
  241.           (error "\"%s\" ring is empty." header)
  242.         (and repeat
  243.              (delete-region (car mail-hist-last-bounds)
  244.                             (cdr mail-hist-last-bounds)))
  245.         (let ((start (point)))
  246.           (insert (ring-ref ring mail-hist-access-count))
  247.           (setq mail-hist-last-bounds (cons start (point)))
  248.           (setq this-command 'mail-hist-input-access))))))
  249.  
  250. (defun mail-hist-next-input (header)
  251.   "Insert next contents of this mail header or message body.
  252. Moves back through the history of sent mail messages.  Each header has
  253. its own independent history, as does the body of the message.
  254.  
  255. Although you can do so, it does not make much sense to call this
  256. without having called `mail-hist-previous-header' first
  257. (\\[mail-hist-previous-header]).
  258.  
  259. The history only contains the contents of outgoing messages, not
  260. received mail."
  261.   (interactive (list (or (mail-hist-current-header-name) "body")))
  262.   (setq header (downcase header))
  263.   (let* ((ring (cdr (assoc header mail-hist-header-ring-alist)))
  264.          (len (ring-length ring))
  265.          (repeat (eq last-command 'mail-hist-input-access)))
  266.     (if repeat
  267.         (setq mail-hist-access-count
  268.               (ring-minus1 mail-hist-access-count len))
  269.       (setq mail-hist-access-count 0))
  270.     (if (null ring)
  271.         (progn
  272.           (ding)
  273.           (message "No history for \"%s\"." header))
  274.       (if (ring-empty-p ring)
  275.           (error "\"%s\" ring is empty." header)
  276.         (and repeat
  277.              (delete-region (car mail-hist-last-bounds)
  278.                             (cdr mail-hist-last-bounds)))
  279.         (let ((start (point)))
  280.           (insert (ring-ref ring mail-hist-access-count))
  281.           (setq mail-hist-last-bounds (cons start (point)))
  282.           (setq this-command 'mail-hist-input-access))))))
  283.  
  284. (provide 'mail-hist)
  285.  
  286. ;; mail-hist.el ends here
  287.