home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gettext-0.10.24-src.tgz / tar.out / fsf / gettext / configure.in < prev    next >
Text File  |  1996-09-28  |  4KB  |  121 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2. AC_REVISION($Revision: 1.132 $)
  3. AC_INIT(src/msgfmt.c)
  4. AC_CONFIG_HEADER(config.h)
  5. AC_PREREQ(2.99)
  6. PACKAGE=gettext
  7. VERSION=0.10.24
  8. AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  9. AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  10. AC_SUBST(PACKAGE)
  11. AC_SUBST(VERSION)
  12.  
  13. changequote(,)dnl
  14. case $VERSION in
  15.   [0-9]*.[0-9]*.[0-9]*) DIST_ALPHA="README-alpha";;
  16.   *) DIST_ALPHA=;;
  17. esac
  18. changequote([, ])dnl
  19. AC_SUBST(DIST_ALPHA)
  20.  
  21. dnl Set of available languages.
  22. ALL_LINGUAS="de es fr ko nl no no@nynorsk pl sl sv"
  23.  
  24. dnl Checks for programs.
  25. AC_ARG_PROGRAM
  26. AC_PROG_MAKE_SET
  27. AC_PROG_CC
  28. AC_ISC_POSIX
  29. AM_PROG_INSTALL
  30. AC_PROG_MKINSTALLDIRS
  31. AC_PROG_RANLIB
  32. AC_PROG_YACC
  33.  
  34. dnl Checks for libraries.
  35.  
  36. dnl Checks for header files.
  37. AC_HEADER_STDC
  38. AC_HAVE_HEADERS(limits.h malloc.h string.h unistd.h values.h)
  39.  
  40. dnl Checks for typedefs, structures, and compiler characteristics.
  41. AC_C_CONST
  42. AC_C_INLINE
  43. AC_TYPE_OFF_T
  44. AC_TYPE_SIZE_T
  45. md_TYPE_PTRDIFF_T
  46.  
  47. dnl Checks for library functions.
  48. AC_FUNC_ALLOCA
  49. AC_FUNC_VPRINTF
  50. AC_CHECK_FUNCS([getcwd mblen memcpy strchr strerror uname])
  51. AC_REPLACE_FUNCS([getline memmove memset stpcpy stpncpy strcspn strncasecmp \
  52. strstr strtoul vasprintf])
  53. if test $ac_cv_func_getline != yes; then
  54.   AC_CHECK_FUNCS(getdelim)
  55. fi
  56.  
  57. AC_CHECK_FUNC(parse_printf_format, gt_cv_func_parse_printf_format=yes,
  58.   gt_cv_func_parse_printf_format=no)
  59. if test $gt_cv_func_parse_printf_format = yes; then
  60.   AC_DEFINE(HAVE_PARSE_PRINTF_FORMAT)
  61. else
  62.   LIBOBJS="$LIBOBJS printf-prs.o"
  63. fi
  64.  
  65. AC_CACHE_CHECK([for obstacks], gt_cv_func_obstack,
  66. [AC_TRY_LINK([#include "obstack.h"],
  67. [struct obstack *mem;obstack_free(mem,(char *) 0)],
  68.     gt_cv_func_obstack=yes, gt_cv_func_obstack=no)])
  69. if test $gt_cv_func_obstack = yes; then
  70.   AC_DEFINE(HAVE_OBSTACK)
  71. else
  72.   LIBOBJS="$LIBOBJS obstack.o"
  73. fi
  74.  
  75. AC_CACHE_CHECK([for error], gt_cv_func_error,
  76. [AC_TRY_LINK([#include "error.h"],
  77. [error_at_line (0, 0, "", 0, "")],
  78.     gt_cv_func_error=yes, gt_cv_func_error=no)])
  79. if test $gt_cv_func_error != yes; then
  80.   LIBOBJS="$LIBOBJS error.o"
  81. fi
  82.  
  83. dnl These are the only lines required to internationalize the package.
  84. dnl (OK, not quite, the AC_OUTPUT has also some parts.)
  85. ud_GNU_GETTEXT
  86.  
  87. dnl Check for Emacs and where to install .elc files.
  88. ud_PATH_LISPDIR
  89.  
  90. dnl The reference to <locale.h> in the installed <libintl.h> file
  91. dnl must be resolved because we cannot expect the users of this
  92. dnl to define HAVE_LOCALE_H.
  93. if test $ac_cv_header_locale_h = yes; then
  94.   INCLUDE_LOCALE_H="#include <locale.h>"
  95. else
  96.   INCLUDE_LOCALE_H="\
  97. /* The system does not provide the header <locale.h>.  Take care yourself.  */"
  98. fi
  99. AC_SUBST(INCLUDE_LOCALE_H)
  100.  
  101. dnl The gettextize script test for the version of the aclocal.m4 file in
  102. dnl user's project.  This must correspond to the number the aclocal.m4
  103. dnl here has.  Extract it.
  104. changequote(,)dnl
  105. ACLOCAL_VERSION=`sed -e 's/.*Last updated for gettext-\([0-9][0-9]*\.[0-9][0-9]*\(\.[0-9][0-9]*\)\).*/\1/p' -e d $srcdir/aclocal.m4`
  106. changequote([, ])dnl
  107. AC_SUBST(ACLOCAL_VERSION)
  108.  
  109.  
  110. dnl Generate the version information file in the intl/ directory.
  111. test -d intl || mkdir intl
  112. echo "GNU gettext library from $PACKAGE-$VERSION" > intl/VERSION
  113.  
  114. AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
  115.  
  116. AC_OUTPUT([Makefile lib/Makefile intl/Makefile src/Makefile \
  117.            po/Makefile.in doc/Makefile checks/Makefile \
  118.        misc/Makefile misc/gettextize intl/intlh.inst],
  119.       [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile
  120.        echo timestamp > stamp-h ])
  121.