Meeting Pearls 3/Meeting_Pearls_III.iso/Pearls/comm/Mail+News/UMS11/UMS-Install

Text File | 1995-09-06 | 13KB | 598 lines

; $VER: Install-UMS 11 (06.09.95)

( if (= @language "english")
(
  (set #intro
  (cat "Installing Universal Message System V11..."
  ))
  (set #info
  (cat "This installation script only configures a basic UMS system with "
        "only one single user and no newsfeeds.\n\n"

        "In order to run a point on any network you need to install "
        "the required network drivers.\n\n"
  ))
  (set #dest
  (cat "In which disk or drawer should Universal Message System be "
       "installed?\n\n"

       "(This script does not create a sub drawer for UMS).\n\n"

       "You can install in place (just select ok)."
  ))
  (set #envoy
  (cat "Do you want to run UMS server on this machine or do you want "
       "to access the message base over a local area network using "
       "the networking software Envoy?"
  ))
  (set #amitcp
  (cat "Do you want to run UMS server on this machine or do you want "
       "to access the message base over a local area network using "
       "the networking software AmiTCP?"
  ))
  (set #localmb
  (cat "message base is on this machine"
  ))
  (set #remotemb
  (cat "message base is accessed via network"
  ))
  (set #umsservice
  (cat "Do you want to export UMS as an Envoy service?\n"
       "(This enables other machines in a local area network "
       "to use the message base of this machine over the net)"
  ))
  (set #umsd
  (cat "Do you want to export UMS using TCP/IP?\n"
       "(This enables other machines in a local area network "
       "to use the message base of this machine over the net)"
  ))
  (set #instrexxdos
  (cat "Installing rexxdossupport.library"
  ))
  (set #instflush
  (cat "Installing flush.library"
  ))
  (set #instumslib
  (cat "Installing ums.library"
  ))
  (set #instumslib10
  (cat "Installing ums.library ('010 version)"
  ))
  (set #instserver
  (cat "Installing UMS Server"
  ))
  (set #instserver10
  (cat "Installing UMS Server ('010 version)"
  ))
  (set #servicedrawer
  (cat "In which drawer should ums.service be placed?"
  ))
  (set #instservice
  (cat "Installing UMS Service"
  ))
  (set #instumsd
  (cat "Installing UMS Deamon"
  ))
  (set #activateservice
  (cat "Please activate \"ums.service\" using Envoy's \"Services Manager\""
  ))
  (set #updaterexxx
  (cat "Updating ARexx Scripts"
  ))
  (set #updatescripts
  (cat "Updating AmigaDOS Scripts"
  ))
  (set #mbdest
  (cat "In which disk or drawer should the message base be placed?\n"
       "(you get better performance increase if you place the "
       "message base on a seperate partition with a larger block "
       "size!)"
  ))
  (set #globconf
  (cat "Now configuring global variables"
  ))
  (set #fullname
  (cat "Please enter your full name"
  ))
  (set #short
  (cat "Please enter your short (nick) name"
  ))
  (set #password
  (cat "Please enter your password"
  ))
  (set #envexists
  (cat "ENV:UMSSERVER ist already set. Overwrite this environment variable?"
  ))
  (set #whichserver
  (cat "Please enter the name of the UMS server you want to use.\n\n"
       "This name consists of two parts. The part following "
       "the \"@\" sign is the name of the machine the server "
       "is running on. The other part is the name of the "
       "message base on this server. Use \"default\" in order "
       "to get the default message base of this server."
  ))
  (set #confexists
  (cat "ums.config already exists in your message base. Overwrite "
       "this configuration file?"
  ))
  (set #instpaths
  (cat "Installing Paths for UMS (binaries/scripts)"
  ))
  (set #uniquename
  (cat "Please enter a unique name (domain address) for your computer\n\n"

       "For RFC-Systems it's easy: just use your fully qualified domain "
       "name\n\n"

       "FTN Systems must convert their fido address to RFC style (eg. "
       "\"2:2471/1216.3\" must be converted to "
       "\"p3.f1216.n2471.z2.fidonet.org\"\n\n"

       "It's VERY important that you enter a correct string!"
  ))
  (set #envalreadyset
  (cat "ENV:UMSMB.default ist already set. Overwrite this environment "
       "variable?"
  ))
  (set #appenddb
  (cat "In order to allow UMS to work with AmiTCP the files "
       "\"AmiTCP:db/services\" and \"AmiTCP:db/inetd.config\" must be "
       "extended. Should this be done automatically (the old files will "
       "be backupped)?"
  ))
;  (set #
;  (cat
;  ))
))

