home *** CD-ROM | disk | FTP | other *** search
/ ISV Strong Games / ISV_STRONG_GAMES.iso / arcade / bomber / !Bomber / Source < prev   
Text File  |  1992-05-23  |  9KB  |  444 lines
  1. BASIC
  2. MODE 0
  3. AUTO 0,10
  4.  
  5. REM ><Bomber$Dir>.!RunImage
  6. : 
  7. REM   Bomber
  8. REM     By
  9. REM Scott Moore
  10. REM 
  11. REM (C) 1992 SJM Software
  12. :       
  13. ON ERROR PROCinternalerror
  14. PROCinitialise
  15. REPEAT
  16. PROCtitlepage
  17. PROCwantinstructions
  18. PROCdogame
  19. PROCdohighscores
  20. PROCcheckplayagain
  21. UNTIL quit
  22. PROCexit
  23. END
  24. :
  25. DEF PROCinitialise
  26. MODE 13
  27. SYS "OS_RemoveCursors"
  28. quit=FALSE
  29. sp_op=&2E
  30. os_byte=&06
  31. space%=FALSE
  32. DIM highname$(10),highscore%(10)
  33. DIM buildtype%(20),buildtop%(20),buildheight%(20)
  34. PROCloadhighscoretable(highname$(),highscore%())
  35. *<Bomber$Dir>.Font
  36. PROCloadsprites
  37. ENDPROC
  38. :
  39. DEF PROCsavehighscores(name$(),score%())
  40. file%=OPENOUT("<Bomber$Dir>.HighScore")
  41. FOR loop%=1 TO 10
  42. BPUT#file%,STR$(score%(loop%))+","+name$(loop%)
  43. NEXT
  44. CLOSE #file%
  45. ENDPROC
  46. :
  47. DEF PROCloadhighscoretable(RETURN name$(),RETURN score%())
  48. file%=OPENIN("<Bomber$Dir>.HighScore")
  49. FOR loop%=1 TO 10
  50. line$=FNgetline(file%)
  51. split%=INSTR(line$,",")
  52. score%(loop%)=VAL(LEFT$(line$,split%-1))
  53. name$(loop%)=MID$(line$,split%+1)
  54. NEXT
  55. CLOSE #file%
  56. ENDPROC
  57. :
  58. DEF FNgetline(file%)
  59. line$=""
  60. byte%=BGET#file%
  61. WHILE byte%<>&0A
  62. line$+=CHR$(byte%)
  63. byte%=BGET#file%
  64. ENDWHILE
  65. =line$
  66. :
  67. DEF PROCloadsprites
  68. PROCloadspritefile("<Bomber$Dir>.Sprites.Sprites",sprites%)
  69. ENDPROC
  70. :
  71. DEF PROCloadspritefile(filename$,RETURN addr%)
  72. SYS "XOS_File",&05,filename$ TO ,,,,filelen%
  73. filelen%+=16
  74. DIM addr% filelen%
  75. addr%!0=filelen%
  76. addr%!4=16
  77. SYS "XOS_SpriteOp",&10A,addr%,filename$
  78. ENDPROC
  79. :
  80. DEF PROCtitlepage
  81. GCOL 62 TINT 192
  82. RECTANGLE FILL 0,0,1276,1020
  83. PROCsetupbuildings(6)
  84. PROCshowbuildings 
  85. PROCcentrestring2("Bomber",2,63,192)
  86. PROCcentrestring1("By",5,%110101,192)
  87. PROCcentrestring1("Scott Moore",7,%010111,192)
  88. PROCcentrestring1("(C) 1992 SJM Software",31,63,192)
  89. ENDPROC
  90. :                
  91. DEF PROCsetupbuildings(maxheight%)
  92. FOR loop%=1 TO 20
  93. buildtype%(loop%)=RND(4)-1
  94. buildheight%(loop%)=(maxheight%*.4)+RND(maxheight%*.6) 
  95. buildtop%(loop%)=buildheight%(loop%)
  96. NEXT
  97. ENDPROC
  98. :
  99. DEF PROCshowbuildings
  100. FOR loop%=1 TO 20
  101. SYS sp_op,&122,sprites%,"9",(loop%-1)*64,0
  102. FOR height%=1 TO buildheight%(loop%)
  103. IF height%<buildtop%(loop%) THEN 
  104. SYS sp_op,&122,sprites%,STR$((buildtype%(loop%)*2)+1),(loop%-1)*64,32+(height%-1)*64
  105. ELSE
  106. SYS sp_op,&122,sprites%,STR$((buildtype%(loop%)*2)+2),(loop%-1)*64,32+(height%-1)*64
  107. ENDIF
  108. NEXT ,
  109. ENDPROC
  110. :
  111. DEF PROCwantinstructions
  112. PROCcentrestring1("Do you want instructions (Y/N)?",15,%001011,192)
  113. SYS os_byte,15,1
  114. REPEAT
  115. key$=GET$
  116. UNTIL INSTR("YyNn",key$)
  117. IF key$="Y" OR key$="y" THEN PROCinstructions
  118. ENDPROC
  119. :
  120. DEF PROCinstructions
  121. GCOL 62 TINT 192
  122. RECTANGLE FILL 0,0,1276,1020
  123. PROCcentrestring2("Instructions",1,63,192)
  124. PROCcentrestring1("You are the pilot of a World War One",4,%000011,192)
  125. PROCcentrestring1("Plane.It is running out of fuel and you",6,%000011,192)
  126. PROCcentrestring1("will not be able to reach your runnway.",8,%000011,192)
  127. PROCcentrestring1("So you must bomb the buildings below",10,%000011,192)
  128. PROCcentrestring1("to clear a stretch of grass to",12,%000011,192)
  129. PROCcentrestring1("land your plane on.",14,%000011,192)
  130. PROCcentrestring1("KEYS",17,63,192)
  131. PROCcentrestring1("----",18,63,0)
  132. PROCcentrestring1("SPACE - Drop Bomb",20,%001100,192)
  133. PROCcentrestring1("  ESC - Quit Game",22,%001100,192)
  134. PROCcentrestring1("Press SPACE to start the game",28,%110101,192)
  135. SYS os_byte,15,1
  136. REPEAT
  137. UNTIL GET=32
  138. ENDPROC
  139. :
  140. DEF PROCdogame
  141. score%=0
  142. lives%=3
  143. level%=1
  144. GCOL 0 TINT 0
  145. RECTANGLE FILL 0,920,1276,103
  146. GCOL 63 TINT 192
  147. RECTANGLE 0,924,1276,99
  148. GCOL 63 TINT 128
  149. RECTANGLE 4,928,1268,91
  150. REPEAT             
  151. planex%=0
  152. planey%=848
  153. bomb%=FALSE
  154. bombx%=0
  155. bomby%=0
  156. bombd%=0
  157. hit%=FALSE
  158. finished%=FALSE
  159. maxheight%=5+level%
  160. IF maxheight%>11 THEN maxheight%=11
  161. GCOL 62 TINT 192
  162. RECTANGLE FILL 0,32,1276,887
  163. PROCsetupbuildings(maxheight%)
  164. buildhit%=0
  165. FOR loop%=1 TO 20
  166. buildhit%+=buildheight%(loop%)
  167. NEXT
  168. PROCshowbuildings
  169. PROCshowstatus
  170. REPEAT
  171.  PROCmovesprites
  172.  PROCcheckkeys
  173.  PROCcheckcollisions
  174.  IF buildhit%=0 THEN finished%=TRUE
  175.  IF hit% THEN PROChitbuilding
  176. UNTIL finished% OR lives%=0
  177. IF lives%>0 THEN
  178.  PROCfinishedlevel
  179. ENDIF
  180. UNTIL lives%=0
  181. PROCgameover
  182. ENDPROC
  183. :
  184. DEF PROCfinishedlevel
  185. REPEAT
  186. opx%=planex%
  187. opy%=planey%    
  188. planex%+=8
  189. IF planey%>32 THEN planey%-=2
  190. IF planey%<32 THEN planey%=32
  191. IF planex%>=1280 THEN
  192. planex%=-80
  193. ENDIF
  194. WAIT
  195. SYS sp_op,&122,sprites%,"12",opx%,opy%
  196. SYS sp_op,&122,sprites%,"0",planex%,planey%,8
  197. UNTIL planex%>=1180 AND planey%=32
  198. PROCcentrestring1("Well done!",15,%010111,192)
  199. PROCcentrestring1("You've finished level "+STR$(level%),17,%011101,192)
  200. bonus%=100+(level%*200)
  201. PROCcentrestring1(STR$(bonus%)+" bonus points",19,%110101,192)
  202. score%+=bonus%
  203. PROCshowstatus
  204. level%+=1
  205. PROCcentrestring1("Press SPACE to try the next level",22,%111111,192)
  206. SYS os_byte,15,1
  207. REPEAT
  208. UNTIL GET=32
  209. ENDPROC
  210. :
  211. DEF PROCgameover
  212. PROCcentrestring1("* * * GAME OVER * * *",27,%111011,192)
  213. TIME=0
  214. REPEAT UNTIL TIME>250
  215. ENDPROC
  216. :
  217. DEF PROChitbuilding
  218. SYS sp_op,&122,sprites%,"11",planex%+8,planey%-8,8
  219. lives%-=1
  220. hit%=FALSE
  221. PROCshowstatus
  222. PROCcentrestring1("Oh no! You've crashed!",25,%010111,192)
  223. IF lives%=0 THEN ENDPROC
  224. PROCcentrestring1("Press SPACE to start again",27,%110101,192)
  225. SYS os_byte,15,1
  226. REPEAT
  227. UNTIL GET=32
  228. planex%=0
  229. planey%=848
  230. buildheight%()=buildtop%()
  231. GCOL 62 TINT 192
  232. RECTANGLE FILL 0,32,1276,887
  233. buildhit%=0
  234. FOR loop%=1 TO 20
  235. buildhit%+=buildheight%(loop%)
  236. NEXT
  237. PROCshowbuildings
  238. ENDPROC
  239. :
  240. DEF PROCcheckcollisions
  241. IF bomb% AND (bomby%-bombd%)<=32 THEN
  242.  bomb%=FALSE
  243.  SYS sp_op,&122,sprites%,"13",bombx%,bomby%
  244.  IF score%>50 THEN 
  245.   score%-=50
  246.  ELSE
  247.   score%=0
  248.  ENDIF
  249.  PROCshowstatus
  250. ENDIF
  251. bombbx%=INT(bombx%/64)+1
  252. IF bomb% AND (bomby%-bombd%)<=(32+(64*(buildheight%(bombbx%)))) THEN
  253.  bomb%=FALSE
  254.  SYS sp_op,&122,sprites%,"13",bombx%,bomby%
  255.  SYS sp_op,&122,sprites%,"14",(bombbx%-1)*64,32+(buildheight%(bombbx%)-1)*64
  256.  buildheight%(bombbx%)-=1     
  257.  score%+=10
  258.  buildhit%-=1
  259.  PROCshowstatus
  260. ENDIF
  261. planebx%=INT((planex%+80)/64)+1
  262. IF planebx%<=20 THEN
  263.  IF 32+(64*buildheight%(planebx%))>planey% THEN hit%=TRUE
  264. ENDIF
  265. ENDPROC
  266. :
  267. DEF PROCcheckkeys
  268. IF NOT INKEY -99 THEN
  269.  space%=FALSE
  270. ENDIF
  271. IF NOT bomb% AND INKEY -99 AND planex%>=0 AND planex%<1276 AND space%=FALSE THEN
  272.  bombx%=INT(planex%/32)*32
  273.  bomby%=planey%-32
  274.  bomb%=TRUE
  275.  bombd%=4
  276.  space%=TRUE
  277. ENDIF
  278. ENDPROC
  279. :
  280. DEF PROCmovesprites
  281. opx%=planex%
  282. opy%=planey%
  283. oby%=bomby%
  284. planex%+=4
  285. IF level%>4 THEN planex%+=4
  286. IF level%>8 THEN planex%+=4
  287. IF bomb% THEN
  288. bomby%-=bombd%
  289. IF bombd%<32 THEN bombd%+=1
  290. ENDIF
  291. IF planex%>=1280 THEN
  292. planex%=-80
  293. planey%-=32+(level%*2)
  294. ENDIF
  295. WAIT
  296. IF bomb% THEN
  297. SYS sp_op,&122,sprites%,"13",bombx%,oby%
  298. SYS sp_op,&122,sprites%,"10",bombx%,bomby%
  299. ENDIF
  300. SYS sp_op,&122,sprites%,"12",opx%,opy%
  301. SYS sp_op,&122,sprites%,"0",planex%,planey%,8
  302. ENDPROC
  303. :
  304. DEF PROCshowstatus
  305. COLOUR 128 TINT 0
  306. COLOUR 63 TINT 192
  307. PRINT TAB(1,1);"Score :";FNnumber(5,score%)
  308. PRINT TAB(16,1);"Lives :";FNnumber(2,lives%)
  309. PRINT TAB(28,1);"Level :";FNnumber(2,level%)
  310. ENDPROC
  311. :
  312. DEF PROCdohighscores
  313. GCOL 62 TINT 192
  314. RECTANGLE FILL 0,0,1276,1020
  315. PROCcentrestring2("BOMBER HIGH SCORES",1,%111111,192)
  316. IF score%>highscore%(10) THEN
  317.  PROCcentrestring1("Well done!",11,%011011,192)
  318.  PROCcentrestring1("You've scored in the top ten!",13,%011110,192)
  319.  PROCcentrestring1("Please type in your name",15,%111001,192)
  320.  SYS os_byte,15,1
  321.  name$=""
  322.  REPEAT
  323.   lastname$=name$
  324.   key$=GET$
  325.   CASE key$ OF
  326.   WHEN CHR$&0D
  327.    REM 
  328.   WHEN CHR$&7F
  329.    IF LEN(name$)>0 THEN name$=LEFT$(name$,LEN(name$)-1)
  330.   OTHERWISE
  331.    IF LEN(name$)<20 THEN name$+=key$
  332.   ENDCASE
  333.   IF name$<>lastname$ THEN
  334.    WAIT
  335.    GCOL 62 TINT 192
  336.    RECTANGLE FILL 316,418,647,31
  337.    PROCcentrestring1(name$,18,%111111,192)
  338.   ENDIF
  339.  UNTIL key$=CHR$&0D
  340.  loop%=0
  341.  REPEAT
  342.   loop%+=1
  343.  UNTIL score%>highscore%(loop%)
  344.  highscore%(loop%)=score%
  345.  highname$(loop%)=name$
  346. GCOL 62 TINT 192
  347. RECTANGLE FILL 0,0,1276,704
  348. PROCsavehighscores(highname$(),highscore%())
  349. ENDIF
  350. FOR loop%=1 TO 10
  351.  PROCcentrestring1(FNnumber(5,highscore%(loop%))+"  "+FNstring(20,highname$(loop%)),3+(loop%*2),%011111,192)
  352. NEXT
  353. ENDPROC
  354. :
  355. DEF PROCcheckplayagain
  356. PROCcentrestring1("Do you wish to play again (Y/N)?",27,%010111,192)
  357. SYS os_byte,15,1
  358. REPEAT
  359. key$=GET$
  360. UNTIL INSTR("YyNn",key$)
  361. IF key$="N" OR key$="n" THEN quit=TRUE
  362. ENDPROC
  363. :
  364. DEF PROCexit
  365. MODE 12
  366. OFF
  367. SYS os_byte,20
  368. *TYPE <Bomber$Dir>.Message
  369. PRINT '
  370. ENDPROC
  371. :
  372. DEF PROCcentrestring1(string$,y%,col%,tint%)
  373. y%=1023-(y%*32)
  374. x%=640-LEN(string$)*16
  375. VDU 5
  376. GCOL 0 TINT 0
  377. MOVE x%-4,y%
  378. PRINT string$
  379. MOVE x%-4,y%-4
  380. PRINT string$
  381. MOVE x%,y%-4
  382. PRINT string$
  383. MOVE x%+4,y%-4
  384. PRINT string$
  385. MOVE x%+4,y%
  386. PRINT string$
  387. MOVE x%+4,y%+4
  388. PRINT string$
  389. MOVE x%,y%+4
  390. PRINT string$
  391. MOVE x%-4,y%+4
  392. PRINT string$
  393. GCOL col% TINT tint%
  394. MOVE x%,y%
  395. PRINT string$
  396. VDU 4
  397. ENDPROC
  398. :      
  399. DEF PROCcentrestring2(string$,y%,col%,tint%)
  400. y%=1023-(y%*32)
  401. x%=640-LEN(string$)*32
  402. VDU 23,17,7,%110,16;16;0,0,5
  403. GCOL 0 TINT 0
  404. MOVE x%-4,y%
  405. PRINT string$
  406. MOVE x%-4,y%-4
  407. PRINT string$
  408. MOVE x%,y%-4
  409. PRINT string$
  410. MOVE x%+4,y%-4
  411. PRINT string$
  412. MOVE x%+4,y%
  413. PRINT string$
  414. MOVE x%+4,y%+4
  415. PRINT string$
  416. MOVE x%,y%+4
  417. PRINT string$
  418. MOVE x%-4,y%+4
  419. PRINT string$
  420. GCOL col% TINT tint%
  421. MOVE x%,y%
  422. PRINT string$
  423. VDU 23,17,7,%110,8;8;0,0,4
  424. ENDPROC
  425. :      
  426. DEF FNnumber(places%,number%)
  427. =RIGHT$(STRING$(places%,"0")+STR$(number%),places%)
  428. :                                                  
  429. DEF FNstring(places%,string$)
  430. =RIGHT$(STRING$(places%," ")+string$,places%)
  431. :
  432. DEF PROCinternalerror
  433. MODE 12
  434. OFF
  435. SYS &06,20
  436. SYS &06,15,1
  437. IF ERR<>17 THEN
  438.  VDU 7
  439.  PRINT "Bomber has suffered an internal error, ";REPORT$;" at line ";ERL
  440. ELSE
  441.  PROCexit
  442. ENDIF
  443. END
  444.