home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / emacs-19.28-src.tgz / tar.out / fsf / emacs / lisp / shell.el < prev    next >
Lisp/Scheme  |  1996-09-28  |  35KB  |  826 lines
  1. ;;; shell.el --- specialized comint.el for running the shell.
  2.  
  3. ;; Copyright (C) 1988, 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Olin Shivers <shivers@cs.cmu.edu>
  6. ;; Maintainer: Simon Marshall <s.marshall@dcs.hull.ac.uk>
  7. ;; Keywords: processes
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24.  
  25. ;;; Commentary:
  26.  
  27. ;;; Please send me bug reports, bug fixes, and extensions, so that I can
  28. ;;; merge them into the master source.
  29. ;;;     - Olin Shivers (shivers@cs.cmu.edu)
  30. ;;;     - Simon Marshall (s.marshall@dcs.hull.ac.uk)
  31.  
  32. ;;; This file defines a a shell-in-a-buffer package (shell mode) built
  33. ;;; on top of comint mode.  This is actually cmushell with things
  34. ;;; renamed to replace its counterpart in Emacs 18.  cmushell is more
  35. ;;; featureful, robust, and uniform than the Emacs 18 version.
  36.  
  37. ;;; Since this mode is built on top of the general command-interpreter-in-
  38. ;;; a-buffer mode (comint mode), it shares a common base functionality, 
  39. ;;; and a common set of bindings, with all modes derived from comint mode.
  40. ;;; This makes these modes easier to use.
  41.  
  42. ;;; For documentation on the functionality provided by comint mode, and
  43. ;;; the hooks available for customising it, see the file comint.el.
  44. ;;; For further information on shell mode, see the comments below.
  45.  
  46. ;;; Needs fixin:
  47. ;;; When sending text from a source file to a subprocess, the process-mark can 
  48. ;;; move off the window, so you can lose sight of the process interactions.
  49. ;;; Maybe I should ensure the process mark is in the window when I send
  50. ;;; text to the process? Switch selectable?
  51.  
  52. ;; YOUR .EMACS FILE
  53. ;;=============================================================================
  54. ;; Some suggestions for your .emacs file.
  55. ;;
  56. ;; ;; Define C-c t to run my favorite command in shell mode:
  57. ;; (setq shell-mode-hook
  58. ;;       '((lambda () 
  59. ;;           (define-key shell-mode-map "\C-ct" 'favorite-cmd))))
  60.  
  61.  
  62. ;;; Brief Command Documentation:
  63. ;;;============================================================================
  64. ;;; Comint Mode Commands: (common to shell and all comint-derived modes)
  65. ;;;
  66. ;;; m-p        comint-previous-input            Cycle backwards in input history
  67. ;;; m-n        comint-next-input                  Cycle forwards
  68. ;;; m-r     comint-previous-matching-input  Previous input matching a regexp
  69. ;;; m-R     comint-previous-matching-input-from-input -"- matching input
  70. ;;; m-s     comint-next-matching-input      Next input that matches
  71. ;;; m-S     comint-next-matching-input-from-input     -"- matching input
  72. ;;; m-c-l   comint-show-output            Show last batch of process output
  73. ;;; return  comint-send-input
  74. ;;; c-d        comint-delchar-or-maybe-eof        Delete char unless at end of buff.
  75. ;;; c-c c-a comint-bol                      Beginning of line; skip prompt
  76. ;;; c-c c-u comint-kill-input                ^u
  77. ;;; c-c c-w backward-kill-word            ^w
  78. ;;; c-c c-c comint-interrupt-subjob         ^c
  79. ;;; c-c c-z comint-stop-subjob                ^z
  80. ;;; c-c c-\ comint-quit-subjob                ^\
  81. ;;; c-c c-o comint-kill-output            Delete last batch of process output
  82. ;;; c-c c-r comint-show-output            Show last batch of process output
  83. ;;; c-c c-h comint-dynamic-list-input-ring  List input history
  84. ;;;         send-invisible                  Read line w/o echo & send to proc
  85. ;;;         comint-continue-subjob        Useful if you accidentally suspend
  86. ;;;                            top-level job
  87. ;;; comint-mode-hook is the comint mode hook.
  88.  
  89. ;;; Shell Mode Commands:
  90. ;;;         shell                Fires up the shell process
  91. ;;; tab     comint-dynamic-complete        Complete filename/command/history
  92. ;;; m-?     comint-dynamic-list-filename-completions List completions in help buffer
  93. ;;; m-c-f   shell-forward-command           Forward a shell command
  94. ;;; m-c-b   shell-backward-command          Backward a shell command
  95. ;;;         dirs                    Resync the buffer's dir stack
  96. ;;;         dirtrack-toggle                 Turn dir tracking on/off
  97. ;;;         shell-strip-ctrl-m              Remove trailing ^Ms from output
  98. ;;;
  99. ;;; The shell mode hook is shell-mode-hook
  100. ;;; comint-prompt-regexp is initialised to shell-prompt-pattern, for backwards
  101. ;;; compatibility.
  102.  
  103. ;;; Read the rest of this file for more information.
  104.  
  105. ;;; SHELL.EL COMPATIBILITY
  106. ;;; Notes from when this was called cmushell, and was not the standard emacs
  107. ;;; shell package.
  108. ;;;============================================================================
  109. ;;; In brief: this package should have no trouble coexisting with shell.el.
  110. ;;; 
  111. ;;; Most customising variables -- e.g., explicit-shell-file-name -- are the
  112. ;;; same, so the users shouldn't have much trouble. Hooks have different
  113. ;;; names, however, so you can customise shell mode differently from cmushell
  114. ;;; mode. You basically just have to remember to type M-x cmushell instead of
  115. ;;; M-x shell.
  116. ;;; 
  117. ;;; It would be nice if this file was completely plug-compatible with the old
  118. ;;; shell package -- if you could just name this file shell.el, and have it
  119. ;;; transparently replace the old one. But you can't.  Several other packages
  120. ;;; (tex-mode, background, dbx, gdb, kermit, monkey, prolog, telnet) are also
  121. ;;; clients of shell mode. These packages assume detailed knowledge of shell
  122. ;;; mode internals in ways that are incompatible with cmushell mode (mostly
  123. ;;; because of cmushell mode's greater functionality).  So, unless we are
  124. ;;; willing to port all of these packages, we can't have this file be a
  125. ;;; complete replacement for shell.el -- that is, we can't name this file
  126. ;;; shell.el, and its main entry point (shell), because dbx.el will break
  127. ;;; when it loads it in and tries to use it.
  128. ;;; 
  129. ;;; There are two ways to fix this. One: rewrite these other modes to use the
  130. ;;; new package. This is a win, but can't be assumed. The other, backwards
  131. ;;; compatible route, is to make this package non-conflict with shell.el, so
  132. ;;; both files can be loaded in at the same time. And *that* is why some
  133. ;;; functions and variables have different names: (cmushell),
  134. ;;; cmushell-mode-map, that sort of thing. All the names have been carefully
  135. ;;; chosen so that shell.el and cmushell.el won't tromp on each other.
  136.  
  137. ;;; Customization and Buffer Variables
  138. ;;; ===========================================================================
  139. ;;; 
  140.  
  141. ;;; Code:
  142.  
  143. (require 'comint)
  144.  
  145. ;;;###autoload
  146. (defvar shell-prompt-pattern "^[^#$%>\n]*[#$%>] *"
  147.   "Regexp to match prompts in the inferior shell.
  148. Defaults to \"^[^#$%>\\n]*[#$%>] *\", which works pretty well.
  149. This variable is used to initialise `comint-prompt-regexp' in the 
  150. shell buffer.
  151.  
  152. The pattern should probably not match more than one line.  If it does,
  153. shell-mode may become confused trying to distinguish prompt from input
  154. on lines which don't start with a prompt.
  155.  
  156. This is a fine thing to set in your `.emacs' file.")
  157.  
  158. (defvar shell-completion-fignore nil
  159.   "*List of suffixes to be disregarded during file/command completion.
  160. This variable is used to initialize `comint-completion-fignore' in the shell
  161. buffer.  The default is nil, for compatibility with most shells.
  162. Some people like (\"~\" \"#\" \"%\").
  163.  
  164. This is a fine thing to set in your `.emacs' file.")  
  165.  
  166. (defvar shell-delimiter-argument-list '(?\| ?& ?< ?> ?\( ?\) ?\;)
  167.   "List of characters to recognise as separate arguments.
  168. This variable is used to initialize `comint-delimiter-argument-list' in the
  169. shell buffer.  The default is (?\\| ?& ?< ?> ?\\( ?\\) ?\\;).
  170.  
  171. This is a fine thing to set in your `.emacs' file.")
  172.  
  173. (defvar shell-dynamic-complete-functions
  174.   '(comint-replace-by-expanded-history
  175.     shell-dynamic-complete-environment-variable
  176.     shell-dynamic-complete-command
  177.     shell-replace-by-expanded-directory
  178.     comint-dynamic-complete-filename)
  179.   "List of functions called to perform completion.
  180. This variable is used to initialise `comint-dynamic-complete-functions' in the
  181. shell buffer.
  182.  
  183. This is a fine thing to set in your `.emacs' file.")
  184.  
  185. (defvar shell-command-regexp "[^;&|\n]+"
  186.   "*Regexp to match a single command within a pipeline.
  187. This is used for directory tracking and does not do a perfect job.")
  188.  
  189. (defvar shell-completion-execonly t
  190.   "*If non-nil, use executable files only for completion candidates.
  191. This mirrors the optional behavior of tcsh.
  192.  
  193. Detecting executability of files may slow command completion considerably.")
  194.  
  195. (defvar shell-popd-regexp "popd"
  196.   "*Regexp to match subshell commands equivalent to popd.")
  197.  
  198. (defvar shell-pushd-regexp "pushd"
  199.   "*Regexp to match subshell commands equivalent to pushd.")
  200.  
  201. (defvar shell-pushd-tohome nil
  202.   "*If non-nil, make pushd with no arg behave as \"pushd ~\" (like cd).
  203. This mirrors the optional behavior of tcsh.")
  204.  
  205. (defvar shell-pushd-dextract nil
  206.   "*If non-nil, make \"pushd +n\" pop the nth dir to the stack top.
  207. This mirrors the optional behavior of tcsh.")
  208.  
  209. (defvar shell-pushd-dunique nil
  210.   "*If non-nil, make pushd only add unique directories to the stack.
  211. This mirrors the optional behavior of tcsh.")
  212.  
  213. (defvar shell-cd-regexp "cd"
  214.   "*Regexp to match subshell commands equivalent to cd.")
  215.  
  216. (defvar explicit-shell-file-name nil
  217.   "*If non-nil, is file name to use for explicitly requested inferior shell.")
  218.  
  219. (defvar explicit-csh-args
  220.   (if (eq system-type 'hpux)
  221.       ;; -T persuades HP's csh not to think it is smarter
  222.       ;; than us about what terminal modes to use.
  223.       '("-i" "-T")
  224.     '("-i"))
  225.   "*Args passed to inferior shell by M-x shell, if the shell is csh.
  226. Value is a list of strings, which may be nil.")
  227.  
  228. (defvar shell-input-autoexpand 'history
  229.   "*If non-nil, expand input command history references on completion.
  230. This mirrors the optional behavior of tcsh (its autoexpand and histlit).
  231.  
  232. If the value is `input', then the expansion is seen on input.
  233. If the value is `history', then the expansion is only when inserting
  234. into the buffer's input ring.  See also `comint-magic-space' and
  235. `comint-dynamic-complete'.
  236.  
  237. This variable supplies a default for `comint-input-autoexpand',
  238. for Shell mode only.")
  239.  
  240. (defvar shell-dirstack nil
  241.   "List of directories saved by pushd in this buffer's shell.
  242. Thus, this does not include the shell's current directory.")
  243.  
  244. (defvar shell-dirtrackp t
  245.   "Non-nil in a shell buffer means directory tracking is enabled.")
  246.  
  247. (defvar shell-last-dir nil
  248.   "Keep track of last directory for ksh `cd -' command.")
  249.  
  250. (defvar shell-dirstack-query nil
  251.   "Command used by `shell-resync-dir' to query the shell.")
  252.  
  253. (defvar shell-mode-map nil)
  254. (cond ((not shell-mode-map)
  255.        (setq shell-mode-map (copy-keymap comint-mode-map))
  256.        (define-key shell-mode-map "\C-c\C-f" 'shell-forward-command)
  257.        (define-key shell-mode-map "\C-c\C-b" 'shell-backward-command)
  258.        (define-key shell-mode-map "\t" 'comint-dynamic-complete)
  259.        (define-key shell-mode-map "\M-?"
  260.      'comint-dynamic-list-filename-completions)
  261.        (define-key-after (lookup-key shell-mode-map [menu-bar completion])
  262.      [complete-env-variable] '("Complete Env. Variable Name" .
  263.                    shell-dynamic-complete-environment-variable)
  264.      'complete-file)
  265.        (define-key-after (lookup-key shell-mode-map [menu-bar completion])
  266.      [expand-directory] '("Expand Directory Reference" .
  267.                   shell-replace-by-expanded-directory)
  268.      'complete-expand)))
  269.  
  270. (defvar shell-mode-hook '()
  271.   "*Hook for customising Shell mode.")
  272.  
  273.  
  274. ;;; Basic Procedures
  275. ;;; ===========================================================================
  276. ;;;
  277.  
  278. (defun shell-mode ()
  279.   "Major mode for interacting with an inferior shell.
  280. Return after the end of the process' output sends the text from the 
  281.     end of process to the end of the current line.
  282. Return before end of process output copies the current line (except
  283.     for the prompt) to the end of the buffer and sends it.
  284. M-x send-invisible reads a line of text without echoing it, and sends it to
  285.     the shell.  This is useful for entering passwords.  Or, add the function
  286.     `comint-watch-for-password-prompt' to `comint-output-filter-functions'.
  287.  
  288. If you accidentally suspend your process, use \\[comint-continue-subjob]
  289. to continue it.
  290.  
  291. cd, pushd and popd commands given to the shell are watched by Emacs to keep
  292. this buffer's default directory the same as the shell's working directory.
  293. M-x dirs queries the shell and resyncs Emacs' idea of what the current 
  294.     directory stack is.
  295. M-x dirtrack-toggle turns directory tracking on and off.
  296.  
  297. \\{shell-mode-map}
  298. Customization: Entry to this mode runs the hooks on `comint-mode-hook' and
  299. `shell-mode-hook' (in that order).  Before each input, the hooks on
  300. `comint-input-filter-functions' are run.  After each shell output, the hooks
  301. on `comint-output-filter-functions' are run.
  302.  
  303. Variables `shell-cd-regexp', `shell-pushd-regexp' and `shell-popd-regexp'
  304. are used to match their respective commands, while `shell-pushd-tohome',
  305. `shell-pushd-dextract' and `shell-pushd-dunique' control the behavior of the
  306. relevant command.
  307.  
  308. Variables `comint-completion-autolist', `comint-completion-addsuffix',
  309. `comint-completion-recexact' and `comint-completion-fignore' control the
  310. behavior of file name, command name and variable name completion.  Variable
  311. `shell-completion-execonly' controls the behavior of command name completion.
  312. Variable `shell-completion-fignore' is used to initialise the value of
  313. `comint-completion-fignore'.
  314.  
  315. Variables `comint-input-ring-file-name' and `comint-input-autoexpand' control
  316. the initialisation of the input ring history, and history expansion.
  317.  
  318. Variables `comint-output-filter-functions', a hook, and
  319. `comint-scroll-to-bottom-on-input' and `comint-scroll-to-bottom-on-output'
  320. control whether input and output cause the window to scroll to the end of the
  321. buffer."
  322.   (interactive)
  323.   (comint-mode)
  324.   (setq major-mode 'shell-mode)
  325.   (setq mode-name "Shell")
  326.   (use-local-map shell-mode-map)
  327.   (setq comint-prompt-regexp shell-prompt-pattern)
  328.   (setq comint-completion-fignore shell-completion-fignore)
  329.   (setq comint-delimiter-argument-list shell-delimiter-argument-list)
  330.   (setq comint-dynamic-complete-functions shell-dynamic-complete-functions)
  331.   (make-local-variable 'paragraph-start)
  332.   (setq paragraph-start comint-prompt-regexp)
  333.   (make-local-variable 'shell-dirstack)
  334.   (setq shell-dirstack nil)
  335.   (setq shell-last-dir nil)
  336.   (make-local-variable 'shell-dirtrackp)
  337.   (setq shell-dirtrackp t)
  338.   (add-hook 'comint-input-filter-functions 'shell-directory-tracker)
  339.   (setq comint-input-autoexpand shell-input-autoexpand)
  340.   ;; shell-dependent assignments.
  341.   (let ((shell (file-name-nondirectory (car
  342.          (process-command (get-buffer-process (current-buffer)))))))
  343.     (setq comint-input-ring-file-name
  344.       (or (getenv "HISTFILE")
  345.           (cond ((string-equal shell "bash") "~/.bash_history")
  346.             ((string-equal shell "ksh") "~/.sh_history")
  347.             (t "~/.history"))))
  348.     (if (equal comint-input-ring-file-name "/dev/null")
  349.     (setq comint-input-ring-file-name nil))
  350.     (setq shell-dirstack-query
  351.       (if (string-match "^k?sh$" shell) "pwd" "dirs")))
  352.   (run-hooks 'shell-mode-hook)
  353.   (comint-read-input-ring t))
  354.  
  355. ;;;###autoload
  356. (defun shell ()
  357.   "Run an inferior shell, with I/O through buffer *shell*.
  358. If buffer exists but shell process is not running, make new shell.
  359. If buffer exists and shell process is running, just switch to buffer `*shell*'.
  360. Program used comes from variable `explicit-shell-file-name',
  361.  or (if that is nil) from the ESHELL environment variable,
  362.  or else from SHELL if there is no ESHELL.
  363. If a file `~/.emacs_SHELLNAME' exists, it is given as initial input
  364.  (Note that this may lose due to a timing error if the shell
  365.   discards input when it starts up.)
  366. The buffer is put in Shell mode, giving commands for sending input
  367. and controlling the subjobs of the shell.  See `shell-mode'.
  368. See also the variable `shell-prompt-pattern'.
  369.  
  370. The shell file name (sans directories) is used to make a symbol name
  371. such as `explicit-csh-args'.  If that symbol is a variable,
  372. its value is used as a list of arguments when invoking the shell.
  373. Otherwise, one argument `-i' is passed to the shell.
  374.  
  375. \(Type \\[describe-mode] in the shell buffer for a list of commands.)"
  376.   (interactive)
  377.   (if (not (comint-check-proc "*shell*"))
  378.       (let* ((prog (or explicit-shell-file-name
  379.                (getenv "ESHELL")
  380.                (getenv "SHELL")
  381.                "/bin/sh"))             
  382.          (name (file-name-nondirectory prog))
  383.          (startfile (concat "~/.emacs_" name))
  384.          (xargs-name (intern-soft (concat "explicit-" name "-args"))))
  385.     (set-buffer (apply 'make-comint "shell" prog
  386.                (if (file-exists-p startfile) startfile)
  387.                (if (and xargs-name (boundp xargs-name))
  388.                    (symbol-value xargs-name)
  389.                  '("-i"))))
  390.     (shell-mode)))
  391.   (switch-to-buffer "*shell*"))
  392.  
  393. ;;; Directory tracking
  394. ;;; ===========================================================================
  395. ;;; This code provides the shell mode input sentinel
  396. ;;;     SHELL-DIRECTORY-TRACKER
  397. ;;; that tracks cd, pushd, and popd commands issued to the shell, and
  398. ;;; changes the current directory of the shell buffer accordingly.
  399. ;;;
  400. ;;; This is basically a fragile hack, although it's more accurate than
  401. ;;; the version in Emacs 18's shell.el. It has the following failings:
  402. ;;; 1. It doesn't know about the cdpath shell variable.
  403. ;;; 2. It cannot infallibly deal with command sequences, though it does well
  404. ;;;    with these and with ignoring commands forked in another shell with ()s.
  405. ;;; 3. More generally, any complex command is going to throw it. Otherwise,
  406. ;;;    you'd have to build an entire shell interpreter in emacs lisp.  Failing
  407. ;;;    that, there's no way to catch shell commands where cd's are buried
  408. ;;;    inside conditional expressions, aliases, and so forth.
  409. ;;;
  410. ;;; The whole approach is a crock. Shell aliases mess it up. File sourcing
  411. ;;; messes it up. You run other processes under the shell; these each have
  412. ;;; separate working directories, and some have commands for manipulating
  413. ;;; their w.d.'s (e.g., the lcd command in ftp). Some of these programs have
  414. ;;; commands that do *not* affect the current w.d. at all, but look like they
  415. ;;; do (e.g., the cd command in ftp).  In shells that allow you job
  416. ;;; control, you can switch between jobs, all having different w.d.'s. So
  417. ;;; simply saying %3 can shift your w.d..
  418. ;;;
  419. ;;; The solution is to relax, not stress out about it, and settle for
  420. ;;; a hack that works pretty well in typical circumstances. Remember
  421. ;;; that a half-assed solution is more in keeping with the spirit of Unix, 
  422. ;;; anyway. Blech.
  423. ;;;
  424. ;;; One good hack not implemented here for users of programmable shells
  425. ;;; is to program up the shell w.d. manipulation commands to output
  426. ;;; a coded command sequence to the tty. Something like
  427. ;;;     ESC | <cwd> |
  428. ;;; where <cwd> is the new current working directory. Then trash the
  429. ;;; directory tracking machinery currently used in this package, and
  430. ;;; replace it with a process filter that watches for and strips out
  431. ;;; these messages.
  432.  
  433. (defun shell-directory-tracker (str)
  434.   "Tracks cd, pushd and popd commands issued to the shell.
  435. This function is called on each input passed to the shell.
  436. It watches for cd, pushd and popd commands and sets the buffer's
  437. default directory to track these commands.
  438.  
  439. You may toggle this tracking on and off with M-x dirtrack-toggle.
  440. If emacs gets confused, you can resync with the shell with M-x dirs.
  441.  
  442. See variables `shell-cd-regexp', `shell-pushd-regexp', and `shell-popd-regexp',
  443. while `shell-pushd-tohome', `shell-pushd-dextract' and `shell-pushd-dunique'
  444. control the behavior of the relevant command.
  445.  
  446. Environment variables are expanded, see function `substitute-in-file-name'."
  447.   (if shell-dirtrackp
  448.       ;; We fail gracefully if we think the command will fail in the shell.
  449.       (condition-case chdir-failure
  450.       (let ((start (progn (string-match "^[;\\s ]*" str) ; skip whitespace
  451.                   (match-end 0)))
  452.         end cmd arg1)
  453.         (while (string-match shell-command-regexp str start)
  454.           (setq end (match-end 0)
  455.             cmd (comint-arguments (substring str start end) 0 0)
  456.             arg1 (comint-arguments (substring str start end) 1 1))
  457.           (cond ((eq (string-match shell-popd-regexp cmd) 0)
  458.              (shell-process-popd (substitute-in-file-name arg1)))
  459.             ((eq (string-match shell-pushd-regexp cmd) 0)
  460.              (shell-process-pushd (substitute-in-file-name arg1)))
  461.             ((eq (string-match shell-cd-regexp cmd) 0)
  462.              (shell-process-cd (substitute-in-file-name arg1))))
  463.           (setq start (progn (string-match "[;\\s ]*" str end) ; skip again
  464.                  (match-end 0)))))
  465.     (error "Couldn't cd"))))
  466.  
  467. ;;; popd [+n]
  468. (defun shell-process-popd (arg)
  469.   (let ((num (or (shell-extract-num arg) 0)))
  470.     (cond ((and num (= num 0) shell-dirstack)
  471.        (cd (car shell-dirstack))
  472.        (setq shell-dirstack (cdr shell-dirstack))
  473.        (shell-dirstack-message))
  474.       ((and num (> num 0) (<= num (length shell-dirstack)))
  475.        (let* ((ds (cons nil shell-dirstack))
  476.           (cell (nthcdr (1- num) ds)))
  477.          (rplacd cell (cdr (cdr cell)))
  478.          (setq shell-dirstack (cdr ds))
  479.          (shell-dirstack-message)))
  480.       (t
  481.        (error "Couldn't popd")))))
  482.  
  483. ;; Return DIR prefixed with comint-file-name-prefix as appropriate.
  484. (defun shell-prefixed-directory-name (dir)
  485.   (if (= (length comint-file-name-prefix) 0)
  486.       dir
  487.     (if (file-name-absolute-p dir)
  488.     ;; The name is absolute, so prepend the prefix.
  489.     (concat comint-file-name-prefix dir)
  490.       ;; For a relative name we assume default-directory already has the prefix.
  491.       (expand-file-name dir))))
  492.  
  493. ;;; cd [dir]
  494. (defun shell-process-cd (arg)
  495.   (let ((new-dir (cond ((zerop (length arg)) (concat comint-file-name-prefix
  496.                              "~"))
  497.                ((string-equal "-" arg) shell-last-dir)
  498.                (t (shell-prefixed-directory-name arg)))))
  499.     (setq shell-last-dir default-directory)
  500.     (cd new-dir)
  501.     (shell-dirstack-message)))
  502.  
  503. ;;; pushd [+n | dir]
  504. (defun shell-process-pushd (arg)
  505.   (let ((num (shell-extract-num arg)))
  506.     (cond ((zerop (length arg))
  507.        ;; no arg -- swap pwd and car of stack unless shell-pushd-tohome
  508.        (cond (shell-pushd-tohome
  509.           (shell-process-pushd (concat comint-file-name-prefix "~")))
  510.          (shell-dirstack
  511.           (let ((old default-directory))
  512.             (cd (car shell-dirstack))
  513.             (setq shell-dirstack
  514.               (cons old (cdr shell-dirstack)))
  515.             (shell-dirstack-message)))
  516.          (t
  517.           (message "Directory stack empty."))))
  518.       ((numberp num)
  519.        ;; pushd +n
  520.        (cond ((> num (length shell-dirstack))
  521.           (message "Directory stack not that deep."))
  522.          ((= num 0)
  523.           (error (message "Couldn't cd.")))
  524.          (shell-pushd-dextract
  525.           (let ((dir (nth (1- num) shell-dirstack)))
  526.             (shell-process-popd arg)
  527.             (shell-process-pushd default-directory)
  528.             (cd dir)
  529.             (shell-dirstack-message)))
  530.          (t
  531.           (let* ((ds (cons default-directory shell-dirstack))
  532.              (dslen (length ds))
  533.              (front (nthcdr num ds))
  534.              (back (reverse (nthcdr (- dslen num) (reverse ds))))
  535.              (new-ds (append front back)))
  536.             (cd (car new-ds))
  537.             (setq shell-dirstack (cdr new-ds))
  538.             (shell-dirstack-message)))))
  539.       (t
  540.        ;; pushd <dir>
  541.        (let ((old-wd default-directory))
  542.          (cd (shell-prefixed-directory-name arg))
  543.          (if (or (null shell-pushd-dunique)
  544.              (not (member old-wd shell-dirstack)))
  545.          (setq shell-dirstack (cons old-wd shell-dirstack)))
  546.          (shell-dirstack-message))))))
  547.  
  548. ;; If STR is of the form +n, for n>0, return n. Otherwise, nil.
  549. (defun shell-extract-num (str)
  550.   (and (string-match "^\\+[1-9][0-9]*$" str)
  551.        (string-to-int str)))
  552.  
  553.  
  554. (defun shell-dirtrack-toggle ()
  555.   "Turn directory tracking on and off in a shell buffer."
  556.   (interactive)
  557.   (setq shell-dirtrackp (not shell-dirtrackp))
  558.   (message "Directory tracking %s" (if shell-dirtrackp "ON" "OFF")))
  559.  
  560. ;;; For your typing convenience:
  561. (defalias 'dirtrack-toggle 'shell-dirtrack-toggle)
  562.  
  563.  
  564. (defun shell-resync-dirs ()
  565.   "Resync the buffer's idea of the current directory stack.
  566. This command queries the shell with the command bound to 
  567. `shell-dirstack-query' (default \"dirs\"), reads the next
  568. line output and parses it to form the new directory stack.
  569. DON'T issue this command unless the buffer is at a shell prompt.
  570. Also, note that if some other subprocess decides to do output
  571. immediately after the query, its output will be taken as the
  572. new directory stack -- you lose. If this happens, just do the
  573. command again."
  574.   (interactive)
  575.   (let* ((proc (get-buffer-process (current-buffer)))
  576.      (pmark (process-mark proc)))
  577.     (goto-char pmark)
  578.     (insert shell-dirstack-query) (insert "\n")
  579.     (sit-for 0) ; force redisplay
  580.     (comint-send-string proc shell-dirstack-query) 
  581.     (comint-send-string proc "\n")
  582.     (set-marker pmark (point))
  583.     (let ((pt (point))) ; wait for 1 line
  584.       ;; This extra newline prevents the user's pending input from spoofing us.
  585.       (insert "\n") (backward-char 1)
  586.       (while (not (looking-at ".+\n"))
  587.     (accept-process-output proc)
  588.     (goto-char pt)))
  589.     (goto-char pmark) (delete-char 1) ; remove the extra newline
  590.     ;; That's the dirlist. grab it & parse it.
  591.     (let* ((dl (buffer-substring (match-beginning 0) (1- (match-end 0))))
  592.        (dl-len (length dl))
  593.        (ds '())            ; new dir stack
  594.        (i 0))
  595.       (while (< i dl-len)
  596.     ;; regexp = optional whitespace, (non-whitespace), optional whitespace
  597.     (string-match "\\s *\\(\\S +\\)\\s *" dl i) ; pick off next dir
  598.     (setq ds (cons (concat comint-file-name-prefix
  599.                    (substring dl (match-beginning 1)
  600.                       (match-end 1)))
  601.                ds))
  602.     (setq i (match-end 0)))
  603.       (let ((ds (nreverse ds)))
  604.     (condition-case nil
  605.         (progn (cd (car ds))
  606.            (setq shell-dirstack (cdr ds))
  607.            (shell-dirstack-message))
  608.       (error (message "Couldn't cd.")))))))
  609.  
  610. ;;; For your typing convenience:
  611. (defalias 'dirs 'shell-resync-dirs)
  612.  
  613.  
  614. ;;; Show the current dirstack on the message line.
  615. ;;; Pretty up dirs a bit by changing "/usr/jqr/foo" to "~/foo".
  616. ;;; (This isn't necessary if the dirlisting is generated with a simple "dirs".)
  617. ;;; All the commands that mung the buffer's dirstack finish by calling
  618. ;;; this guy.
  619. (defun shell-dirstack-message ()
  620.   (let* ((msg "")
  621.      (ds (cons default-directory shell-dirstack))
  622.      (home (expand-file-name (concat comint-file-name-prefix "~/")))
  623.      (homelen (length home)))
  624.     (while ds
  625.       (let ((dir (car ds)))
  626.     (and (>= (length dir) homelen) (string= home (substring dir 0 homelen))
  627.         (setq dir (concat "~/" (substring dir homelen))))
  628.     ;; Strip off comint-file-name-prefix if present.
  629.     (and comint-file-name-prefix
  630.          (>= (length dir) (length comint-file-name-prefix))
  631.          (string= comint-file-name-prefix
  632.               (substring dir 0 (length comint-file-name-prefix)))
  633.          (setq dir (substring dir (length comint-file-name-prefix)))
  634.          (setcar ds dir))
  635.     (setq msg (concat msg (directory-file-name dir) " "))
  636.     (setq ds (cdr ds))))
  637.     (message msg)))
  638.  
  639. (defun shell-forward-command (&optional arg)
  640.   "Move forward across ARG shell command(s).  Does not cross lines.
  641. See `shell-command-regexp'."
  642.   (interactive "p")
  643.   (let ((limit (save-excursion (end-of-line nil) (point))))
  644.     (if (re-search-forward (concat shell-command-regexp "\\([;&|][\t ]*\\)+")
  645.                limit 'move arg)
  646.     (skip-syntax-backward " "))))
  647.  
  648.  
  649. (defun shell-backward-command (&optional arg)
  650.   "Move backward across ARG shell command(s).  Does not cross lines.
  651. See `shell-command-regexp'."
  652.   (interactive "p")
  653.   (let ((limit (save-excursion (comint-bol nil) (point))))
  654.     (if (> limit (point))
  655.     (save-excursion (beginning-of-line) (setq limit (point))))
  656.     (skip-syntax-backward " " limit)
  657.     (if (re-search-backward
  658.      (format "[;&|]+[\t ]*\\(%s\\)" shell-command-regexp) limit 'move arg)
  659.     (progn (goto-char (match-beginning 1))
  660.            (skip-chars-forward ";&|")))))
  661.  
  662.  
  663. (defun shell-dynamic-complete-command ()
  664.   "Dynamically complete the command at point.
  665. This function is similar to `comint-dynamic-complete-filename', except that it
  666. searches `exec-path' (minus the trailing emacs library path) for completion
  667. candidates.  Note that this may not be the same as the shell's idea of the
  668. path.
  669.  
  670. Completion is dependent on the value of `shell-completion-execonly', plus
  671. those that effect file completion.  See `shell-dynamic-complete-as-command'.
  672.  
  673. Returns t if successful."
  674.   (interactive)
  675.   (let ((filename (comint-match-partial-filename)))
  676.     (if (and filename
  677.          (save-match-data (not (string-match "[~/]" filename)))
  678.          (eq (match-beginning 0)
  679.          (save-excursion (shell-backward-command 1) (point))))
  680.     (prog2 (message "Completing command name...")
  681.         (shell-dynamic-complete-as-command)))))
  682.  
  683.  
  684. (defun shell-dynamic-complete-as-command ()
  685.   "Dynamically complete at point as a command.
  686. See `shell-dynamic-complete-filename'.  Returns t if successful."
  687.   (let* ((filename (or (comint-match-partial-filename) ""))
  688.      (pathnondir (file-name-nondirectory filename))
  689.      (paths (cdr (reverse exec-path)))
  690.      (cwd (file-name-as-directory (expand-file-name default-directory)))
  691.      (ignored-extensions
  692.       (and comint-completion-fignore
  693.            (mapconcat (function (lambda (x) (concat (regexp-quote x) "$")))
  694.               comint-completion-fignore "\\|")))
  695.      (path "") (comps-in-path ()) (file "") (filepath "") (completions ()))
  696.     ;; Go thru each path in the search path, finding completions.
  697.     (while paths
  698.       (setq path (file-name-as-directory (comint-directory (or (car paths) ".")))
  699.         comps-in-path (and (file-accessible-directory-p path)
  700.                    (file-name-all-completions pathnondir path)))
  701.       ;; Go thru each completion found, to see whether it should be used.
  702.       (while comps-in-path
  703.     (setq file (car comps-in-path)
  704.           filepath (concat path file))
  705.     (if (and (not (member file completions))
  706.          (not (and ignored-extensions
  707.                (string-match ignored-extensions file)))
  708.          (or (string-equal path cwd)
  709.              (not (file-directory-p filepath)))
  710.          (or (null shell-completion-execonly)
  711.              (file-executable-p filepath)))
  712.         (setq completions (cons file completions)))
  713.     (setq comps-in-path (cdr comps-in-path)))
  714.       (setq paths (cdr paths)))
  715.     ;; OK, we've got a list of completions.
  716.     (let ((success (let ((comint-completion-addsuffix nil))
  717.              (comint-dynamic-simple-complete pathnondir completions))))
  718.       (if (and (memq success '(sole shortest)) comint-completion-addsuffix
  719.            (not (file-directory-p (comint-match-partial-filename))))
  720.       (insert " "))
  721.       success)))
  722.  
  723.  
  724. (defun shell-match-partial-variable ()
  725.   "Return the variable at point, or nil if non is found."
  726.   (save-excursion
  727.     (let ((limit (point)))
  728.       (if (re-search-backward "[^A-Za-z0-9_{}]" nil 'move)
  729.       (or (looking-at "\\$") (forward-char 1)))
  730.       ;; Anchor the search forwards.
  731.       (if (or (eolp) (looking-at "[^A-Za-z0-9_{}$]"))
  732.       nil
  733.     (re-search-forward "\\$?{?[A-Za-z0-9_]*}?" limit)
  734.     (buffer-substring (match-beginning 0) (match-end 0))))))
  735.  
  736.  
  737. (defun shell-dynamic-complete-environment-variable ()
  738.   "Dynamically complete the environment variable at point.
  739. Completes if after a variable, i.e., if it starts with a \"$\".
  740. See `shell-dynamic-complete-as-environment-variable'.
  741.  
  742. This function is similar to `comint-dynamic-complete-filename', except that it
  743. searches `process-environment' for completion candidates.  Note that this may
  744. not be the same as the interpreter's idea of variable names.  The main problem
  745. with this type of completion is that `process-environment' is the environment
  746. which Emacs started with.  Emacs does not track changes to the environment made
  747. by the interpreter.  Perhaps it would be more accurate if this function was
  748. called `shell-dynamic-complete-process-environment-variable'.
  749.  
  750. Returns non-nil if successful."
  751.   (interactive)
  752.   (let ((variable (shell-match-partial-variable)))
  753.     (if (and variable (string-match "^\\$" variable))
  754.     (prog2 (message "Completing variable name...")
  755.         (shell-dynamic-complete-as-environment-variable)))))
  756.  
  757.  
  758. (defun shell-dynamic-complete-as-environment-variable ()
  759.   "Dynamically complete at point as an environment variable.
  760. Used by `shell-dynamic-complete-environment-variable'.
  761. Uses `comint-dynamic-simple-complete'."
  762.   (let* ((var (or (shell-match-partial-variable) ""))
  763.      (variable (substring var (or (string-match "[^$({]\\|$" var) 0)))
  764.      (variables (mapcar (function (lambda (x)
  765.                     (substring x 0 (string-match "=" x))))
  766.                 process-environment))
  767.      (addsuffix comint-completion-addsuffix)
  768.      (comint-completion-addsuffix nil)
  769.      (success (comint-dynamic-simple-complete variable variables)))
  770.     (if (memq success '(sole shortest))
  771.     (let* ((var (shell-match-partial-variable))
  772.            (variable (substring var (string-match "[^$({]" var)))
  773.            (protection (cond ((string-match "{" var) "}")
  774.                  ((string-match "(" var) ")")
  775.                  (t "")))
  776.            (suffix (cond ((null addsuffix) "")
  777.                  ((file-directory-p
  778.                    (comint-directory (getenv variable))) "/")
  779.                  (t " "))))
  780.       (insert protection suffix)))
  781.     success))
  782.  
  783.  
  784. (defun shell-replace-by-expanded-directory ()
  785.   "Expand directory stack reference before point.
  786. Directory stack references are of the form \"=digit\" or \"=-\".
  787. See `default-directory' and `shell-dirstack'.
  788.  
  789. Returns t if successful."
  790.   (interactive)
  791.   (if (comint-match-partial-filename)
  792.       (save-excursion
  793.     (goto-char (match-beginning 0))
  794.     (let ((stack (cons default-directory shell-dirstack))
  795.           (index (cond ((looking-at "=-/?")
  796.                 (length shell-dirstack))
  797.                ((looking-at "=\\([0-9]+\\)")
  798.                 (string-to-number
  799.                  (buffer-substring
  800.                   (match-beginning 1) (match-end 1)))))))
  801.       (cond ((null index)
  802.          nil)
  803.         ((>= index (length stack))
  804.          (error "Directory stack not that deep."))
  805.         (t
  806.          (replace-match (file-name-as-directory (nth index stack)) t t)
  807.          (message "Directory item: %d" index)
  808.          t))))))
  809.  
  810. (defun shell-strip-ctrl-m (&optional string)
  811.   "Strip trailing `^M' characters from the current output group.
  812.  
  813. This function could be in the list `comint-output-filter-functions' or bound to
  814. a key."
  815.   (interactive)
  816.   (let ((pmark (process-mark (get-buffer-process (current-buffer)))))
  817.     (save-excursion
  818.       (goto-char
  819.        (if (interactive-p) comint-last-input-end comint-last-output-start))
  820.       (while (re-search-forward "\r+$" pmark t)
  821.     (replace-match "" t t)))))
  822.  
  823. (provide 'shell)
  824.  
  825. ;;; shell.el ends here
  826.