(transcript #intro)

(complete 0)

(message #info)

(set @default-dest
  (expandpath
    (askdir
      (prompt #dest)
      (help @askdir-help)
      (default (expandpath ""))
    )
  )
)

(set inplace (= (expandpath "") @default-dest))

(if (= inplace 0)
  (
    (copyfiles
      (help @copyfiles-help)
      (prompt #copying)
      (source "")
      (dest @default-dest)
      (all)
      (optional "force" "askuser")
    )
  )
)

(if (<> (substr @default-dest (- (strlen @default-dest) 1) 1) ":")
  (
    (set @default-dest (cat @default-dest "/"))
  )
)


(complete 25)

; -------------------------------------------------------------------------

(set envoy (exists "LIBS:nipc.library"))
(set amitcp (exists "AmiTCP:AmiTCP"))

(if envoy
  (
    (set envoyclient
      (askchoice
        (prompt #envoy)
        (default 0)
        (help @askchoices-help)
        (choices #localmb
                 #remotemb)
      )
    )
    (if (= envoyclient 0)
      (
        (set envoyserver
          (askbool
            (prompt #umsservice)
            (default 0)
            (help @askbool-help)
          )
        )
      )
    )
  )
  (
    (set envoyclient 0)
  )
)

(if amitcp
  (
    (if (= envoy 0)
      (
        (set tcpclient
          (askchoice
            (prompt #amitcp)
            (default 0)
            (help @askchoices-help)
            (choices #localmb
                     #remotemb)
          )
        )
      )
    )
  )
)

(if amitcp
  (
    (if (= tcpclient 0)
      (
        (set tcpserver
          (askbool
            (prompt #umsd)
            (default 0)
            (help @askbool-help)
          )
        )
      )
    )
  )
  (
    (set tcpclient 0)
  )
)

(set client 0)
(if envoyclient
  (
    (set client 1)
  )
)
(if tcpclient
  (
    (set client 1)
  )
)

(complete 50)

; -------------------------------------------------------------------------

(copylib
  (help @copylib-help)
  (prompt #instrexxdos)
  (confirm)
  (source "libs/rexxdossupport.library")
  (dest "LIBS:")
)

(if (= client 0)
  (
    (copylib
      (help @copylib-help)
      (prompt #instflush)
      (confirm)
      (source "libs/flush.library")
      (dest "LIBS:")
    )
  )
)

; (set slowprocessor (= (database "cpu") "68000"))

(set slowprocessor 1)

; (if slowprocessor
;   (
    (copylib
      (help @copylib-help)
      (prompt #instumslib)
      (confirm)
      (source "libs/ums.library")
      (dest "LIBS:")
    )
;   )
;   (
;     (copylib
;       (help @copylib-help)
;       (prompt #instumslib10)
;       (confirm)
;       (source "libs/ums.library.010")
;       (newname "ums.library")
;       (dest "LIBS:")
;     )
;   )
; )

(complete 60)

(if (= client 0)
  (
    (if slowprocessor
      (
        (copylib
          (help @copylib-help)
          (prompt #instserver)
          (confirm)
          (source "l/umsserver")
          (dest "L:")
        )
      )
      (
        (copylib
          (help @copylib-help)
          (prompt #instserver10)
          (confirm)
          (source "l/umsserver.nodebug010")
          (newname "umsserver")
          (dest "L:")
        )
      )
    )
    (if envoyserver
      (
        (set servicepath
          (expandpath
            (askdir
              (prompt #servicedrawer)
              (help @askdir-help)
              (default "SYS:Envoy/Services")
            )
          )
        )
        (copylib
          (help @copylib-help)
          (prompt #instservice)
          (confirm)
          (infos)
          (source "Envoy/services/ums.service")
          (dest servicepath)
        )
        (message #activateservice)
      )
    )
    (if tcpserver
      (copylib
        (help @copylib-help)
        (prompt #instservice)
        (confirm)
        (infos)
        (source "AmiTCP/serv/umsd")
        (dest "AmiTCP:serv/")
      )
    )
    (if (OR tcpserver tcpclient)
      (
        (set appenddb
          (askbool
            (prompt #appenddb)
            (help @askbool-help)
          )
        )
        (if appenddb
          (
            (rename "AmiTCP:db/services" "AmiTCP:db/services.bak")
            (rename "AmiTCP:db/inetd.conf" "AmiTCP:db/inetd.conf.bak")
            (textfile
              (dest "AmiTCP:db/services")
              (include "AmiTCP:db/services.bak")
              (include "AmiTCP/db/services")
            )
            (textfile
              (dest "AmiTCP:db/inetd.conf")
              (include "AmiTCP:db/inetd.conf.bak")
              (include "AmiTCP/db/inetd.conf")
            )
          )
        )
      )
    )
  )
)

(complete 70)

; -------------------------------------------------------------------------

(if (= envoyclient 0)
  (
    (set writeit 1)

    (if (= (exists "ENV:UMSMB.default") 1)
      (
        (set writeit
          (askbool
            (prompt #envalreadyset)
            (help @askbool-help)
          )
        )
      )
    )

    (if writeit
      (
        (makedir (tackon @default-dest "mb"))
        (set mbpath (tackon @default-dest "mb/"))

        (set mbpath
          (expandpath
            (askdir
              (prompt #mbdest)
              (help @askdir-help)
              (default mbpath)
            )
          )
        )
        (textfile
          (dest "ENV:UMSMB.default")
          (append mbpath)
        )

        (textfile
          (dest "ENVARC:UMSMB.default")
          (append mbpath)
        )
      )
      (
        (set mbpath (getenv "UMSMB.default"))
      )
    )
  )
)

(complete 80)

; -------------------------------------------------------------------------

(set serverdefault "")

(if (= envoyclient 1)
  (
    (set serverdefault "default@envoyserver")
  )
)

(if (= tcpclient 1)
  (
    (set tcpdefault "host.do.main:ums")
  )
)

(if (<> serverdefault "")
  (
    (set writeit 1)
    (if (= (exists "ENV:UMSSERVER") 1)
      (
        (set writeit
          (askbool
            (prompt #envexists)
            (help @askbool-help)
          )
        )
      )
    )
    (if writeit
      (
        (set umsserver
          (askstring
            (prompt #whichserver)
            (default serverdefault)
            (help @askstring-help)
          )
        )
        (textfile
          (dest "ENV:UMSSERVER")
          (append umsserver)
        )
        (textfile
          (dest "ENVARC:UMSSERVER")
          (append umsserver)
        )
      )
    )
  )
)

(complete 90)

; -------------------------------------------------------------------------

(if (= client 0)
  (
    (set writeit 1)

    (if (= (exists (tackon mbpath "ums.config")) 1)
      (
        (set writeit
          (askbool
            (prompt #confexists)
            (help @askbool-help)
          )
        )
      )
    )
  )
  (
    (set writeit 0)
  )
)

(if writeit
  (
    (message #globconf)

    (set username
      (askstring
        (prompt #fullname)
        (help @askstring-help)
        (default "Joe User")
      )
    )

    (set shortusername
      (askstring
        (prompt #shortname)
        (help @askstring-help)
        (default "joe")
      )
    )

    (set password
      (askstring
        (prompt #password)
        (help @askstring-help)
        (default "joshua")
      )
    )

    (set domainaddress
      (askstring
        (prompt #uniquename)
        (help @askstring-help)
        (default "mycomputer.foo.bar")
      )
    )
    (textfile
      (dest (tackon mbpath "ums.config"))
      (append (cat "( SysName \"" domainaddress "\" )\n\n"))
      (append (cat "( LogFile \"" (tackon @default-dest "ums.log") "\" )\n\n"))
      (append "( Sysop\n")
      (append (cat "  ( Name \"" username "\" )\n"))
      (append (cat "  ( Alias\n      \"" shortusername "\"\n"))
      (append "      \"sysop\"\n")
      (append "      \"root\"\n")
      (append "      \"postmaster\"\n  )\n")
      (append (cat "  ( Password \"" password "\" )\n"))
      (append "  ( ReadAccess \"#?\" )\n")
      (append "  ( WriteAccess \"#?\" )\n")
      (append "  ( NetAccess \"#?\" )\n")
      (append ")\n")
    )
  )
)

(startup "UMS"
  (prompt #instpaths)
  (help @startup-help)
  (set path (cat "\""     (expandpath (tackon @default-dest "bin")) "\"" ))
  (set path (cat path " \"" (expandpath (tackon @default-dest "rexx")) "\"" ))
  (command (cat "Path " path " ADD\n"))
)

(complete 100)

(exit)