home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / perl-5.003-bin.lha / lib / perl5 / File / Basename.pm next >
Text File  |  1996-10-09  |  9KB  |  261 lines
  1. package File::Basename;
  2.  
  3. =head1 NAME
  4.  
  5. Basename - parse file specifications
  6.  
  7. fileparse - split a pathname into pieces
  8.  
  9. basename - extract just the filename from a path
  10.  
  11. dirname - extract just the directory from a path
  12.  
  13. =head1 SYNOPSIS
  14.  
  15.     use File::Basename;
  16.  
  17.     ($name,$path,$suffix) = fileparse($fullname,@suffixlist)
  18.     fileparse_set_fstype($os_string);
  19.     $basename = basename($fullname,@suffixlist);
  20.     $dirname = dirname($fullname);
  21.  
  22.     ($name,$path,$suffix) = fileparse("lib/File/Basename.pm","\.pm");
  23.     fileparse_set_fstype("VMS");
  24.     $basename = basename("lib/File/Basename.pm",".pm");
  25.     $dirname = dirname("lib/File/Basename.pm");
  26.  
  27. =head1 DESCRIPTION
  28.  
  29. These routines allow you to parse file specifications into useful
  30. pieces using the syntax of different operating systems.
  31.  
  32. =over 4
  33.  
  34. =item fileparse_set_fstype
  35.  
  36. You select the syntax via the routine fileparse_set_fstype().
  37. If the argument passed to it contains one of the substrings
  38. "VMS", "MSDOS", "MacOS" or "AmigaOS", the file specification 
  39. syntax of that operating system is used in future calls to 
  40. fileparse(), basename(), and dirname().  If it contains none of
  41. these substrings, UNIX syntax is used.  This pattern matching is
  42. case-insensitive.  If you've selected VMS syntax, and the file
  43. specification you pass to one of these routines contains a "/",
  44. they assume you are using UNIX emulation and apply the UNIX syntax
  45. rules instead, for that function call only.
  46.  
  47. If you haven't called fileparse_set_fstype(), the syntax is chosen
  48. by examining the builtin variable C<$^O> according to these rules.
  49.  
  50. =item fileparse
  51.  
  52. The fileparse() routine divides a file specification into three
  53. parts: a leading B<path>, a file B<name>, and a B<suffix>.  The
  54. B<path> contains everything up to and including the last directory
  55. separator in the input file specification.  The remainder of the input
  56. file specification is then divided into B<name> and B<suffix> based on
  57. the optional patterns you specify in C<@suffixlist>.  Each element of
  58. this list is interpreted as a regular expression, and is matched
  59. against the end of B<name>.  If this succeeds, the matching portion of
  60. B<name> is removed and prepended to B<suffix>.  By proper use of
  61. C<@suffixlist>, you can remove file types or versions for examination.
  62.  
  63. You are guaranteed that if you concatenate B<path>, B<name>, and
  64. B<suffix> together in that order, the result will be identical to the
  65. input file specification.
  66.  
  67. =back
  68.  
  69. =head1 EXAMPLES
  70.  
  71. Using UNIX file syntax:
  72.  
  73.     ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7', 
  74.                     '\.book\d+');
  75.  
  76. would yield
  77.  
  78.     $base eq 'draft'
  79.     $path eq '/virgil/aeneid',
  80.     $tail eq '.book7'
  81.  
  82. Similarly, using VMS syntax:
  83.  
  84.     ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh',
  85.                    '\..*');
  86.  
  87. would yield
  88.  
  89.     $name eq 'Rhetoric'
  90.     $dir  eq 'Doc_Root:[Help]'
  91.     $type eq '.Rnh'
  92.  
  93. =item C<basename>
  94.  
  95. The basename() routine returns the first element of the list produced
  96. by calling fileparse() with the same arguments.  It is provided for
  97. compatibility with the UNIX shell command basename(1).
  98.  
  99. =item C<dirname>
  100.  
  101. The dirname() routine returns the directory portion of the input file
  102. specification.  When using VMS or MacOS syntax, this is identical to the
  103. second element of the list produced by calling fileparse() with the same
  104. input file specification.  When using UNIX or MSDOS syntax, the return
  105. value conforms to the behavior of the UNIX shell command dirname(1).  This
  106. is usually the same as the behavior of fileparse(), but differs in some
  107. cases.  For example, for the input file specification F<lib/>, fileparse()
  108. considers the directory name to be F<lib/>, while dirname() considers the
  109. directory name to be F<.>).
  110.  
  111. =cut
  112.  
  113. require 5.002;
  114. require Exporter;
  115. @ISA = qw(Exporter);
  116. @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);
  117.  
  118. #   fileparse_set_fstype() - specify OS-based rules used in future
  119. #                            calls to routines in this package
  120. #
  121. #   Currently recognized values: VMS, MSDOS, MacOS
  122. #       Any other name uses Unix-style rules
  123.  
  124. sub fileparse_set_fstype {
  125.   my($old) = $Fileparse_fstype;
  126.   $Fileparse_fstype = $_[0] if $_[0];
  127.   $old;
  128. }
  129.  
  130. #   fileparse() - parse file specification
  131. #
  132. #   calling sequence:
  133. #     ($filename,$prefix,$tail) = &basename_pat($filespec,@excludelist);
  134. #     where  $filespec    is the file specification to be parsed, and
  135. #            @excludelist is a list of patterns which should be removed
  136. #                         from the end of $filename.
  137. #            $filename    is the part of $filespec after $prefix (i.e. the
  138. #                         name of the file).  The elements of @excludelist
  139. #                         are compared to $filename, and if an  
  140. #            $prefix     is the path portion $filespec, up to and including
  141. #                        the end of the last directory name
  142. #            $tail        any characters removed from $filename because they
  143. #                         matched an element of @excludelist.
  144. #
  145. #   fileparse() first removes the directory specification from $filespec,
  146. #   according to the syntax of the OS (code is provided below to handle
  147. #   VMS, Unix, MSDOS, MacOS and AmigaOS; you can pick the one you want using
  148. #   fileparse_set_fstype(), or you can accept the default, which is
  149. #   based on the information in the builtin variable $^O).  It then compares
  150. #   each element of @excludelist to $filename, and if that element is a
  151. #   suffix of $filename, it is removed from $filename and prepended to
  152. #   $tail.  By specifying the elements of @excludelist in the right order,
  153. #   you can 'nibble back' $filename to extract the portion of interest
  154. #   to you.
  155. #
  156. #   For example, on a system running Unix,
  157. #   ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7',
  158. #                                       '\.book\d+');
  159. #   would yield $base == 'draft',
  160. #               $path == '/virgil/aeneid/'  (note trailing slash)
  161. #               $tail == '.book7'.
  162. #   Similarly, on a system running VMS,
  163. #   ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh','\..*');
  164. #   would yield $name == 'Rhetoric';
  165. #               $dir == 'Doc_Root:[Help]', and
  166. #               $type == '.Rnh'.
  167. #
  168. #   Version 2.2  13-Oct-1994  Charles Bailey  bailey@genetics.upenn.edu 
  169.  
  170.  
  171. sub fileparse {
  172.   my($fullname,@suffices) = @_;
  173.   my($fstype) = $Fileparse_fstype;
  174.   my($dirpath,$tail,$suffix);
  175.  
  176.   if ($fstype =~ /^VMS/i) {
  177.     if ($fullname =~ m#/#) { $fstype = '' }  # We're doing Unix emulation
  178.     else {
  179.       ($dirpath,$basename) = ($fullname =~ /(.*[:>\]])?(.*)/);
  180.       $dirpath = $ENV{'DEFAULT'} unless $dirpath;
  181.     }
  182.   }
  183.   if ($fstype =~ /^MSDOS/i) {
  184.     ($dirpath,$basename) = ($fullname =~ /(.*\\)?(.*)/);
  185.     $dirpath = '.\\' unless $dirpath;
  186.   }
  187.   elsif ($fstype =~ /^MAC/i) {
  188.     ($dirpath,$basename) = ($fullname =~ /(.*:)?(.*)/);
  189.   }
  190.   elsif ($fstype =~ /^AmigaOS/i) {
  191.     ($dirpath,$basename) = ($fullname =~ /(.*[:\/])?(.*)/);
  192.   }
  193.   elsif ($fstype !~ /^VMS/i) {  # default to Unix
  194.     ($dirpath,$basename) = ($fullname =~ m#(.*/)?(.*)#);
  195.     $dirpath = './' unless $dirpath;
  196.   }
  197.  
  198.   if (@suffices) {
  199.     $tail = '';
  200.     foreach $suffix (@suffices) {
  201.       if ($basename =~ /($suffix)$/) {
  202.         $tail = $1 . $tail;
  203.         $basename = $`;
  204.       }
  205.     }
  206.   }
  207.  
  208.   wantarray ? ($basename,$dirpath,$tail) : $basename;
  209.  
  210. }
  211.  
  212.  
  213. #   basename() - returns first element of list returned by fileparse()
  214.  
  215. sub basename {
  216.   my($name) = shift;
  217.   (fileparse($name, map("\Q$_\E",@_)))[0];
  218. }
  219.   
  220.  
  221. #    dirname() - returns device and directory portion of file specification
  222. #        Behavior matches that of Unix dirname(1) exactly for Unix and MSDOS
  223. #        filespecs except for names ending with a separator, e.g., "/xx/yy/".
  224. #        This differs from the second element of the list returned
  225. #        by fileparse() in that the trailing '/' (Unix) or '\' (MSDOS) (and
  226. #        the last directory name if the filespec ends in a '/' or '\'), is lost.
  227.  
  228. sub dirname {
  229.     my($basename,$dirname) = fileparse($_[0]);
  230.     my($fstype) = $Fileparse_fstype;
  231.  
  232.     if ($fstype =~ /VMS/i) { 
  233.         if ($_[0] =~ m#/#) { $fstype = '' }
  234.         else { return $dirname }
  235.     }
  236.     if ($fstype =~ /MacOS/i) { return $dirname }
  237.     elsif ($fstype =~ /MSDOS/i) { 
  238.         if ( $dirname =~ /:\\$/) { return $dirname }
  239.         chop $dirname;
  240.         $dirname =~ s:[^\\]+$:: unless $basename;
  241.         $dirname = '.' unless $dirname;
  242.     }
  243.     elsif ($fstype =~ /AmigaOS/i) {
  244.         if ( $dirname =~ /:$/) { return $dirname }
  245.         chop $dirname;
  246.         $dirname =~ s#[^:/]+$## unless $basename;
  247.     }
  248.     else { 
  249.         if ( $dirname eq '/') { return $dirname }
  250.         chop $dirname;
  251.         $dirname =~ s:[^/]+$:: unless $basename;
  252.         $dirname = '.' unless $dirname;
  253.     }
  254.  
  255.     $dirname;
  256. }
  257.  
  258. $Fileparse_fstype = $^O;
  259.  
  260. 1;
  261.