home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gnat-2.06-src.tgz / tar.out / fsf / gnat / ada / binderr.adb < prev    next >
Text File  |  1996-09-28  |  6KB  |  203 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT COMPILER COMPONENTS                         --
  4. --                                                                          --
  5. --                              B I N D E R R                               --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.17 $                             --
  10. --                                                                          --
  11. --           Copyright (c) 1992,1993,1994 NYU, All Rights Reserved          --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. --
  22. --                                                                          --
  23. ------------------------------------------------------------------------------
  24.  
  25. with Butil;            use Butil;
  26. with Namet;            use Namet;
  27. with Opt;              use Opt;
  28. with Osint;            use Osint;
  29. with Output;           use Output;
  30.  
  31. package body Binderr is
  32.  
  33.    -----------------------
  34.    -- Local Subprograms --
  35.    -----------------------
  36.  
  37.    procedure Error_Msg_Output (Msg : String; Info : Boolean := False);
  38.    --  Output given message, with insertions, to current message output file.
  39.    --  The second argument is True for an info message, false for a normal
  40.    --  warning or error message.
  41.  
  42.    ---------------
  43.    -- Error_Msg --
  44.    ---------------
  45.  
  46.    procedure Error_Msg (Msg : String) is
  47.    begin
  48.       if Msg (Msg'First) = '?' then
  49.          if Warning_Mode = Suppress then
  50.             return;
  51.          end if;
  52.  
  53.          if Warning_Mode = Treat_As_Error then
  54.             Errors_Detected := Errors_Detected + 1;
  55.          else
  56.             Warnings_Detected := Warnings_Detected + 1;
  57.          end if;
  58.  
  59.       else
  60.          Errors_Detected := Errors_Detected + 1;
  61.       end if;
  62.  
  63.       if Brief_Output or else (not Verbose_Mode) then
  64.          Set_Standard_Error;
  65.          Error_Msg_Output (Msg);
  66.          Set_Standard_Output;
  67.       end if;
  68.  
  69.       if Verbose_Mode then
  70.          if Errors_Detected + Warnings_Detected = 0 then
  71.             Write_Eol;
  72.          end if;
  73.  
  74.          Error_Msg_Output (Msg);
  75.       end if;
  76.  
  77.       if Warnings_Detected + Errors_Detected > Maximum_Errors then
  78.          raise Unrecoverable_Error;
  79.       end if;
  80.  
  81.    end Error_Msg;
  82.  
  83.    --------------------
  84.    -- Error_Msg_Info --
  85.    --------------------
  86.  
  87.    procedure Error_Msg_Info (Msg : String) is
  88.    begin
  89.       if Brief_Output or else (not Verbose_Mode) then
  90.          Set_Standard_Error;
  91.          Error_Msg_Output (Msg, True);
  92.          Set_Standard_Output;
  93.       end if;
  94.  
  95.       if Verbose_Mode then
  96.          Error_Msg_Output (Msg, True);
  97.       end if;
  98.  
  99.    end Error_Msg_Info;
  100.  
  101.    ----------------------
  102.    -- Error_Msg_Output --
  103.    ----------------------
  104.  
  105.    procedure Error_Msg_Output (Msg : String; Info : Boolean := False) is
  106.       Use_Second_Name : Boolean := False;
  107.  
  108.    begin
  109.       if Warnings_Detected + Errors_Detected > Maximum_Errors then
  110.          Write_Str ("error: maximum errors exceeded");
  111.          Write_Eol;
  112.          return;
  113.       end if;
  114.  
  115.       if Msg (Msg'First) = '?' then
  116.          Write_Str ("warning: ");
  117.       elsif Info then
  118.          Write_Str ("info:  ");
  119.       else
  120.          Write_Str ("error: ");
  121.       end if;
  122.  
  123.       for I in Msg'Range loop
  124.          if Msg (I) = '%' then
  125.  
  126.             if Use_Second_Name then
  127.                Get_Decoded_Name_String (Error_Msg_Name_2);
  128.             else
  129.                Use_Second_Name := True;
  130.                Get_Decoded_Name_String (Error_Msg_Name_1);
  131.             end if;
  132.  
  133.             Write_Char ('"');
  134.             Write_Str (Name_Buffer (1 .. Name_Len));
  135.             Write_Char ('"');
  136.  
  137.          elsif Msg (I) = '&' then
  138.             Write_Char ('"');
  139.  
  140.             if Use_Second_Name then
  141.                Write_Unit_Name (Error_Msg_Name_2);
  142.             else
  143.                Use_Second_Name := True;
  144.                Write_Unit_Name (Error_Msg_Name_1);
  145.             end if;
  146.  
  147.             Write_Char ('"');
  148.  
  149.          elsif Msg (I) /= '?' then
  150.             Write_Char (Msg (I));
  151.          end if;
  152.       end loop;
  153.  
  154.       Write_Eol;
  155.    end Error_Msg_Output;
  156.  
  157.    ----------------------
  158.    -- Finalize_Binderr --
  159.    ----------------------
  160.  
  161.    procedure Finalize_Binderr is
  162.    begin
  163.       --  Message giving number of errors detected (verbose mode only)
  164.  
  165.       if Verbose_Mode then
  166.          Write_Eol;
  167.  
  168.          if Errors_Detected = 0 then
  169.             Write_Str ("No errors");
  170.  
  171.          elsif Errors_Detected = 1 then
  172.             Write_Str ("1 error");
  173.  
  174.          else
  175.             Write_Int (Errors_Detected);
  176.             Write_Str (" errors");
  177.          end if;
  178.  
  179.          if Warnings_Detected = 1 then
  180.             Write_Str (", 1 warning");
  181.  
  182.          elsif Warnings_Detected > 1 then
  183.             Write_Str (", ");
  184.             Write_Int (Warnings_Detected);
  185.             Write_Str (" warnings");
  186.          end if;
  187.  
  188.          Write_Eol;
  189.       end if;
  190.    end Finalize_Binderr;
  191.  
  192.    ------------------------
  193.    -- Initialize_Binderr --
  194.    ------------------------
  195.  
  196.    procedure Initialize_Binderr is
  197.    begin
  198.       Errors_Detected := 0;
  199.       Warnings_Detected := 0;
  200.    end Initialize_Binderr;
  201.  
  202. end Binderr;
  203.