home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / octave-1.1.1p1-src.tgz / tar.out / fsf / octave / libcruft / lapack / zunml2.f < prev    next >
Text File  |  1996-09-28  |  6KB  |  207 lines
  1.       SUBROUTINE ZUNML2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
  2.      $                   WORK, INFO )
  3. *
  4. *  -- LAPACK routine (version 2.0) --
  5. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  6. *     Courant Institute, Argonne National Lab, and Rice University
  7. *     September 30, 1994
  8. *
  9. *     .. Scalar Arguments ..
  10.       CHARACTER          SIDE, TRANS
  11.       INTEGER            INFO, K, LDA, LDC, M, N
  12. *     ..
  13. *     .. Array Arguments ..
  14.       COMPLEX*16         A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
  15. *     ..
  16. *
  17. *  Purpose
  18. *  =======
  19. *
  20. *  ZUNML2 overwrites the general complex m-by-n matrix C with
  21. *
  22. *        Q * C  if SIDE = 'L' and TRANS = 'N', or
  23. *
  24. *        Q'* C  if SIDE = 'L' and TRANS = 'C', or
  25. *
  26. *        C * Q  if SIDE = 'R' and TRANS = 'N', or
  27. *
  28. *        C * Q' if SIDE = 'R' and TRANS = 'C',
  29. *
  30. *  where Q is a complex unitary matrix defined as the product of k
  31. *  elementary reflectors
  32. *
  33. *        Q = H(k)' . . . H(2)' H(1)'
  34. *
  35. *  as returned by ZGELQF. Q is of order m if SIDE = 'L' and of order n
  36. *  if SIDE = 'R'.
  37. *
  38. *  Arguments
  39. *  =========
  40. *
  41. *  SIDE    (input) CHARACTER*1
  42. *          = 'L': apply Q or Q' from the Left
  43. *          = 'R': apply Q or Q' from the Right
  44. *
  45. *  TRANS   (input) CHARACTER*1
  46. *          = 'N': apply Q  (No transpose)
  47. *          = 'C': apply Q' (Conjugate transpose)
  48. *
  49. *  M       (input) INTEGER
  50. *          The number of rows of the matrix C. M >= 0.
  51. *
  52. *  N       (input) INTEGER
  53. *          The number of columns of the matrix C. N >= 0.
  54. *
  55. *  K       (input) INTEGER
  56. *          The number of elementary reflectors whose product defines
  57. *          the matrix Q.
  58. *          If SIDE = 'L', M >= K >= 0;
  59. *          if SIDE = 'R', N >= K >= 0.
  60. *
  61. *  A       (input) COMPLEX*16 array, dimension
  62. *                               (LDA,M) if SIDE = 'L',
  63. *                               (LDA,N) if SIDE = 'R'
  64. *          The i-th row must contain the vector which defines the
  65. *          elementary reflector H(i), for i = 1,2,...,k, as returned by
  66. *          ZGELQF in the first k rows of its array argument A.
  67. *          A is modified by the routine but restored on exit.
  68. *
  69. *  LDA     (input) INTEGER
  70. *          The leading dimension of the array A. LDA >= max(1,K).
  71. *
  72. *  TAU     (input) COMPLEX*16 array, dimension (K)
  73. *          TAU(i) must contain the scalar factor of the elementary
  74. *          reflector H(i), as returned by ZGELQF.
  75. *
  76. *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
  77. *          On entry, the m-by-n matrix C.
  78. *          On exit, C is overwritten by Q*C or Q'*C or C*Q' or C*Q.
  79. *
  80. *  LDC     (input) INTEGER
  81. *          The leading dimension of the array C. LDC >= max(1,M).
  82. *
  83. *  WORK    (workspace) COMPLEX*16 array, dimension
  84. *                                   (N) if SIDE = 'L',
  85. *                                   (M) if SIDE = 'R'
  86. *
  87. *  INFO    (output) INTEGER
  88. *          = 0: successful exit
  89. *          < 0: if INFO = -i, the i-th argument had an illegal value
  90. *
  91. *  =====================================================================
  92. *
  93. *     .. Parameters ..
  94.       COMPLEX*16         ONE
  95.       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ) )
  96. *     ..
  97. *     .. Local Scalars ..
  98.       LOGICAL            LEFT, NOTRAN
  99.       INTEGER            I, I1, I2, I3, IC, JC, MI, NI, NQ
  100.       COMPLEX*16         AII, TAUI
  101. *     ..
  102. *     .. External Functions ..
  103.       LOGICAL            LSAME
  104.       EXTERNAL           LSAME
  105. *     ..
  106. *     .. External Subroutines ..
  107.       EXTERNAL           XERBLA, ZLACGV, ZLARF
  108. *     ..
  109. *     .. Intrinsic Functions ..
  110.       INTRINSIC          DCONJG, MAX
  111. *     ..
  112. *     .. Executable Statements ..
  113. *
  114. *     Test the input arguments
  115. *
  116.       INFO = 0
  117.       LEFT = LSAME( SIDE, 'L' )
  118.       NOTRAN = LSAME( TRANS, 'N' )
  119. *
  120. *     NQ is the order of Q
  121. *
  122.       IF( LEFT ) THEN
  123.          NQ = M
  124.       ELSE
  125.          NQ = N
  126.       END IF
  127.       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
  128.          INFO = -1
  129.       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
  130.          INFO = -2
  131.       ELSE IF( M.LT.0 ) THEN
  132.          INFO = -3
  133.       ELSE IF( N.LT.0 ) THEN
  134.          INFO = -4
  135.       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
  136.          INFO = -5
  137.       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
  138.          INFO = -7
  139.       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
  140.          INFO = -10
  141.       END IF
  142.       IF( INFO.NE.0 ) THEN
  143.          CALL XERBLA( 'ZUNML2', -INFO )
  144.          RETURN
  145.       END IF
  146. *
  147. *     Quick return if possible
  148. *
  149.       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 )
  150.      $   RETURN
  151. *
  152.       IF( ( LEFT .AND. NOTRAN .OR. .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
  153.          I1 = 1
  154.          I2 = K
  155.          I3 = 1
  156.       ELSE
  157.          I1 = K
  158.          I2 = 1
  159.          I3 = -1
  160.       END IF
  161. *
  162.       IF( LEFT ) THEN
  163.          NI = N
  164.          JC = 1
  165.       ELSE
  166.          MI = M
  167.          IC = 1
  168.       END IF
  169. *
  170.       DO 10 I = I1, I2, I3
  171.          IF( LEFT ) THEN
  172. *
  173. *           H(i) or H(i)' is applied to C(i:m,1:n)
  174. *
  175.             MI = M - I + 1
  176.             IC = I
  177.          ELSE
  178. *
  179. *           H(i) or H(i)' is applied to C(1:m,i:n)
  180. *
  181.             NI = N - I + 1
  182.             JC = I
  183.          END IF
  184. *
  185. *        Apply H(i) or H(i)'
  186. *
  187.          IF( NOTRAN ) THEN
  188.             TAUI = DCONJG( TAU( I ) )
  189.          ELSE
  190.             TAUI = TAU( I )
  191.          END IF
  192.          IF( I.LT.NQ )
  193.      $      CALL ZLACGV( NQ-I, A( I, I+1 ), LDA )
  194.          AII = A( I, I )
  195.          A( I, I ) = ONE
  196.          CALL ZLARF( SIDE, MI, NI, A( I, I ), LDA, TAUI, C( IC, JC ),
  197.      $               LDC, WORK )
  198.          A( I, I ) = AII
  199.          IF( I.LT.NQ )
  200.      $      CALL ZLACGV( NQ-I, A( I, I+1 ), LDA )
  201.    10 CONTINUE
  202.       RETURN
  203. *
  204. *     End of ZUNML2
  205. *
  206.       END
  207.