home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gnat-2.06-src.tgz / tar.out / fsf / gnat / ada / s-fileio.ads < prev    next >
Text File  |  1996-09-28  |  11KB  |  241 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUN-TIME COMPONENTS                         --
  4. --                                                                          --
  5. --                       S Y S T E M . F I L E _ I O                        --
  6. --                                                                          --
  7. --                                 S p e c                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.11 $                             --
  10. --                                                                          --
  11. --        Copyright (c) 1992,1993,1994,1995 NYU, All Rights Reserved        --
  12. --                                                                          --
  13. -- The GNAT library is free software; you can redistribute it and/or modify --
  14. -- it under terms of the GNU Library General Public License as published by --
  15. -- the Free Software  Foundation; either version 2, or (at your option) any --
  16. -- later version.  The GNAT library is distributed in the hope that it will --
  17. -- be useful, but WITHOUT ANY WARRANTY;  without even  the implied warranty --
  18. -- of MERCHANTABILITY  or  FITNESS FOR  A PARTICULAR PURPOSE.  See the  GNU --
  19. -- Library  General  Public  License for  more  details.  You  should  have --
  20. -- received  a copy of the GNU  Library  General Public License  along with --
  21. -- the GNAT library;  see the file  COPYING.LIB.  If not, write to the Free --
  22. -- Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.        --
  23. --                                                                          --
  24. ------------------------------------------------------------------------------
  25.  
  26. --  This package provides support for the routines described in (RM A.8.2)
  27. --  which are common to Text_IO, Direct_IO, Sequential_IO and Stream_IO.
  28.  
  29. with Ada.Streams;
  30. with Interfaces.C_Streams;
  31.  
  32. with System.File_Control_Block;
  33.  
  34. package System.File_IO is
  35.  
  36.    use System.File_Control_Block;
  37.  
  38.    package ICS renames Interfaces.C_Streams;
  39.  
  40.    ---------------------
  41.    -- File Management --
  42.    ---------------------
  43.  
  44.    procedure Open
  45.      (File_Ptr  : in out AFCB_Ptr;
  46.       Dummy_FCB : in out AFCB'Class;
  47.       Mode      : File_Mode;
  48.       Name      : String;
  49.       Form      : String;
  50.       Amethod   : Character;
  51.       Creat     : Boolean;
  52.       Text      : Boolean;
  53.       C_Stream  : ICS.FILEs := ICS.NULL_Stream);
  54.    --  This routine is used for both Open and Create calls:
  55.    --
  56.    --    File_Ptr is the file type, which must be null on entry
  57.    --    (i.e. the file must be closed before the call).
  58.    --
  59.    --    Dummy_FCB is a default initialized file control block of appropriate
  60.    --    type. Note that the tag of this record indicates the type and length
  61.    --    of the control block. This control block is used only for the purpose
  62.    --    of providing the controlling argument for calling the write version
  63.    --    of Allocate_AFCB. It has no other purpose, and its fields are never
  64.    --    read or written.
  65.    --
  66.    --    Mode is the required mode
  67.    --
  68.    --    Name is the file name, with a null string indicating that a temporary
  69.    --    file is to be created (only permitted in create mode, not open mode)
  70.    --
  71.    --    Creat is True for a create call, and false for an open call
  72.    --
  73.    --    Text is set True to open the file in text mode (w+t or r+t) instead
  74.    --    of the usual binary mode open (w+b or r+b).
  75.    --
  76.    --    Form is the form string given in the open or create call, this is
  77.    --    stored in the AFCB, but otherwise is not used by this or any other
  78.    --    routine in this unit (except Form which retrieves the original value)
  79.    --
  80.    --    Amethod indicates the access method
  81.    --
  82.    --      D = Direct_IO
  83.    --      Q = Sequential_IO
  84.    --      S = Stream_IO
  85.    --      T = Text_IO
  86.    --      W = Wide_Text_IO
  87.    --
  88.    --    C_Stream is left at its default value for the normal case of an
  89.    --    Open or Create call as defined in the RM. The only time this is
  90.    --    non-null is for the Open call from Ada.xxx_IO.C_Streams.Open.
  91.    --
  92.    --  On return, if the open/create succeeds, then the fields of File are
  93.    --  filled in, and this value is copied to the heap. File_Ptr points to
  94.    --  this allocated file control block. If the open/create fails, then the
  95.    --  fields of File are undefined, and File_Ptr is unchanged.
  96.  
  97.    procedure Close (File : in out AFCB_Ptr);
  98.    --  The file is closed, all storage associated with it is released, and
  99.    --  File is set to null. Note that this routine calls AFCB_Close to perform
  100.    --  any specialized close actions, then closes the file at the system level,
  101.    --  then frees the mode and form strings, and finally calls AFCB_Free to
  102.    --  free the file control block itself, setting File to null.
  103.  
  104.    procedure Delete (File : in out AFCB_Ptr);
  105.    --  The indicated file is unlinked
  106.  
  107.    procedure Reset (File : in out AFCB_Ptr; Mode : in File_Mode);
  108.    --  The file is reset, and the mode changed as indicated.
  109.  
  110.    procedure Reset (File : in out AFCB_Ptr);
  111.    --  The files is reset, and the mode is unchanged
  112.  
  113.    function Mode (File : in AFCB_Ptr) return File_Mode;
  114.    --  Returns the mode as supplied by create, open or reset
  115.  
  116.    function Name (File : in AFCB_Ptr) return String;
  117.    --  Returns the file name as supplied by Open or Create. Raises Use_Error
  118.    --  if used with temporary files or standard files.
  119.  
  120.    function Form (File : in AFCB_Ptr) return String;
  121.    --  Returns the form as supplied by create, open or reset
  122.    --  The string is normalized to all lower case letters.
  123.  
  124.    function Is_Open (File : in AFCB_Ptr) return Boolean;
  125.    --  Determines if file is open or not
  126.  
  127.    ----------------------
  128.    -- Utility Routines --
  129.    ----------------------
  130.  
  131.    --  Some internal routines not defined in A.8.2. These are routines which
  132.    --  provide required common functionality shared by separate packages.
  133.  
  134.    procedure Chain_File (File : AFCB_Ptr);
  135.    --  Used to chain the given file into the list of open files. Normally this
  136.    --  is done implicitly by Open. Chain_File is used for the spcial cases of
  137.    --  the system files defined by Text_IO (stdin, stdout, stderr) which are
  138.    --  not opened in the normal manner. Note that the caller is responsible
  139.    --  for task lock out to protect the global data structures if this is
  140.    --  necessary (it is needed for the calls from within this unit itself,
  141.    --  but not required for the calls from Text_IO and Wide_Text_IO that
  142.    --  are made during elaboration of the environment task).
  143.  
  144.    procedure Check_File_Open (File : AFCB_Ptr);
  145.    --  If the current file is not open, then Status_Error is raised.
  146.    --  Otherwise control returns normally (with File pointing to the
  147.    --  control block for the open file.
  148.  
  149.    procedure Check_Read_Status (File : AFCB_Ptr);
  150.    --  If the current file is not open, then Status_Error is raised. If
  151.    --  the file is open, then the mode is checked to ensure that reading
  152.    --  is permitted, and if not Mode_Error is raised, otherwise control
  153.    --  returns normally.
  154.  
  155.    procedure Check_Write_Status (File : AFCB_Ptr);
  156.    --  If the current file is not open, then Status_Error is raised. If
  157.    --  the file is open, then the mode is checked to ensure that writing
  158.    --  is permitted, and if not Mode_Error is raised, otherwise control
  159.    --  returns normally.
  160.  
  161.    function End_Of_File (File : AFCB_Ptr) return Boolean;
  162.    --  File must be opened in read mode. True is returned if the stream is
  163.    --  currently positioned at the end of file, otherwise False is returned.
  164.    --  The position of the stream is not affected.
  165.  
  166.    procedure Flush (File : AFCB_Ptr);
  167.    --  Flushes the stream associated with the given file. The file must be
  168.    --  open and in write mode (if not, an appropriate exception is raised)
  169.  
  170.    function Form_Boolean
  171.      (Form    : String;
  172.       Keyword : String;
  173.       Default : Boolean)
  174.       return    Boolean;
  175.    --  Searches form string for an entry of the form Keyword=xx where xx is
  176.    --  either Yes/No or y/n. Returns True if Yes or Y is found, False if No
  177.    --  or N is found. If the keyword parameter is not found, returns the
  178.    --  value given as Default. May raise Use_Error if a form string syntax
  179.    --  error is detected. Keyword and Form must be in lower case.
  180.  
  181.    function Form_Integer
  182.      (Form    : String;
  183.       Keyword : String;
  184.       Default : Integer)
  185.       return    Integer;
  186.    --  Searches form string for an entry of the form Keyword=xx where xx is
  187.    --  an unsigned decimal integer in the range 0 to 999_999. Returns this
  188.    --  integer value if it is found. If the keyword parameter is not found,
  189.    --  returns the value given as Default. Raise Use_Error if a form string
  190.    --  syntax error is detected. Keyword and Form must be in lower case.
  191.  
  192.    procedure Form_Parameter
  193.      (Form    : String;
  194.       Keyword : String;
  195.       Start   : out Natural;
  196.       Stop    : out Natural);
  197.    --  Searches form string for an entry of the form Keyword=xx and if found
  198.    --  Sets Start and Stop to the first and last characters of xx. Keyword
  199.    --  and Form must be in lower case. If no entry matches, then Start is
  200.    --  set to zero. Use_Error can be raised if a malformed string is found,
  201.    --  but there is no guarantee of full syntax checking.
  202.  
  203.    procedure Read_Buf
  204.      (File : AFCB_Ptr;
  205.       Buf  : Address;
  206.       Siz  : Interfaces.C_Streams.size_t);
  207.    --  Reads size_t bytes from File.Stream into Buf. The caller has checked
  208.    --  that the file is open in read mode. Raises an expcetion if Siz bytes
  209.    --  cannot be read (End_Error if no data was read, Data_Error if a partial
  210.    --  buffer was read, Device_Error if an error occurs).
  211.  
  212.    procedure Read_Buf
  213.      (File  : AFCB_Ptr;
  214.       Buf   : Address;
  215.       Siz   : in Interfaces.C_Streams.size_t;
  216.       Count : out Interfaces.C_Streams.size_t);
  217.    --  Reads size_t bytes from File.Stream into Buf. The caller has checked
  218.    --  that the file is open in read mode. Device Error is raised if an error
  219.    --  occurs. Count is the actual number of bytes read, which may be less
  220.    --  than Siz if the end of file is encountered.
  221.  
  222.    procedure Append_Set (File : AFCB_Ptr);
  223.    --  If the mode of the file is Append_File, then the file is positioned
  224.    --  at the end of file using fseek, otherwise this call has no effect.
  225.  
  226.    procedure Write_Buf
  227.      (File : AFCB_Ptr;
  228.       Buf  : Address;
  229.       Siz  : Interfaces.C_Streams.size_t);
  230.    --  Writes size_t bytes to File.Stream from Buf. The caller has checked
  231.    --  that the file is open in write mode. Raises Device_Error if the
  232.    --  complete buffer cannot be written.
  233.  
  234. private
  235.    pragma Inline (Check_Read_Status);
  236.    pragma Inline (Check_Write_Status);
  237.    pragma Inline (Form);
  238.    pragma Inline (Mode);
  239.  
  240. end System.File_IO;
  241.