home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gnat-2.06-src.tgz / tar.out / fsf / gnat / ada / gnatsort.adb < prev    next >
Text File  |  1996-09-28  |  5KB  |  125 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --                             G N A T S O R T                              --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.2 $                              --
  10. --                                                                          --
  11. --           Copyright (c) 1992,1993,1994 NYU, All Rights Reserved          --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. --
  22. --                                                                          --
  23. ------------------------------------------------------------------------------
  24.  
  25. with Output; use Output;
  26. with Types;  use Types;
  27.  
  28. package body Gnatsort is
  29.  
  30.    ----------
  31.    -- Sort --
  32.    ----------
  33.  
  34.    --  We are using the classical heapsort algorithm (i.e. Floyd's Treesort3)
  35.    --  as described by Knuth (ref???) with the modification that is mentioned
  36.    --  in excercise ???. For more details on this algorithm, see Robert B. K.
  37.    --  Dewar PhD thesis "The use of Computers in the X-ray Phase Problem".
  38.    --  University of Chicago, 1968.
  39.  
  40.    procedure Sort (N : Positive; Move : Move_Procedure; Lt : Lt_Function) is
  41.  
  42.       Max : Positive := N;
  43.       --  Current Max index in tree being sifted
  44.  
  45.       procedure Sift (S : Positive);
  46.       --  This procedure sifts up node S, i.e. converts the subtree rooted
  47.       --  at node S into a heap, given the precondition that any sons of
  48.       --  S are already heaps. On entry, the contents of node S is found
  49.       --  in the temporary (index 0), the actual contents of node S on
  50.       --  entry are irrelevant. This is just a minor optimization to avoid
  51.       --  what would otherwise be two junk moves in phase two of the sort.
  52.  
  53.       procedure Sift (S : Positive) is
  54.          C      : Positive := S;
  55.          Son    : Positive;
  56.          Father : Positive;
  57.  
  58.       begin
  59.          --  This is where the optimization is done, normally we would do a
  60.          --  comparison at each stage between the current node and the larger
  61.          --  of the two sons, and continue the sift only if the current node
  62.          --  was less than this maximum. In this modified optimized version,
  63.          --  we assume that the current node will be less than the larger
  64.          --  son, and unconditionally sift up. Then when we get to the bottom
  65.          --  of the tree, we check parents to make sure that we did not make
  66.          --  a mistake. This roughly cuts the number of comparisions in half,
  67.          --  since it is almost always the case that our assumption is correct.
  68.  
  69.          --  Loop to pull up larger sons
  70.  
  71.          loop
  72.             Son := 2 * C;
  73.             exit when Son > Max;
  74.  
  75.             if Son < Max and then Lt (Son, Son + 1) then
  76.                Son := Son + 1;
  77.             end if;
  78.  
  79.             Move (Son, C);
  80.             C := Son;
  81.          end loop;
  82.  
  83.          --  Loop to check fathers
  84.  
  85.          while C /= S loop
  86.             Father := C / 2;
  87.  
  88.             if Lt (Father, 0) then
  89.                Move (Father, C);
  90.                C := Father;
  91.             else
  92.                exit;
  93.             end if;
  94.          end loop;
  95.  
  96.          --  Last step is to pop the sifted node into place
  97.  
  98.          Move (0, C);
  99.       end Sift;
  100.  
  101.    --  Start of processing for Sort
  102.  
  103.    begin
  104.       --  Phase one of heapsort is to build the heap. This is done by
  105.       --  sifting nodes N/2 .. 1 in sequence.
  106.  
  107.       for J in reverse 1 .. N / 2 loop
  108.          Move (J, 0);
  109.          Sift (J);
  110.       end loop;
  111.  
  112.       --  In phase 2, we sift node 1 repeatedly, so that it is the largest
  113.       --  node in the remaining heap, and then exchange it with the last node.
  114.  
  115.       while Max > 1 loop
  116.          Sift (1);
  117.          Move (Max, 0);
  118.          Move (1, Max);
  119.          Max := Max - 1;
  120.       end loop;
  121.  
  122.    end Sort;
  123.  
  124. end Gnatsort;
  125.