home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gnat-2.06-src.tgz / tar.out / fsf / gnat / ada / a-timoau.adb < prev    next >
Text File  |  1996-09-28  |  9KB  |  296 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --              A D A . T E X T _ I O . M O D U L A R  _ A U X              --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.7 $                              --
  10. --                                                                          --
  11. --        Copyright (c) 1992,1993,1994,1995 NYU, All Rights Reserved        --
  12. --                                                                          --
  13. -- The GNAT library is free software; you can redistribute it and/or modify --
  14. -- it under terms of the GNU Library General Public License as published by --
  15. -- the Free Software  Foundation; either version 2, or (at your option) any --
  16. -- later version.  The GNAT library is distributed in the hope that it will --
  17. -- be useful, but WITHOUT ANY WARRANTY;  without even  the implied warranty --
  18. -- of MERCHANTABILITY  or  FITNESS FOR  A PARTICULAR PURPOSE.  See the  GNU --
  19. -- Library  General  Public  License for  more  details.  You  should  have --
  20. -- received  a copy of the GNU  Library  General Public License  along with --
  21. -- the GNAT library;  see the file  COPYING.LIB.  If not, write to the Free --
  22. -- Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.        --
  23. --                                                                          --
  24. ------------------------------------------------------------------------------
  25.  
  26. with Ada.Text_IO.Generic_Aux; use Ada.Text_IO.Generic_Aux;
  27.  
  28. with System.Img_BIU;   use System.Img_BIU;
  29. with System.Img_Uns;   use System.Img_Uns;
  30. with System.Img_LLB;   use System.Img_LLB;
  31. with System.Img_LLU;   use System.Img_LLU;
  32. with System.Img_LLW;   use System.Img_LLW;
  33. with System.Img_WIU;   use System.Img_WIU;
  34. with System.Val_Uns;   use System.Val_Uns;
  35. with System.Val_LLU;   use System.Val_LLU;
  36.  
  37. package body Ada.Text_IO.Modular_Aux is
  38.  
  39.    -----------------------
  40.    -- Local Subprograms --
  41.    -----------------------
  42.  
  43.    procedure Load_Modular
  44.      (File : in File_Type;
  45.       Buf  : out String;
  46.       Ptr  : in out Natural);
  47.    --  This is an auxiliary routine that is used to load an possibly signed
  48.    --  modular literal value from the input file into Buf, starting at Ptr + 1.
  49.    --  Ptr is left set to the last character stored.
  50.  
  51.    -------------
  52.    -- Get_Uns --
  53.    -------------
  54.  
  55.    procedure Get_Uns
  56.      (File  : in File_Type;
  57.       Item  : out Unsigned;
  58.       Width : in Field)
  59.    is
  60.       Buf  : String (1 .. Field'Last);
  61.       Stop : Integer := 0;
  62.       Ptr  : aliased Integer := 1;
  63.  
  64.    begin
  65.       if Width /= 0 then
  66.          Load_Width (File, Width, Buf, Stop);
  67.          String_Skip (Buf, Ptr);
  68.       else
  69.          Load_Modular (File, Buf, Stop);
  70.       end if;
  71.  
  72.       Item := Scan_Unsigned (Buf, Ptr'Access, Stop);
  73.       Check_End_Of_Field (File, Buf, Stop, Ptr, Width);
  74.    end Get_Uns;
  75.  
  76.    -------------
  77.    -- Get_LLU --
  78.    -------------
  79.  
  80.    procedure Get_LLU
  81.      (File  : in File_Type;
  82.       Item  : out Long_Long_Unsigned;
  83.       Width : in Field)
  84.    is
  85.       Buf  : String (1 .. Field'Last);
  86.       Stop : Integer := 0;
  87.       Ptr  : aliased Integer := 1;
  88.  
  89.    begin
  90.       if Width /= 0 then
  91.          Load_Width (File, Width, Buf, Stop);
  92.          String_Skip (Buf, Ptr);
  93.       else
  94.          Load_Modular (File, Buf, Stop);
  95.       end if;
  96.  
  97.       Item := Scan_Long_Long_Unsigned (Buf, Ptr'Access, Stop);
  98.       Check_End_Of_Field (File, Buf, Stop, Ptr, Width);
  99.    end Get_LLU;
  100.  
  101.    --------------
  102.    -- Gets_Uns --
  103.    --------------
  104.  
  105.    procedure Gets_Uns
  106.      (From : in String;
  107.       Item : out Unsigned;
  108.       Last : out Positive)
  109.    is
  110.       Pos : aliased Integer;
  111.  
  112.    begin
  113.       String_Skip (From, Pos);
  114.       Item := Scan_Unsigned (From, Pos'Access, From'Last);
  115.       Last := Pos - 1;
  116.  
  117.    exception
  118.       when Constraint_Error =>
  119.          Last := Pos - 1;
  120.          raise Data_Error;
  121.    end Gets_Uns;
  122.  
  123.    --------------
  124.    -- Gets_LLU --
  125.    --------------
  126.  
  127.    procedure Gets_LLU
  128.      (From : in String;
  129.       Item : out Long_Long_Unsigned;
  130.       Last : out Positive)
  131.    is
  132.       Pos : aliased Integer;
  133.  
  134.    begin
  135.       String_Skip (From, Pos);
  136.       Item := Scan_Long_Long_Unsigned (From, Pos'Access, From'Last);
  137.       Last := Pos - 1;
  138.  
  139.    exception
  140.       when Constraint_Error =>
  141.          Last := Pos - 1;
  142.          raise Data_Error;
  143.    end Gets_LLU;
  144.  
  145.    ------------------
  146.    -- Load_Modular --
  147.    ------------------
  148.  
  149.    procedure Load_Modular
  150.      (File : in File_Type;
  151.       Buf  : out String;
  152.       Ptr  : in out Natural)
  153.    is
  154.       Hash_Loc : Natural;
  155.       Loaded   : Boolean;
  156.  
  157.    begin
  158.       Load_Skip (File);
  159.  
  160.       --  Note: it is a bit strange to allow a minus sign here, but it seems
  161.       --  consistent with the general behavior expected by the ACVC tests
  162.       --  which is to scan past junk and then signal data error, see ACVC
  163.       --  test CE3704F, case (6), which is for signed integer exponents,
  164.       --  which seems a similar case.
  165.  
  166.       Load (File, Buf, Ptr, '+', '-');
  167.       Load_Digits (File, Buf, Ptr, Loaded);
  168.  
  169.       if Loaded then
  170.          Load (File, Buf, Ptr, '#', ':', Loaded);
  171.  
  172.          if Loaded then
  173.             Hash_Loc := Ptr;
  174.             Load_Extended_Digits (File, Buf, Ptr);
  175.             Load (File, Buf, Ptr, Buf (Hash_Loc));
  176.          end if;
  177.  
  178.          Load (File, Buf, Ptr, 'E', 'e', Loaded);
  179.  
  180.          if Loaded then
  181.  
  182.             --  Note: it is strange to allow a minus sign, since the syntax
  183.             --  does not, but that is what ACVC test CE3704F, case (6) wants
  184.             --  for the signed case, and there seems no good reason to treat
  185.             --  exponents differently for the signed and unsigned cases.
  186.  
  187.             Load (File, Buf, Ptr, '+', '-');
  188.             Load_Digits (File, Buf, Ptr);
  189.          end if;
  190.       end if;
  191.    end Load_Modular;
  192.  
  193.    -------------
  194.    -- Put_Uns --
  195.    -------------
  196.  
  197.    procedure Put_Uns
  198.      (File  : in File_Type;
  199.       Item  : in Unsigned;
  200.       Width : in Field;
  201.       Base  : in Number_Base)
  202.    is
  203.       Buf : String (1 .. Field'Last);
  204.       Ptr : Natural := 0;
  205.  
  206.    begin
  207.       if Base = 10 and then Width = 0 then
  208.          Set_Image_Unsigned (Item, Buf, Ptr);
  209.       elsif Base = 10 then
  210.          Set_Image_Width_Unsigned (Item, Width, Buf, Ptr);
  211.       else
  212.          Set_Image_Based_Unsigned (Item, Base, Width, Buf, Ptr);
  213.       end if;
  214.  
  215.       Put_Item (File, Buf (1 .. Ptr));
  216.    end Put_Uns;
  217.  
  218.    -------------
  219.    -- Put_LLU --
  220.    -------------
  221.  
  222.    procedure Put_LLU
  223.      (File  : in File_Type;
  224.       Item  : in Long_Long_Unsigned;
  225.       Width : in Field;
  226.       Base  : in Number_Base)
  227.    is
  228.       Buf : String (1 .. Field'Last);
  229.       Ptr : Natural := 0;
  230.  
  231.    begin
  232.       if Base = 10 and then Width = 0 then
  233.          Set_Image_Long_Long_Unsigned (Item, Buf, Ptr);
  234.       elsif Base = 10 then
  235.          Set_Image_Width_Long_Long_Unsigned (Item, Width, Buf, Ptr);
  236.       else
  237.          Set_Image_Based_Long_Long_Unsigned (Item, Base, Width, Buf, Ptr);
  238.       end if;
  239.  
  240.       Put_Item (File, Buf (1 .. Ptr));
  241.    end Put_LLU;
  242.  
  243.    --------------
  244.    -- Puts_Uns --
  245.    --------------
  246.  
  247.    procedure Puts_Uns
  248.      (To   : out String;
  249.       Item : in Unsigned;
  250.       Base : in Number_Base)
  251.    is
  252.       Buf : String (1 .. Field'Last);
  253.       Ptr : Natural := 0;
  254.  
  255.    begin
  256.       if Base = 10 then
  257.          Set_Image_Width_Unsigned (Item, To'Length, Buf, Ptr);
  258.       else
  259.          Set_Image_Based_Unsigned (Item, Base, To'Length, Buf, Ptr);
  260.       end if;
  261.  
  262.       if Ptr > To'Length then
  263.          raise Layout_Error;
  264.       else
  265.          To (To'First .. To'First + Ptr - 1) := Buf (1 .. Ptr);
  266.       end if;
  267.    end Puts_Uns;
  268.  
  269.    --------------
  270.    -- Puts_LLU --
  271.    --------------
  272.  
  273.    procedure Puts_LLU
  274.      (To   : out String;
  275.       Item : in Long_Long_Unsigned;
  276.       Base : in Number_Base)
  277.    is
  278.       Buf : String (1 .. Field'Last);
  279.       Ptr : Natural := 0;
  280.  
  281.    begin
  282.       if Base = 10 then
  283.          Set_Image_Width_Long_Long_Unsigned (Item, To'Length, Buf, Ptr);
  284.       else
  285.          Set_Image_Based_Long_Long_Unsigned (Item, Base, To'Length, Buf, Ptr);
  286.       end if;
  287.  
  288.       if Ptr > To'Length then
  289.          raise Layout_Error;
  290.       else
  291.          To (To'First .. To'First + Ptr - 1) := Buf (1 .. Ptr);
  292.       end if;
  293.    end Puts_LLU;
  294.  
  295. end Ada.Text_IO.Modular_Aux;
  296.