home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / mex / mexxapii.lbr / MXH-AP52.AQM / MXH-AP52.ASM
Assembly Source File  |  1986-12-08  |  22KB  |  769 lines
  1. ;    TITLE  'MEX Overlay for Apple ][ / SSC / Smartmodem'
  2. ;
  3. ;  MXH-AP52.ASM 
  4. ;
  5. REV    EQU    52           ; 01 Nov 1986
  6. ; 
  7. ; This overlay is specific for the following hardware:
  8. ;
  9. ;    Apple ][ +/e  with PCPI Applicard
  10. ;    Apple Super Serial Card
  11. ;
  12. ;            - Jim Lill via "Sparrow" 716-377-1113
  13. ;------------------------------------------------------------------
  14. ; REVISION HISTORY:
  15. ;------+---------+----------------+--------------------------------
  16. ; Rev. |  Date   |     Author     |       Description
  17. ;------+---------+----------------+--------------------------------
  18. ; 5.2  |1 Nov 86 | Jim Lill       | -eliminated Modem specific section
  19. ;      |         |                |  requires use of Modem overlay
  20. ;      |         |                |  such as MXO-SM14 or MXM-2413
  21. ;      |         |                |  Seems to work better with MXM-2413
  22. ;------+---------+----------------+--------------------------------
  23. ; 5.1  |5 Apr 86 | Jim Lill       | -changed CLSMSG and EOSMSG
  24. ;      |         |                | -added INITBAUD equate for setting
  25. ;      |         |                |  MSPEED and baud in INITMOD
  26. ;------+---------+----------------+--------------------------------
  27. ; 5.0  |1 Apr 86 | Jim Lill       | created adaption, includes DCD
  28. ;      |         |                | and a spot for RND detect.
  29. ;------+---------+----------------+--------------------------------
  30. ; IMPORTANT NOTE:
  31. ;    This overlay is based on MXO-AP50.ASM by Henry Middlebrook
  32. ;    Refer to it for additional info. The changes in this overlay
  33. ;    could be easily adapted to other Middlebrook work like AP34
  34. ;    To find changes, search for "MEXplus"
  35. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  36. ;            PORT OVERLAY SECTION
  37. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  38. ;
  39. BELL        EQU    07H    ;bell
  40. CR        EQU    0DH    ;carriage return
  41. ESC        EQU    1BH    ;escape
  42. LF        EQU    0AH    ;linefeed
  43. TAB        EQU    09H    ;tab
  44. YES        EQU    0FFH
  45. NO        EQU    0
  46. ;
  47. ;----------------------------------------------------------------------
  48. ;    Apple Super Serial Card equates
  49. ;    -------------------------------
  50. ;
  51. SSCSLOT        EQU    2        ;Slot of Super Serial Card
  52. ;
  53. INITBAUD    EQU    5        ;Initial Baud Rate
  54.                     ; 0=110   5=1200
  55.                     ; 1=300   6=2400
  56.                     ; 2=450   7=4800
  57.                     ; 3=600   8=9600
  58.                     ; 4=710   9=19200
  59. ;
  60. MODDATP        EQU    0C088H + (SSCSLOT*10H)    ;data port of ACIA
  61. MODSTAP        EQU    0C089H + (SSCSLOT*10H)    ;status port of ACIA
  62. MODCTLP        EQU    0C08BH + (SSCSLOT*10H)    ;control port of ACIA
  63. MODCMDP        EQU    0C08AH + (SSCSLOT*10H)    ;command port of ACIA
  64. ;
  65. ;
  66. RDBYTE        EQU    0FFE0H    ;Read a Byte from Apple (A = BYTE)
  67. WRBYTE        EQU    0FFE3H    ;Write a Byte to Apple (C = BYTE)
  68. RDWORD        EQU    0FFE6H    ;Read 2 Bytes from Apple (DE = BYTES)
  69. WRWORD        EQU    0FFE9H    ;Write 2 Bytes to Apple (DE = BYTES)
  70. RDNBYTS        EQU    0FFECH    ;Read N Bytes (DE = COUNT, HL = BUFFER)
  71. WRNBYTS        EQU    0FFEFH    ;Write N Bytes (DE = COUNT, HL = BUFFER)
  72. ;
  73. PEEK1BYTE    EQU    6    ;Command to Peek 1 Byte in the Apple
  74. POKE1BYTE    EQU    7    ;Command to Poke 1 Byte to the Apple
  75. ;
  76. ; New DCD routine equate MEXplus
  77. ;
  78. CTSMSK        EQU    00100000B    ;mask to test for carrier
  79. ;
  80. ; Status bit equates for CCS serial port
  81. ;
  82. MDSNDB        EQU    10H
  83. MDSNDR        EQU    10H
  84. MDRCVB        EQU    08H
  85. MDRCVR        EQU    08H
  86. ;
  87. ; Equates for PSW (Parity, Stop Bit, Word Length) used by SSC ACIA
  88. ;  In these bytes the high nibble is the Word Length mask, the low
  89. ;  nibble is the Parity mask for the ACIA PSWFIX routine.
  90. ;
  91. P8N1        EQU    010H    ;8 NONE 1
  92. P7E1        EQU    036H    ;7 EVEN 1
  93. P7O1        EQU    032H    ;7 ODD 1
  94. P7N1        EQU    030H    ;7 NONE 1
  95. ;
  96. BRKMSK        EQU    0CH    ;mask byte for BREAK function
  97. DISCB        EQU    0AH    ;command byte for ACIA to drop DTR
  98. ;
  99. ;----------------------------------------------------------------------
  100. ;
  101. ;    MEX Service Processor Calls
  102. ;
  103. MEX    EQU    0D00H    ;address of the service processor
  104. INMDM    EQU    255    ;get char from port to A, CY=no more in 100 ms
  105. TIMER    EQU    254    ;delay 100ms * reg B
  106. TMDINP    EQU    253    ;B=# secs to wait for char, cy=no char
  107. CHEKCC    EQU    252    ;check for ^C from KBD, Z=present
  108. SNDRDY    EQU    251    ;test for modem-send ready
  109. RCVRDY    EQU    250    ;test for modem-receive ready
  110. SNDCHR    EQU    249    ;send a character to the modem (after sndrdy)
  111. RCVCHR    EQU    248    ;recv a char from modem (after rcvrdy)
  112. LOOKUP    EQU    247    ;table search: see CMDTBL comments for info
  113. PARSFN    EQU    246    ;parse filename from input stream
  114. BDPARS    EQU    245    ;parse baud-rate from input stream
  115. SBLANK    EQU    244    ;scan input stream to next non-blank
  116. EVALA    EQU    243    ;evaluate numeric from input stream
  117. LKAHED    EQU    242    ;get nxt char w/o removing from input
  118. GNC    EQU    241    ;get char from input, cy=1 if none
  119. ILP    EQU    240    ;inline print
  120. DECOUT    EQU    239    ;decimal output
  121. PRBAUD    EQU    238    ;print baud rate
  122. PRNTBL    EQU    237    ;print command table in columns (HL=addr)
  123. PRID    EQU    236    ;print MEX ID string on console
  124. ;
  125. CONOUT    EQU    2    ;simulated BDOS function 2: console char out
  126. PRINT    EQU    9    ;simulated BDOS function 9: print string
  127. INBUF    EQU    10    ;input buffer, same structure as BDOS 10
  128. ;
  129. ;
  130. ;======================================================================
  131. ;
  132.     ORG    100H    ;we begin
  133. ;
  134. ; changed jumps for MEXplus
  135. ;
  136.     DB    0C3H    ;flags a LOADable file (for 8080)
  137.     DS    2    ;MEX has a JMP START here    
  138. ;
  139. ; The following variables are located at the beginning of the program
  140. ; to facilitate modification without the need of re-assembly. They will
  141. ; be moved in MEX 2.0.
  142. ;
  143. PMODEM:    DB    YES    ;\ / These two locations are            103H
  144. SMODEM:    DB    NO    ;/ \ not referenced by MEX.            104H
  145. TPULSE:    DB    'T'    ;Tone/Pulse (used only in Smodem overlay)    105H
  146. CLOCK:    DB    70    ;70-72 valid range for PCPI               106H
  147. MSPEED:    DB    INITBAUD;sets display time for sending a file        107H
  148.             ;uses INITBAUD equate, changes during
  149.             ;use via PBAUD routine
  150. BYTDLY:    DB    1    ;default time to send character in        108H
  151.             ;terminal mode file transfer (0-9)
  152.             ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  153. CRDLY:    DB    1    ;end-of-line delay in terminal            109H
  154.             ;mode file transfer for slow BBS systems
  155.             ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  156. COLUMS:    DB    5    ;number of directory columns            10AH
  157. SETFL:    DB    YES    ;yes=user-defined SET command            10BH
  158. SCRTST:    DB    YES    ;yes=if home cursor and clear screen        10CH
  159.             ;routine at CLRSCRN
  160.     DB    0    ;was once ACKNAK, now spare            10DH
  161. BAKFLG:    DB    NO    ;yes=make .BAK file                10EH
  162. CRCDFL:    DB    YES    ;yes=default to CRC checking            10FH
  163.             ;no=default to Checksum checking
  164. TOGCRC:    DB    YES    ;yes=allow toggling of Checksum to CRC        110H
  165. CVTBS:    DB    NO    ;yes=convert backspace to rub            111H
  166. TOGLBK:    DB    YES    ;yes=allow toggling of bksp to rub        112H
  167. ADDLF:    DB    NO    ;no=no LF after CR to send file in        113H
  168.             ;terminal mode (added by remote echo)
  169. TOGLF:    DB    YES    ;yes=allow toggling of LF after CR        114H
  170. TRNLOG:    DB    NO    ;yes=allow transmission of logon        115H
  171.             ;write logon sequence at location LOGON
  172. SAVCCP:    DB    YES    ;yes=do not overwrite CCP            116H
  173. LOCNXT:    DB    NO    ;yes=local cmd if EXTCHR precedes        117H
  174.             ;no=not local cmd if EXTCHR precedes
  175. TOGLOC:    DB    YES    ;yes=allow toggling of LOCNXTCHR        118H
  176. LSTTST:    DB    YES    ;yes=allow toggling of printer on/off        119H
  177.             ;in terminal mode. Set to no if using
  178.             ;the printer port for the modem
  179. XOFTST:    DB    YES    ;yes=allow testing of XOFF from remote        11AH
  180.             ;while sending a file in terminal mode
  181. XONWT:    DB    NO    ;yes=wait for XON after sending CR while    11BH
  182.             ;transmitting a file in terminal mode    
  183. TOGXOF:    DB    YES    ;yes=allow toggling of XOFF testing        11CH
  184. IGNCTL:    DB    NO    ;yes=do not send control characters        11DH
  185.             ;above CTL-M to CRT in terminal mode
  186.             ;no=send any incoming CTL-char to CRT
  187. EXTRA1:    DB    0    ;for future expansion                11EH
  188. EXTRA2:    DB    0    ;for future expansion                11FH
  189. BRKCHR:    DB    '@'-40H    ;^@ = Send a 300 ms. break tone            120H
  190. NOCONN:    DB    'N'-40H    ;^N = Disconnect from phone line        121H
  191. LOGCHR:    DB    'L'-40H    ;^L = Send logon                122H
  192. LSTCHR:    DB    'P'-40H    ;^P = Toggle printer                123H
  193. UNSVCH:    DB    'R'-40H    ;^R = Close input text buffer            124H
  194. TRNCHR:    DB    'T'-40H    ;^T = Transmit file to remote            125H
  195. SAVCHR:    DB    'Y'-40H    ;^Y = Open input text buffer            126H
  196. EXTCHR:    DB    '^'-40H    ;^^ = Send next character            127H
  197. ;
  198. ; Equates used only by PMMI routines grouped together here.
  199. ;
  200. PRATE:    DB    125    ;125=20pps dialing, 250=10pps            128H
  201.     DB    0    ;not used                    129H
  202. ;
  203. ; Jump table accessed by MEX to write/read serial port
  204. ;
  205. IN$MODSTAP:    JMP    RD$MODSTAP     ;read ACIA status port        12AH
  206.         DS    7
  207. OUT$MODDATP:    JMP    WR$MODDATP    ;send character to ACIA        134H
  208.         DS    7
  209. IN$MODDATP:    JMP    RD$MODDATP    ;read character from ACIA    13EH
  210.         DS    7
  211. ;
  212. ; Bit-test routines.  These will be merged with the above
  213. ; routines in MEX 2.0 to provide a more reasonable format
  214. ;
  215. MASKR:        ANI    MDRCVB ! RET    ;bit to test for receive ready    148H
  216. TESTR:        CPI    MDRCVR ! RET    ;value of rcv. bit when ready    14BH
  217. MASKS:        ANI    MDSNDB ! RET    ;bit to test for send ready    14EH
  218. TESTS:        CPI    MDSNDR ! RET    ;value of send bit when ready    151H
  219. ;---------------------------------------------------------------------------
  220. ; MEXplus changes:
  221. ;  - was unused area. >>> MUST total 12bytes <<<
  222. ;  - now used for the Ringing and Carrier Detect jumps
  223. ;
  224. ; Note: There seems to be a conflict between other MXH overlays and
  225. ;       what is in the MexPlus Dist. Notes dated 2/20/86 regarding
  226. ;       the correct location of the two JMP. Other overlays inspected
  227. ;    have DCD at 154H and RNG at 157H. Notes say DCD at 157H and
  228. ;       RNG at 15AH. The following does work......
  229. ;
  230. DCDTEST:    JMP    DCDVEC        ;jump to carrier-detect routine 154H
  231. RNGTEST:    JMP    RNGVEC        ;jump to ring detect routine    157H
  232.                     ;
  233.                 DS    6        ;remainder of space           
  234. ;
  235. ;---------------------------------------------------------------------------
  236. ;
  237. LOGON:        DS    2        ;not used by MEX          160H
  238. DIALV:        DS     3        ;dial a digit in A (ref SMOVL)    162H
  239. DISCV:        JMP    DISCON        ;drops DTR to hang-up fast!    165H
  240. GOODBV:        JMP    GOODBYE        ;called before exit to CPM    168H
  241. INMODV:        JMP    INITMOD        ;go to user written routine    16BH
  242. NEWBDV:        JMP    PBAUD        ;changes baud with phone #    16EH
  243. NOPARV:        RET  !    NOP  !    NOP    ;set modem for no-parity     171H
  244. PARITV:        RET  !    NOP  !    NOP    ;set modem parity             174H
  245. SETUPV:        JMP    SETCMD        ;                177H
  246. SPMENV:        DS     3        ;not used by MEX        17AH
  247. VERSNV:        JMP    SYSVER        ;                17DH
  248. BREAKV:        JMP    SENDBRK        ;                180H
  249. ;
  250. ; The following jump vector provides the overlay with access to special
  251. ; routines in the main program (retained and supported in the main pro-
  252. ; gram for MDM overlay compatibility). These should not be modified by
  253. ; the overlay.
  254. ;
  255. ; Note that for MEX 2.0 compatibility, you should not try to use these
  256. ; routines, since this table will go away with MEX 2.0 (use the MEX
  257. ; service call processor instead).
  258. ;
  259. ILPRTV:        DS    3    ;replace with MEX function 9         183H
  260. INBUFV:        DS    3    ;replace with MEX functin 10        186H
  261. ILCMPV:        DS    3    ;replace with table lookup funct 247    189H
  262. INMDMV:        DS    3    ;replace with MEX function 255        18CH
  263. NXSCRV:        DS    3    ;not supported by MEX            18FH
  264. TIMERV:        DS    3    ;replace with MEX function 254        192H
  265. ;
  266. ; Clear/screen and clear/end-of-screen. Each routine must use the
  267. ; full 9 bytes alloted (may be padded with nulls).
  268. ;
  269. ;
  270. CLREOS:        LXI    D,EOSMSG    ;                195H
  271.         MVI    C,PRINT
  272.         CALL    MEX
  273.         RET            ;                19DH
  274. ;
  275. CLS:        LXI    D,CLSMSG    ;                19EH
  276.         MVI    C,PRINT
  277.         CALL    MEX
  278.         RET            ;                1A6H
  279. ;
  280. ;
  281. ;        *** END OF FIXED FORMAT AREA ***
  282. ;--------------------------------------------------------------------------
  283. ; Make sure MEXplus has all of its' reserved area..
  284. ;
  285.         ORG    0200H        
  286.  
  287. ;--------------------------------------------------------------------------
  288. ;        Overlay  Fixed  Messages  Area
  289. ;
  290. ; these codes changed to match PCPI CONFIGSV values for Televideo 950
  291. ;
  292. ;
  293. EOSMSG:    DB    ESC,89,0,0,'$'        ;clear to end of screen message
  294. ;
  295. CLSMSG:    DB    ESC,42,0,0,'$'        ;clear screen message
  296. ;
  297. VERMSG:    DB    CR,LF,'MEX for Apple ][ / PCPI / SSC, '
  298.     DB    'Overlay Version: ',REV/10+'0','.'
  299.     DB    REV MOD 10+'0'
  300.     DB    CR,LF,LF,'$'
  301.     DB    0,'Overlay by Middlebrook/Lill',0,'$'
  302. ;
  303. ;----------------------------------------------------------------------
  304. ; These routines are specific to the Apple ][+ with Applicard.  The
  305. ; routines read modem hardware (Apple Super Serial Card ACIA) directly
  306. ; from the Applicard.
  307. ;
  308. ; Read the Command Port of ACIA
  309. ;
  310. RD$MODCMDP:    PUSH    D
  311.         LXI    D,MODCMDP
  312.         CALL    PEEK
  313.         POP    D
  314.         RET
  315. ;
  316. ; Write to the Command Port of ACIA
  317. ;
  318. WR$MODCMDP:    PUSH    D
  319.         LXI    D,MODCMDP
  320.         CALL    POKE
  321.         POP    D
  322.         RET
  323. ;
  324. ; Read the Status Port of the ACIA
  325. ;
  326. RD$MODSTAP:    PUSH    D
  327.         LXI    D,MODSTAP
  328.         CALL    PEEK
  329.         POP    D
  330.         RET
  331. ;
  332. ; Write to the Control Port of the ACIA
  333. ;
  334. WR$MODCTLP:    PUSH    D
  335.         LXI    D,MODCTLP
  336.         CALL    POKE
  337.         POP    D
  338.         RET
  339. ;
  340. ; Read the Control Port of the ACIA
  341. ;
  342. RD$MODCTLP:    PUSH    D
  343.         LXI    D,MODCTLP
  344.         CALL    PEEK
  345.         POP    D
  346.         RET
  347. ;
  348. ; Read Data Port of ACIA
  349. ;
  350. RD$MODDATP:    PUSH    D
  351.         LXI    D,MODDATP
  352.         CALL    PEEK
  353.         POP    D
  354.         RET
  355. ;
  356. ; Write to the Serial Data Port of the ACIA
  357. ;
  358. WR$MODDATP:    PUSH    D
  359.         LXI    D,MODDATP
  360.         CALL    POKE
  361.         POP    D
  362.         RET
  363. ;
  364. ; Peek at 1 byte from Apple 6502 address space
  365. ; ENTRY: DE = Address in Apple
  366. ; EXIT:    A = Data
  367. ;
  368. PEEK:    PUSH    B
  369.     MVI    C,PEEK1BYTE
  370.     CALL    WRBYTE
  371.     CALL    WRWORD
  372.     CALL    RDBYTE
  373.     POP    B
  374.     RET
  375. ;
  376. ; Poke 1 byte to Apple 6502 address space
  377. ; ENTRY: DE = Address in Apple
  378. ; EXIT:    A = Data
  379. ;
  380. POKE:    PUSH    B
  381.     MOV    B,A
  382.     MVI    C,POKE1BYTE
  383.     CALL    WRBYTE
  384.     CALL    WRWORD
  385.     MOV    C,B
  386.     CALL    WRBYTE
  387.     POP    B
  388.     RET
  389. ;
  390. ;----------------------------------------------------------------------
  391. ; The new stuff for MEXplus
  392. ;
  393. ; Data Carrier Detect Routine
  394. ;
  395. DCDVEC:        CALL    RD$MODSTAP    ;read SSC status port
  396.         ANI    CTSMSK        ;isolate carrier bit
  397.         JNZ    NOCARR        ;0=carrier detected
  398.         CMA            ;make it 0ffh
  399.         RET            ;
  400. NOCARR:        XRA    A        ;make it 0
  401.         RET             ;
  402. ;
  403. ; Ring Detect Routine
  404. ;
  405. RNGVEC:        JMP    DCDVEC        ;overlay doesn't know
  406. ;
  407. ;----------------------------------------------------------------------
  408. ;
  409. ; This routine sends a timed Break to modem from SSC card.
  410. ;
  411. SENDBRK:CALL    RD$MODCMDP    ;get current command status
  412.     STA    CMDSV
  413.     ORI    BRKMSK        ;mask to make ACIA send BREAK
  414.     CALL    WR$MODCMDP    ;send command
  415.     MVI    B,5
  416.     MVI    C,TIMER        ;wait 500 msecs
  417.     CALL    MEX
  418.     LDA    CMDSV        ;get old command state
  419.     CALL    WR$MODCMDP    ;put it back
  420.     RET
  421. ;
  422. ;.....
  423. ;
  424. ; You can add your own routine here to set DTR low and/or send a break
  425. ; tone to disconnect when exiting to CPM.
  426. ;
  427. GOODBYE:    RET        ;just return so exit to system
  428.                 ;will not cause disconnect
  429. ;.....
  430. ;
  431. ; The following is used to initialize the SSC card for eight data bits,
  432. ; no parity, one stop bit, and baud=INITBAUD     
  433. ;
  434. INITMOD:MVI    A,0BH        ;default No Parity byte for ACIA
  435.     STA    PARSV        ;save it
  436.     MVI    A,10H        ;default 8 Data, 1 Stop Bits for ACIA
  437.     STA    WRDSV        ;save it
  438.     MVI    A,INITBAUD      ;set to initial baud equate
  439.     JMP    PBAUD        ;let PBAUD setup ACIA
  440. ;
  441. ; This is the secondary entry used by the overlay to set baud,
  442. ; parity, and stop bit parameters of ACIA.
  443. ;
  444. INITMOD1:
  445.     LDA    PARSV        ;get current parity byte
  446.     ORI    0BH        ;enable DTR, RECV IRQ, and RTS
  447.     STA    CMDSV        ;save byte for other uses
  448.     CALL    WR$MODCMDP    ;send to command port
  449.     PUSH    H
  450.     LXI    H,BAUDSV    ;get address of current baud byte
  451.     LDA    WRDSV        ;get current word length byte
  452.     ORA    M        ;put 'em together
  453.     STA    CTLSV        ;...and save for other uses
  454.     POP    H
  455.     CALL    WR$MODCTLP    ;now send to control port
  456.     RET
  457. ;
  458. CMDSV:    DB    0        ;temporary storage
  459. CTLSV:    DB    0        ;temporary storage
  460. ;
  461. ;.....
  462. ;
  463. ; This routine drops DTR to force modem to disconnect.  Does NOT do
  464. ; any initialization.
  465. ;
  466. DISCON:    CALL    RD$MODCMDP    ;get current command status
  467.     STA    CMDSV        ;save it
  468.     MVI    A,DISCB        ;get disconnect byte (drops DTR)
  469.     CALL    WR$MODCMDP    ;send to ACIA
  470.     MVI    B,10
  471.     MVI    C,TIMER        ;wait 1 second
  472.     CALL    MEX
  473.     LDA    CMDSV        ;get back command status
  474.     CALL    WR$MODCMDP    ;put it back in ACIA register
  475.     MVI    B,10
  476.     MVI    C,TIMER        ;wait another second
  477.     CALL    MEX
  478.     RET            ;back to program
  479. ;
  480. ;.....
  481. ;
  482. ; This routine changes the modem baud rate with phone list entry
  483. ;
  484. ; Set baud-rate code in A (if supported by your modem overlay).  PMMI
  485. ; supports only five rates, which are validated here. NOTE: this routine
  486. ; (ie, the one vectored through NEWBDV) should update MSPEED with the
  487. ; passed code, but ONLY if that rate is supported by the hardware.
  488. ;
  489. PBAUD:    PUSH    H        ;don't alter anybody
  490.     PUSH    D
  491.     PUSH    B
  492.     MOV    E,A        ;code to DE
  493.     MVI    D,0
  494.     LXI    H,BAUDTB    ;offset into table
  495.     DAD    D
  496.     MOV    A,M        ;fetch code
  497.     ORA    A        ;0 means unsupported code
  498.     JZ    PBEXIT        ;exit if so
  499.     STA    BAUDSV         ;good rate, save it for INITMOD1
  500.     CALL    INITMOD1    ;set baud (and PSW)
  501.     MOV    A,E        ;get speed code back
  502.     STA    MSPEED        ;make it current
  503.     JMP    PBEXIT + 1    ;jump error flag set
  504. PBEXIT:    STC            ;set return error for STBAUD caller
  505.     POP    B        ;all done
  506.     POP    D
  507.     POP    H
  508.     RET
  509. ;
  510. ; Table of baud rate parameters for supported rates
  511. ;
  512. BAUDTB:    DB    03H,06H,0,07H,0        ;110,300,450,610,710
  513.     DB    08H,0AH,0CH,0EH,0FH    ;1200,2400,4800,9600,19200
  514. BAUDSV: DB    06H            ;current baud byte
  515. ;
  516. ;.....
  517. ;
  518. ; Sign-on message
  519. ;
  520. SYSVER:    LXI    D,VERMSG
  521.     MVI    C,PRINT
  522.     CALL    MEX
  523.     RET
  524. ;
  525. ;.....
  526. ;
  527. ; Newline on console
  528. ;
  529. CRLF:    MVI    A,CR
  530.     CALL    TYPE
  531.     MVI    A,LF        ;fall into TYPE
  532. ;
  533. ; type char in A on console
  534. ;
  535. TYPE:    PUSH    H        ;save 'em
  536.     PUSH    D
  537.     PUSH    B
  538.     MOV    E,A        ;align output character
  539.     MVI    C,CONOUT    ;print via MEX
  540.     CALL    MEX
  541.     POP    B
  542.     POP    D
  543.     POP    H
  544.     RET
  545. ;
  546. ;----------------------------------------------------------------------
  547. ;
  548. ; The remainder of this overlay implements a very versatile SET command
  549. ; -- if you prefer not to write a SET for your modem, you may delete the
  550. ; code from here to the END statement. Control is passed here after
  551. ; MEX parses a SET command.
  552. ;
  553. ;
  554. SETCMD:    MVI    C,SBLANK    ;any arguments?
  555.     CALL    MEX
  556.     JC    SETSHO        ;if not, go print out values
  557.     LXI    D,CMDTBL    ;parse command
  558.     CALL    TSRCH        ;from table
  559.     PUSH    H        ;any address on stack
  560.     RNC            ;if we have one, execute it
  561.     POP    H        ;nope, fix stack
  562. SETERR:    LXI    D,SETEMS    ;print error
  563.     MVI    C,PRINT
  564.     CALL    MEX
  565.     RET
  566. ;
  567. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  568. ;
  569. ; SET command table ... note that tables are constructed of command-
  570. ; name (terminated by high bit=1) followed by word-data-value returned
  571. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  572. ; a binary zero.
  573. ;
  574. ; Note that LOOKUP attempts to find the next item in the input stream
  575. ; in the table passed to it in HL ... if found, the table data item is
  576. ; returned in HL; if not found, LOOKUP returns carry set.
  577. ;
  578. CMDTBL:    DB    '?'+80H            ;"set ?"
  579.     DW    STHELP
  580.     DB    'BAU','D'+80H        ;"set baud"
  581.     DW    STBAUD
  582.     DB    'PS','W'+80H        ;"set PSW"
  583.     DW    STPSW
  584.     DB    'TON','E'+80H        ;'set TONE/PULSE byte to 'T'
  585.     DW    STTONE
  586.     DB    'PULS','E'+80H        ;'set TONE/PULSE byte to 'P'
  587.     DW    STPULSE
  588.     DB    0            ;<<=== table terminator
  589. ;
  590. ; SET <no-args>: print current statistics
  591. ;
  592. SETSHO:    LXI    H,SHOTBL    ;get table of SHOW subroutines
  593. SETSLP:    MOV    E,M        ;get table address
  594.     INX    H
  595.     MOV    D,M
  596.     INX    H
  597.     MOV    A,D        ;end of table?
  598.     ORA    E
  599.     RZ            ;exit if so
  600.     PUSH    H        ;save table pointer
  601.     XCHG            ;adrs to HL
  602.     CALL    GOHL        ;do it
  603.     CALL    CRLF        ;print newline
  604.     MVI    C,CHEKCC    ;check for console abort
  605.     CALL    MEX
  606.     POP    H        ;it's done
  607.     JNZ    SETSLP        ;continue if no abort
  608.     RET
  609. ;
  610. GOHL:    PCHL
  611. ;
  612. ; Table of SHOW subroutines
  613. ;
  614. SHOTBL:    
  615.     DW    BDSHOW        ;displays current baud
  616.     DW    PSWSHOW        ;displays current PSW
  617.     DW    TPSHOW        ;displays current TPULSE byte (0105H)
  618.     DW    CRLF
  619.     DW    0        ;<<== table terminator
  620. ;
  621. ; SET ?  processor
  622. ;
  623. STHELP:    CALL     CLS            ;clear screen
  624.     LXI    D,HLPMSG
  625.     MVI    C,PRINT
  626.     CALL    MEX
  627.     RET
  628. ;
  629. ; The help message
  630. ;
  631. HLPMSG:    DB    CR,LF,'SET Commands available are:',CR,LF,LF
  632.     DB    'SET BAUD  <110, 300, 600, 1200, 2400, 4800,'
  633.     DB    ' 9600, or 19200>',CR,LF
  634.     DB    'SET PSW   <8N1, 7E1, 7O1, or 7N1> -- Word Length,'
  635.     DB    ' Parity, Stop Bits',CR,LF
  636.     DB    'SET TONE  (Sets flag for TONE  dialing)',CR,LF
  637.     DB    'SET PULSE (Sets flag for PULSE dialing)'
  638.     DB    CR,LF,LF,'$'
  639. ;
  640. ; SET BAUD processor
  641. ;
  642. STBAUD:    MVI    C,BDPARS    ;function code
  643.     CALL    MEX    
  644.     JC    SETERR        ;invalid code
  645.     CALL    PBAUD        ;try to set it
  646.     JC    SETERR        ;unsupported code
  647. BDSHOW:    CALL    ILPRT        ;display baud
  648.     DB    'Baud rate:',TAB,' ',0
  649.     LDA    MSPEED
  650.     MVI    C,PRBAUD    ;use MEX routine
  651.     CALL    MEX
  652.     RET
  653. ;
  654. ; SET PSW processor
  655. ;
  656. STPSW:    MVI    C,SBLANK
  657.     CALL    MEX
  658.     JC    SETERR        ;SET PSW should have had argument
  659.     LXI    D,PSWTBL    ;look for PSW match in table
  660.     CALL    TSRCH
  661.     JC    SETERR        ;not there, so report error
  662.     CALL    FIXPSW        ;routine to set PARSV and WRDSV
  663.     CALL    INITMOD1    ;now fix ACIA registers
  664. ;
  665. PSWSHOW:
  666.     CALL    ILPRT
  667.     DB    'PSW setting:',TAB,' ',0
  668.     LDA    PSWSET
  669.     CPI    P8N1
  670.     JNZ    PSW1
  671.     CALL    ILPRT
  672.     DB    '8N1',0
  673.     RET
  674. PSW1:    CPI    P7E1
  675.     JNZ    PSW2
  676.     CALL    ILPRT
  677.     DB    '7E1',0
  678.     RET
  679. PSW2:    CPI    P7O1
  680.     JNZ    PSW3
  681.     CALL    ILPRT
  682.     DB    '7O1',0
  683.     RET
  684. PSW3:    CPI    P7N1
  685.     JNZ    PSW4
  686.     CALL    ILPRT
  687.     DB    '7N1',0
  688.     RET
  689. PSW4:    CALL    ILPRT
  690.     DB    '<< ERROR >>',0
  691.     RET
  692. ;
  693. ;
  694. PSWSET:    DB    010H        ;storage and default (8N1)
  695. PARSV:    DB    0BH        ;storage and default (no parity)
  696. WRDSV:    DB    010H        ;storage and default (8 data, 1 stop bits)
  697. ;
  698. FIXPSW:    MOV    A,L        ;PSW byte from table
  699.     STA    PSWSET        ;save it
  700.     ANI    0F0H        ;mask for word length bits
  701.     STA    WRDSV        ;put in storage
  702.     LDA    PSWSET        ;get back PSW byte
  703.     ANI    0FH        ;mask for parity bits
  704.     RLC            ;first shift into upper nibble..
  705.     RLC            ;...away we go...
  706.     RLC            ;.....and go...
  707.     RLC            ;......and done
  708.     ORI    0BH        ;mask needed for ACIA command register
  709.     STA    PARSV        ;put in storage
  710.     RET
  711. ;
  712. PSWTBL:    DB    '8N','1'+80H
  713.     DW    P8N1        ;filled in with equ's
  714.     DB    '7E','1'+80H
  715.     DW    P7E1        ; - ditto -
  716.     DB    '7O','1'+80H
  717.     DW    P7O1        ; - ditto -
  718.     DB    '7N','1'+80H
  719.     DW    P7N1        ; - ditto -
  720.     DB    0        ;<<==== table terminator
  721. ;
  722. ;.....
  723. ;
  724. ; These routines set TPULSE flag at 0105H to either 'T' or 'P' so that
  725. ; MODEM (specifically MXO-SM13.ASM) overlay will dial in TONE or PULSE
  726. ; mode.  The settings are mutually exclusive.
  727. ;
  728. STTONE:    MVI    A,'T'        ;get T flag
  729.     STA    TPULSE        ;put into proper place
  730.     JMP    TPSHOW        ;display dial mode
  731. ;
  732. STPULSE:
  733.     MVI    A,'P'        ;get P flag
  734.     STA    TPULSE
  735. ;
  736. TPSHOW:    CALL    ILPRT
  737.     DB    'Dial Mode:',TAB,' ',0
  738.     LDA    TPULSE
  739.     CPI    'T'
  740.     JNZ    TP1
  741.     CALL    ILPRT
  742.     DB    'TONE',0
  743.     RET
  744. TP1:    CPI    'P'
  745.     JNZ    TP2
  746.     CALL    ILPRT
  747.     DB    'PULSE',0
  748.     RET
  749. TP2:    CALL    ILPRT
  750.     DB    '<< ERROR >>',0
  751.     RET
  752. ;
  753. ;......
  754. ;
  755. ; Compare next input-stream item in table @DE; CY=1 if not found,
  756. ; else HL = matched data item
  757. ;
  758. TSRCH:    MVI    C,LOOKUP    ;get function code
  759.     JMP    MEX        ;pass to MEX processor
  760. ;
  761. ; Print in-line message ... blows away C register
  762. ;
  763. ILPRT:    MVI    C,ILP        ;get function code
  764.     JMP    MEX        ;go do it
  765. ;
  766. ;
  767. ;    >>>>   End of MXH-APnn   <<<<
  768.  
  769.