home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / octave-1.1.1p1-src.tgz / tar.out / fsf / octave / libcruft / blas / dgemm.f < prev    next >
Text File  |  1996-09-28  |  11KB  |  348 lines
  1. ************************************************************************
  2. *
  3. *     File of the DOUBLE PRECISION Level-3 BLAS.
  4. *     ==========================================
  5. *
  6. *     SUBROUTINE DGEMM ( TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB,
  7. *    $                   BETA, C, LDC )
  8. *
  9. *     SUBROUTINE DSYMM ( SIDE,   UPLO,   M, N,    ALPHA, A, LDA, B, LDB,
  10. *    $                   BETA, C, LDC )
  11. *
  12. *     SUBROUTINE DSYRK ( UPLO,   TRANS,     N, K, ALPHA, A, LDA,
  13. *    $                   BETA, C, LDC )
  14. *
  15. *     SUBROUTINE DSYR2K( UPLO,   TRANS,     N, K, ALPHA, A, LDA, B, LDB,
  16. *    $                   BETA, C, LDC )
  17. *
  18. *     SUBROUTINE DTRMM ( SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA,
  19. *    $                   B, LDB )
  20. *
  21. *     SUBROUTINE DTRSM ( SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA,
  22. *    $                   B, LDB )
  23. *
  24. *     See:
  25. *
  26. *        Dongarra J. J.,   Du Croz J. J.,   Duff I.  and   Hammarling S.
  27. *        A set of  Level 3  Basic Linear Algebra Subprograms.  Technical
  28. *        Memorandum No.88 (Revision 1), Mathematics and Computer Science
  29. *        Division,  Argonne National Laboratory, 9700 South Cass Avenue,
  30. *        Argonne, Illinois 60439.
  31. *
  32. *
  33. ************************************************************************
  34. *
  35.       SUBROUTINE DGEMM ( TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB,
  36.      $                   BETA, C, LDC )
  37. *     .. Scalar Arguments ..
  38.       CHARACTER*1        TRANSA, TRANSB
  39.       INTEGER            M, N, K, LDA, LDB, LDC
  40.       DOUBLE PRECISION   ALPHA, BETA
  41. *     .. Array Arguments ..
  42.       DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), C( LDC, * )
  43. *     ..
  44. *
  45. *  Purpose
  46. *  =======
  47. *
  48. *  DGEMM  performs one of the matrix-matrix operations
  49. *
  50. *     C := alpha*op( A )*op( B ) + beta*C,
  51. *
  52. *  where  op( X ) is one of
  53. *
  54. *     op( X ) = X   or   op( X ) = X',
  55. *
  56. *  alpha and beta are scalars, and A, B and C are matrices, with op( A )
  57. *  an m by k matrix,  op( B )  a  k by n matrix and  C an m by n matrix.
  58. *
  59. *  Parameters
  60. *  ==========
  61. *
  62. *  TRANSA - CHARACTER*1.
  63. *           On entry, TRANSA specifies the form of op( A ) to be used in
  64. *           the matrix multiplication as follows:
  65. *
  66. *              TRANSA = 'N' or 'n',  op( A ) = A.
  67. *
  68. *              TRANSA = 'T' or 't',  op( A ) = A'.
  69. *
  70. *              TRANSA = 'C' or 'c',  op( A ) = A'.
  71. *
  72. *           Unchanged on exit.
  73. *
  74. *  TRANSB - CHARACTER*1.
  75. *           On entry, TRANSB specifies the form of op( B ) to be used in
  76. *           the matrix multiplication as follows:
  77. *
  78. *              TRANSB = 'N' or 'n',  op( B ) = B.
  79. *
  80. *              TRANSB = 'T' or 't',  op( B ) = B'.
  81. *
  82. *              TRANSB = 'C' or 'c',  op( B ) = B'.
  83. *
  84. *           Unchanged on exit.
  85. *
  86. *  M      - INTEGER.
  87. *           On entry,  M  specifies  the number  of rows  of the  matrix
  88. *           op( A )  and of the  matrix  C.  M  must  be at least  zero.
  89. *           Unchanged on exit.
  90. *
  91. *  N      - INTEGER.
  92. *           On entry,  N  specifies the number  of columns of the matrix
  93. *           op( B ) and the number of columns of the matrix C. N must be
  94. *           at least zero.
  95. *           Unchanged on exit.
  96. *
  97. *  K      - INTEGER.
  98. *           On entry,  K  specifies  the number of columns of the matrix
  99. *           op( A ) and the number of rows of the matrix op( B ). K must
  100. *           be at least  zero.
  101. *           Unchanged on exit.
  102. *
  103. *  ALPHA  - DOUBLE PRECISION.
  104. *           On entry, ALPHA specifies the scalar alpha.
  105. *           Unchanged on exit.
  106. *
  107. *  A      - DOUBLE PRECISION array of DIMENSION ( LDA, ka ), where ka is
  108. *           k  when  TRANSA = 'N' or 'n',  and is  m  otherwise.
  109. *           Before entry with  TRANSA = 'N' or 'n',  the leading  m by k
  110. *           part of the array  A  must contain the matrix  A,  otherwise
  111. *           the leading  k by m  part of the array  A  must contain  the
  112. *           matrix A.
  113. *           Unchanged on exit.
  114. *
  115. *  LDA    - INTEGER.
  116. *           On entry, LDA specifies the first dimension of A as declared
  117. *           in the calling (sub) program. When  TRANSA = 'N' or 'n' then
  118. *           LDA must be at least  max( 1, m ), otherwise  LDA must be at
  119. *           least  max( 1, k ).
  120. *           Unchanged on exit.
  121. *
  122. *  B      - DOUBLE PRECISION array of DIMENSION ( LDB, kb ), where kb is
  123. *           n  when  TRANSB = 'N' or 'n',  and is  k  otherwise.
  124. *           Before entry with  TRANSB = 'N' or 'n',  the leading  k by n
  125. *           part of the array  B  must contain the matrix  B,  otherwise
  126. *           the leading  n by k  part of the array  B  must contain  the
  127. *           matrix B.
  128. *           Unchanged on exit.
  129. *
  130. *  LDB    - INTEGER.
  131. *           On entry, LDB specifies the first dimension of B as declared
  132. *           in the calling (sub) program. When  TRANSB = 'N' or 'n' then
  133. *           LDB must be at least  max( 1, k ), otherwise  LDB must be at
  134. *           least  max( 1, n ).
  135. *           Unchanged on exit.
  136. *
  137. *  BETA   - DOUBLE PRECISION.
  138. *           On entry,  BETA  specifies the scalar  beta.  When  BETA  is
  139. *           supplied as zero then C need not be set on input.
  140. *           Unchanged on exit.
  141. *
  142. *  C      - DOUBLE PRECISION array of DIMENSION ( LDC, n ).
  143. *           Before entry, the leading  m by n  part of the array  C must
  144. *           contain the matrix  C,  except when  beta  is zero, in which
  145. *           case C need not be set on entry.
  146. *           On exit, the array  C  is overwritten by the  m by n  matrix
  147. *           ( alpha*op( A )*op( B ) + beta*C ).
  148. *
  149. *  LDC    - INTEGER.
  150. *           On entry, LDC specifies the first dimension of C as declared
  151. *           in  the  calling  (sub)  program.   LDC  must  be  at  least
  152. *           max( 1, m ).
  153. *           Unchanged on exit.
  154. *
  155. *
  156. *  Level 3 Blas routine.
  157. *
  158. *  -- Written on 8-February-1989.
  159. *     Jack Dongarra, Argonne National Laboratory.
  160. *     Iain Duff, AERE Harwell.
  161. *     Jeremy Du Croz, Numerical Algorithms Group Ltd.
  162. *     Sven Hammarling, Numerical Algorithms Group Ltd.
  163. *
  164. *
  165. *     .. External Functions ..
  166.       LOGICAL            LSAME
  167.       EXTERNAL           LSAME
  168. *     .. External Subroutines ..
  169.       EXTERNAL           XERBLA
  170. *     .. Intrinsic Functions ..
  171.       INTRINSIC          MAX
  172. *     .. Local Scalars ..
  173.       LOGICAL            NOTA, NOTB
  174.       INTEGER            I, INFO, J, L, NCOLA, NROWA, NROWB
  175.       DOUBLE PRECISION   TEMP
  176. *     .. Parameters ..
  177.       DOUBLE PRECISION   ONE         , ZERO
  178.       PARAMETER        ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  179. *     ..
  180. *     .. Executable Statements ..
  181. *
  182. *     Set  NOTA  and  NOTB  as  true if  A  and  B  respectively are not
  183. *     transposed and set  NROWA, NCOLA and  NROWB  as the number of rows
  184. *     and  columns of  A  and the  number of  rows  of  B  respectively.
  185. *
  186.       NOTA  = LSAME( TRANSA, 'N' )
  187.       NOTB  = LSAME( TRANSB, 'N' )
  188.       IF( NOTA )THEN
  189.          NROWA = M
  190.          NCOLA = K
  191.       ELSE
  192.          NROWA = K
  193.          NCOLA = M
  194.       END IF
  195.       IF( NOTB )THEN
  196.          NROWB = K
  197.       ELSE
  198.          NROWB = N
  199.       END IF
  200. *
  201. *     Test the input parameters.
  202. *
  203.       INFO = 0
  204.       IF(      ( .NOT.NOTA                 ).AND.
  205.      $         ( .NOT.LSAME( TRANSA, 'C' ) ).AND.
  206.      $         ( .NOT.LSAME( TRANSA, 'T' ) )      )THEN
  207.          INFO = 1
  208.       ELSE IF( ( .NOT.NOTB                 ).AND.
  209.      $         ( .NOT.LSAME( TRANSB, 'C' ) ).AND.
  210.      $         ( .NOT.LSAME( TRANSB, 'T' ) )      )THEN
  211.          INFO = 2
  212.       ELSE IF( M  .LT.0               )THEN
  213.          INFO = 3
  214.       ELSE IF( N  .LT.0               )THEN
  215.          INFO = 4
  216.       ELSE IF( K  .LT.0               )THEN
  217.          INFO = 5
  218.       ELSE IF( LDA.LT.MAX( 1, NROWA ) )THEN
  219.          INFO = 8
  220.       ELSE IF( LDB.LT.MAX( 1, NROWB ) )THEN
  221.          INFO = 10
  222.       ELSE IF( LDC.LT.MAX( 1, M     ) )THEN
  223.          INFO = 13
  224.       END IF
  225.       IF( INFO.NE.0 )THEN
  226.          CALL XERBLA( 'DGEMM ', INFO )
  227.          RETURN
  228.       END IF
  229. *
  230. *     Quick return if possible.
  231. *
  232.       IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
  233.      $    ( ( ( ALPHA.EQ.ZERO ).OR.( K.EQ.0 ) ).AND.( BETA.EQ.ONE ) ) )
  234.      $   RETURN
  235. *
  236. *     And if  alpha.eq.zero.
  237. *
  238.       IF( ALPHA.EQ.ZERO )THEN
  239.          IF( BETA.EQ.ZERO )THEN
  240.             DO 20, J = 1, N
  241.                DO 10, I = 1, M
  242.                   C( I, J ) = ZERO
  243.    10          CONTINUE
  244.    20       CONTINUE
  245.          ELSE
  246.             DO 40, J = 1, N
  247.                DO 30, I = 1, M
  248.                   C( I, J ) = BETA*C( I, J )
  249.    30          CONTINUE
  250.    40       CONTINUE
  251.          END IF
  252.          RETURN
  253.       END IF
  254. *
  255. *     Start the operations.
  256. *
  257.       IF( NOTB )THEN
  258.          IF( NOTA )THEN
  259. *
  260. *           Form  C := alpha*A*B + beta*C.
  261. *
  262.             DO 90, J = 1, N
  263.                IF( BETA.EQ.ZERO )THEN
  264.                   DO 50, I = 1, M
  265.                      C( I, J ) = ZERO
  266.    50             CONTINUE
  267.                ELSE IF( BETA.NE.ONE )THEN
  268.                   DO 60, I = 1, M
  269.                      C( I, J ) = BETA*C( I, J )
  270.    60             CONTINUE
  271.                END IF
  272.                DO 80, L = 1, K
  273.                   IF( B( L, J ).NE.ZERO )THEN
  274.                      TEMP = ALPHA*B( L, J )
  275.                      DO 70, I = 1, M
  276.                         C( I, J ) = C( I, J ) + TEMP*A( I, L )
  277.    70                CONTINUE
  278.                   END IF
  279.    80          CONTINUE
  280.    90       CONTINUE
  281.          ELSE
  282. *
  283. *           Form  C := alpha*A'*B + beta*C
  284. *
  285.             DO 120, J = 1, N
  286.                DO 110, I = 1, M
  287.                   TEMP = ZERO
  288.                   DO 100, L = 1, K
  289.                      TEMP = TEMP + A( L, I )*B( L, J )
  290.   100             CONTINUE
  291.                   IF( BETA.EQ.ZERO )THEN
  292.                      C( I, J ) = ALPHA*TEMP
  293.                   ELSE
  294.                      C( I, J ) = ALPHA*TEMP + BETA*C( I, J )
  295.                   END IF
  296.   110          CONTINUE
  297.   120       CONTINUE
  298.          END IF
  299.       ELSE
  300.          IF( NOTA )THEN
  301. *
  302. *           Form  C := alpha*A*B' + beta*C
  303. *
  304.             DO 170, J = 1, N
  305.                IF( BETA.EQ.ZERO )THEN
  306.                   DO 130, I = 1, M
  307.                      C( I, J ) = ZERO
  308.   130             CONTINUE
  309.                ELSE IF( BETA.NE.ONE )THEN
  310.                   DO 140, I = 1, M
  311.                      C( I, J ) = BETA*C( I, J )
  312.   140             CONTINUE
  313.                END IF
  314.                DO 160, L = 1, K
  315.                   IF( B( J, L ).NE.ZERO )THEN
  316.                      TEMP = ALPHA*B( J, L )
  317.                      DO 150, I = 1, M
  318.                         C( I, J ) = C( I, J ) + TEMP*A( I, L )
  319.   150                CONTINUE
  320.                   END IF
  321.   160          CONTINUE
  322.   170       CONTINUE
  323.          ELSE
  324. *
  325. *           Form  C := alpha*A'*B' + beta*C
  326. *
  327.             DO 200, J = 1, N
  328.                DO 190, I = 1, M
  329.                   TEMP = ZERO
  330.                   DO 180, L = 1, K
  331.                      TEMP = TEMP + A( L, I )*B( J, L )
  332.   180             CONTINUE
  333.                   IF( BETA.EQ.ZERO )THEN
  334.                      C( I, J ) = ALPHA*TEMP
  335.                   ELSE
  336.                      C( I, J ) = ALPHA*TEMP + BETA*C( I, J )
  337.                   END IF
  338.   190          CONTINUE
  339.   200       CONTINUE
  340.          END IF
  341.       END IF
  342. *
  343.       RETURN
  344. *
  345. *     End of DGEMM .
  346. *
  347.       END
  348.