home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 10: Diskmags / nf_archive_10.iso / MAGS / LEDGERS / LEDG_05.MSA / SOURCE / WILD.S < prev   
Text File  |  1987-04-22  |  3KB  |  122 lines
  1. ***************************************************************************
  2. * FULLSCREEN ROUTINE, CODED BY POWERMAN OF THE WILD BOYS          *
  3. * (C) THE WILD BOYS, 1991                          *
  4. * Credit us if you use this source!  It doesn't work on the STE though.   *
  5. * I know how to do an STE fullscreen (thanks Tony!) but I dont want to    *
  6. * give away this information...tought shit....we're outta here, SEE YA!      *
  7. ***************************************************************************
  8.  
  9.         CLR.L -(A7)
  10.         MOVE.W #32,-(A7)
  11.         TRAP #1
  12.         ADDQ.L #6,A7
  13.  
  14.         CLR.W -(A7)
  15.         PEA $70000
  16.         PEA $70000
  17.         MOVE.W #5,-(A7)
  18.         TRAP #14
  19.         LEA 12(A7),A7
  20.  
  21.         LEA $70000,A6
  22.         MOVE.W #64000/4-1,D7
  23. FILL        MOVE.W #17,-(A7)
  24.         TRAP #14
  25.         ADDQ.L #2,A7
  26.         MOVE.L D0,(A6)+
  27.         MOVE.L D0,(A6)+
  28.         DBF D7,FILL
  29.  
  30.         LEA PALETTE,A0
  31.         LEA $FFFF8240.W,A1
  32.         REPT 8    
  33.         MOVE.L (A0)+,(A1)+    
  34.         ENDR
  35.  
  36.         MOVE.L $70.W,-(A7)
  37.         MOVE.B #$12,$FFFFFC02.W
  38.         MOVE.B $FFFFFA07.W,-(A7)
  39.         MOVE.B $FFFFFA09.W,-(A7)
  40.         CLR.B $FFFFFA07.W
  41.         CLR.B $FFFFFA09.W
  42.         MOVE.L #VBL,$70.W
  43. WAIT_KEY    CMPI.B #57,$FFFFFC02.W
  44.         BNE WAIT_KEY
  45.         MOVE.W #$2700,SR
  46.         MOVE.B (A7)+,$FFFFFA09.W
  47.         MOVE.B (A7)+,$FFFFFA07.W
  48.         MOVE.L (A7)+,$70.W
  49.         MOVE.B #$8,$FFFFFC02.W
  50.         CLR.W $FFFF8246.W
  51.         MOVE.W #$777,$FFFF8240.W
  52.  
  53.         CLR.L -(A7)
  54.         TRAP #1
  55.  
  56. PALETTE        DC.W 0,$700,$770,$070,$077,$007,$777,$740
  57.         DC.W $363,$233,$373,$182,$772,$307,$764,$712
  58.  
  59. * Here comes the overscan bit.......
  60.  
  61. VBL        MOVE.W #$2700,SR
  62.         LEA $FFFF8209.W,A0        Video counter low byte
  63.         MOVEQ.W #16,D1
  64.         MOVE.W #1432-1,D0
  65. .L1        DBF D0,.L1
  66.         CLR.W D0
  67.  
  68.         MOVE.B #0,$FFFF820A.W        open top border
  69.         DCB.W 10,$4E71
  70.         MOVE.B #2,$FFFF820A.W
  71.  
  72. .L2        MOVE.B (A0),D0
  73.         BEQ.S .L2
  74.         SUB.W D0,D1
  75.         LSL.W D1,D1
  76.         DCB.W 90,$4E71
  77.         MOVEQ.W #0,D0            low res/60hz
  78.         MOVEQ.W #2,D1            high res/50hz
  79.         LEA $FFFF820A.W,A0        sync mode
  80.         LEA $FFFF8260.W,A1        shift mode
  81.         MOVE.W #227-1,D2
  82. .L3        MOVE.B D1,(A1)               high/low res for left border
  83.         MOVE.B D0,(A1)
  84.         DCB.W 89,$4E71
  85.         MOVE.B D0,(A0)               60/50hz for right border
  86.         MOVE.B D1,(A0)    
  87.         DCB.W 13,$4E71
  88.         MOVE.B D1,(A1)               high/low res again
  89.         NOP
  90.         MOVE.B D0,(A1)
  91.         DCB.W 10,$4E71
  92.         DBF D2,.L3
  93.         
  94.         MOVE.B D1,(A1)         
  95.         MOVE.B D0,(A1)
  96.         DCB.W 88,$4E71
  97.         MOVE.B D0,(A0)         
  98.         MOVE.B D1,(A0)    
  99.         DCB.W 12,$4E71
  100.  
  101.         MOVE.B D0,(A0)            60hz for lower border
  102.         MOVE.B D1,(A1)    
  103.         NOP
  104.         MOVE.B D0,(A1)
  105.         
  106.         MOVEQ.W #45-1,D2
  107.         DCB.W 9,$4E71
  108.         MOVE.B D1,(A0)            50hz
  109.  
  110. .L4        MOVE.B D1,(A1)          
  111.         MOVE.B D0,(A1)
  112.         DCB.W 89,$4E71
  113.         MOVE.B D0,(A0)          
  114.         MOVE.B D1,(A0)    
  115.         DCB.W 13,$4E71
  116.         MOVE.B D1,(A1)          
  117.         NOP
  118.         MOVE.B D0,(A1)
  119.         DCB.W 10,$4E71
  120.         DBF D2,.L4
  121.         RTE
  122.