home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / language / nasm20 / nasm20s / string1.s65 < prev    next >
Encoding:
Text File  |  1993-10-23  |  4.0 KB  |  144 lines
  1.          .ZEXT          _string1
  2.          .VfL_BOCHUM    _string2                ;; VFL_BOCHUM == ZEXT
  3.          .VfL_BOCHUM    _tmp1
  4.  
  5. ; --------------------------------------------------------------
  6. ;           These are just like the C-routines you know
  7. ; To properly use these, you must define in the source three
  8. ; word locations for _string1, _string2, _tmp1 in zero page
  9. ; --------------------------------------------------------------
  10. ; STRCAT    strcat( dst, src), where >dst< = _string1 >src< = 2
  11. ; Appends src string that ends with a 0 to dst, which also ends
  12. ; with a 0. Wild things will happen, if they don't end with a 0
  13. ; 
  14. ; STRCPY    strcpy( dst, src), where >dsr< = _string1 >src< = 2
  15. ; Copies src string that ends with a 0 into dst.
  16. ; --------------------------------------------------------------
  17.          .local
  18. STREND   ldy   #0                ; don't really use this for now
  19. :loop    lda   (_string1),y       
  20.          beq   :done
  21.          inc   _string1
  22.          bne   :loop
  23.          inc   _string1+1
  24.          bne   :loop
  25. :done    rts
  26.  
  27. STRCAT:  jsr   STREND            ; Go to the of DST
  28.          beq   :copy             ; hop into copy of STRCPY
  29.  
  30. STRCPY:  ldy   #0                ; cleverly use code for STRCPY as well
  31. :copy    lda   (_string2),y
  32.          sta   (_string1),y         
  33.          beq   :finish
  34.          iny
  35.          bne   :copy
  36.          inc   _string2+1
  37.          inc   _string1+1
  38.          bne   :copy
  39. :finish  rts         
  40.  
  41.          .local
  42. ; -------------------------------------------------------------
  43. ; Flags on exit mean:
  44. ;     CS -- _string1 > _string2
  45. ;     CC -- _string1 > _string2
  46. ;     EQ -- _string1 = _string2
  47. ; -------------------------------------------------------------
  48. STRCMP:  ldy   #0                
  49. :copy    lda   (_string2),y
  50.          cmp   (_string1),y
  51.          bne   :done
  52.          lda   (_string1),y
  53.          beq   :done
  54.          clc
  55.          lda   (_string2),y
  56.          beq   :done
  57.          iny
  58.          bne   :copy
  59.          inc   _string2+1
  60.          inc   _string1+1
  61.          bne   :copy
  62. :done    rts         
  63.  
  64.          .local
  65. ; --------------------------------------------------------------
  66. ; These are STRNCAT and STRNCPY. Note that there is an inplied
  67. ; limit on string size that is 32K. That won't hurt on a 6502
  68. ; I would say.
  69. ; STRNCAT( dst, src, aux)
  70. ; STRNCPY( dst, src, aux) where aux is the maximum number of 
  71. ; bytes in both cases. 
  72. ; --------------------------------------------------------------
  73. STRNCAT: jsr   STREND
  74.          bcc   :load
  75.          
  76. STRNCPY: ldy   #0                ; cleverly use code for STRCPY as well
  77. :load    ldx   _tmp1
  78.          bne   :copy
  79.          lda   _tmp1+1
  80.          beq   :done
  81.          dec   _tmp1+1
  82.          
  83. :copy    lda   (_string2),y
  84.          sta   (_string1),y         
  85.          beq   :done
  86.          dex
  87.          bne   :cont
  88.          dec   _tmp1+1
  89.          bpl   :done
  90. :cont    iny
  91.          bne   :copy
  92.          inc   _string2+1
  93.          inc   _string1+1
  94.          bne   :copy
  95. :done    rts         
  96.  
  97.          .local
  98.  
  99. ; -------------------------------------------------------------
  100. ; Flags on exit mean:
  101. ;     CS -- _string1 < _string2
  102. ;     CC -- _string1 > _string2
  103. ;     EQ -- _string1 = _string2
  104. ; -------------------------------------------------------------
  105. STRNCMP: ldy   #0            
  106. :load    ldx   _tmp1
  107.          bne   :copy
  108.          lda   _tmp1+1
  109.          beq   :done
  110.          dec   _tmp1+1
  111.          
  112. :copy    lda   (_string2),y
  113.          cmp   (_string1),y
  114.          bne   :done
  115.          lda   (_string1),y
  116.          beq   :done
  117.          clc
  118.          lda   (_string2),y
  119.          beq   :done
  120.          dex
  121.          bne   :cont
  122.          dec   _tmp1+1
  123.          bpl   :done
  124. :cont    iny
  125.          bne   :copy
  126.          inc   _string2+1
  127.          inc   _string1+1
  128.          bne   :copy
  129. :done    rts         
  130.  
  131.          .local
  132.          
  133. STRLEN   ldy   #0
  134.          sty   _tmp1+1
  135. :loop    lda   (_string1),y
  136.          beq   :done 
  137.          iny
  138.          bne   :loop
  139.          inc   _tmp1+1
  140.          bne   :loop
  141. :done    sty   _tmp1
  142.          rts
  143.  
  144.