home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / filutl / crck44.lbr / CRCK44.AQM / CRCK44.ASM
Assembly Source File  |  1985-06-13  |  18KB  |  887 lines
  1. ; CRCK v4.4         CYCLIC REDUNDANCY CHECK               10/17/82
  2. ;
  3. ;                               by
  4. ;
  5. ;                   KEITH B. PETERSEN, W8SDZ
  6. ;
  7. ;
  8. ; NOTE TO SYSOPS:   SET FILEOK: AND SYSOK: (0103 AND 0104) BOTH TO '0'
  9. ;                   TO PREVENT REMOTE USERS FROM CREATING A FILE OR TO
  10. ;                   FIND RESTRICTED '.SYS' FILES.
  11. ;
  12. ; *     *     *     *     *     *     *     *     *     *     *     *
  13. ;
  14. ; 10/17/82 v4.4  -  Made buffer size automatic to make all transient
  15. ;                   area memory available for the disk file.  Should
  16. ;                   handle the largest Winchester disk directory.
  17. ;                   Modest changes for appearance.         - Irv Hoff
  18. ;
  19. ; 08/17/82 v4.3  -  Removed need for SEQIO.LIB so can now assemble with
  20. ;                   'ASM.COM' or other assemblers.  Used some of Kelly
  21. ;                   Smith' previous work to help in removing SEQIO.LIB.
  22. ;                                                          - Irv Hoff
  23. ;
  24. ; 06/03/82 v4.2B -  Added 2 RCPM aids:  Patch location label 'FILEOK' to
  25. ;                   FALSE (zero) to disallow CRC output file.  Patch
  26. ;                   label 'SYSOK' to FALSE (zero) to treat '.SYS' files
  27. ;                   the same as "NO FILE FOUND" to help hide them from
  28. ;                   those phoning in.  Previous version said 'DONE' with
  29. ;                   no report if '.SYS' or '.$$$' files were skipped. If
  30. ;                   you want to know what is there, patch the label or
  31. ;                   use 'STAT'.  
  32. ;                                 FILEOK = 0103H
  33. ;                                 SYSOK  = 0104H
  34. ;
  35. ; 04/02/82 v4.2A -  Make serially re-entrant to allow ZCPR "GO" again.
  36. ;                   Remove exta CR-LF to get mre CRC's on screen at one
  37. ;                   time.  Use name specified in 2nd FCB with '.CRC'
  38. ;                   extension instead of CRCKLIST.CRC for more operator
  39. ;                   convenience.
  40. ;
  41. ;
  42. ; 10/06/80 v4.2  -  Fix to erase temporary file when output flie is re-
  43. ;                   quested and name not found in directory.
  44. ;
  45. ; 06/27/79 v4.2  -  Written by Keith B. Petersen, W8SDZ
  46. ;
  47. ;
  48. ; *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *
  49. ;
  50. ;
  51. ; CRCK can read any CP/M file then print a CRC (CYCLIC-REDUNDANCY-CHECK)
  52. ; number based on the CCITT standard polynominal:
  53. ;
  54. ;           X^16 + X^15 + X^13 + X^7 + X^4 + X^2 + X + 1
  55. ;
  56. ; Useful for checking accuracy of file transfers. More accurate than a
  57. ; simple checksum.  It will Optionally write an output file to the de-
  58. ; fault drive, listing the CRC's of all files requested.
  59. ;
  60. ;
  61. ; COMMANDS:  CRCK [drive:]<filename.filetype> [F]
  62. ;
  63. ; Examples:
  64. ;            CRCK B:HELLO.ASM    check only HELLO.ASM
  65. ;            CRCK *.ASM          check all .ASM  files
  66. ;            CRCK *.* FILE       check all files, make disk
  67. ;                                  file (FILE.CRC) of results
  68. ;                                  (use any file name desired)
  69. ;
  70. ; *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *
  71. ;
  72. ;
  73. ; DEFINE TRUE AND FALSE
  74. ;
  75. FALSE    EQU    0
  76. TRUE    EQU    NOT FALSE
  77. ;
  78. ;
  79. ; CONDITIONAL ASSEMBLY SWITCHES
  80. ;
  81. STDCPM    EQU    TRUE        ;TRUE FOR STANDARD CP/M
  82. ALTCPM    EQU    FALSE        ;TRUE FOR H8 OR TRS-80
  83. ;
  84. ;
  85. ; SYSTEM EQUATES
  86. ;
  87. BASE    SET    0        ;FOR STANDARD CP/M USERS
  88. ;
  89.     IF    ALTCPM        ;FOR H8 OR TRS-80
  90. BASE    SET    4200H
  91.     ENDIF
  92. ;
  93. ; 
  94. ; BDOS EUATES
  95. ; 
  96. RDCON    EQU    1
  97. WRCON    EQU    2
  98. PRINT    EQU    9
  99. CSTAT    EQU    11
  100. OPEN    EQU    15
  101. CLOSE    EQU    16
  102. SRCHF    EQU    17
  103. SRCHN    EQU    18
  104. DELET    EQU    19
  105. READ    EQU    20
  106. WRITE    EQU    21
  107. MAKE    EQU    22
  108. RENAM    EQU    23
  109. STDMA    EQU    26
  110. ;
  111. ;
  112. ; FILE HANDLING EQUATES
  113. ;
  114. BUF$SIZ    EQU    80H        ;BUFFER SIZE (128 BYTES)
  115. BDOS    EQU    BASE+5
  116. FCB    EQU    BASE+5CH 
  117. FCB2    EQU    BASE+6CH
  118. FCBEXT    EQU    FCB+12
  119. FCBRNO    EQU    FCB+32
  120. TBUF    EQU    BASE+80H    ;TEMPORARY BUFFER (DEFAULT) ADDRESS
  121. ;
  122. ;
  123. ; CONTROL CHARACTERS
  124. ;
  125. CTLC    EQU    'C'-40H        ;CONTROL-C CHARACTER
  126. EOF    EQU    'Z'-40H        ;END-OF-FILE CHARACTER
  127. LF    EQU    'J'-40H        ;LINE FEED CHARACTER
  128. CR    EQU    'M'-40H        ;CARRIAGE RETURN CHARACTER
  129. TAB    EQU    'I'-40H        ;TAB CHARACTER
  130. ;
  131. ;
  132. ; *   *   *   *   *   *   *   *   *   *   *   *  *   *   *   *   *   *
  133. ;
  134. ;
  135.     ORG    BASE+100H
  136. ;
  137. ;
  138. CRCK:    JMP    BEGIN        ;JUMP AROUND PATCH PARAMETERS
  139. ;
  140. ;
  141. FILEOK:    DB    1    ;0 = No, 1 = Yes  TO ALLOW DISK FILE OF RESULTS
  142. SYSOK:    DB    1    ;0 = No, 1 = Yes  TO ALLOW HANDLING '.SYS' FILES
  143. SOM:    DB    CR,LF,'CRCK version 4.4 of 10/17/82'
  144.         DB    CR,LF,'(Ctl-C aborts, Ctl-S pauses)',CR,LF,LF,'$'
  145. ;
  146. ;
  147. ;***********************************************************************
  148. ;                                                                      ;
  149. ;                     PROGRAM STARTS HERE                              ;
  150. ;                                                                      ;
  151. ;***********************************************************************
  152. ;
  153. ;
  154. BEGIN:    LXI    H,0        ;GET STACK...
  155.     DAD    SP        ;POINTER SO WE CAN...
  156.     SHLD    STACK        ;SAVE IT
  157.     LXI    SP,STACK    ;INITIALIZE LOCAL STACK
  158.     MVI    A,1
  159.     STA    MFFLG1        ;INIT 1ST TIME SWITCH
  160.     STA    FOUND        ;NO FILES FOUND YET
  161.     MVI    A,' '        ;NO OUTPUT FILE YET
  162.     STA    FFLAG
  163.     LXI    D,SOM        ;PRINT SIGNON MESSAGE
  164.     MVI    C,PRINT
  165.     CALL    BDOS
  166.     LDA    FCB+1
  167.     CPI    ' '        ;SEE IF NAME THERE
  168.     JNZ    BEGIN2        ;YES, CONTINUE
  169. ;
  170.     CALL    ERXIT        ;PRINT MSG, THEN EXIT
  171. ;
  172.     DB    CR,LF,LF,TAB,'++No file name specified++'
  173.     DB    CR,LF,LF,LF,LF,TAB
  174.     DB    'COMMANDS:  CRCK [drive:]<filename.filetye> FILE'
  175.     DB    CR,LF,LF,LF,TAB
  176.     DB    'Examples:  CRCK B:HELLO.ASM     check only HELLO.ASM'
  177.     DB    CR,LF,TAB,TAB
  178.     DB    '   CRCK *.ASM           check only .ASM files'
  179.     DB    CR,LF,TAB,TAB
  180.     DB    '   CRCK *.* FILE        check all files, make disk'
  181.     DB    CR,LF,TAB,TAB
  182.     DB    '                          file (FILE.CRC) of results'
  183.     DB    CR,LF,TAB,TAB
  184.     DB    '                          (use any file name desired)'
  185.     DB    CR,LF,LF,LF,LF,LF,'$'
  186. ;
  187. ;
  188. ; FIND AMOUNT OF SPACE FOR BUFFER
  189. ;
  190. BEGIN2:    LXI    D,FILEADR    ;START OF BUFFER ADDRESS
  191.     LDA    BDOS+2        ;GET 'BDOS' ADDRESS
  192.     SUI    8        ;PROTECT 'CCP'
  193.     MOV    H,A        ;GET THE MAIN PAGE
  194.     XRA    A        ;CLEAR CARRY IF SET
  195. ;
  196. ;
  197. ; CALCULATE THE DIFFERENCE TO GET SPACE AVAILABLE
  198. ;
  199.     SUB    E
  200.     MOV    L,A
  201. ;
  202.     MOV    A,H
  203.     SBB    D
  204.     MOV    H,A
  205. ;
  206. ;
  207. ; FREE SPACE AVAILABLE NOW IN 'HL', SO STORE FOR BUFFER SIZE
  208. ;
  209.     SHLD    FILELEN        ;STORE BUFFER LENGTH
  210. ;
  211. ;
  212. ; DECLARE 'FCB' FOR  OUTPUT FILE (TEMPORARILY NAMED CRCKLIST.$$$)
  213. ;
  214.     LDA    FILEOK        ;OK TO MAKE A '.CRC' DISK FILE?
  215.     ORA    A
  216.     JZ    AGAIN        ;EXIT, IF NOT
  217. ;
  218.     LDA    FCB2+1        ;GET OPTION
  219.     STA    FFLAG        ;SAVE IT FOR LATER
  220.     CPI    ' '        ;FILE WANTED?
  221.     JZ    AGAIN        ;NO, SKIP FILE INITIALIZATION
  222. ;
  223. ;
  224.     XRA    A
  225.     STA    FCBFILE+12    ;CLEAR EXTENT
  226.     STA    FCBFILE+32    ;CLEAR CURRENT RECORD COUNT
  227.     LXI    H,0
  228.     SHLD    FILEPTR        ;RESET FILE POINTERS
  229.     MVI    C,DELET        ;'DELETE FILE' FUNCTION
  230.     LXI    D,FCBFILE    ;DELETE 'OLD' CRCKLIST FILE
  231.     CALL    BDOS
  232.     MVI    C,MAKE        ;'MAKE FILE' FUNCTON
  233.     LXI    D,FCBFILE    ;MAKE 'NEW' CRCKLIST FILE
  234.     CALL    BDOS
  235.     INR    A        ;MAKE THE NEW FILE OK?
  236.     JNZ    COPYNAME    ;COPY THE FILE NAME REQUESTED
  237. ;
  238.     MVI    C,PRINT        ;PRINT STRING FUNCTION
  239.     LXI    D,DIR$FULL    ;INDICATE THAT DIRECTORY IS FULL
  240.     CALL    BDOS
  241.     JMP    FILERR
  242. ;...
  243. ;
  244. ;
  245. COPYNAME:
  246.     LXI    H,FCB2
  247.     LXI    D,FCBFINAL
  248.     MVI    C,9        ;FILENAME IS 8 CHAR. PLUS .
  249. ;
  250. COPYNAME1:
  251.     MOV    A,M
  252.     STAX    D
  253.     INX    H
  254.     INX    D
  255.     DCR    C
  256.     JNZ    COPYNAME1
  257. ;...
  258. ; 
  259. AGAIN:    LXI    SP,STACK    ;RE-INIT STACK POINTER
  260.     CALL    MFNAME        ;SEARCH FOR NAMES
  261.     JNC    NAMTST        ;ANOTHER FOUND, PRINT NAME
  262.     LDA    FOUND        ;NOTHING FOUND, CHECK...
  263.     ORA    A        ;... FIRST TIME FLAG
  264.     JZ    DONE        ;AT LEAST ONE WAS FOUND
  265.     CALL    ABEXIT        ;PRINT MSG, THEN EXIT
  266.     DB    '++File(s) not found++$'
  267. ; 
  268. DONE:    LDA    FFLAG        ;MAKING A '.CRC' DISK FILE?
  269.     CPI    ' '
  270.     JZ    DONE2        ;NO, SKIP THE FILE STUFF
  271. ;
  272. ;
  273. ; CLOSE CRCKLIST.$$$
  274. ;
  275. CLOSEFILE:
  276.     LHLD    FILEPTR
  277.     MOV    A,L
  278.      ANI    07FH
  279.     JNZ    CLOSEFILE1
  280. ;
  281.     SHLD    FILELEN
  282. ;
  283. CLOSEFILE1:
  284.     MVI    A,EOF
  285.     PUSH    PSW
  286.     CALL    PUTFILE
  287.     POP    PSW
  288.     JNZ    CLOSEFILE
  289. ;
  290.     MVI    C,CLOSE
  291.     LXI    D,FCBFILE
  292.     CALL    BDOS
  293.     INR    A
  294.     JNZ    ERASE
  295. ;
  296.     MVI    C,PRINT
  297.     LXI    D,NO$CLOSE
  298.     CALL    BDOS
  299. ;
  300. ;
  301. ; ERASE ANY EXISTING OLD FILE
  302. ;
  303. ERASE:    MVI    C,DELET
  304.     LXI    D,FCBFINAL
  305.     CALL    BDOS
  306. ;
  307. ; 
  308. ; RENAME CRCKLIST.$$$ TO CRCKLIST.CRC
  309. ;
  310.     LXI    H,FCBFILE
  311.     LXI    D,FCBFINAL
  312.     PUSH    H
  313.     LXI    B,16
  314.     DAD    B
  315. ;
  316. MOV$NAME:
  317.     LDAX    D
  318.     MOV    M,A
  319.     INX    D
  320.      INX    H
  321.     DCR    C
  322.     JNZ    MOV$NAME
  323.     POP    D
  324.     MVI    C,RENAM
  325.     CALL    BDOS
  326. ;
  327. ; 
  328. ; NOW EXIT TO CP/M
  329. ;
  330. DONE2:    CALL    MSGEXIT        ;PRINT 'DONE' THEN EXIT
  331.     DB    CR,LF,'Done',CR,LF,'$'
  332. ;.....
  333. ;
  334. ; 
  335. ; TEST FOR NAMES TO IGNORE
  336. ; 
  337. NAMTST:    LDA    SYSOK        ;SEE IF '.SYS' FILES ALLOWED
  338.     ORA    A
  339.     JNZ    DOSYS        ;IF ALLOWED, EXIT
  340. ;
  341.     LDA    FCB+10        ;GET 'SYS' ATTRIBUTE
  342.     ANI    80H        ;IS IT 'SYS'?
  343.     JNZ    AGAIN        ;YES, IGNORE THIS FILE
  344. ;
  345. ;
  346. ; IGNORE FILES WITH .$$$ FILETYPE (THEY ARE USUALLY ZERO-LENGTH AND
  347. ; CLUTTER UP OUR DISPLAY.  WE ALSO WANT TO IGNORE OUR CRCKLIST.$$$
  348. ; TEMPORARY FILE).
  349. ; 
  350. DOSYS:    LXI    H,FCB+9        ;POINT TO FILETYPE IN 'FCB'
  351.     CALL    TSTBAD        ;CHECK FOR .$$$ FILES
  352.     JZ    AGAIN        ;IF ZERO FLAG, IGNORE THEM
  353. ;
  354.     XRA    A        ;FOUND SOME NAMES
  355.     STA    FOUND
  356. ;
  357. ;
  358. ; MOVE 8 CHARACTERS FROM FCB+1 TO FNAME
  359. ;
  360.     LXI    H,FCB+1
  361.     LXI    D,FNAME
  362.     LXI    B,8
  363.     CALL    MOVER
  364. ;
  365. ;
  366. ; MOVE 3 CHARACTERS FROM FCB+9 TO FNAME+9
  367. ;
  368.     LXI    H,FCB+9
  369.     LXI    D,FNAME+9
  370.     LXI    B,3
  371.     CALL    MOVER
  372. ;
  373. ;
  374. ; NOW PRINT FILENAME.TYPE
  375. ;
  376.     CALL    ILPRT        ; PRINT:
  377. ;
  378.         DB    '---> '
  379. FNAME:    DB    'XXXXXXXX.XXX     CRC  =  ',0
  380. ;
  381. ;
  382. ; OPEN THE FILE
  383. ;
  384.     LXI    D,FCB
  385.     MVI    C,OPEN
  386.     CALL    BDOS
  387.     INR    A
  388.     JNZ    RDINIT
  389. ;
  390.     CALL    ABEXIT
  391.     DB    '++OPEN FAILED++$'
  392. ;
  393. ; 
  394. ; INITIALIZE 'CRC' TO ZERO AND SET 'BUFAD' TO CAUSE INITIAL READ
  395. ;
  396. RDINIT:    LXI    H,0
  397.      SHLD    REM        ;INIT REMAINDER TO ZERO
  398.     LXI    H,BASE+100H
  399.     SHLD    BUFAD        ;INIT BUFFER ADRS
  400. ;
  401. ;
  402. ; THIS IS THE READ LOOP
  403. ;
  404. READIT:    LHLD    BUFAD
  405.     MOV    A,H        ;TIME TO READ?
  406.     CPI    BASE SHR 8
  407.     JZ    NORD        ;NO READ
  408.     MVI    C,CSTAT
  409.     CALL    BDOS        ;CHECK FOR OPERATOR ABORT
  410.     ORA    A
  411.     JZ    READ2        ;NOTHING TO READ, EXIT
  412. ;
  413.     MVI    C,RDCON
  414.     CALL    BDOS        ;GET CHARACTER INPUTTED
  415.     CPI    CTLC        ;CONTROL-C?
  416.     JZ    ABEXT2        ;YES EXIT
  417. ;
  418. READ2:    LXI    D,FCB
  419.     MVI    C,READ        ;READ ANOTHER SECTOR OF FILE
  420.     CALL    BDOS
  421.     ORA    A        ;CHECK RETURN CODE
  422.     JNZ    FINISH        ;ERROR OR 'EOF'
  423.     LXI    H,TBUF        ;BUFFER LOCATION
  424. ;
  425. NORD:    MOV    A,M        ;GET FILE CHARACTER
  426.     STA    MESS        ;SAVE FOR 'DIVP'
  427.     INX    H
  428.     SHLD    BUFAD
  429.     CALL    DIVP        ;CALCULATE NEW 'CRC'
  430.     JMP    READIT        ;GO READ MORE CHARACTERS
  431. ;.....
  432. ;
  433. ;
  434. FINISH:    CPI    1        ;NORMAL END-OF-FILE?
  435.     JNZ    FILERR        ;NO, IT WAS A READ ERROR
  436. ;
  437.     LDA    REM+1        ;GET MSP OF 'CRC'
  438.     CALL    HEXO        ;PRINT IT
  439.     MVI    A,' '        ;SEPARATE 'LSP' AND 'LST'
  440.     CALL    TYPE
  441.     LDA    REM        ;GET 'LSP' OF 'CRC'
  442.     CALL    HEXO        ;PRINT IT
  443.     CALL    CRLF        ;TURN UP NEW LINE
  444.     JMP    AGAIN        ;SEE IF MORE FILES TO DO
  445. ;.....
  446. ;
  447. ; 
  448. FILERR:    CALL    ABEXIT        ; ABORT BECAUSE OF FILE READ ERROR
  449.     DB    '++File read error++$'
  450. ;.....
  451. ;
  452. ;
  453. ; 8080 ROUTINE FOR GENERATING A CYCLIC-REDUNDANCY-CHECK.  CHARACTER
  454. ; LEAVES THAT CHARACTER IN LOCATION 'REM'.  BY FRED GUTMAN.  FROM
  455. ; 'EDN' MAGAZINE, 5 JUNE 1979, PAGE 84.
  456. ;
  457. DIVP:    LHLD    REM        ;GET REMAINDER
  458.     MOV    A,H
  459.     ANI    128        ;Q-BIT MASK
  460.     PUSH    PSW        ;SAVE STATUS
  461.     DAD    H        ;2 * R(X)
  462.     LDA    MESS        ;MESSAGE BIT IN 'LSB'
  463.     ADD    L
  464.     MOV    L,A
  465.     POP    PSW
  466.     JZ    QB2        ;IF Q-BIT IS ZERO
  467. ;
  468. QB:    MOV    A,H
  469.     XRI    0A0H        ;'MS' HALF OF GENERAL POLYNOMINAL
  470.     MOV    H,A
  471.     MOV    A,L
  472.     XRI    97H        ;'LS' HALF OF GENERAL POLYNOMINAL
  473.     MOV    L,A
  474. ;
  475. QB2:    SHLD    REM
  476.     RET
  477. ;.....
  478. ;
  479. ; 
  480. ; HEX OUTPUT
  481. ; 
  482. HEXO:    PUSH    PSW        ;SAVE FOR RIGHT DIGIT
  483.     RAR            ;RIGHT..
  484.     RAR            ;..JUSTIFY..
  485.     RAR            ;..LEFT..
  486.     RAR            ;..DIGIT..
  487.     CALL    NIBBL        ;PRINT LEFT DIGIT
  488.     POP    PSW        ;RESTORE RIGHT
  489. ; 
  490. NIBBL:    ANI    0FH        ;ISOLATE DIGIT
  491.     CPI    10        ;IS IS LESS THAN 10?
  492.     JC    ISNUM        ;YES, NOT ALPHA
  493.     ADI    7        ;ADD ALPHA BIAS
  494. ; 
  495. ISNUM:    ADI    '0'        ;CONVERT FROM BINARY TO ASCII
  496.     JMP    TYPE        ;PRINT IT, THEN RETURN
  497. ;.....
  498. ;
  499. ;
  500. ; INLINE PRINT ROUTINE
  501. ;
  502. ILPRT:    XTHL            ;SAVE 'HL', GET MSG
  503. ; 
  504. ILPLP:    MOV    A,M        ;GET CHAR
  505.     CALL    TYPE        ;OUTPUT IT
  506.     INX    H        ;POINT TO NEXT
  507.     MOV    A,M        ;TEST
  508.     ORA    A        ;..FOR END
  509.     JNZ    ILPLP
  510.     XTHL            ;RESTORE 'HL', RETURN ADDRESS
  511.     RET            ;RETURN PAST MSG
  512. ;.....
  513. ;
  514. ;
  515. ; SEND CARRIAGE RETURN, LINE FEED TO OUTPUT
  516. ;
  517. CRLF:    MVI    A,CR        ;CARRIAGE RETURN
  518.     CALL    TYPE
  519.     MVI    A,LF        ;LINE FEED, FALL INTO 'TYPE'
  520. ;
  521. ;
  522. ; SEND CHARACTER IN 'A' REGISTER TO OUTPUT
  523. ; 
  524. TYPE:    PUSH    B
  525.     PUSH    D
  526.     PUSH    H
  527.     ANI    7FH        ;STRIP OFF ANY PARITY
  528.     MOV    E,A
  529.     PUSH    D
  530.     CALL    WRFILE        ;WRITE TO FILE IF REQUESTED
  531.     POP    D
  532.     MVI    C,WRCON        ;SEND CHARACTER TO CONSOLE
  533.     CALL    BDOS
  534.     POP    H
  535.     POP    D
  536.     POP    B
  537.     RET
  538. ;.....
  539. ;
  540. ;
  541. PUTFILE:
  542.     PUSH    PSW        ;SAVE OUTPUT CHARACTER
  543.     LHLD    FILELEN        ;GET CURRENT BUFFER LENGTH
  544.     XCHG            ;'DE' HAS LENGTH
  545.     LHLD    FILEPTR        ;LOAD NEXT TO GET/PUT TO 'HL'
  546.     MOV    A,L        ;COMPUTE CURRENT LENGTH
  547.     SUB    E     
  548.     MOV    A,H
  549.     SBB    D        ;CARRY IF NEXT < LENGTH
  550.     JC    PUTCRC4        ;CARRY IF LENGTH > CURRENT
  551. ;
  552.     LXI    H,0        ;END OF BUFFER, FILL (EMPTY) BUFFERS    
  553.     SHLD    FILEPTR        ;CLEAR NEXT TO GET/PUT
  554. ;
  555. PUTCRC1:            ;PROCESS NEXT DISK SECTOR
  556.     XCHG            ;FILE POINTER TO 'DE'
  557.     LHLD    FILELEN        ;'HL' IS MAXIMUM BUFFER LENGTH
  558.     MOV    A,E        ;COMPUTE NEXT LENGTH
  559.     SUB    L        ;TO GET CARRY, IF MORE FILL
  560.     MOV    A,D
  561.     SBB    H        
  562.     JNC    PUTCRC3
  563.     LHLD    FILEADR        ;GOT CARRY, MORE TO FILL YET
  564.     DAD    D        ;HL IS NEXT BUFFER ADDRESS
  565.     XCHG
  566.     MVI    C,STDMA        ;SET 'DMA' ADDRESS
  567.     CALL    BDOS
  568.     LXI    D,FCBFILE    ;'FCB' ADDRESS TO 'DE'
  569.     MVI    C,WRITE        ;FILE WRITE
  570.     CALL    BDOS
  571.     ORA    A        ;CHECK RETURN CODE
  572.     JNZ    PUTCRC2        ;END-OF-FILE YET?
  573.     LXI    D,BUF$SIZ    ;NOT 'EOF', INCREMENT LENGTH BY 128
  574.     LHLD    FILEPTR        ;NEXT TO FILL
  575.     DAD    D
  576.     SHLD    FILEPTR        ;SAVE NEW POINTER
  577.     JMP    PUTCRC1        ;PROCESS ANOTHER SECTOR
  578. ;...
  579. ;
  580. ;
  581. PUTCRC2:            ;GOT END-OF-FILE
  582.     MVI    C,PRINT        ;PRINT STRING FUNCTION
  583.     LXI    D,DSK$FULL    ;DISK IS FULL
  584.     CALL    BDOS
  585.     POP    PSW        ;CLEAN STACK
  586.     JMP    FILERR        ;FILE ERROR, EXIT
  587. ;...
  588. ;
  589. ;
  590. PUTCRC3:            ;END OF BUFFER, RESET 'DMA' AND POINTER
  591.     LXI    D,TBUF        ;POINT TO TEMPORARY BUFFER
  592.     MVI    C,STDMA        ;SET 'DMA' FUNCTION
  593.     CALL    BDOS
  594.     LXI    H,0        ;RESET POINTER FOR NEXT TO GET
  595.     SHLD    FILEPTR
  596. ;
  597. PUTCRC4:            ;PROCESS THE NEXT CHARACTER
  598.     XCHG            ;INDEX TO GET/PUT IN 'DE'
  599.     LHLD    FILEADR        ;BASE OF BUFFER
  600.     DAD    D        ;ADDRESS OF CHARACTER IN 'HL'
  601.     XCHG            ;AND SWAP TO 'DE'
  602.     POP    PSW        ;GET SAVE CHARACTER
  603.     STAX    D        ;CHARACTER TO BUFFER
  604.     LHLD    FILEPTR        ;INDEX TO GET/PUT
  605.     INX    H        ;AND UPDATE FOR NEXT CHARACTER
  606.     SHLD    FILEPTR
  607.     RET
  608. ;.....
  609. ;
  610. ;
  611. ; WRITE CHARACTER IN 'E' REGISTER TO OUTPUT FILE
  612. ;
  613. WRFILE:    LDA    FFLAG        ;GET FILE TRIGGER
  614.     CPI    ' '        ;IS IT SET?
  615.     RZ            ;NO, RETURN
  616. ;
  617.     MOV    A,E        ;GET CHARACTER BACK
  618.     CALL    PUTFILE
  619.     RET
  620. ;.....
  621. ;
  622. ; 
  623. ; MULTI-FILE ACCESS SUBROUTINE.  ALLOWS PROCESSING OF MULTIPLE FILES
  624. ; (I.E., *.ASM) FROM DISK.  THIS ROUTINE BUILDS THE PROPER NAME IN THE
  625. ; FCB EACH TIME IT IS CALLED.  CARRY IS SET IF NO MORE NAMES CAN BE
  626. ; FOUND.
  627. ; 
  628. MFNAME:    MVI    C,STDMA        ;INIT 'DMA' ADDRESS AND 'FCB'
  629.     LXI    D,TBUF
  630.     CALL    BDOS
  631.     XRA    A
  632.     STA    FCBEXT
  633.     STA    FCBRNO
  634. ;
  635. ;
  636. ; IF FIRST TIME
  637. ;
  638.     LDA    MFFLG1
  639.     ORA    A
  640.     JZ    MFN01
  641. ;
  642. ;
  643. ; SAVE THE REQUESTED NAME - SAVE ORIGINAL REQUEST
  644. ;
  645.     LXI    H,FCB
  646.     LXI    D,MFREQ
  647.     LXI    B,12
  648.      CALL    MOVER
  649.     LDA    FCB
  650.     STA    MFCUR        ;SAVE DISK IN CURRENT 'FCB'
  651. ;
  652. ; SEARCH FOR THE FIRT REQUESTED NAME
  653. ;
  654.     LXI    H,MFREQ
  655.     LXI    D,FCB
  656.     LXI    B,12
  657.     CALL    MOVER
  658.     MVI    C,SRCHF        ;SEARCH FOR FIRST NAME
  659.     LXI    D,FCB
  660.     CALL    BDOS
  661. ;
  662. ;
  663. ; ELSE
  664. ;
  665.     JMP    MFN02
  666. ; 
  667. MFN01:
  668.     LXI    H,MFCUR
  669.     LXI    D,FCB
  670.     LXI    B,12
  671.     CALL    MOVER
  672.     MVI    C,SRCHF        ;SEARCH FOR FIRST NAME
  673.     LXI    D,FCB
  674.     CALL    BDOS
  675. ;
  676. ;
  677. ; SEARCH FOR NEXT REQUESTED NAME
  678. ;
  679.     LXI    H,MFREQ
  680.     LXI    D,FCB
  681.     LXI    B,12
  682.     CALL    MOVER
  683.     MVI    C,SRCHN        ;SEARCH FOR NEXT NAME
  684.     LXI    D,FCB
  685.     CALL    BDOS
  686. ;
  687. ; ENDIF
  688. ;
  689. MFN02:                ;RETURN CARRY IF NOT FOUND
  690.     INR    A
  691.     STC
  692.     RZ
  693. ;
  694. ;
  695. ; MOVE NAME FOUND TO CURRENT NAME
  696. ;
  697.     DCR    A
  698.     ANI    3
  699.     ADD    A
  700.     ADD    A
  701.     ADD    A
  702.     ADD    A
  703.     ADD    A
  704.     ADI    128+1
  705.     MOV    L,A
  706.     MVI    H,BASE SHR 8
  707.     PUSH    H        ;SAVE NAME POINTER
  708.     LXI    D,MFCUR+1
  709.     LXI    B,11
  710.     CALL    MOVER
  711. ;
  712. ;
  713. ; MOVE NAME FOUND TO FCB
  714. ;
  715.     POP    H
  716.     LXI    D,FCB+1
  717.     LXI    B,11
  718.     CALL    MOVER
  719. ;
  720. ;
  721. ; SETUP FCB
  722. ;
  723.      XRA    A
  724.     STA    FCBEXT
  725.     STA    FCBRNO
  726.     STA    MFFLG1        ;TURN OFF 1ST TIME SWITCH 
  727.     RET
  728. ;.....
  729. ;
  730. ; 
  731. ; CHECK FOR .$$$ FILES
  732. ; 
  733. TSTBAD:    CALL    TESTIT        ;CHECK FIRST ONE FOR '$'
  734.     RNZ            ;NO, RETURN
  735. ;
  736.     CALL    TESTIT        ;CHECK SECOND ONE
  737.     RNZ            ;NO, RETURN
  738. ;...
  739. ;
  740. ;
  741. TESTIT:    MOV    A,M
  742.     ANI    7FH        ;STRIP ATTRIBUTE
  743.     CPI    '$'        ;CHECK FOR $ FILETYPE
  744.     INX    H
  745.     RET
  746. ;.....
  747. ;
  748. ; 
  749. ; MOVE (BC) BYTES FROM (HL) TO (DE)
  750. ; 
  751. MOVER:    MOV    A,M
  752.     STAX    D
  753.     INX    H
  754.     INX    D
  755.     DCX    B
  756.     MOV    A,B
  757.     ORA    C
  758.     JNZ    MOVER
  759. ;
  760.     RET
  761. ;..... 
  762. ;
  763. ;
  764. ; ABORTED - PRINT REASON.  IF MAKING OUTPUT FILE, CLOSE THE INCOMPLETE
  765. ; FILE TO UPDATE CP/M'S BIT MAP, THEN ERASE IT.
  766. ; 
  767. ABEXIT:    POP    D        ;GET MSG ADRS
  768.     MVI    C,PRINT
  769.     CALL    BDOS        ;PRINT MSG
  770. ; 
  771. ABEXT2:    LDA    FFLAG        ;SEE IF WE ARE MAKING A DISK FILE
  772.     CPI    ' '
  773.     JZ    ABEXT5        ;IF NOT, EXIT
  774. ;
  775. ABEXT3:    LHLD    FILEPTR
  776.     MOV    A,L
  777.     ANI    07FH
  778.     JNZ    ABEXT4
  779.     SHLD    FILELEN
  780. ;
  781. ABEXT4:    MVI    A,EOF
  782.     PUSH    PSW
  783.     CALL    PUTFILE
  784.     POP    PSW
  785.     JNZ    ABEXT3
  786. ;
  787.      MVI    C,CLOSE
  788.     LXI    D,FCBFILE
  789.     CALL    BDOS
  790.     INR    A
  791.     JNZ    ERA$CRC
  792. ;
  793.     MVI    C,PRINT
  794.     LXI    D,NO$CLOSE
  795.     CALL    BDOS
  796. ;
  797. ;
  798. ; ERASE INCOMPLETE FILE
  799. ;
  800. ERA$CRC:
  801.     MVI    C,DELET
  802.     LXI    D,FCBFILE
  803.     CALL    BDOS
  804. ; 
  805. ABEXT5:    CALL    ERXIT        ;PRINT MSG, EXIT
  806.     DB    CR,LF,LF,'++ABORTED++',CR,LF,'$'
  807. ;
  808. ;
  809. ; EXIT WITH MESSAGE
  810. ; 
  811. MSGEXIT:
  812.     DS    0        ;EXIT WITH "INFORMATIONAL" MESSAGE
  813. ;
  814. ERXIT:    POP    D        ;GET MSG
  815.     MVI    C,PRINT
  816.     CALL    BDOS
  817. ; 
  818. ; EXIT, RESTORING STACK AND RETURN TO 'CCP'
  819. ; 
  820. EXIT:    LHLD    STACK                ;GET OLD STACK RETURN ADDRESS BACK
  821.     SPHL
  822.     RET            ;TO 'CCP'
  823. ;.....
  824. ;
  825. ;
  826. DIR$FULL:
  827.     DB    CR,LF
  828.     DB    '++NO DIRECTORY SPACE FOR CRC FILE++',CR,LF,'$'
  829. ;
  830. DSK$FULL:
  831.     DB    CR,LF
  832.     DB    '++NO DISK SPACE FOR CRC FILE++',CR,LF,'$'
  833. ;
  834. NO$CLOSE:
  835.     DB    CR,LF
  836.     DB    '++CANNOT CLOSE CRC FILE++',CR,LF,'$'
  837. ;
  838. ; 
  839. ; PROGRAM STORAGE AREA
  840. ; 
  841. BUFAD:    DB    0,0        ;READ BUFFER ADDRESS
  842. FFLAG:    DB    0        ;FILE WRITE REQUEST FLAG
  843. FOUND:    DB    0        ;SET TO ZERO IF FILE(S) FOUND
  844. MESS:    DB    0        ;'CRC' MESSAGE CHAR GOES HERE
  845. MFCUR:    DB    '            '    ;CURRENT NAME
  846. MFFLG1:    DB    1        ;1ST TIME SWITCH
  847. MFREQ:    DB    '            '    ;REQUESTED NAME
  848. OLDSTK:    DB    0,0        ;OLD STACK POINTER SAVED HERE
  849. REM:    DB    0,0        ;'CRC' REMAINDER STORAGE
  850. ;
  851. FILELEN:
  852.     DB    0,0        ;FILLED AUTOMATICALLY
  853. ;
  854. FILEPTR:
  855.     DB    0,0
  856. ;
  857. ;
  858. ; BUILD FCB FOR FINAL NAME OF CRCKLIST.CRC
  859. ;
  860. FCBFINAL:
  861.     DB    0,'CRCKLISTCRC'
  862.     DB    0
  863.     DS    20
  864. ;
  865. ;
  866. ; OUTPUT FILE (TEMPORARILY NAMED CRCKLIST.$$$)
  867. ;
  868. FCBFILE:
  869.     DB    0,'CRCKLIST$$$'
  870.     DB    0
  871.     DS    20
  872. ;
  873.     DS    80        ;MINIMUM STACK AREA
  874. ;
  875. SETEVEN EQU    ($+127)/128*128    ;SET BUFFER TO EVEN PAGE
  876. ;
  877. ;
  878.     ORG    SETEVEN
  879. ;
  880. STACK:    EQU    $-2        ;SAVE 2 BYTES FOR OLD STACK POINTER
  881. ;
  882. FILEADR:
  883.     DW    FILEADR+2    ;BUFFER ALL 'CRC' FILE DATA HERE
  884. ;
  885. ; 
  886.     END
  887.