home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 10: Diskmags / nf_archive_10.iso / MAGS / DNTPAPER / DNT_04.MSA / ARCHIVES.DNT / SOURCES.ZIP / SAMPLING / SON_STF.S < prev    next >
Text File  |  1992-12-07  |  10KB  |  251 lines
  1. ;Routine de restitution 8 bits pour STF.
  2. ;(C)oderight NulloS//DNT 1992
  3. ;
  4. ;
  5. ; Pour restituer le son, il faut utiliser la même fréquence que
  6. ;celle d'échantillonnage, sinon le son va être déformé.
  7. ; Par exemple,si vous utilisez un son digitalisé a 12,5Khz, il faut
  8. ;le restituer à une fréquence de 12,5Khz.
  9. ; Pour tenir cette fréquence précise, il y a deux manières de procéder:
  10. ;
  11. ;    o Faire une routine qui inclu une boucle d'attente de longueur
  12. ;    variable selon la fréquence voulue.
  13. ;    o Se servir d'un timer du MFP réglé à 12,5Khz.
  14. ;
  15. ; On va se servir ici de la 2ème méthode, à savoir la programmation du
  16. ;MFP pour utiliser un timer à 12,5Khz. Si vous avez des problèmes avec les
  17. ;interruptions, jetez un coup d'oeil à ce source, ça pourra peut-être
  18. ;vous aider.
  19. ;
  20. ; Les timers du MFP ont une fréquence de travail de 2,4576 Mhz. Celle
  21. ;ci est divisée à volonté pour obtenir la fréquence que l'on désire.
  22. ;Les diviseurs principaux sont d1=4,10,16,50,64,100 ou 200. Un deuxième
  23. ;diviseur est disponible, et possède un valeur d2=1..255 La fréquence
  24. ;obtenue est 2457600/(d1*d2)
  25. ; Pour avoir du 12,5Khz, on utilise d1=4 et d2=49 ce qui donne du 12538Hz
  26. ;à peu près. Là est la limite du MFP: on ne peut pas choisir au hertz
  27. ;près.Mais comme les logiciels de digitalisation se servent aussi d'un
  28. ;timer, les fréquences sont les mêmes entre digit et restitution.
  29. ;
  30. ; Si vous changez les valeurs du timer, la fréquence de restitution
  31. ;change, ce qui modifie la hauteur du son. Malheureusement, cela
  32. ;déforme le rendu (un son "naturel" comporte un élément appelé
  33. ;timbre qui est invariable, alors qu'un changement de fréquence le
  34. ;modifie.Par exemple, quand on digitalise une voix qui chante le LA
  35. ;d'un octave, et que l'on double sa fréquence de restitution, on
  36. ;obtient le LA de l'octave supérieur, mais le rendu est très différent
  37. ;de la même voix chantant vraiment un LA de l'octave supérieur...Ca
  38. ;permet d'ailleurs de savoir où et quand les voix des "chanteuses" de
  39. ;house-musique est trafiquée....héhé).
  40. ;
  41. ; Amusez vous bien !..
  42. ; 
  43.  
  44.     include    a:\hard_sys.s
  45.  
  46. Start    move.l    4(sp),a6        ;récupère page de base
  47.     move.l    $c(a6),a0        ;Taille programme
  48.     adda.l    $14(a6),a0        ;   +   données
  49.     adda.l    $1c(a6),a0        ;   +   variables
  50.     lea    256+2048(a0),a0    ;   +   page de base+pile
  51.     move.l    a0,d0        ;
  52.     andi.w    #-2,d0        ;arondir à un nombre pair
  53.     move.l    d0,sp        ;nouvelle pile
  54.     adda.l    a6,sp        ;
  55.     move.l    d0,-(sp)        ;taille à conserver
  56.     move.l    a6,-(sp)        ;à partir de la page de base
  57.     move.l    #$004a0000,-(sp)    ;Mshrink. Rend le reste au
  58.     trap    #1        ;Gemdos.
  59.     lea    12(sp),sp        ;rétablit la pile
  60.     
  61.  
  62.     clr.l    -(sp)        ;passage en superviseur
  63.     move.w    #$20,-(sp)        ;
  64.     trap    #1        ;
  65.     addq.l    #6,sp        ;
  66.     move.l    d0,save_SSP    ;sauve la pile système
  67.     move.b    conterm.w,save_conterm;et les paramètres clavier
  68.     clr.b    conterm.w        ;coupe le bip clavier
  69.  
  70.     bsr    Wait_Kbd        ;attendre le clavier
  71.     move.b    #$12,KBD_data.w    ;couper la souris
  72.     
  73.     bsr    InitYamaha        ;prépare le yamaha pour la digit
  74.     lea    sample,a0        ;adresse de début du sample
  75.     lea    endsample,a1    ;adresse de fin
  76.     lea    bclsample,a2    ;adresse de bouclage
  77.     bsr    InstallDigit    ;et lance la resitution !
  78.     
  79. presskey    move.l    #$000bffff,-(sp)    ;demander l'état shift,control 
  80.     trap    #13        ;et altenrate
  81.     addq.l    #4,sp        ;
  82.     and.w    #7,d0        ;Pressée(s) ?
  83.     beq.s    presskey        ;non, attendre encore
  84.     
  85.     bsr    KillDigit        ;couper la digit
  86.     
  87.     bsr    Wait_Kbd        ;attendre clavier
  88.     move.b    #$8,KBD_data.w    ;reprendre les transferts
  89.                 ;souris
  90.     move.b    save_conterm,conterm.w;et remettre bip clavier
  91.     
  92.     move.l    save_SSP,-(sp)    ;repasse en utilisateur
  93.     move.w    #$20,-(sp)        ;
  94.     trap    #1        ;
  95.     clr.w    (sp)        ;et cassos
  96.     trap    #1        ;
  97.  
  98.  
  99. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  100. ;Routine de base. Elle se charge d'installer la digit dans le timer A
  101. ;(qui n'est pas utilisé par le système, mais pour votre usage personnel
  102. ;vous pouvez aussi vous servir d'un autre, comme le TimerB pour les
  103. ;rasters).Le sample est pointé par A0
  104. ;Je rappelle que la signification des différents bits d'interruption MFP
  105. ;sont:
  106. ;IERA/IMRA/ISRA/IPRA: 7..moniteur monochrome
  107. ;        6..sonnerie RS232
  108. ;        5..Timer A
  109. ;        4..tampon de reception plein (RS232)
  110. ;        3..erreur de reception (RS232)
  111. ;        2..tampon d'emission vide (RS232)
  112. ;        1..erreur d'émission (RS232)
  113. ;        0..Timer B
  114. ;
  115. ;IERB/IMRB/ISRB/IPRB: 7..interruption FDC/DMA
  116. ;        6..interruption clavier
  117. ;        5..Timer C
  118. ;        4..Timer D
  119. ;        3..interruption blitter
  120. ;        2..signal CTS (RS232)
  121. ;        1..detection de porteuse (RS232)
  122. ;        0..gestion Centronics
  123. ;Pour installer une de ces interruptions, il faut l'autoriser dans le
  124. ;bit correspondant de IERA ou IERB en le mettant à 1.Puis la démasquer
  125. ;avec IMRA ou IMRB (en mettant son bit à 1).A la fin de l'interruption,
  126. ;il faut mettre son bit à 0 dans le registre ISRA ou ISRB.
  127. ;Pour un timer, il faut d'abord (avant de l'autoriser) mettre son CR
  128. ;(Control Register) à 0,choisir le diviseur d2 à mettre dans TADR,TBDR
  129. ;TCDR ou TDDR (selon le timer), et mettre le diviseur d1 dans le CR
  130. ;du timer (TACR,TBCR ou TCDCR).
  131. ;On ne met pas directement d1, mais un équivalent:
  132. ;    o 1 pour choisir d1=4
  133. ;    o 2 ""     ""    d1=10
  134. ;    o 3 ""     ""    d1=16
  135. ;    o 4 ""     ""    d1=50
  136. ;          o 5 ""     ""    d1=64
  137. ;    o 6 ""     ""    d1=100
  138. ;    o 7 ""     ""    d1=200
  139. ;
  140. InstallDigit
  141.     move.l    a0,-(sp)
  142.     movem.l    a0-a2,TA_next    ;données de la digit
  143.  
  144.     move.l    #TA_replay,V_TA.w    ;installe notre routine TimerA
  145.     lea    MFP_base.w,a0    ;adresse registres MFP
  146.     clr.b    TACR(a0)        ;CR à 0
  147.     move.b    #49,TADR(a0)    ;diviseur d2=49
  148.     move.b    #1,TACR(a0)    ;diviseur d1=4
  149. ;=Fréquence 2457600/(4*49)=12538 Hz .Maintenant le timer est actif
  150.     ori.b    #%00100000,IERA(a0)    ;autorise le timer A
  151.     ori.b    #%00100000,IMRA(a0)    ;et démasque le.
  152.     movea.l    (sp)+,a0
  153.     rts
  154. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  155. ;Interruption Timer A qui restitue le son.C'est elle qui se charge du
  156. ;plus important: convertir les samples vers le yamaha.
  157. TA_next    dc.l    0
  158. TA_end    dc.l    0
  159. TA_bcl    dc.l    0
  160. TA_replay    movem.l    d0/a0,-(sp)    ;sauve les registres
  161.     moveq    #0,d0        ;annule d0
  162.     movea.l    TA_next(pc),a0    ;adresse prochain échantillon
  163.     move.b    (a0)+,d0        ;récupère le
  164.     cmpa.l    TA_end(pc),a0    ;fin atteinte ?
  165.     blt.s    TA_rsuite        ;non
  166.     movea.l    TA_bcl(pc),a0    ;si, rentre dans la boucle
  167.  
  168. TA_rsuite    move.l    a0,TA_next        ;
  169.     lsl.w    #3,d0        ;*8 pour aller dans la table
  170.     lea    yam_ctrl.w,a0    ;adresse registre yamaha
  171.     move.l    ST_REPLAY+4(pc,d0.w),(a0) ;va chercher l'équivalent du
  172.     move.l    ST_REPLAY(pc,d0.w),d0    ;sample dans la table
  173.     movep.l    d0,0(a0)        ;
  174.  
  175.     move.l    (sp)+,d0        ;
  176.     move.l    (sp)+,a0        ;remet les registres
  177.     andi.b    #%11011111,ISRA+MFP_base.w ;interruption finie
  178.     rte
  179. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  180. __SR_SIGN    equ    1
  181.     include    STREPLAY.S
  182. ;La table est organisé comme suit...les 128 lignes de 8 dc.w contiennent
  183. ;chacune 2 équivalent sample<=>yamaha.
  184. ;Chaque équivalent est comme suit:
  185. ;dc.w    $080x,$090y,$0a0a,$0z0z
  186. ;Les registres du yamaha correspondants aux volumes 0,1 et 2 sont les
  187. ;registres No 8,9 et 10 (donc $08,$09 et $0a).
  188. ;Pour accéder à un registre, il faut écrire son numéro en yam_ctrl=ff8800.w
  189. ;puis écrire sa valeur en yam_write=$ff8802. Ces deux adresses contiennent
  190. ;un octet, donc.Mais les adresses $ff8804 et $ff8806 ont exactement les
  191. ;mêmes rôles (dans l'ordre), ce sont en quelque sorte des images de yam_ctrl
  192. ;et yam_write (en fait, les adresses $ff8800+4*n et $ff8802+4*n sont
  193. ;toutes équivalentes 2 à 2).
  194. ;Bref.Un fois chargé en D0 la valeur 080x090y, on fait un movep.l à l'adresse
  195. ;ffff8800. Or movep écrit les 4 octets du registre D0 aux adresses 0(a0),2(a0)
  196. ;4(a0) et 6(a0), donc $ff8800,$ff8802,$ff8804 et $ff8806...Donc il écrit
  197. ;8 en $ff8800, ce qui sélectionne le volume 0,puis la valeur x en $ff8802,
  198. ;donc dans le registre de volume.Ensuite 9 et y en $ff8804 et $ff8806, ce
  199. ;qui place y dans le volume 1 !!.Deux volumes ont donc été placés.
  200. ;Il reste le troisième. le move.l ST_REPLAY(pc,d0.w),(a0) place la
  201. ;valeur $0a0a0z0z en $ff8800...Les adresses $ff8801 et $ff8803 n'existent
  202. ;pas, mais la manoeuvre ne provoque pas de bombes. Donc on écrit 10=$a
  203. ;en $ff8800 (et $ff8801,mais cela n'a aucun effet), puis z en $ff8802 (et
  204. ;$ff8803).
  205. ;En fin de compte, nous avons placé x,y et z dans les volumes 0,1 et 2
  206. ;selon la valeur de l'échantillon. La somme des volumes 4 bits va ainsi
  207. ;émuler un convertisseur 8 bits, la table permettant de trouver l'équivalent
  208. ;8 bits=>3 fois 4 bits...
  209. ;
  210. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  211. KillDigit    move.l    a0,-(sp)
  212.     lea    MFP_base.w,a0    ;adresse registres MFP
  213.     clr.b    TACR(a0)        ;coupe d'abord le timer A
  214.     clr.b    TADR(a0)        ;annule son diviseur
  215.     andi.b    #%11011111,IERA(a0)    ;interdit le timer A
  216.     andi.b    #%11011111,IMRA(a0)    ;masque le
  217.     move.l    (sp)+,a0        ;le timer est maintenant
  218.     rts            ;totallement enlevé
  219. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  220. Wait_Kbd    btst    #1,KBD_stat.w    ;clavier près à recevoir ?
  221.     beq.s    Wait_Kbd        ;non, attendre
  222.     rts            ;c'est bon !
  223. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  224. ;Coupe les oscillateurs ainsi que les enveloppes du processeur sonore
  225. ;afin de pouvoir se servir du volume de chaque voix comme d'un
  226. ;convertisseur 4 bits.
  227. ;
  228. InitYamaha
  229.     movem.l    d0/a0-a1,-(sp)    ;
  230.     lea    yam_ctrl.w,a1    ;adresse du registre yamaha
  231.     lea    yaminit_data+1(pc),a0    ;données à envoyer
  232.     moveq    #14,d0        ;15 registres
  233. yami_0    move.b    d0,(a1)        ;selectionne le registre No D0
  234.     move.b    (a0)+,2(a1)    ;donne lui la bonne valeur
  235.     dbf    d0,yami_0        ;registre suivant
  236.     movem.l    (sp)+,d0/a0-a1    ;
  237.     rts            ;
  238. yaminit_data
  239.     dc.b    $00,$27,$00,$00,$00,$00,$00,$00
  240.     dc.b    $ff,$00,$ff,$ff,$ff,$ff,$ff,$ff
  241.     
  242.     SECTION    DATA
  243.  
  244. sample    incbin    flut_pan.spl    ;sample à restituer
  245. endsample    equ    *        ;son adresse fin
  246. bclsample    equ    sample+40962    ;bouclage
  247.  
  248.     SECTION    BSS
  249. save_SSP    ds.l    1
  250. save_conterm
  251.     ds.w    1