home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / kaypro / dskdrv13.lbr / DSKDRV13.ZQ0 / DSKDRV13.Z80
Text File  |  1985-06-05  |  43KB  |  1,632 lines
  1.     title    'DSKDRIVE foreign disk driver - using RSX (85/02/02)'
  2.     subttl    'default IBM CPM86 DSDD on Kaypro 4'
  3. ;
  4.     .z80;        for M80 benefit
  5. ver    equ    13;    Version number to be filled in. <10 debug
  6. ; 
  7. false    equ    0
  8. true    equ    NOT false
  9. ;
  10. ; customise the @RSX value for the application.  See BDOS call lists
  11. ; below for guidance.  Try to avoid values likely to create conflicts
  12. @RSX    equ    115;    115 is GSX graphics on CPM86, probably safe
  13. driver    equ    true;    TRUE installs drivers visible to DOS
  14. ;
  15. ; Copyright (c) 1985 by C.B Falconer       (203) 281-1438
  16. ; 680 Hartford Tpk, Hamden, Ct 06504.   All rights reserved.
  17. ;
  18. ; This program may be copied/used/modified etc, but it may NOT
  19. ; be sold without express written permission from C.B. Falconer
  20. ;
  21. ; This system provides a foreign disk driver on the Kaypro 4
  22. ; which can then be configured to any suitable format.  The 
  23. ; default format is that for the IBM PC running CPM86 (DSDD).
  24. ; Once installed (by running) the drive configuration can be
  25. ; altered by auxiliary software (still to be written).  To remove
  26. ; the driver run the program again.  The default foreign drive
  27. ; type can easily be altered, once the paramaters are known.
  28. ;
  29. ; The system uses the generalized CPM 2.2 RSX system published
  30. ; and documented separately, and whose source code is embodied
  31. ; within this program.  The program uses Z80 opcodes only in the
  32. ; actual disk driver (for hardware reasons) and in the transfer
  33. ; between user storage and disk buffer (for performance).  This
  34. ; should ease porting to 8080 only systems.
  35. ;
  36. ; NOTE:    This source file requires SLRs Z80ASM or M80 for assembly,
  37. ;    and RELOCCP.SYS for run-time load and relocation.  M80 has
  38. ;    not been checked.  I suspect some labels may be too long.
  39. ;
  40. ; Revisions:        (in LIFO order)
  41. ; 1.3    85/5/15. Revised alternate table for Kaypro 2 SSDD. No code
  42. ;    changes whatsoever.
  43. ; 1.2    85/2/3. Added support for single density.  DOS dskreset call
  44. ;    resets this drive.  SECSHF calculated from HSTBLK.
  45. ; 1.1    85/2/1. Altered configuration table to reduce portion needed
  46. ;    in external cookbook files for reconfiguration.  A | B | C
  47. ;    runtime parameters for alternate drive type selection added,
  48. ;    so that a total of 5 configuration (including native) are
  49. ;    available without the auxiliary ALTDRIVE program.
  50. ; 1.0    85/01/30. Initial release.  Alteration software needed
  51. ; 0.3    85/01/27. First working disk drive.
  52. ; 0.2    85/01/24. Provisions for BDOS driver installation,
  53. ;    checks etc.
  54. ; 0.1    85/01/05. Inactive causes reversion to original BDOS call in
  55. ;    case this was a substitute for it. debug allows testing.
  56. ;    Keep track of current DMA address.
  57. ; 0.0    Original version, by C.B. Falconer (85/Jan/04).
  58. ;
  59. ; WARNING - When an RSX is installed all warm boots are converted
  60. ; into "returns" to the original calling CCP, which is not removed
  61. ; nor reloaded.  The original Digital Research CCP will not start
  62. ; executing SUBMIT jobs under these circumstances.  Installation
  63. ; of CCPLUS will repair this omission.  ZCPR action has not been
  64. ; checked.  Other problems (with the original CCP) may appear on
  65. ; "select errors", i.e. by logging into a non-existent drive.
  66. ;
  67. ; This system is the outline of a generalized RSX system, with
  68. ; initialization and termination code.  It is expected to 
  69. ; respond to BDOS calls with the value @RSX (normally larger
  70. ; than any usual CPM call value), and receive an argument of
  71. ; some form in the (de) register.  Two special values of (de)
  72. ; are reserved (0 and -1).  In usual operation the (de) value
  73. ; is normally a pointer, which cannot take on either of these
  74. ; special values.  For character output RSXs (e.g. list output
  75. ; replacement) this prevents sending a nul or a rubout with all
  76. ; bits set.  Remember this is a full word parameter.
  77. ;
  78. ; 0 implies a residence inquiry, and should return a zero 
  79. ; value if the system is not resident, (as will CPM 2.2 for any
  80. ; invalid calls), and non-zero if resident and activated.  This
  81. ; allows the initialization code to detect that the system is
  82. ; already mounted, and avoid multiple loading.  Similarly
  83. ; application programs can check that the RSX is available.  A
  84. ; zero value returned in (a) signifies the RSX is not available.
  85. ;
  86. ; The second special value is 0ffffh (i.e. -1), which
  87. ; signals the system to become inactive, so that the next
  88. ; warm boot will remove it entirely.
  89. ; 
  90. ; A third special argument is 0001h.  This is optional, and is
  91. ; used to return a data address.  For DSKDRIVE in particular
  92. ; this is used to return a pointer to the memory resident
  93. ; drive configuration table (whose structure thus should not
  94. ; be altered in order to maintain compatibility with auxiliary
  95. ; software).  DSKDRIVE actually returns this pointer for all
  96. ; DE arguments other than 0 or -1, but this should not be
  97. ; counted on.
  98. ;
  99. ; This file implements the DSKDRIVE RSX, and indicates where the
  100. ; code should be installed, and the calling conventions for other
  101. ; RSXs.  See the label "chkparms" to allow initialization
  102. ; parameters, and the label "rsx" to install the actual code.
  103. ; Note especially than any code located ahead of the label 
  104. ; "@keep" is available only during initialization.  However 
  105. ; the initialization section can call routines in the retained
  106. ; portion.  The "bthoot" connector allows re-initialization on
  107. ; each "warm boot".
  108. ;
  109. ; The system, when combined with "RELOCCP", loads itself just
  110. ; below the CCP, and keeps the CCP resident. (See RELOCCP.OVR,
  111. ; which is an assembly time option for RELOCCP, for a method
  112. ; of minimizing memory wastage for multiple RSX's).  If RSX.COM
  113. ; is executed while resident, it attempts to remove itself and
  114. ; reclaim memory.  If other systems have been loaded below RSX
  115. ; it will not be able to reclaim memory until those systems 
  116. ; (probably further RSX's) have been removed.
  117. ;
  118. ; To create a custom RSX modify the equate for "@RSX" above,
  119. ; and create any necessary code in the "rsx" and "chkparms"
  120. ; areas.  Give the resultant file an approriate name (e.g. MYRSX),
  121. ; assemble, and create the MYRSX.COM with RELOCCP (See RELOCCP
  122. ; documentation).  When executed you now have available a new
  123. ; BDOS function, which executes whatever you put in.
  124. ;
  125. ; Acknowledgement:  Some of the mechanisms used in this system
  126. ; have been taken from various public domain systems, especially
  127. ; those by Gary Novasielski and Bruce Ratoff.
  128. ;
  129. ; This system was created to ease installation of two operations:
  130. ; a generalized foreign disc driver, and a "CHAIN" mechanism
  131. ; whereby programs can load and execute arbitrary commands.  The
  132. ; pre-existing KEYS program can probably be converted to execute
  133. ; under this system, as can UNSPOOL40 (enhancement of Br. Ratoffs
  134. ; UNSPOL30).
  135. ;
  136. ; While some code economies could easily be made for any particular
  137. ; application, I feel that using one standard environment is much
  138. ; more important.  Thus the provisions for bios driver modification
  139. ; have been installed, with the complete check/restore system.  The
  140. ; disadvantage remains that custom code must be included in this 
  141. ; source and assembled, rather than standing by itself.
  142. ;
  143. ; BDOS Functions:
  144. @SYS    equ    0
  145. @KEY    equ    1
  146. @CON    equ    2
  147. @RDR    equ    3
  148. @PUN    equ    4
  149. @LST    equ    5
  150. @DIO    equ    6
  151. @RIO    equ    7
  152. @SIO    equ    8
  153. @MSG    equ    9
  154. @INP    equ    10
  155. @RDY    equ    11
  156. @VER    equ    12
  157. @LOG    equ    13
  158. @DSK    equ    14
  159. @OPN    equ    15
  160. @CLS    equ    16
  161. @DIR    equ    17
  162. @NXT    equ    18
  163. @DEL    equ    19
  164. @FRD    equ    20
  165. @FWR    equ    21
  166. @MAK    equ    22
  167. @REN    equ    23
  168. @LGV    equ    24
  169. @CUR    equ    25
  170. @DMA    equ    26
  171. @ALO    equ    27
  172. @WPT    equ    28
  173. @GRO    equ    29
  174. @CHG    equ    30
  175. @GPM    equ    31
  176. @USR    equ    32
  177. @RRD    equ    33
  178. @RWR    equ    34
  179. @SIZ    equ    35
  180. @REC    equ    36
  181. @RDV    equ    37
  182. @WRZ    equ    40;    38 and 39 are MPM functions
  183. ;
  184. ; some CPM 3.0 functions, for reference.  Match function if
  185. ; possible when a 2.2 RSX is created.
  186. ; 41 thru 50 are used
  187. @CHN    equ    47;    Chain to command line in (dmaadr)
  188. @OVL    equ    59;    Load overlay
  189. ;@RSX    equ    60;    Call RSX.  Different usage than here
  190. ; 98 thru 112 are used.  115 is CPM86 GSX graphics.
  191. @PFN    equ    152;    parse filename
  192. ;
  193. ; System equates:
  194. CPMBASE    equ    0
  195. boot    equ    CPMBASE
  196. bdos    equ    boot+5
  197. tfcb    equ    boot+5CH
  198. tfcb1    equ    tfcb
  199. tfcb2    equ    tfcb+16
  200. tbuff    equ    boot+80H
  201. TPA    equ    boot+100H
  202. CTRL    equ    ' '-1;        CTRL CHAR MASK
  203. CR    equ    CTRL AND 'M'
  204. LF    equ    CTRL AND 'J'
  205. TAB    equ    CTRL AND 'I'
  206. FF    equ    CTRL AND 'L'
  207. BS    equ    CTRL AND 'H'
  208. eof    equ    CTRL AND 'Z'
  209. fcblen    equ    36;        Length of input FCB
  210. ;
  211. ; nvects is larger than the CPM 2.2 standard to allow for:
  212. ;   1. CPM 3 bios system
  213. ;   2. Other systems with extended bios calls and/or use
  214. ;      e.g. Kaypro has a key table, which some applications
  215. ;      alter (via the pointer at 1).  If the space is not
  216. ;      reserved system crashes will result.
  217. nvects    equ    29;        Number of BIOS vectors
  218. n22vec    equ    16;        Number of CPM 2.2 vectors
  219. ;
  220. ; Macro Definitions
  221. ;
  222. ; Force location counter zero modulo val
  223. ; with respect to "relative" by filling with "fill" bytes
  224. align    macro    val,relative,fill
  225.     local    here
  226. here    equ    $-relative
  227.     if    (here+val)/val*val-here-val
  228.      if    nul fill
  229.       ds    (here+val)/val*val-here
  230.      else;;    Z80ASM specific coding.
  231.       ds    (here+val)/val*val-here,fill
  232.      endif
  233.     endif
  234.     endm
  235. ;
  236. ; ************************************************************
  237. ; * This is my standard page relocatable system. See RELOCCP *
  238. ; ************************************************************
  239. ;
  240.     cseg;    system requires org 0 and org 100h modules
  241. ;        You may replace this with two "orgs" in two
  242. ;        different assemblies to get the overall system
  243. ;        for RELOCCP to prepare and relocate at run-time.
  244. ;
  245. ; This defines the first location of the relocated image.
  246. ; The portion from here to "@keep" is not retained after
  247. ; initialization.  The data here is used for relocation
  248. @base:    jp    intro;        Following is std relocation data
  249. @size:    dw    segsiz;        size of segment to relocate
  250. @memsz:    db    pages;        total memory use in pages
  251. ;
  252. ; Patch/alter this value to non-zero if the RSX may only be
  253. ; loaded in a virgin system.  This should be done if the system
  254. ; installs bios modifications that the BDOS can see.
  255. chkflg:    db    driver;        Set non-zero for virgin system only
  256. ;
  257. ; This code gets everything started
  258. intro:    ld    hl,(bdos+1);    First so other calls work
  259.     ld    (gobdos+1),hl;    Save the BDOS entry point
  260.     ld    de,signon
  261.     call    tstr
  262.     call    chkparms;    Do any parameter checking needed
  263.     jp    c,exeunt;    ..with help message on carry=fault
  264.     ld    de,0
  265.     ld    a,@RSX;
  266.     call    DOS;        enquire whether loaded
  267.     or    a;        If loaded, 
  268.     jp    nz,intro1;      then bring it down
  269.     call    rsxsetup;    initialize.
  270.     call    init;        Customized portion
  271.     jp    bootrq;        ..bootrq, which sets connectors
  272. ;
  273. ; already loaded, bring it down
  274. intro1:    ld    de,-1
  275.     ld    a,@RSX
  276.     call    DOS;        tell it to come down on next boot
  277.     jp    boot;        which should kill it
  278. ;
  279. ; Setup the system.  First, check environment to see if
  280. ; BIOS vectors are accessible and reasonable.
  281. rsxsetup:
  282.     ld    a,(boot);    Location BOOT should
  283.     cp    0c3h;        have a JMP instruction
  284.     jp    nz,vecterr
  285.     ld    hl,(boot+1);    Location one points to
  286.     ex    de,hl;         the table of bios jumps
  287.     ld    hl,(bdos+1);    This should point to BDOS
  288.     ld    a,(chkflg)
  289.     ld    (kill+1),a;    Save for use at exit time. Unclean
  290.     or    a;         but want it user patchable (1 place)
  291.     call    nz,chksys;    Hook, prevent loading invalid system
  292.     ex    de,hl
  293.     ld    c,nvects;    preserve z flag in here
  294.     ld    de,biosv
  295.     push    de;        by default init our vector
  296.     jp    nz,vecterr;    after push, to correct stack
  297.     ld    de,bsave;    which we move into
  298.     ex    de,hl;        the code.
  299. rsxsetup1:
  300.     ld    a,nvects-n22vec
  301.     cp    c
  302.     jp    nc,rsxsetup2;    stop checking after 2.2 types
  303.     ld    a,(de)
  304.     xor    (hl);        another JMP?
  305.     and    0f1h;        allow Call or Jmp
  306.     jp    nz,vecterr
  307. rsxsetup2:
  308.     ld    a,(de)
  309.     ld    (hl),a;        bsave[n,0]
  310.     inc    de
  311.     inc    hl
  312.     ex    (sp),hl
  313.     inc    hl
  314.     ld    a,(de)
  315.     ld    (hl),a;        biosv[n,1]
  316.     inc    hl
  317.     ex    (sp),hl
  318.     ld    (hl),a;        bsave[n,1]
  319.     inc    de
  320.     inc    hl
  321.     ld    a,(de)
  322.     ld    (hl),a;        bsave[n,2]
  323.     ex    (sp),hl
  324.     ld    (hl),a;        biosv[n,2]
  325.     inc    hl;    biosv[n+1,0]
  326.     ex    (sp),hl
  327.     inc    hl;    biosv[n+1,0]
  328.     inc    de
  329.     dec    c;    n := n+1;
  330.     jp    nz,rsxsetup1
  331.     pop    hl;        purge 2nd transfer address
  332. ; This was satisfactory, now if "driver" is TRUE, patch the
  333. ; BIOS drivers to point to the new copy (only the std CPM 2.2
  334. ; entries) so that new entries can be made locally.  The final
  335. ; exit mechanism will restore everything.
  336.     ld    a,(chkflg)
  337.     or    a
  338.     call    nz,bpatch
  339. ; Save old vectors and CCP return address. BDOS saved at the very
  340. ; beginning of system. User code can patch new vectors as required.
  341.     ld    hl,(boot+1)
  342.     ld    (boot0+1),hl;    Save the BOOT vector
  343.     ld    hl,2;        Retrieve the CCP
  344.     add    hl,sp;        return address from
  345.     ld    a,(hl);        down the stack a ways.
  346.     inc    hl
  347.     ld    h,(hl)
  348.     ld    l,a
  349.     ld    (ccpret+1),hl;    Save the CCP re-entry point
  350.     ret
  351. ;
  352. ; Patch the original bios drivers, which have been checked
  353. ; for validity and a reasonable location, to point to the
  354. ; new bios table. Only called when "driver" is TRUE.  DO NOT
  355. ; PATCH the original warm/cold boot entries.
  356. bpatch:    ld    hl,(boot+1)
  357.     inc    hl
  358.     inc    hl
  359.     ld    de,biosv
  360.     ld    c,n22vec-1;    count of 2.2 bios entries only
  361. bpat1:    inc    hl
  362.     inc    de
  363.     inc    de
  364.     inc    de
  365.     inc    hl
  366.     ld    (hl),e
  367.     inc    hl
  368.     ld    (hl),d
  369.     dec    c
  370.     jp    nz,bpat1;    more
  371.     ret
  372. ;
  373. ; Check system is in usable state. (de) holds the bios pointer,
  374. ; and (hl) holds the bdos pointer.  If the values are not
  375. ; reasonable, return non-zero flag. 
  376. ; This routine has no relocated code, so it may be patched.
  377. ; a,f,h,l
  378. chksys:    ld    a,e
  379.     cp    3
  380.     ret    nz;        boot pointer should end in 3
  381.     add    e
  382.     sub    l
  383.     ret    nz;        bdos pointer should end in 6
  384.     ld    a,d
  385.     sub    h
  386.     sub    0eh
  387.     ret    nz;        Page difference should be 0eh
  388.     ld    a,(hl)
  389.     sub    0c3h;        JMP instruction
  390.     ret    nz
  391.     inc    hl
  392.     ld    a,(hl)
  393.     sub    011h
  394.     ret    nz;        bdos destination should go to 11
  395.     inc    hl
  396.     ld    a,h
  397.     sub    (hl);        on same page to be valid
  398.     ret
  399. ;
  400. vecterr:
  401.     pop    de;        remove the extra pointer
  402.     ld    de,vcterrmsg
  403. ;    "    "
  404. ; exit with message de^
  405. exeunt:    call    tstr
  406.     jp    boot;        try re-booting.
  407. ;
  408. vcterrmsg:
  409.     db    CR,LF,'Invalid system$'
  410. ;
  411. ; =============================================================
  412. ; ****    Custom portion of initialization code here       ****
  413. ; =============================================================
  414. ;
  415. ; Check run command parameters.  Carry if not satisfactory
  416. ; This version for DSKDRIVE moves alternate configurations into
  417. ; place on "DSKDRIVE A", "DSKDRIVE B" or "DSKDRIVE C" commands.
  418. chkparms:
  419.     ld    hl,alta
  420.     ld    a,(tfcb+1)
  421.     sub    'A';        fcbs are always upshifted
  422.     jp    z,chkp1;    A, go move it in
  423.     dec    a
  424.     or    a;        clear any carry
  425.     ld    hl,altb
  426.     jp    z,chkp1;    B
  427.     dec    a
  428.     ret    nz;        not C
  429.     ld    hl,altc
  430. chkp1:    ex    de,hl;        move configuration (hl) into
  431.     ld    hl,info;    "info" area
  432.     ld    b,infosz
  433. chkp2:    ld    a,(de)
  434.     ld    (hl),a
  435.     inc    de
  436.     inc    hl
  437.     dec    b
  438.     jp    nz,chkp2
  439.     ret
  440. ;
  441. ; Custom initialization. 
  442. ; When this routine is reached the various bios vector copies
  443. ; (and patches if "driver" is true) have been made.  This 
  444. ; routine may alter the connectors in "biosv" to install new
  445. ; drivers, etc.  The original routines are available thru
  446. ; "bsave" table.  Remember that any routines connected MUST
  447. ; live in the retained portion of code, following "@keep"
  448. ; below, and I recommend putting their code in the "rsx" area.
  449. ; If "driver" is false any bios modifications made through
  450. ; this routine will only be available to applications calling
  451. ; the bios directly (through location 1), and not to BDOS.
  452. init:    ld    de,home
  453.     ld    a,8
  454.     call    apatch
  455.     ld    de,seldsk
  456.     ld    a,9
  457.     call    apatch
  458.     ld    de,setrk
  459.     ld    a,10
  460.     call    apatch
  461.     ld    de,setsec
  462.     ld    a,11
  463.     call    apatch
  464.     ld    de,setdma
  465.     ld    a,12
  466.     call    apatch
  467.     ld    de,read
  468.     ld    a,13
  469.     call    apatch
  470.     ld    de,write
  471.     ld    a,14
  472.     call    apatch
  473.     ld    de,sectran
  474.     ld    a,16
  475. ;    "    "
  476. ; Patch bios connector (a) to connect to (de).  Note that
  477. ; the 0th connector is the cold boot entry (per DR standards).
  478. ; Also note that the first entry in biosv is entry # 1
  479. ; DO NOT patch connectors 0 or 1, nor any above "n22vecs"
  480. ; a,f
  481. apatch:    dec    a
  482.     dec    a
  483.     push    hl
  484.     ld    l,a
  485.     add    a
  486.     add    l;        *3
  487.     ld    hl,biosv+4;    offset past "jmp" opcode
  488.     add    l
  489.     ld    l,a
  490.     adc    h
  491.     sub    l
  492.     ld    h,a
  493.     ld    (hl),e
  494.     inc    hl
  495.     ld    (hl),d
  496.     pop    hl
  497.     ret    
  498. ;
  499. signon:    db    'DSKDRIVE [A|B|C] (an RSX) '
  500.     db    ver / 10 + '0', '.', ver MOD 10 + '0', '$'
  501. ;
  502. ; Alternate drive configurations, used on "DSKDRIVE A" 
  503. ; or "DSKDRIVE B" commands.  No parameter uses default.
  504. ; see "info" table for for parameter meanings.  You may
  505. ; reconfigure these tables for your most used types, thus
  506. ; allowing up to five (including native) drive versions.
  507. ;
  508. alta:    dw    40;        cpmspt
  509.     db    3;        bsh
  510.     db    07h,0;        blm,exm
  511.     dw    194;        dsm
  512.     dw    63;        drm
  513.     db    0F0h,0;        al0,al1
  514.     dw    16;        cks
  515.     dw    1;        off
  516.     db    4;        hstblk
  517.     db     0, 1, 2, 3, 4, 5, 6, 7;    sxltbl
  518.     db     8, 9,10,11,12,13,14,15
  519.     db    16,17,18,19,20,21,22,23
  520.     db    24,25,26,27,28,29,30,31
  521.     db    32,33,34,35,36,37,38,39
  522.     db    40,41,42,43,44,45,46,47
  523.     db    48,49,50,51,52,53,54,55
  524.     db    56,57,58,59,60,61,62,63
  525.     db    64,65,66,67,68,69,70,71
  526.     db    72,73,74,75,76,77,78,79
  527.     db    0;        spare
  528.     db    0;        sec1st
  529.     db    0;        config
  530.     db    40;        ntrks
  531.     db    0;        nsecs
  532.     db    'KAYPRO 2 (SSDD)$$$$$$$$$$$$'
  533. ;
  534. altb:    dw    36;        cpmspt
  535.     db    4;        bsh
  536.     db    0Fh,0;        blm,exm
  537.     dw    170;        dsm
  538.     dw    63;        drm
  539.     db    080h,0;        al0,al1
  540.     dw    16;        cks
  541.     dw    4;        off
  542.     db    2;        hstblk
  543.     db     0, 1, 2, 3, 4, 5, 6, 7;    sxltbl
  544.     db     8, 9,10,11,12,13,14,15
  545.     db    16,17,18,19,20,21,22,23
  546.     db    24,25,26,27,28,29,30,31
  547.     db    32,33,34,35,36,37,38,39
  548.     db    40,41,42,43,44,45,46,47
  549.     db    48,49,50,51,52,53,54,55
  550.     db    56,57,58,59,60,61,62,63
  551.     db    64,65,66,67,68,69,70,71
  552.     db    72,73,74,75,76,77,78,79
  553.     db    0;        spare
  554.     db    1;        sec1st
  555.     db    2;        config
  556.     db    40;        ntrks
  557.     db    0;        nsecs
  558.     db    'TS802 (Televideo DSDD)$$$$$'
  559. ;
  560. altc:    dw    32;        cpmspt
  561.     db    3;        bsh
  562.     db    07h,0;        blm,exm
  563.     dw    251;        dsm
  564.     dw    127;        drm
  565.     db    0F0h,0;        al0,al1
  566.     dw    32;        cks
  567.     dw    3;        off
  568.     db    2;        hstblk
  569.     db     0, 1, 2, 3, 4, 5, 6, 7;    sxltbl
  570.     db     8, 9,10,11,12,13,14,15
  571.     db    16,17,18,19,20,21,22,23
  572.     db    24,25,26,27,28,29,30,31
  573.     db    32,33,34,35,36,37,38,39
  574.     db    40,41,42,43,44,45,46,47
  575.     db    48,49,50,51,52,53,54,55
  576.     db    56,57,58,59,60,61,62,63
  577.     db    64,65,66,67,68,69,70,71
  578.     db    72,73,74,75,76,77,78,79
  579.     db    0;        spare
  580.     db    1;        sec1st
  581.     db    2;        config
  582.     db    40;        ntrks
  583.     db    0;        nsecs
  584.     db    'HP125 (DSDD)$$$$$$$$$$$$$$$'
  585. ;
  586. ;
  587. ; ------------------ End custom initialization area ----------------
  588. ;
  589.     align    256,@base,0;    ensure page aligned
  590. ;
  591. ; *******************************************************
  592. ; * The code from here up is retained in memory after     *
  593. ; * initialization.  It may be used by the initializer    *
  594. ; * This code MUST start on a page boundary.        *
  595. ; *******************************************************
  596. @keep:
  597. ;
  598. ; During operation, this location will point to intercept and will
  599. ; be jumped to by BDOS calls from location 5.  This organization 
  600. ; depends on the fact that BDOS calls the bios directly (ignoring
  601. ; the pointer at location 1), except when needing a warm boot
  602. ; (e.g. after a disk error), when it uses the pointer at 1.
  603. ;
  604. ; This must be at the lowest location in the protected code segment.
  605. bdosv:    jp    intercept;    the bdos link
  606. ;
  607. ; This area replaces the bios jump table, allowing intercepts.
  608. ; Any intercepts (usually console commands) are set up by the
  609. ; initializing code, which is discarded after execution. See
  610. ; comments on "nvects" above.  Normally these bios vectors will be
  611. ; accessed only by executing programs, and not by the BDOS unit.
  612. ; To insert drivers in the bios it is necessary to save the original
  613. ; bios pointers (for restoration when the RSX is removed) and
  614. ; install jumps to this revised table in the original table.  Note
  615. ; that the original table may contain a CALL for the warmboot vector,
  616. ; so that ROM based code can tell the CPM system size when called.
  617. biosv:    REPT    nvects
  618.     jp    $-$
  619.     endm
  620. ;
  621. ; This table has two purposes - it allows connection to the original
  622. ; bios vectors destinations, and it saves all the values for
  623. ; restoration upon RSX exit.  Thus the custom initialization section
  624. ; can patch the real bios table to install new disk drivers, etc.
  625. ; Note that this can only work when this is the FIRST rsx installed.
  626. ; Further ones can only intercept user bios calls and BDOS calls.
  627. ; Provided that the bios table in effect on entry to this system
  628. ; does not hold any data areas, the restoration on RSX removal will
  629. ; be harmless.
  630. bsave:    REPT    nvects
  631.     jp    $-$
  632.     endm
  633. ;
  634. ; The "old" entries needed.  Index 0 here is warmboot, not cold
  635. @home        equ    bsave+(7*3)
  636. @seldk        equ    bsave+(8*3)
  637. @setrk        equ    bsave+(9*3)
  638. @setsec        equ    bsave+(10*3)
  639. @setdma        equ    bsave+(11*3)
  640. @read        equ    bsave+(12*3)
  641. @write        equ    bsave+(13*3)
  642. @sectran    equ    bsave+(15*3)
  643. ;
  644. ; This routine intercepts all BDOS calls.
  645. ; Note that the initial code sequence allows applications to
  646. ; find the actual BDOS, if necessary.  See SD88F6 for one use.
  647. intercept:
  648.     ld    a,0ffh
  649.     cp    c
  650.     jp    c,gobdos;    Never taken, but SD trackable
  651.     ld    a,@SYS;        Get function
  652.     cp    c
  653.     jp    z,sysreq;    a reboot request
  654.     ld    a,@DMA
  655.     cp    c
  656.     jp    z,dodma
  657.     ld    a,@LOG
  658.     cp    c
  659.     jp    z,drvreset;    reset this drive also
  660.     ld    a,@RSX;        defined for this system
  661.     cp    c
  662.     jp    nz,gobdos;    not for us
  663. ; DO NOT optimize the above sequence.  It is intended to be
  664. ; trackable by utilities to list the RSX's active.  The series
  665. ; stops when the instruction is not "ld a,bytevalue".  The
  666. ; initial "ld a,0ffh" will not be counted by tracking utilities
  667. ; and the checks on @SYS and @DMA are always expected.  This
  668. ; organization allows a range of BDOS calls to be intercepted.
  669. ;    "    "
  670.     ld    hl,0
  671.     add    hl,sp
  672.     ld    sp,lclstk
  673.     push    hl;        save entry stack pointer
  674.     call    doit;        This is an extension call
  675.     ex    de,hl;        save return value
  676.     pop    hl
  677.     ld    sp,hl
  678.     ex    de,hl;        return its result
  679.     ld    a,l;        copy result to (a)
  680.     ld    b,h;        so (ba)=(hl), like BDOS
  681.     ret;            to the caller.
  682. ;
  683. ; Reset this drive also when application wants a drive reset
  684. ; Added to RSX system for disk drive application.
  685. drvreset:
  686.     push    bc
  687.     call    bthook
  688.     pop    bc
  689.     jp    gobdos
  690. ;
  691. ; Keep track of the current DMA address on general principles
  692. dodma:    ex    de,hl
  693.     ld    (dmadr),hl;    BDOS' view, not BIOS
  694.     ex    de,hl
  695. ;    "    "
  696. ; Connects to the "real" BDOS routine
  697. gobdos:    jp    $-$;        Patched on entry
  698. ;
  699. ; The RSX (resident system extension).  Argument is de as usual,
  700. ; and the extension specified is (c).  Return value is put in hl.
  701. ; The stack is already set to the local stack, with the old
  702. ; stack pointer under the return from doit.
  703. ; a,f,b,c,d,e,h,l (allowed)
  704. doit:    ld    hl,(active);    set "enquiry" return value in (l)
  705.     ld    a,l
  706.     or    a
  707.     jp    z,gobdos;    inactive, use bdos call
  708.     ld    h,0
  709.     ld    a,e;        check for "loaded enquiry"
  710.     or    d
  711.     ret    z;        signal active on enquiry
  712.     ld    a,e
  713.     and    d
  714.     inc    a
  715.     jp    nz,rsx;        not "pulldown" request.
  716. ;    "    "
  717. ; Inactivate the RSX.  Next boot will try to recover the memory.
  718. kill:    ld    a,$-$;        patched with "chkflg" at init
  719.     or    a
  720.     call    nz,unpch;    Remove any bios alterations
  721.     xor    a
  722.     ld    (active),a;    mark inactive
  723.     ld    l,a;        return 0, pulldown accepted
  724.     ld    h,a;        and we are now inactive.
  725.     ret
  726. ;
  727. ; Remove any bios patches made on initialization, in case this is a
  728. ; driver being inactivated, and further RSX's are loaded beyond it.
  729. ; Thus a "kill" request will be logically executed, even though the
  730. ; memory is not reclaimed. However bios alterations via the pointer
  731. ; at 1 cannot be removed until a warm boot occurs (that pointer may
  732. ; be pointing to an RSX installed later).  Thus the table at biosv
  733. ; must be updated to point to the original bios entries
  734. unpch:    ld    de,bsave+3
  735.     ld    hl,(boot0+1)
  736.     inc    hl
  737.     inc    hl
  738.     inc    hl;        start at the constat entry
  739.     push    hl
  740.     ld    hl,biosv+3
  741.     ld    c,n22vec-1;    dont alter the warm boot entries
  742. unpch1:    ld    b,l;        offset, depends on page alignment
  743.     inc    de;        past opcode
  744.     inc    hl;        Ignore the opcode (dont change)
  745.     ld    (hl),b;    biosv[n,1]  --> oldbios[n,0]
  746.     inc    hl
  747.     ex    (sp),hl
  748.     ld    b,h;        oldbios page
  749.     inc    hl
  750.     ld    a,(de);        lsb
  751.     ld    (hl),a;    oldbios[n,1]
  752.     inc    de;        ^msb
  753.     inc    hl
  754.     ld    a,(de);        msb
  755.     ld    (hl),a;    oldbios[n,2]
  756.     inc    hl;    oldbios[n+1,0]
  757.     ex    (sp),hl
  758.     ld    (hl),b;    biosv[n,2] --> oldbios[n,0]
  759.     inc    hl;    biosv[n+1,0]
  760.     inc    de;        next opcode
  761.     dec    c;    n := n+1
  762.     jp    nz,unpch1
  763.     pop    hl
  764.     ret
  765. ;
  766. ; Note that the following "boot" entries will never be reached if a
  767. ; further RSX has been installed, since that RSX will intercept the
  768. ; boot and do a direct return to the CCP (unless it is inactive, and
  769. ; removes itself, when a whole chain of RSX removals can be started)
  770. ;
  771. ; The application process has requested a warm-boot by invoking BDOS
  772. ; function 0.  If the system is inactive remove it, otherwise return
  773. ; to the CCP via the stored (on initialization) CCP return value.
  774. sysreq:    jp    bootrq;        This allows separation if needed
  775. ;
  776. ; The application process has requested a reboot by jumping to
  777. ; location 0.  If we are no longer active, we will honor the request
  778. ; by executing the address found in the BOOT vector at entry.
  779. ; Otherwise return to CCP without rebooting.
  780. bootrq:    ld    sp,lclstk;    set up a valid stack
  781.     ld    a,(active)
  782.     or    a
  783.     jp    z,done;        Not active, all done. Remove self
  784.     call    bthook;        Application specific boot action
  785.     ld    c,@LOG
  786.     call    gobdos;        Reset drives, like any
  787.     ld    de,actmsg;    other reboot does.
  788.     call    tstr
  789.     ld    de,altid;    added message portion for
  790.     call    tstr;          DSKDRIVE use
  791. ;    "    "
  792. ; Reset the system pointers to use this system.
  793.     ld    hl,bdosv
  794.     ld    (bdos+1),hl
  795.     ld    hl,bootrq
  796.     ld    (biosv+1),hl
  797.     ld    hl,biosv
  798.     ld    (boot+1),hl
  799.     ld    hl,tbuff
  800.     ld    (dmadr),hl;    Will be set by CCP
  801. ccpret:    jp    $-$;        Patched on startup
  802. ;
  803. ; Done with the system
  804. done:    ld    de,donemsg;    Message and jump to old boot addr.
  805.     call    tstr;        as originally read from memory wd 1 
  806. boot0:    jp    $-$;        Reboot. Patched on initialization
  807. ;                This value points to old bios table
  808. ;
  809. ; ================================================================
  810. ;          Utility routine area
  811. ; ================================================================
  812. ;
  813. ; Put string (de) to console, '$' terminated
  814. tstr:    ld    a,@MSG
  815. ;    "    "
  816. ; dos call (a) without disturbing registers.  Does not use the RSX
  817. DOS:    push    bc
  818.     push    de
  819.     push    hl
  820.     ld    c,a
  821.     call    gobdos
  822.     pop    hl
  823.     pop    de
  824.     pop    bc
  825.     ret
  826. ;
  827. ; ==================================================================
  828. ; **** To keep as much as possible constant, put real RSX here    ****
  829. ; ==================================================================
  830. ;
  831. ; This routine MUST be supplied
  832. ; The actual code for the application goes here
  833. ; Note that the (de) parameter can never be 0 or 0ffffh on entry.
  834. ; If this system is really an i/o driver (such as a foreign disk
  835. ; reader/writer) then the RSX itself never need do anything, and
  836. ; this code can be left alone (except that a DOS call is available
  837. ; to trigger the message below).
  838. ; Return any value in hl.
  839. rsx:    ld    hl,info;    return info address only
  840.     ret;            Used to reconfigure the driver
  841. ;
  842. ; This routine MUST be supplied.  It may be only a "ret"
  843. ; for DSKDRIVE recalculates some parameters in case the drive
  844. ; configuration has been changed, and ensures drive reset.
  845. ; a,f,b,h,l
  846. bthook:    xor    a
  847.     ld    (hstact),a
  848.     ld    (unacnt),a
  849.     ld    hl,tbuff
  850.     ld    (dmaadr),hl;    BIOS view of it
  851.     ld    a,(hstblk)
  852.     ld    b,-1
  853. bthk1:    inc    b;        compute secshf from hstblk
  854.     rra;            cy was clear
  855.     or    a
  856.     jp    nz,bthk1;    secshf := log2(hstblk)
  857.     ld    a,b
  858.     ld    (secshf),a
  859.     ld    a,(cpmspt)
  860.     ld    b,a
  861.     ld    a,(config)
  862.     and    0fh;        mask off density selector
  863.     cp    1
  864.     jp    nz,bthk4
  865.     ld    a,b
  866.     or    a
  867.     rrca
  868.     ld    b,a
  869. bthk4:    ld    a,(secshf)
  870. bthk5:    or    a
  871.     jp    z,bthk6
  872.     push    af
  873.     ld    a,b
  874.     rrca
  875.     ld    b,a
  876.     pop    af
  877.     dec    a
  878.     jp    bthk5
  879. bthk6:    ld    a,b
  880.     ld    (offsec),a
  881.     ret
  882. ;
  883. ; ----------- Driver configuration area ------------
  884. ;
  885. ; Host specific ports
  886. ctrlpt    equ    10H;        Controller ports (WD 1791)
  887. statpt    equ    ctrlpt
  888. trkreg    equ    ctrlpt+1
  889. secreg    equ    ctrlpt+2
  890. datapt    equ    ctrlpt+3
  891. ;
  892. ; 1791/2/3 Controller chip specific
  893. ; For most Z80 implementations the data request and interrupt from
  894. ; the 1791 is connected to NMI (possibly gated by the CPU halt
  895. ; status line).  Thus a CPU halt is ended by the appropriate
  896. ; controller status, with the RET instruction in memory location
  897. ; 066h.  A status read after the interrupt will reset the interrupt,
  898. ; as will satisfying the data request.  8080s need more hardware.
  899. wrtmsk    equ    0FCH;        Status bits useful after write
  900. rdmask    equ    09CH;            "    "    read
  901. clrcmd    equ    0CH;        clear controller/reset
  902. rdcmd    equ    08CH;        read physical sector
  903. wtcmd    equ    0ACH;        write physical sector
  904. seekcmd    equ    014H;        seek track
  905. ;
  906. ; Kaypro Specific
  907. bitpt    equ    01CH;        KAYPRO control
  908. drvmsk    equ    3;        bits 0 & 1 select drive
  909. sideb    equ    4;        side selection bit
  910. prtbsy    equ    8;        Parallel printer busy (in)
  911. prtstrb    equ    16;        strobe printer data
  912. densb    equ    32;        density selection bit, 1=single
  913. mtroff    equ    64;        1 bit stops drive motors
  914. bank    equ    128;        Select memory bank.
  915. ;
  916. ;    *** This area is accessed/altered by support programs ***
  917. info:
  918. ; The "info" area has been organized to fit into exactly 128 bytes
  919. ; for convenience in auxiliary programs that reconfigure this.
  920. ;
  921. ; The CPM standard Disk Parameter Block, extended
  922. ; Modification to this structure changes the driver
  923. ;
  924. dpblk:    ; Different values for:    KPRO4    KPRO2    HP125    TVTS802
  925. ;     CPM sectors/physical track
  926. cpmspt:    dw    32;        40    40    32    36
  927. ;    log2(sectors/cpmallocation block)
  928. bsh:    db    4;        4    3    3    4
  929. ;    blm, exm calculated from bsh
  930.     db    0FH,01H;    0Fh,1    7,0    7,0    0Fh,0
  931. ;    total blocks on drive
  932. dsm:    dw    157;        196    194    251    170
  933. ;    directory entries - 1
  934. drm:    dw    63;        63    63    127    63
  935. ;    directory/other blocks pre-allocated
  936.     db    80H,00H;    0C0h,0    0F0h,0    0F0h,0    080h,0
  937. ;    cks=(drm+1)/4 (or 0 for fixed)
  938. cks:    dw    16;        16    16    32    16
  939. ;    reserved tracks
  940. off:    dw    1;        1    1    3    4
  941. ;    CPM extension. 1,2,4,8 sectors/phys record
  942. hstblk:    db    4;        4    4    2    2
  943. ;
  944. ; The sector skew translation table. Room for 10k/track
  945. sxltbl:    db     0, 1, 2, 3, 4, 5, 6, 7
  946.     db     8, 9,10,11,12,13,14,15
  947.     db    16,17,18,19,20,21,22,23
  948.     db    24,25,26,27,28,29,30,31
  949.     db    32,33,34,35,36,37,38,39
  950.     db    40,41,42,43,44,45,46,47
  951.     db    48,49,50,51,52,53,54,55
  952.     db    56,57,58,59,60,61,62,63
  953.     db    64,65,66,67,68,69,70,71
  954.     db    72,73,74,75,76,77,78,79
  955. ;
  956. ; Customization tables for system
  957.     db    0;    SPARE BYTE
  958. ;    Physical ID of 1st sector on track
  959. sec1st:    db    1;        0    0    1    1
  960. ;    Strategy in computing physical addresses
  961. config:    db    4;        2    0    2    2
  962. ; (high bit set for single density)
  963. ; = 0:    1 sided, phys adr = hst adr
  964. ;   1:    sec>offsec side1, adrsec=off-sec
  965. ;   2:    odd trks on side 1, trkadr=hstrk/2
  966. ;   3:    side1 is ntrks up
  967. ;   4:    side1 is ntrks up, count backward
  968. maxcase    equ    4
  969. ;    Number of tracks on physical disk
  970. ntrks:    db    40;        40    40    40    40
  971. ;    Correction to side 1 sector adr.
  972. nsecs:    db    0;        10    0    0    0
  973. ;
  974. ; This portion of "actmsg" is used as ID by altdrive.
  975. altid:        db    'IBM PC (CP/M-86 DSDD)$$$$$$'
  976. ; At least one terminal "$" must be left in above message
  977. ; DO NOT CHANGE LENGTH OF MESSAGE
  978. infosz    equ    $-info
  979. ;
  980. ; The following area is not altered when changing disk types,
  981. ; but includes the standard CPM configuration tables.  This
  982. ; portion must be customized on installation to host only.
  983. ;
  984. modrv:    db    1;    Which drive to alter (0 = A)
  985. dskode:    db    02H;     and the drive selection coding
  986. dendbl:    db    0;    base command for double density
  987. densgl:    db    32;    base command for single density
  988. invert:    db    0;    1 to invert data bits on transfer
  989. ;
  990. ; The CPM standard dpb.  Pointers to above and CPM storage.
  991. dpb:    dw    sxltbl;        0 for no translation
  992.     dw    0,0,0;    *** CPM mungs these, must be in RAM ***
  993.     dw    dirbuf;        pointer
  994.     dw    dpblk;        pointer
  995.     dw    csv;        pointer
  996.     dw    alv;        pointer
  997. ;
  998. ; END of Unalterable (except for values) configuration area
  999. ;
  1000. ; "donemsg" and "actmsg" messages MUST be supplied
  1001. donemsg:    db    cr,lf,'(DSKDRIVE terminated)$'; on removal
  1002. actmsg:    
  1003. drvmsg:        db    cr,lf,'Drive '
  1004. drvid:        db    'B: set to $'
  1005. ;
  1006. ; The revised foreign disk drivers.
  1007. ;
  1008. home:    ld    bc,0
  1009.     call    setrk
  1010.     ld    a,(hstwrt)
  1011.     or    a
  1012.     jp    nz,home1
  1013.     ld    (hstact),a
  1014. home1:    ret    
  1015. ;
  1016. seldsk:    ld    a,c
  1017.     ld    (sekdsk),a
  1018.     ld    a,(modrv)
  1019.     cp    c
  1020.     jp    nz,@seldk
  1021.     ld    hl,dpb
  1022.     ret    
  1023. ;
  1024. ; Postpone actual selection of originals until read/write
  1025. ; to avoid motor turn-ons, pre-seeks etc. until needed
  1026. setrk:    ld    h,b
  1027.     ld    l,c
  1028.     ld    (sektrk),hl
  1029.     ret    
  1030. ;
  1031. setsec:    ld    a,c
  1032.     ld    (seksec),a
  1033.     jp    @setsec
  1034.  
  1035. setdma:    ld    h,b
  1036.     ld    l,c
  1037.     ld    (dmaadr),hl
  1038.     jp    @setdma
  1039. ;
  1040. sectran:
  1041.     ld    a,(sekdsk);    Needed because RAMDISK fouls
  1042.     ld    hl,modrv;    by not knowing it was not
  1043.     cp    (hl);        selected.
  1044.     jp    nz,@sectran
  1045.     ld    a,d
  1046.     or    e
  1047.     jp    z,sectran2;    no translation, return alone
  1048.     ex    de,hl
  1049.     add    hl,bc
  1050.     ld    l,(hl)
  1051.     ld    h,0
  1052.     ret
  1053. sectran2:
  1054.     ld    h,b
  1055.     ld    l,c
  1056.     ret
  1057. ;
  1058. oread:    ld    hl,(sektrk);    do original read routine
  1059.     ld    b,h
  1060.     ld    c,l
  1061.     call    @setrk
  1062.     jp    @read
  1063. ;
  1064. owrite:    push    bc;        do original write routine
  1065.     ld    hl,(sektrk)
  1066.     ld    b,h
  1067.     ld    c,l
  1068.     call    @setrk
  1069.     pop    bc
  1070.     jp    @write
  1071. ;
  1072. ; Digital Researchs (flawed) deblocking algorithm.
  1073. read:    ld    a,(modrv)
  1074.     ld    b,a
  1075.     ld    a,(sekdsk)
  1076.     cp    b
  1077.     jp    nz,oread
  1078.     xor    a
  1079.     ld    (unacnt),a
  1080.     ld    a,1
  1081.     ld    (readop),a
  1082.     ld    (rsflag),a
  1083.     ld    a,2;        mark "write unallocated"
  1084.     ld    (wrtype),a
  1085.     jp    rdwrt
  1086. ;
  1087. write:    ld    a,(modrv)
  1088.     ld    b,a
  1089.     ld    a,(sekdsk)
  1090.     cp    b
  1091.     jp    nz,owrite
  1092.     xor    a
  1093.     ld    (readop),a;    Not a read
  1094.     ld    a,c
  1095.     ld    (wrtype),a
  1096.     cp    2;        Code for "write unallocated"
  1097.     jp    nz,chkuna;    else wrt to unalloc, set params
  1098.     ld    hl,(bsh);    l := bsh, minimum 3
  1099.     ld    a,1
  1100. write1:    rlca
  1101.     dec    l
  1102.     jp    nz,write1;    Compute block size, in sectors
  1103.     ld    (unacnt),a
  1104. ;    ld    a,(sekdsk)
  1105. ;    ld    (unadsk),a
  1106.     ld    hl,(sektrk)
  1107.     ld    (unatrk),hl
  1108.     ld    a,(seksec)
  1109.     ld    (unasec),a
  1110. ;    "    "
  1111. ; Check for write to unallocated sector
  1112. chkuna:    ld    a,(unacnt)
  1113.     or    a
  1114.     jp    z,alloc;    No unallocated remain
  1115.     dec    a
  1116.     ld    (unacnt),a;    Reduce for next time
  1117. ;    ld    a,(sekdsk)
  1118. ;    ld    hl,unadsk
  1119. ;    cp    (hl)
  1120. ;    jp    nz,alloc;    Not same disk
  1121.     ld    hl,unatrk
  1122.     call    eqtrks
  1123.     jp    nz,alloc;    Not same track
  1124.     ld    a,(seksec)
  1125.     ld    hl,unasec
  1126.     cp    (hl)
  1127.     jp    nz,alloc;    seksec <> unasec
  1128. ;
  1129.     inc    (hl);        unacnt > 0, disk, track sector ok
  1130.     ld    a,(hl)
  1131.     ld    hl,cpmspt
  1132.     cp    (hl)
  1133.     jp    c,inbuff;    Not overflow to next track
  1134.     xor    a
  1135.     ld    (unasec),a
  1136.     ld    hl,(unatrk)
  1137.     inc    hl
  1138.     ld    (unatrk),hl
  1139. inbuff:    xor    a
  1140.     ld    (rsflag),a;    match found, mark unnecessary read
  1141.     jp    rdwrt
  1142. ;
  1143. ; Not an unallocated record, requires pre-read
  1144. alloc:    xor    a
  1145.     ld    (unacnt),a
  1146.     inc    a
  1147.     ld    (rsflag),a
  1148. ;    "    "
  1149. rdwrt:    xor    a;        read or write
  1150.     ld    (errflg),a
  1151.     ld    a,(secshf);    Compute host sector
  1152.     ld    b,a
  1153.     inc    b
  1154.     ld    a,(seksec)
  1155.     rla;            Saving Hi bit in carry
  1156. rdwrt1:    rra
  1157.     or    a;        clear carry
  1158.     dec    b
  1159.     jp    nz,rdwrt1;    sekhst := seksec SHR secshf
  1160.     ld    (sekhst),a
  1161.     ld    hl,hstact
  1162.     ld    a,(hl)
  1163.     ld    (hl),01H;    Set hstact for next
  1164.     or    a
  1165.     jp    z,filhst;    Was not active
  1166. ;    ld    a,(sekdsk)
  1167. ;    ld    hl,hstdsk
  1168. ;    cp    (hl)
  1169. ;    jp    nz,flush
  1170.     ld    hl,hsttrk
  1171.     call    eqtrks
  1172.     jp    nz,flush
  1173.     ld    a,(sekhst)
  1174.     ld    hl,hstsec
  1175.     cp    (hl)
  1176.     jp    z,match
  1177. flush:    ld    a,(hstwrt);    Proper disk but not correct sector
  1178.     or    a
  1179.     call    nz,wthst;    dirty buffer, write it out
  1180. ;    "    "
  1181. filhst:    ld    a,(sekhst)
  1182.     ld    (hstsec),a
  1183.     ld    hl,(sektrk)
  1184.     ld    (hsttrk),hl
  1185. ;    ld    a,(sekdsk);    May have to fill the host buffer
  1186. ;    ld    (hstdsk),a
  1187.     ld    a,(rsflag)
  1188.     or    a
  1189.     call    nz,rdhst
  1190.     xor    a
  1191.     ld    (hstwrt),a;    Mark buffer clean
  1192. ;    "    "
  1193. ; Copy data to or from buffer, depending on "readop"
  1194. match:    ld    a,(hstblk)
  1195.     dec    a
  1196.     ld    hl,seksec
  1197.     and    (hl)
  1198.     ld    l,a
  1199.     ld    h,00H
  1200.     add    hl,hl;        *128
  1201.     add    hl,hl
  1202.     add    hl,hl
  1203.     add    hl,hl
  1204.     add    hl,hl
  1205.     add    hl,hl
  1206.     add    hl,hl
  1207.     ld    de,buff
  1208.     add    hl,de;        point to buffer area
  1209.     ex    de,hl
  1210.     ld    hl,(dmaadr)
  1211.     ex    de,hl
  1212.     ld    bc,128
  1213.     ld    a,(readop)
  1214.     or    a
  1215.     jp    nz,rwmov
  1216.     ld    a,01H
  1217.     ld    (hstwrt),a;    Mark buffer dirty for write
  1218.     ex    de,hl;        And trade move direction
  1219. ;    "    "
  1220. ; Transfer hl^ to de^ for bc, invert bits on "invert"
  1221. rwmov:    ld    a,(invert)
  1222.     or    a
  1223.     jp    z,rwmov2
  1224. rwmov1:    ld    a,(hl)
  1225.     cpl
  1226.     ld    (de),a
  1227.     inc    de
  1228.     inc    hl
  1229.     dec    bc
  1230.     ld    a,b
  1231.     or    c
  1232.     jp    nz,rwmov1
  1233.     jp    qflush
  1234. ;
  1235. ; No inversion, move as rapidly as possible
  1236. rwmov2:    ldir;                    *** Z80 code ***
  1237. ;    "    "
  1238. ; Clear host buffer if this is a directory write
  1239. qflush:    ld    a,(wrtype)
  1240.     cp    1;        Code for directory write
  1241.     ld    a,(errflg)
  1242.     ret    nz
  1243.     or    a
  1244.     ret    nz
  1245.     xor    a
  1246.     ld    (hstwrt),a;    will be clean after write
  1247. ;    "    "
  1248. wthst:    call    rwtbgn
  1249. wthst1:    ei;            during seeks
  1250.     call    setup
  1251.     or    a
  1252.     jp    nz,rwtxit
  1253.     ld    a,(hstblk)
  1254.     ld    e,wtcmd;    write command
  1255.     ld    c,datapt;    I/o port for data
  1256.     ld    hl,buff
  1257.     di
  1258.     rrca
  1259.     jp    nc,wthst2;    Not 128 byte physical rcd
  1260.     ld    b,128
  1261.     call    dcmnde
  1262.     jp    w256
  1263. wthst2:    ld    b,0
  1264.     rrca
  1265.     jp    nc,wthst3;    Not 256 byte physical rcd
  1266.     call    dcmnde
  1267.     jp    w256
  1268. wthst3:    rrca
  1269.     jp    nc,wthst4;    1024 byte physical rcd
  1270.     call    dcmnde
  1271.     jp    w512;        512 byte physical rcd
  1272. wthst4:    call    dcmnde
  1273. ;    "    "
  1274. w1024:    halt;            Else 1024 byte rcd.
  1275.     outi;                        *** Z80 code
  1276.     jp    nz,w1024
  1277. w768:    halt
  1278.     outi
  1279.     jp    nz,w768
  1280. w512:    halt
  1281.     outi
  1282.     jp    nz,w512
  1283. w256:    halt
  1284.     outi
  1285.     jp    nz,w256;    May be a W128, on entry bc
  1286. wthst5:    in    a,(statpt)
  1287.     rra
  1288.     jp    c,wthst5;    Await non-busy
  1289.     rla
  1290.     and    wrtmsk
  1291.     jp    z,rwtxit
  1292.     call    clear
  1293.     dec    d
  1294.     jp    nz,wthst1;    retry
  1295.     ld    a,0FFH;        Signal error
  1296.     jp    rwtxit
  1297. ;
  1298. ; Set up NMI return, save controller track setting
  1299. rwtbgn:    ld    a,(0066H)
  1300.     ld    (save66),a
  1301.     ld    a,0C9H;        "RET" instruction for NMI
  1302.     ld    (0066H),a
  1303.     in    a,(trkreg)
  1304.     ld    (trksav),a
  1305.     ld    d,10;        retries
  1306.     ret
  1307. ;
  1308. eqtrks:    ex    de,hl
  1309.     ld    hl,sektrk
  1310.     ld    a,(de)
  1311.     cp    (hl)
  1312.     ret    nz
  1313.     inc    de
  1314.     inc    hl
  1315.     ld    a,(de)
  1316.     cp    (hl)
  1317.     ret    
  1318. ;
  1319. rdhst:    call    rwtbgn
  1320. rdhst1:    ei
  1321.     call    setup
  1322.     or    a
  1323.     jp    nz,rwtxit
  1324.     ld    a,(hstblk)
  1325.     ld    e,rdcmd;    read command
  1326.     ld    c,datapt;    port to read data from
  1327.     ld    hl,buff
  1328.     di
  1329.     rrca
  1330.     jp    nc,rdhst2;    Not 128 bytes per phys. block
  1331.     ld    b,128
  1332.     call    dcmnde
  1333.     jp    r256
  1334. rdhst2:    ld    b,0;        i.e. 256
  1335.     rrca
  1336.     jp    nc,rdhst3;    Not 256 bytes per block
  1337.     call    dcmnde
  1338.     jp    r256
  1339. rdhst3:    rrca
  1340.     jp    nc,rdhst4;    1024 byte physical record
  1341.     call    dcmnde
  1342.     jp    r512;        512 bytes per block
  1343. rdhst4:    call    dcmnde
  1344. ;    "    "
  1345. r1024:    halt;            else 1024 bytes per block
  1346.     ini;                        *** Z80 code
  1347.     jp    nz,r1024
  1348. r768:    halt
  1349.     ini
  1350.     jp    nz,r768
  1351. r512:    halt
  1352.     ini
  1353.     jp    nz,r512
  1354. r256:    halt
  1355.     ini
  1356.     jp    nz,r256;    May be r128, on entry (b)
  1357. rdhst5:    in    a,(statpt)
  1358.     rra
  1359.     jp    c,rdhst5;    Await non-busy status
  1360.     rla
  1361.     and    rdmask
  1362.     jp    z,rwtxit
  1363.     call    clear
  1364.     dec    d
  1365.     jp    nz,rdhst1;    retry
  1366.     ld    a,0FFH;        Signal error
  1367. ;    "    "
  1368. ; Exit, restoring 66, trkreg, setting errflg on (a)
  1369. rwtxit:    push    af
  1370.     ld    a,(save66)
  1371.     ld    (0066H),a
  1372.     ld    a,(trksav)
  1373.     out    (trkreg),a
  1374.     pop    af
  1375.     ei
  1376.     ld    (errflg),a
  1377.     ret    
  1378. ;
  1379. ; docase (a) on table (hl)^
  1380. docase:    add    a
  1381.     add    l
  1382.     ld    l,a
  1383.     adc    h
  1384.     sub    l
  1385.     ld    h,a
  1386.     ld    a,(hl)
  1387.     inc    hl
  1388.     ld    h,(hl)
  1389.     ld    l,a
  1390.     jp    (hl)
  1391. ;
  1392. cases:    dw    case0, case1, case2
  1393.     dw    case3, case4
  1394. ;
  1395. setup:    ld    hl,(hsttrk)
  1396.     ld    (adrtrk),hl
  1397.     ld    a,(hstsec)
  1398.     ld    (adrsec),a
  1399.     xor    a
  1400.     ld    (side),a;    default use side 0
  1401.     ld    a,(config)
  1402.     and    0fh;        remove density selection
  1403.     cp    maxcase+1
  1404.     jp    nc,error
  1405.     ld    hl,cases;    Execute the appropriate code
  1406.     call    docase
  1407.     jp    seek
  1408. ;
  1409. case0:    ret
  1410. ;
  1411. case1:    ld    a,(adrsec);    config = 1
  1412.     ld    hl,offsec
  1413.     sub    (hl)
  1414.     ret    c
  1415.     ld    hl,nsecs
  1416.     add    (hl)
  1417.     ld    (adrsec),a
  1418.     ld    a,1
  1419.     ld    (side),a
  1420.     ret
  1421. ;
  1422. case2:    ld    hl,(adrtrk)
  1423.     ld    a,l
  1424.     and    1
  1425.     ld    (side),a
  1426.     ld    a,h
  1427.     rra
  1428.     ld    h,a
  1429.     ld    a,l
  1430.     rra
  1431.     ld    l,a    
  1432.     ld    (adrtrk),hl
  1433.     ret    nc;        on side 0
  1434.     ld    hl,nsecs
  1435.     ld    a,(adrsec);    side 1, correct sector address
  1436.     add    (hl)
  1437.     ld    (adrsec),a
  1438.     ret
  1439. ;
  1440. case3:    ld    a,(adrtrk)
  1441.     ld    hl,ntrks
  1442.     cp    (hl);        tracks per side
  1443.     ret    c
  1444.     sub    (hl);        On second side
  1445.     ld    (adrtrk),a
  1446.     ld    a,1
  1447.     ld    (side),a
  1448.     ret
  1449. ;
  1450. case4:    ld    a,(adrtrk)
  1451.     ld    hl,ntrks
  1452.     cp    (hl)
  1453.     ret    c;        On first side
  1454.     cpl
  1455.     add    (hl)
  1456.     add    (hl);        Now we count down
  1457.     ld    (adrtrk),a
  1458.     ld    a,1
  1459.     ld    (side),a
  1460.     ret
  1461. ;
  1462. error:    ld    a,0FFH;        config unknown, error
  1463.     ret
  1464. ;
  1465. ; Host specific routines here - setup for Kaypro 4
  1466. seek:    ld    a,(dsktrk);    If we have switched drives set
  1467.     out    (trkreg),a;    the controller to match history
  1468.     ld    a,(config);    Set up for side and density
  1469.     or    a
  1470.     ld    a,(dendbl)
  1471.     jp    p,seek1;    Normal double density system
  1472.     ld    a,(densgl);    else set single density command
  1473. seek1:    ld    b,a
  1474.     ld    a,(side);    Move side selection bit into place.
  1475.     and    1
  1476.     rla
  1477.     rla
  1478.     or    b;        Compute drive selection/density code
  1479.     ld    b,a
  1480.     in    a,(bitpt);    Keep bank (80), turn mtr on (40=0)
  1481.     push    af;        clear DDEN (20), keep lptstrobe (10)
  1482.     and    98H;        ignore prtbusy(8), clear side(4),
  1483.     or    b;        drive code (2, 1)     bit weights
  1484.     ld    b,a
  1485.     ld    a,(dskode)
  1486.     or    b
  1487.     or    10H;        turn off any lptstrobe bit (Kaypro)
  1488.     out    (bitpt),a;    selecting drive/side/density
  1489.     pop    af
  1490.     and    40H
  1491.     call    nz,pause;    Motor was off, wait for it
  1492.     ld    a,(dsktrk)
  1493.     inc    a
  1494.     call    z,clear;    Never used yet
  1495.     ld    a,(adrtrk)
  1496.     ld    hl,dsktrk
  1497.     cp    (hl)
  1498.     jp    z,seek4
  1499. ;    "    "
  1500.     out    (datapt),a;    changing tracks
  1501.     ld    a,seekcmd;    seek track
  1502.     call    dcmnd
  1503.     halt
  1504. seek3:    in    a,(statpt)
  1505.     rra
  1506.     jp    c,seek3;    await non-busy
  1507.     rla
  1508.     and    98H;        Check status
  1509.     jp    z,seek4
  1510.     call    clear
  1511.     dec    d
  1512.     jp    nz,seek;    retry allowd
  1513.     ld    a,0FFH;        Else signal error
  1514.     ret    
  1515. ;
  1516. seek4:    ld    a,(adrsec);    Successful seek
  1517.     ld    hl,sec1st
  1518.     add    a,(hl)
  1519.     out    (secreg),a;    set physical sector
  1520.     ld    a,(adrtrk)
  1521.     ld    (dsktrk),a
  1522.     xor    a
  1523.     ret    
  1524. ;
  1525. ; Clear disc controller.
  1526. ; a,f
  1527. clear:    ld    a,clrcmd
  1528.     call    dcmnd
  1529.     halt
  1530. clear1:    in    a,(statpt);    Await "not busy"
  1531.     rra
  1532.     jp    c,clear1
  1533.     xor    a
  1534.     ld    (dsktrk),a
  1535.     ret    
  1536. ;
  1537. ; command (e) to disk controller
  1538. ; a,f
  1539. dcmnde:    ld    a,e
  1540. ;    "    "
  1541. ; command (a) to disk controller
  1542. ; f
  1543. dcmnd:    out    (ctrlpt),a
  1544.     push    bc
  1545.     ld    b,20
  1546. dcmnd1:    dec    b
  1547.     jp    nz,dcmnd1;    pause for controller status
  1548.     pop    bc
  1549.     ret    
  1550. ;
  1551. ; pause (b) * 10 Millisec.  Set for 2.5 Mhz clock.
  1552. ; a,f,b
  1553. pause:    push    de
  1554. pause1:    ld    de,0686H;    <<<< Change for other clocks <<<
  1555. pause2:    dec    de
  1556.     ld    a,e
  1557.     or    d
  1558.     jp    nz,pause2
  1559.     dec    b
  1560.     jp    nz,pause1
  1561.     pop    de
  1562.     ret    
  1563. ;
  1564. ; ------------------- Initialized storage --------------------------
  1565. active:        db    true;    Non zero if active. allows 1..255
  1566. ;
  1567. ; ==================================================================
  1568. ; ****    Put initialized application storage past this point    ****    
  1569. ; ==================================================================
  1570. ;
  1571. dsktrk:    db    0FFH;    mark not selected/used?
  1572. ;
  1573. ; ------------------ End initialized storage -----------------------
  1574. ;
  1575. ; ------------------- Uninitialized storage ------------------------
  1576. segsiz    equ    $-@base;    Relocation bit table starts here
  1577. dmadr:    ds    2;    This value is known to BDOS.  It is not
  1578. ;            necessarily the same as the BIOS value
  1579. ;
  1580. ; ==================================================================
  1581. ; ****    Put uninitialized application storage past this point    ****
  1582. ; ==================================================================
  1583. ;
  1584. dmaadr:    ds    2;    this is the value known to the BIOS
  1585. secshf:    ds    1;    log2(hstblk).  For run-time addressing
  1586. ;
  1587. sekdsk:    ds    1;    seek ids, at CPM level
  1588. sektrk:    ds    2
  1589. seksec:    ds    1
  1590. ;
  1591. save66:    ds    1;    Save/restore 066h, for NMI operation
  1592. trksav:    ds    1;    Save/restore controller track reg.
  1593. ;
  1594. ;hstdsk: ds    1;    Host ids, at blocked level
  1595. hsttrk:    ds    2
  1596. hstsec:    ds    1
  1597. ;
  1598. adrtrk:    ds    2;    Physical trk adr. for controller
  1599. adrsec:    ds    1;        and sector
  1600. offsec:    ds    1;    Sector offset for 2nd side
  1601. ;
  1602. sekhst:    ds    1;    block/deblock variables
  1603. hstact:    ds    1
  1604. hstwrt:    ds    1
  1605. unacnt:    ds    1
  1606. ;unadsk: ds    1
  1607. unatrk:    ds    2
  1608. unasec:    ds    1
  1609. errflg:    ds    1
  1610. rsflag:    ds    1
  1611. readop:    ds    1
  1612. wrtype:    ds    1
  1613. ;
  1614. side:    ds    1
  1615. dirbuf:    ds    128
  1616. csv:    ds    64
  1617. alv:    ds    64
  1618. buff:    ds    1024;    Can handle 1024 byte host sector
  1619. ;
  1620. ; --------------- End application uninitialized storage --------------
  1621. ;
  1622.     ds    32;    Local stack of at least 16 words
  1623. ;            plus any remainder on page
  1624. ; align to next page boundary
  1625.     align    256,bdosv
  1626. lclstk:
  1627. ;*************************************************
  1628. ; End of segment to be relocated.
  1629. pages    equ    ($-@base)/256;    So loader knows memory needs.
  1630. ;
  1631.     end
  1632. Eô