home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / id-utils-3.2-src.tgz / tar.out / fsf / id-utils / configure.in < prev    next >
Text File  |  1996-09-28  |  6KB  |  150 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2.  
  3. dnl Note: the banner comments below are intentionally done in shell syntax.
  4. dnl These help me identify sections of the configure script produced
  5. dnl by autoconf.  Some comments might appear inane and obvious, but again
  6. dnl they are there to delimit sections in the output configure script.
  7.  
  8. ##############################################################################
  9. ################ Setup #######################################################
  10. ##############################################################################
  11.  
  12. AC_INIT(src/mkid.c)
  13. AC_CONFIG_HEADER(config.h)
  14. AC_PREREQ(2.10)
  15. AC_ARG_PROGRAM
  16.  
  17. ##############################################################################
  18. ################ Identify Package ############################################
  19. ##############################################################################
  20.  
  21. PACKAGE=id-utils
  22. VERSION=3.2
  23. PACKAGE_VERSION="GNU $PACKAGE $VERSION"
  24. AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  25. AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  26. AC_DEFINE_UNQUOTED(PACKAGE_VERSION, "$PACKAGE_VERSION")
  27. AC_SUBST(PACKAGE)
  28. AC_SUBST(VERSION)
  29. AC_SUBST(PACKAGE_VERSION)
  30.  
  31. ##############################################################################
  32. ################ Maintainer Stuff ############################################
  33. ##############################################################################
  34.  
  35. AM_MAINTAINER_MODE
  36.  
  37. ALL_LINGUAS="de fr"
  38.  
  39. changequote(,)dnl
  40. case $VERSION in
  41. *[a-z]) README_ALPHA=README-alpha;;
  42. *)      README_ALPHA=;;
  43. esac
  44. changequote([, ])dnl
  45. AC_SUBST(README_ALPHA)
  46.  
  47. ##############################################################################
  48. ################ Check for tools #############################################
  49. ##############################################################################
  50.  
  51. AC_PROG_CC
  52. AC_PROG_LN_S
  53. AM_PROG_INSTALL
  54. AC_PROG_MAKE_SET
  55. AC_PROG_CPP
  56. AC_PROG_GCC_TRADITIONAL
  57. AC_PROG_RANLIB
  58. AC_AIX
  59. AC_MINIX
  60. AC_ISC_POSIX
  61.  
  62. ##############################################################################
  63. ################ Check for libraries #########################################
  64. ##############################################################################
  65.  
  66. dnl no library checks
  67.  
  68. ##############################################################################
  69. ################ Check for header files ######################################
  70. ##############################################################################
  71.  
  72. AC_HEADER_DIRENT
  73. AC_HEADER_STDC
  74. AC_HEADER_STAT
  75. AC_HEADER_SYS_WAIT
  76. AC_CHECK_HEADERS(sys/types.h sys/param.h sys/stat.h sys/ioctl.h)
  77. AC_CHECK_HEADERS(limits.h stddef.h stdlib.h unistd.h string.h fcntl.h)
  78. AC_CHECK_HEADERS(malloc.h termios.h termio.h sgtty.h regex.h memory.h)
  79.  
  80. ##############################################################################
  81. ################ Check for typedefs, structs, and compiler params ############
  82. ##############################################################################
  83.  
  84. AC_C_CONST
  85. AM_C_PROTOTYPES
  86. AC_TYPE_SIGNAL
  87. AC_TYPE_OFF_T
  88. AC_TYPE_SIZE_T
  89. md_TYPE_PTRDIFF_T
  90.  
  91. ##############################################################################
  92. ################ Set default compilation flags ###############################
  93. ##############################################################################
  94.  
  95. : ${CFLAGS="-O -g"}
  96. : ${LDFLAGS=-g}
  97. AC_SUBST(CFLAGS)
  98. AC_SUBST(LDFLAGS)
  99.  
  100. ##############################################################################
  101. ################ Check for library functions & system calls ##################
  102. ##############################################################################
  103.  
  104. AC_FUNC_ALLOCA
  105. ud_WITH_REGEX
  106. AC_FUNC_VPRINTF
  107. AC_CHECK_FUNCS(getwd getcwd link strerror isascii bcopy bzero memcpy sbrk)
  108. AC_REPLACE_FUNCS(strdup strndup strspn strcspn strpbrk strstr strtok)
  109. AC_REPLACE_FUNCS(basename dirname fnmatch error memcpy memset)
  110. AC_REPLACE_GNU_GETOPT
  111. AC_REPLACE_OBSTACK
  112.  
  113. ##############################################################################
  114. ################ Internationalization ########################################
  115. ##############################################################################
  116.  
  117. ud_GNU_GETTEXT
  118. AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
  119.  
  120. ##############################################################################
  121. ################ Find a home for language map ################################
  122. ##############################################################################
  123.  
  124. if test "x$prefix" != xNONE; then
  125.     datadir=$prefix/share
  126. else
  127.     datadir=$ac_default_prefix/share
  128. fi
  129. LANGUAGE_MAP_FILE=$datadir/id-lang.map
  130. AC_DEFINE_UNQUOTED(LANGUAGE_MAP_FILE, "$LANGUAGE_MAP_FILE")
  131. AC_SUBST(LANGUAGE_MAP_FILE)
  132.  
  133. ##############################################################################
  134. ################ Find a home for Emacs Lisp code #############################
  135. ##############################################################################
  136.  
  137. ud_PATH_LISPDIR
  138.  
  139. ##############################################################################
  140. ################ Generate the configure script ###############################
  141. ##############################################################################
  142.  
  143. AC_OUTPUT([Makefile doc/Makefile lib/Makefile libidu/Makefile src/Makefile lisp/Makefile intl/Makefile po/Makefile.in testsuite/Makefile],
  144.     [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile; \
  145.      test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
  146.  
  147. ##############################################################################
  148. ################ Done ########################################################
  149. ##############################################################################
  150.