home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 4: The Falcon Archive / nf_archive_four_v1.0.iso / ARCHIVE / WORK / MSX / MEGPL116.ZIP / MGPL-116 / AMIGA / VIDEO.S < prev   
Text File  |  1995-08-23  |  17KB  |  636 lines
  1. ***********************************************************************
  2. ***********                                        ***********
  3. ***********                                        ***********
  4. ***********        Initialisations Video Falcon030        ***********
  5. ***********                                        ***********
  6. ***********                                        ***********
  7. ***********          Par Simplet / FATAL DESIGN            ***********
  8. ***********                                        ***********
  9. ***********************************************************************
  10.  
  11.         Section    TEXT
  12.  
  13. Save_Video
  14.         lea.l    Old_Video,a0            ; Espace de sauvegarde
  15.  
  16.         move.b    $ffff8201.w,(a0)+        ; Vidéo (poids fort)
  17.         move.b    $ffff8203.w,(a0)+        ; Vidéo (poids moyen)
  18.         move.b    $ffff820d.w,(a0)+        ; Vidéo (poids faible)
  19.         move.b    $ffff820a.w,(a0)+        ; Synchronisation vidéo
  20.         move.w    $ffff820e.w,(a0)+        ; Offset pour prochaine ligne
  21.         move.w    $ffff8210.w,(a0)+        ; Largeur d'une ligne en mots
  22.         move.b    $ffff8260.w,(a0)+        ; Résolution ST
  23.         move.b    $ffff8265.w,(a0)+        ; Décalage Pixel
  24.         move.w    $ffff8266.w,(a0)+        ; Résolution Falcon
  25.         move.w    $ffff8282.w,(a0)+        ; HHT-Synchro
  26.         move.w    $ffff8284.w,(a0)+        ; Fin Bordure Droite
  27.         move.w    $ffff8286.w,(a0)+        ; Début Bordure Gauche
  28.         move.w    $ffff8288.w,(a0)+        ; Début Ligne
  29.         move.w    $ffff828a.w,(a0)+        ; Fin Ligne
  30.         move.w    $ffff828c.w,(a0)+        ; HSS-Synchro
  31.         move.w    $ffff828e.w,(a0)+        ; HFS ???
  32.         move.w    $ffff8290.w,(a0)+        ; HEE ???
  33.         move.w    $ffff82a2.w,(a0)+        ; VFT-Synchro
  34.         move.w    $ffff82a4.w,(a0)+        ; Fin Bordure Basse
  35.         move.w    $ffff82a6.w,(a0)+        ; Début Bordure Haute
  36.         move.w    $ffff82a8.w,(a0)+        ; Début Image
  37.         move.w    $ffff82aa.w,(a0)+        ; Fin Image
  38.         move.w    $ffff82ac.w,(a0)+        ; VSS-Synchro
  39.         move.w    $ffff82c0.w,(a0)+        ; Reconnaissance ST/Falcon
  40.         move.w    $ffff82c2.w,(a0)+        ; Informations résolution
  41.  
  42.         lea.l    $ffff8240.w,a1            ; Palette ST
  43.         moveq.l    #16/2-1,d0            ; 8 longs...
  44. Save_ST_Palette
  45.         move.l    (a1)+,(a0)+            ; Sauve 2 couleurs
  46.         dbra        d0,Save_ST_Palette        ; Boucle les 16 mots !
  47.  
  48.         lea.l    $ffff9800.w,a1            ; Palette Falcon
  49.         move.w    #256-1,d0                ; 256 longs...
  50. Save_Falcon_Palette
  51.         move.l    (a1)+,(a0)+            ; Sauve 1 couleur
  52.         dbra        d0,Save_Falcon_Palette    ; Boucle les 256 longs !
  53.         rts
  54.  
  55. * Attend en a0 le tableau des infos Video
  56. * en a1, tableau des adresses ecran
  57. * en a2, buffer pour les ecrans
  58. * et en d0, le nombre d'écrans à réserver -1
  59.  
  60. Init_Video
  61.         move.l    (a0)+,d2                ; Taille d'un écran
  62.         tst.w    d0
  63.         bmi.s    No_Reserv_Screen
  64.         move.l    a1,a3
  65.  
  66. Init_Screen_Adr
  67.         move.l    a2,d7                ; Adresse écran
  68.         addi.l    #256,d7                ; + 256
  69.         clr.b    d7                    ; Multiple de 256
  70.         move.l    d7,(a1)+                ; Adresse sauvée !
  71.         adda.l    d2,a2                ; Prochain écran
  72.         dbra        d0,Init_Screen_Adr        ; Boucle tous les écrans
  73.  
  74.         move.l    (a3),d0                ; Nouvelle
  75.         lsr.w    #8,d0                ; Adresse
  76.         move.l    d0,$ffff8200.w            ; Ecran
  77.  
  78. No_Reserv_Screen
  79.         move.b    #2,$ffff820a.w            ; Horloge Interne
  80.         clr.b    $ffff8265.w            ; Décalage Pixel Nul
  81.  
  82.         move.w    (a0)+,$ffff820e.w        ; Offset pour prochaine ligne nul
  83.         move.w    (a0)+,$ffff8210.w        ; Largeur d'une ligne en mots
  84.  
  85.         move.w    (a0)+,d0                ; Résolution ST
  86.         move.w    (a0)+,d1                ; Résolution Falcon
  87.  
  88.         move.w    d1,$ffff8266.w            ; Fixe Résolution Falcon
  89.  
  90.         tst.w    (a0)+                ; Résolution Falcon ?
  91.         beq.s    No_ST_Rez                ; Si oui, saut !
  92.  
  93.         move.b    d0,$ffff8260.w            ; Fixe Résolution ST
  94.         move.w    -8(a0),$ffff8210.w        ; Largeur d'une ligne en mots
  95.  
  96. No_ST_Rez    btst.b    #7,$ffff8006.w            ; Ecran VGA ?
  97.         beq.s    No_VGA                ; Si non, saut...
  98.  
  99.         adda.w    #16*2,a0
  100.  
  101. No_VGA    move.w    (a0)+,$ffff8282.w        ; HHT-Synchro
  102.         move.w    (a0)+,$ffff8284.w        ; Fin Bordure Droite
  103.         move.w    (a0)+,$ffff8286.w        ; Début Bordure Gauche
  104.         move.w    (a0)+,$ffff8288.w        ; Début Ligne
  105.         move.w    (a0)+,$ffff828a.w        ; Fin Ligne
  106.         move.w    (a0)+,$ffff828c.w        ; HSS-Synchro
  107.         move.w    (a0)+,$ffff828e.w        ; HFS ???
  108.         move.w    (a0)+,$ffff8290.w        ; HEE ???
  109.         move.w    (a0)+,$ffff82a2.w        ; VFT-Synchro
  110.         move.w    (a0)+,$ffff82a4.w        ; Fin Bordure Basse
  111.         move.w    (a0)+,$ffff82a6.w        ; Début Bordure Haute
  112.         move.w    (a0)+,$ffff82a8.w        ; Début Image
  113.         move.w    (a0)+,$ffff82aa.w        ; Fin Image
  114.         move.w    (a0)+,$ffff82ac.w        ; VSS-Synchro
  115.         move.w    (a0)+,$ffff82c0.w        ; Reconnaissance ST/Falcon
  116.         move.w    (a0),$ffff82c2.w        ; Informations résolution
  117.         rts
  118.  
  119.  
  120. Init_Falcon_Palette
  121.         moveq.l    #0,d0                ; d0 nul
  122.         lea.l    $ffff9800.w,a0            ; Palette Falcon
  123.         move.w    #256-1,d1                ; 256 longs
  124. Init_FalconPalette
  125.         move.l    d0,(a0)+                ; 1 couleur noire
  126.         dbra        d1,Init_FalconPalette    ; Boucle les 256 longs !
  127.         rts    
  128.  
  129.  
  130. Init_ST_Palette
  131.         moveq.l    #0,d0                ; d0 nul
  132.         lea.l    $ffff8240.w,a0            ; Palette ST
  133.         moveq.l    #16/2-1,d1            ; 8 longs
  134. Init_STPalette
  135.         move.l    d0,(a0)+                ; 2 couleurs noires
  136.         dbra        d1,Init_STPalette        ; Boucle les 16 mots !
  137.         rts
  138.  
  139.  
  140. Restore_Video
  141.         lea.l    Old_Video,a0            ; Espace de sauvegarde
  142.  
  143.         move.b    (a0)+,$ffff8201.w        ; Vidéo (poids fort)
  144.         move.b    (a0)+,$ffff8203.w        ; Vidéo (poids moyen)
  145.         move.b    (a0)+,$ffff820d.w        ; Vidéo (poids faible)
  146.         move.b    (a0)+,$ffff820a.w        ; Synchronisation vidéo
  147.         move.w    (a0)+,$ffff820e.w        ; Offset pour prochaine ligne
  148.         move.w    (a0)+,$ffff8210.w        ; Largeur d'une ligne en mots
  149.         move.b    (a0)+,d0                ; Résolution ST
  150.         move.b    (a0)+,$ffff8265.w        ; Décalage Pixel
  151.         move.w    (a0)+,d1                ; Résolution Falcon
  152.  
  153.         move.w    d1,$ffff8266.w            ; Fixe Résolution Falcon
  154.  
  155.         btst.b    #0,28(a0)                ; Résolution Falcon ?
  156.         bne.s    No_STRez                ; Si oui, saut !
  157.  
  158.         move.b    d0,$ffff8260.w            ; Fixe Résolution ST
  159.         move.w    -6(a0),$ffff8210.w        ; Largeur d'une ligne en mots
  160.  
  161. No_STRez    move.w    (a0)+,$ffff8282.w        ; HHT-Synchro
  162.         move.w    (a0)+,$ffff8284.w        ; Fin Bordure Droite
  163.         move.w    (a0)+,$ffff8286.w        ; Début Bordure Gauche
  164.         move.w    (a0)+,$ffff8288.w        ; Début Ligne
  165.         move.w    (a0)+,$ffff828a.w        ; Fin Ligne
  166.         move.w    (a0)+,$ffff828c.w        ; HSS-Synchro
  167.         move.w    (a0)+,$ffff828e.w        ; HFS ???
  168.         move.w    (a0)+,$ffff8290.w        ; HEE ???
  169.         move.w    (a0)+,$ffff82a2.w        ; VFT-Synchro
  170.         move.w    (a0)+,$ffff82a4.w        ; Fin Bordure Basse
  171.         move.w    (a0)+,$ffff82a6.w        ; Début Bordure Haute
  172.         move.w    (a0)+,$ffff82a8.w        ; Début Image
  173.         move.w    (a0)+,$ffff82aa.w        ; Fin Image
  174.         move.w    (a0)+,$ffff82ac.w        ; VSS-Synchro
  175.         move.w    (a0)+,$ffff82c0.w        ; Reconnaissance ST/Falcon
  176.         move.w    (a0)+,$ffff82c2.w        ; Informations résolution
  177.  
  178.  
  179.         lea.l    $ffff8240.w,a1            ; Palette ST
  180.         moveq.l    #16/2-1,d0            ; 8 longs...
  181. Restore_ST_Palette
  182.         move.l    (a0)+,(a1)+            ; Restaure 2 couleurs
  183.         dbra        d0,Restore_ST_Palette    ; Boucle les 16 mots !
  184.  
  185.         lea.l    $ffff9800.w,a1            ; Palette Falcon
  186.         move.w    #256-1,d0                ; 256 longs...
  187. Restore_Falcon_Palette
  188.         move.l    (a0)+,(a1)+            ; Restaure 1 couleur
  189.         dbra        d0,Restore_Falcon_Palette    ; Boucle les 256 longs !
  190.  
  191. Wait_No_Key
  192.         move.b    $fffffc02.w,d0            ; Code clavier
  193.         btst.b    #0,$fffffc00.w            ; Buffer vide ?
  194.         bne.s    Wait_No_Key            ; Sinon,on continue...
  195.  
  196.         move.w    #$2300,sr
  197.         rts
  198.  
  199. ***********************************************************************
  200. ***********                Section DATA                ***********
  201. ***********************************************************************
  202.  
  203.         Section    DATA
  204.  
  205. Videl_320_100_True
  206.         dc.l        320*100*16/8+256                * Général
  207.         dc.w        0,320,0,$100
  208.         dc.w        0                            * Flag Ordre
  209.  
  210.         dc.w        254,203,39,46,143,216,0,0        * RVB
  211.         dc.w        625,613,47,127,527,619
  212.         dc.w        $181,%0001                    * Double Ligne
  213.  
  214. Videl_320_200_4
  215.         dc.l        320*200*2/8+256                * Général
  216.         dc.w        0,40,1,$0
  217.         dc.w        -1                            * Flag Ordre
  218.  
  219.         dc.w        62,48,8,569,18,52,0,0            * RVB
  220.         dc.w        625,613,47,127,527,619
  221.         dc.w        $181,%0000
  222.  
  223.         dc.w        23,18,1,522,9,17,0,0            * VGA 47 Hz
  224.          dc.w        1337,1300,100,315,1115,1333
  225.         dc.w        $186,%0101
  226.  
  227. Videl_320_200_16
  228.         dc.l        320*200*4/8+256                * Général
  229.         dc.w        0,80,0,$0
  230.         dc.w        0                            * Flag Ordre
  231.  
  232.         dc.w        254,203,39,12,109,216,0,0        * RVB
  233.         dc.w        625,613,47,127,527,619
  234.         dc.w        $181,%0000
  235.  
  236.         dc.w        198,141,21,650,107,150,0,0        * VGA 47 Hz
  237.          dc.w        1337,1300,100,315,1115,1333
  238.         dc.w        $186,%0101
  239.  
  240. Videl_320_200_256
  241.         dc.l        320*200+256                    * Général
  242.         dc.w        0,160,0,$10
  243.         dc.w        0                            * Flag Ordre
  244.  
  245.         dc.w        254,203,39,28,125,216,0,0        * RVB
  246.         dc.w        625,613,47,127,527,619
  247.         dc.w        $181,%0000
  248.  
  249.         dc.w        198,141,21,666,123,150,0,0        * VGA 47 Hz
  250.          dc.w        1337,1300,100,315,1115,1333
  251.         dc.w        $186,%0101
  252.  
  253. Videl_320_200_True
  254.         dc.l        320*200*16/8+256                * Général
  255.         dc.w        0,320,0,$100
  256.         dc.w        0                            * Flag Ordre
  257.  
  258.         dc.w        254,203,39,46,143,216,0,0        * RVB
  259.         dc.w        625,613,47,127,527,619
  260.         dc.w        $181,%0000
  261.  
  262.         dc.w        198,150,15,682,139,150,0,0        * VGA 47 Hz
  263.          dc.w        1337,1300,100,315,1115,1333
  264.         dc.w        $186,%0101
  265.  
  266. Videl_320_400_4
  267.         dc.l        320*400*2/8+256                * Général
  268.         dc.w        0,40,1,$0
  269.         dc.w        -1                            * Flag Ordre
  270.  
  271.         dc.w        62,48,8,569,18,52,0,0            * RVB
  272.         dc.w        624,613,47,126,526,619
  273.         dc.w        $181,%0010
  274.  
  275.         dc.w        23,18,1,522,9,17,0,0            * VGA 47 Hz
  276.          dc.w        1337,1300,100,315,1115,1333
  277.         dc.w        $186,%0101
  278.  
  279. Videl_320_400_16
  280.         dc.l        320*400*4/8+256                * Général
  281.         dc.w        0,80,0,$0
  282.         dc.w        0                            * Flag Ordre
  283.  
  284.         dc.w        254,203,39,12,109,216,0,0        * RVB
  285.         dc.w        624,613,47,126,526,619
  286.         dc.w        $181,%0010
  287.  
  288.         dc.w        198,141,21,650,107,150,0,0        * VGA 47 Hz
  289.          dc.w        1337,1300,100,315,1115,1333
  290.         dc.w        $186,%0101
  291.  
  292. Videl_320_400_256
  293.         dc.l        320*400+256                    * Général
  294.         dc.w        0,160,0,$10
  295.         dc.w        0                            * Flag Ordre
  296.  
  297.         dc.w        254,203,39,28,125,216,0,0        * RVB
  298.         dc.w        624,613,47,126,526,619
  299.         dc.w        $181,%0010
  300.  
  301.         dc.w        198,141,21,666,123,150,0,0        * VGA 47 Hz
  302.          dc.w        1337,1300,100,315,1115,1333
  303.         dc.w        $186,%0101
  304.  
  305. Videl_320_400_True
  306.         dc.l        320*200*16/8+256                * Général
  307.         dc.w        0,320,0,$100
  308.         dc.w        0                            * Flag Ordre
  309.  
  310.         dc.w        254,203,39,46,143,216,0,0        * RVB
  311.         dc.w        624,613,47,126,526,619
  312.         dc.w        $181,%0010
  313.  
  314.         dc.w        198,150,15,682,139,150,0,0        * VGA 47 Hz
  315.          dc.w        1337,1300,100,315,1115,1333
  316.         dc.w        $186,%0101
  317.  
  318. Videl_640_200_2
  319.         dc.l        640*200/8+256                    * Général
  320.         dc.w        0,40,0,$400
  321.         dc.w        0                            * Flag Ordre
  322.  
  323.         dc.w        510,409,80,1007,160,434,0,0        * RVB
  324.         dc.w        625,613,47,127,527,619
  325.         dc.w        $181,%0100
  326.  
  327.         dc.w        198,141,21,627,80,150,0,0        * VGA 47 Hz
  328.          dc.w        1337,1300,100,315,1115,1333
  329.         dc.w        $186,%1001
  330.  
  331. Videl_640_200_4
  332.         dc.l        640*200*2/8+256                * Général
  333.         dc.w        0,80,1,$0
  334.         dc.w        -1                            * Flag Ordre
  335.  
  336.         dc.w        62,48,8,2,32,52,0,0                * RVB
  337.         dc.w        625,613,47,127,527,619
  338.         dc.w        $181,%0100
  339.  
  340.         dc.w        23,18,1,526,13,17,0,0            * VGA 47 Hz
  341.          dc.w        1337,1300,100,315,1115,1333
  342.         dc.w        $186,%1001
  343.  
  344. Videl_640_200_16
  345.         dc.l        640*200*4/8+256                * Général
  346.         dc.w        0,160,0,$0
  347.         dc.w        0                            * Flag Ordre
  348.  
  349.         dc.w        510,409,80,77,254,434,0,0        * RVB
  350.         dc.w        625,613,47,127,527,619
  351.         dc.w        $181,%0100
  352.  
  353.         dc.w        198,141,21,675,124,150,0,0        * VGA 47 Hz
  354.          dc.w        1337,1300,100,315,1115,1333
  355.         dc.w        $186,%1001
  356.  
  357. Videl_640_200_256
  358.         dc.l        640*200+256                    * Général
  359.         dc.w        0,320,0,$10
  360.         dc.w        0                            * Flag Ordre
  361.  
  362.         dc.w        510,409,80,93,270,434,0,0        * RVB
  363.         dc.w        625,613,47,127,527,619
  364.         dc.w        $181,%0100
  365.  
  366.         dc.w        198,141,21,683,132,150,0,0        * VGA 47 Hz
  367.          dc.w        1337,1300,100,315,1115,1333
  368.         dc.w        $186,%1001
  369.  
  370. Videl_640_200_True
  371.         dc.l        640*200*16/8+256                * Général
  372.         dc.w        0,640,0,$100
  373.         dc.w        0                            * Flag Ordre
  374.  
  375.         dc.w        510,409,80,113,290,434,0,0        * RVB
  376.         dc.w        625,613,47,127,527,619
  377.         dc.w        $181,%0100
  378.  
  379. Videl_640_400_2
  380.         dc.l        640*400/8+256                    * Général
  381.         dc.w        0,40,0,$400
  382.         dc.w        0                            * Flag Ordre
  383.  
  384.         dc.w        510,409,80,1007,160,434,0,0        * RVB
  385.         dc.w        624,613,47,126,526,619
  386.         dc.w        $181,%0110
  387.  
  388.         dc.w        198,141,21,627,80,150,0,0        * VGA 47 Hz
  389.          dc.w        1337,1300,100,315,1115,1333
  390.         dc.w        $186,%1001
  391.  
  392. Videl_640_400_4
  393.         dc.l        640*400*2/8+256                * Général
  394.         dc.w        0,80,1,$0
  395.         dc.w        -1                            * Flag Ordre
  396.  
  397.         dc.w        62,48,8,2,32,52,0,0                * RVB
  398.         dc.w        624,613,47,126,526,619
  399.         dc.w        $181,%0110
  400.  
  401.         dc.w        23,18,1,526,13,17,0,0            * VGA 47 Hz
  402.          dc.w        1337,1300,100,315,1115,1333
  403.         dc.w        $186,%1001
  404.  
  405. Videl_640_400_16
  406.         dc.l        640*400*4/8+256                * Général
  407.         dc.w        0,160,0,$0
  408.         dc.w        0                            * Flag Ordre
  409.  
  410.         dc.w        510,409,80,77,254,434,0,0        * RVB
  411.         dc.w        624,613,47,126,526,619
  412.         dc.w        $181,%0110
  413.  
  414.         dc.w        198,141,21,675,124,150,0,0        * VGA 47 Hz
  415.          dc.w        1337,1300,100,315,1115,1333
  416.         dc.w        $186,%1001
  417.  
  418. Videl_640_400_256
  419.         dc.l        640*400+256                    * Général
  420.         dc.w        0,320,0,$10
  421.         dc.w        0                            * Flag Ordre
  422.  
  423.         dc.w        510,409,80,93,270,434,0,0        * RVB
  424.         dc.w        624,613,47,126,526,619
  425.         dc.w        $181,%0110
  426.  
  427.         dc.w        198,141,21,683,132,150,0,0        * VGA 47 Hz
  428.          dc.w        1337,1300,100,315,1115,1333
  429.         dc.w        $186,%1001
  430.  
  431. Videl_640_400_True
  432.         dc.l        640*400*16/8+256                * Général
  433.         dc.w        0,640,0,$100
  434.         dc.w        0                            * Flag Ordre
  435.  
  436.         dc.w        510,409,80,113,290,434,0,0        * RVB
  437.         dc.w        624,613,47,126,526,619
  438.         dc.w        $181,%0110
  439.  
  440. ; Modes Overscan seulement en RVB
  441.  
  442. Videl_384_128_True
  443.         dc.l        384*128*16/8+256                * Général
  444.         dc.w        0,384,0,$100
  445.         dc.w        0                            * Flag Ordre
  446.  
  447.         dc.w        254,203,39,14,175,216,0,0        * RVB
  448.         dc.w        625,613,47,71,583,619
  449.         dc.w        $181,%0001                    * Double Ligne
  450.  
  451. Videl_384_256_4
  452.         dc.l        384*256*2/8+256                * Général
  453.         dc.w        0,48,1,$0
  454.         dc.w        -1                            * Flag Ordre
  455.  
  456.         dc.w        62,48,8,562,27,52,0,0            * RVB
  457.         dc.w        625,613,47,71,583,619
  458.         dc.w        $181,%0000
  459.  
  460. Videl_384_256_16
  461.         dc.l        384*256*4/8+256                * Général
  462.         dc.w        0,96,0,$0
  463.         dc.w        0                            * Flag Ordre
  464.  
  465.         dc.w        254,203,39,748,141,216,0,0        * RVB
  466.         dc.w        625,613,47,71,583,619
  467.         dc.w        $181,%0000
  468.  
  469. Videl_384_256_256
  470.         dc.l        384*256+256                    * Général
  471.         dc.w        0,192,0,$10
  472.         dc.w        0                            * Flag Ordre
  473.  
  474.         dc.w        254,203,39,764,157,216,0,0        * RVB
  475.         dc.w        625,613,47,71,583,619
  476.         dc.w        $181,%0000
  477.  
  478. Videl_768_256_2
  479.         dc.l        768*256/8+256                    * Général
  480.         dc.w        0,48,0,$400
  481.         dc.w        0                            * Flag Ordre
  482.  
  483.         dc.w        510,409,80,943,224,434,0,0        * RVB
  484.         dc.w        625,613,47,71,583,619
  485.         dc.w        $181,%0100
  486.  
  487. Videl_768_256_4
  488.         dc.l        768*256*2/8+256                * Général
  489.         dc.w        0,96,1,$0
  490.         dc.w        -1                            * Flag Ordre
  491.  
  492.         dc.w        62,48,8,567,32,52,0,0            * RVB
  493.         dc.w        625,613,47,71,583,619
  494.         dc.w        $181,%0100
  495.  
  496. Videl_768_256_16
  497.         dc.l        768*256*4/8+256                * Général
  498.         dc.w        0,192,0,$0
  499.         dc.w        0                            * Flag Ordre
  500.  
  501.         dc.w        510,409,80,13,318,434,0,0        * RVB
  502.         dc.w        625,613,47,71,583,619
  503.         dc.w        $181,%0100
  504.  
  505. Videl_768_256_256
  506.         dc.l        768*256+256                    * Général
  507.         dc.w        0,384,0,$10
  508.         dc.w        0                            * Flag Ordre
  509.  
  510.         dc.w        510,409,80,29,334,434,0,0        * RVB
  511.         dc.w        625,613,47,71,583,619
  512.         dc.w        $181,%0100
  513.  
  514. Videl_768_240_True
  515.         dc.l        768*240*16/8+256                * Général
  516.         dc.w        0,768,0,$100
  517.         dc.w        0                            * Flag Ordre
  518.  
  519.         dc.w        510,409,80,49,354,434,0,0        * RVB
  520.         dc.w        625,613,47,87,567,619
  521.         dc.w        $181,%0100
  522.  
  523. Videl_768_256_True
  524.         dc.l        768*256*16/8+256                * Général
  525.         dc.w        0,768,0,$100
  526.         dc.w        0                            * Flag Ordre
  527.  
  528.         dc.w        510,409,80,49,354,434,0,0        * RVB
  529.         dc.w        625,613,47,71,583,619
  530.         dc.w        $181,%0100
  531.  
  532. Videl_768_480_True
  533.         dc.l        768*480*16/8+256                * Général
  534.         dc.w        0,768,0,$100
  535.         dc.w        0                            * Flag Ordre
  536.  
  537.         dc.w        510,409,80,49,354,434,0,0        * RVB
  538.         dc.w        624,613,47,86,566,619
  539.         dc.w        $181,%0110
  540.  
  541. Videl_768_512_True
  542.         dc.l        768*512*16/8+256                * Général
  543.         dc.w        0,768,0,$100
  544.         dc.w        0                            * Flag Ordre
  545.  
  546.         dc.w        510,409,80,49,354,434,0,0        * RVB
  547.         dc.w        624,613,47,70,582,619
  548.         dc.w        $181,%0110
  549.  
  550. ; Modes Overscan accessibles aussi en VGA
  551.  
  552. Videl_384_240_True
  553.         dc.l        384*240*16/8+256                * Général
  554.         dc.w        0,384,0,$100
  555.         dc.w        0                            * Flag Ordre
  556.  
  557.         dc.w        254,203,39,14,175,216,0,0        * RVB
  558.         dc.w        625,613,47,87,567,619
  559.         dc.w        $181,%0000
  560.  
  561.         dc.w        240,160,0,714,151,200,0,0        * VGA 52.11 Hz
  562.          dc.w        1207,1300,0,163,1123,1203
  563.         dc.w        $186,%0101
  564.  
  565. Videl_384_256_True
  566.         dc.l        384*256*16/8+256                * Général
  567.         dc.w        0,384,0,$100
  568.         dc.w        0                            * Flag Ordre
  569.  
  570.         dc.w        254,203,39,14,175,216,0,0        * RVB
  571.         dc.w        625,613,47,71,583,619
  572.         dc.w        $181,%0000
  573.  
  574.         dc.w        240,160,0,714,151,200,0,0        * VGA 52.11 Hz
  575.          dc.w        1207,1300,0,131,1155,1203
  576.         dc.w        $186,%0101
  577.  
  578. Videl_384_480_True
  579.         dc.l        384*480*16/8+256                * Général
  580.         dc.w        0,384,0,$100
  581.         dc.w        0                            * Flag Ordre
  582.  
  583.         dc.w        254,203,39,14,175,216,0,0        * RVB
  584.         dc.w        625,613,47,86,566,619
  585.         dc.w        $181,%0010
  586.  
  587.         dc.w        240,160,0,714,151,200,0,0        * VGA 50.2 Hz
  588.          dc.w        1257,1300,0,163,1123,1253
  589.         dc.w        $186,%0100
  590.  
  591. Videl_384_512_True
  592.         dc.l        384*512*16/8+256                * Général
  593.         dc.w        0,384,0,$100
  594.         dc.w        0                            * Flag Ordre
  595.  
  596.         dc.w        254,203,39,14,175,216,0,0        * RVB
  597.         dc.w        625,613,47,70,582,619
  598.         dc.w        $181,%0010
  599.  
  600.         dc.w        240,160,0,714,151,200,0,0        * VGA 50.2 Hz
  601.          dc.w        1257,1300,0,131,1155,1253
  602.         dc.w        $186,%0100
  603.  
  604. ***********************************************************************
  605. ***********                Section BSS                ***********
  606. ***********************************************************************
  607.  
  608.             Section    BSS
  609.  
  610. Old_Video        ds.b        3            ; Adresse Mémoire Vidéo
  611.             ds.b        1            ; Synchronisation vidéo
  612.             ds.w        1            ; Offset pour prochaine ligne
  613.             ds.w        1            ; Largeur d'une ligne en mots
  614.             ds.b        1            ; Résolution ST
  615.             ds.b        1            ; Décalage Pixel
  616.             ds.w        1            ; Résolution Falcon
  617.             ds.w        1            ; HHT-Synchro
  618.             ds.w        1            ; Fin Bordure Droite
  619.             ds.w        1            ; Début Bordure Gauche
  620.             ds.w        1            ; Début Ligne
  621.             ds.w        1            ; Fin Ligne
  622.             ds.w        1            ; HSS-Synchro
  623.             ds.w        1            ; HFS ???
  624.             ds.w        1            ; HEE ???
  625.             ds.w        1            ; VFT-Synchro
  626.             ds.w        1            ; Fin Bordure Basse
  627.             ds.w        1            ; Début Bordure Haute
  628.             ds.w        1            ; Début Image
  629.             ds.w        1            ; Fin Image
  630.             ds.w        1            ; VSS-Synchro
  631.             ds.w        1            ; Reconnaissance ST/Falcon
  632.             ds.w        1            ; Informations résolution
  633.  
  634.             ds.w        16            ; Palette ST
  635.             ds.l        256            ; Palette Falcon
  636.