home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / emacs-19.28-src.tgz / tar.out / fsf / emacs / lisp / timer.el < prev    next >
Lisp/Scheme  |  1996-09-28  |  7KB  |  158 lines
  1. ;;; timer.el --- run a function with args at some time in future
  2.  
  3. ;; Copyright (C) 1990, 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6.  
  7. ;; This file is part of GNU Emacs.
  8.  
  9. ;; GNU Emacs is free software; you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation; either version 2, or (at your option)
  12. ;; any later version.
  13.  
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;; GNU General Public License for more details.
  18.  
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22.  
  23. ;;; Commentary:
  24.  
  25. ;; This package gives you the capability to run Emacs Lisp commands at
  26. ;; specified times in the future, either as one-shots or periodically.
  27. ;; The single entry point is `run-at-time'.
  28.  
  29. ;;; Code:
  30.  
  31. ;;; The name of the program to run as the timer subprocess.  It should
  32. ;;; be in exec-directory.
  33. (defconst timer-program "timer")
  34.  
  35. (defvar timer-process nil)
  36. (defvar timer-alist ())
  37. (defvar timer-out "")
  38. (defvar timer-dont-exit nil
  39.   ;; this is useful for functions which will be doing their own erratic
  40.   ;; rescheduling or people who otherwise expect to use the process frequently
  41.   "If non-nil, don't exit the timer process when no more events are pending.")
  42.  
  43. ;; This should not be necessary, but on some systems, we get
  44. ;; unkillable processes without this.
  45. ;; It may be a kernel bug, but that's not certain.
  46. (defun timer-kill-emacs-hook ()
  47.   (if timer-process
  48.       (progn
  49.     (set-process-sentinel timer-process nil)
  50.     (set-process-filter timer-process nil)
  51.     (delete-process timer-process))))
  52. (add-hook 'kill-emacs-hook 'timer-kill-emacs-hook)
  53.  
  54. ;;;###autoload
  55. (defun run-at-time (time repeat function &rest args)
  56.   "Run a function at a time, and optionally on a regular interval.
  57. Arguments are TIME, REPEAT, FUNCTION &rest ARGS.
  58. TIME, a string, can be specified absolutely or relative to now.
  59. TIME can also be an integer, a number of seconds.
  60. REPEAT, an integer number of seconds, is the interval on which to repeat
  61. the call to the function.  If REPEAT is nil or 0, call it just once.
  62.  
  63. Absolute times may be specified in a wide variety of formats;
  64. Something of the form `HOUR:MIN:SEC TIMEZONE MONTH/DAY/YEAR', where
  65. all fields are numbers, works; the format used by the Unix `date'
  66. command works too.
  67.  
  68. Relative times may be specified as a series of numbers followed by units:
  69.   1 min             denotes one minute from now.
  70.   min            does too.
  71.   1 min 5 sec        denotes 65 seconds from now.
  72.   1 min 2 sec 3 hour 4 day 5 week 6 fortnight 7 month 8 year
  73.             denotes the sum of all the given durations from now."
  74.   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
  75.   (if (equal repeat 0)
  76.       (setq repeat nil))
  77.   ;; Make TIME a string.
  78.   (if (integerp time)
  79.       (setq time (format "%d sec" time)))
  80.   (cond ((or (not timer-process) 
  81.              (memq (process-status timer-process) '(exit signal nil)))
  82.          (if timer-process (delete-process timer-process))
  83.          (setq timer-process
  84.            (let ((process-connection-type nil))
  85.          ;; Don't search the exec path for the timer program;
  86.          ;; we know exactly which one we want.
  87.          (start-process "timer" nil
  88.                 (expand-file-name timer-program
  89.                           exec-directory)))
  90.                timer-alist nil)
  91.          (set-process-filter   timer-process 'timer-process-filter)
  92.          (set-process-sentinel timer-process 'timer-process-sentinel)
  93.          (process-kill-without-query timer-process))
  94.         ((eq (process-status timer-process) 'stop)
  95.          (continue-process timer-process)))
  96.   ;; There should be a living, breathing timer process now
  97.   (let* ((token (concat (current-time-string) "-" (length timer-alist)))
  98.      (elt (list token repeat function args)))
  99.     (process-send-string timer-process (concat time "@" token "\n"))
  100.     (setq timer-alist (cons elt timer-alist))
  101.     elt))
  102.  
  103. (defun cancel-timer (elt)
  104.   "Cancel a timer previously made with `run-at-time'.
  105. The argument should be a value previously returned by `run-at-time'.
  106. Cancelling the timer means that nothing special 
  107. will happen at the specified time."
  108.   (setcar (cdr elt) nil)
  109.   (setcar (cdr (cdr elt)) 'ignore))
  110.  
  111. (defun timer-process-filter (proc str)
  112.   (setq timer-out (concat timer-out str))
  113.   (let (do token error)
  114.     (while (string-match "\n" timer-out)
  115.       (setq token (substring timer-out 0 (match-beginning 0))
  116.             do (assoc token timer-alist)
  117.             timer-out (substring timer-out (match-end 0)))
  118.       (cond
  119.        (do
  120.     (apply (nth 2 do) (nth 3 do))   ; do it
  121.     (if (natnump (nth 1 do))        ; reschedule it
  122.         (send-string proc (concat (nth 1 do) " sec@" (car do) "\n"))
  123.       (setq timer-alist (delq do timer-alist))))
  124.        ((string-match "timer: \\([^:]+\\): \\([^@]*\\)@\\(.*\\)$" token)
  125.         (setq error (substring token (match-beginning 1) (match-end 1))
  126.               do    (substring token (match-beginning 2) (match-end 2))
  127.               token (assoc (substring token (match-beginning 3) (match-end 3))
  128.                            timer-alist)
  129.               timer-alist (delq token timer-alist))
  130.         (ding 'no-terminate) ; using error function in process filters is rude
  131.         (message "%s for %s; couldn't set at \"%s\"" error (nth 2 token) do))))
  132.     (or timer-alist timer-dont-exit (process-send-eof proc))))
  133.  
  134. (defun timer-process-sentinel (proc str)
  135.   (let ((stat (process-status proc)))
  136.     (if (eq stat 'stop) (continue-process proc)
  137.       ;; if it exited normally, presumably it was intentional.
  138.       ;; if there were no pending events, who cares that it exited?
  139.       (if (or (not timer-alist) (eq stat 'exit)) ()
  140.         (ding 'no-terminate)
  141.         (message "Timer exited abnormally.  All events cancelled."))
  142.       ;; Used to set timer-scratch to "", but nothing uses that var.
  143.       (setq timer-process nil timer-alist nil))))
  144.  
  145. (defun cancel-function-timers (function)
  146.   "Cancel all events scheduled by `run-at-time' which would run FUNCTION."
  147.   (interactive "aCancel timers of function: ")
  148.   (let ((alist timer-alist))
  149.     (while alist
  150.       (if (eq (nth 2 (car alist)) function)
  151.           (setq timer-alist (delq (car alist) timer-alist)))
  152.       (setq alist (cdr alist))))
  153.   (or timer-alist timer-dont-exit (process-send-eof timer-process)))
  154.  
  155. (provide 'timer)
  156.  
  157. ;;; timer.el ends here
  158.