home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / mex / mxm-us13.aqm / MXM-US13.ASM
Assembly Source File  |  1985-08-05  |  26KB  |  818 lines
  1.     PAGE    0        ; Let print utility paginate
  2.     Title    'MEX overlay for the U.S. Robotics S-100 version 1.3'
  3. ;     08/27/84 by Don Wilke
  4. ;    08/29/84 added fancy video conditionals
  5. ;    08/30/84 added parity routines
  6. ;
  7. REV    EQU    13        ; Overlay revision level
  8. ;
  9. ; Misc equates
  10. ;
  11. NO    EQU    0
  12. YES    EQU    0FFH
  13. BELL    EQU    07H        ; Bell
  14. TAB    EQU    09H        ; Tab
  15. LF    EQU    0AH        ; Line feed
  16. CR    EQU    0DH        ; Carriage return
  17. ESC    EQU    1BH        ; Escape
  18. TPA    EQU    100H        ; Transient prog area
  19. MEX    EQU    0D00H        ; Address of the service processor
  20. ATTRIB    EQU    YES        ; Yes if fancy video supported
  21. ;
  22. ; USR port equates
  23. ;
  24. PORT    EQU    0C0H        ; Base I/O address for USR S-100 card
  25. MODCT1  EQU    PORT+1        ; 8251 control port
  26. MODDAT  EQU    PORT        ; 8251 data port
  27. MDDCDB    EQU    10000000B    ; Carrier detect bit
  28. MDDCDA    EQU    10000000B    ; Value when active
  29. MDRCVB    EQU    00000010B    ; Bit to test for receive
  30. MDRCVR    EQU    00000010B    ; Value when ready
  31. MDSNDB    EQU    00000001B    ; Bit to test for send
  32. MDSNDR    EQU    00000001B    ; Value when ready
  33. MMODEA    EQU    11001111B    ; 8 bits, clock/64, 2 stop bits 
  34. MMODEB    EQU    01001110B    ; 8 bits, clock/16, 1 stop bit
  35. MMCMDA    EQU    00110111B    ; RTS hi, error reset, DTR hi, enable TX/RX
  36. MMCMDB    EQU    00010111B    ; Error reset, DTR hi, enable TX/RX
  37. MRESET    EQU    01000000B    ; 8251 reset
  38. ;
  39. ; Following are function codes for the MEX service call processor
  40. ;
  41. INMDM    EQU    255        ; Get char from port to A, CY=no more in 100 ms
  42. TIMER    EQU    254        ; Delay 100ms * reg B
  43. TMDINP    EQU    253        ; B=# secs to wait for char, cy=no char
  44. CHEKCC    EQU    252        ; Check for ^C from KBD, Z=present
  45. SNDRDY    EQU    251        ; Test for modem-send ready
  46. RCVRDY    EQU    250        ; Test for modem-receive ready
  47. SNDCHR    EQU    249        ; Send a character to the modem (after sndrdy)
  48. RCVCHR    EQU    248        ; Recv a char from modem (after rcvrdy)
  49. LOOKUP    EQU    247        ; Table search: see CMDTBL comments for info
  50. PARSFN    EQU    246        ; Parse filename from input stream
  51. BDPARS    EQU    245        ; Parse baud-rate from input stream
  52. SBLANK    EQU    244        ; Scan input stream to next non-blank
  53. EVALA    EQU    243        ; Evaluate numeric from input stream
  54. LKAHED    EQU    242        ; Get nxt char w/o removing from input
  55. GNC    EQU    241        ; Get char from input, cy=1 if none
  56. ILP    EQU    240        ; Inline print
  57. DECOUT    EQU    239        ; Decimal output
  58. PRBAUD    EQU    238        ; Print baud rate
  59. ; 
  60. CONOUT    EQU    2        ; Simulated BDOS function 2: console char out
  61. PRINT    EQU    9        ; Simulated BDOS function 9: print string
  62. INBUF    EQU    10        ; Input buffer,same structure as BDOS 10
  63.  
  64.     ORG    TPA        ; We begin
  65. ; 
  66.     DS    3        ; MEX has a JMP START here
  67. ; 
  68. ; The following variables are located at the beginning of the program
  69. ; to facilitate modification without the need of re-assembly. They will
  70. ; be moved in MEX 2.0.
  71. ; 
  72. PMODEM:    DB    NO        ; Yes=PMMI modem \ / These 2 locations are not
  73. SMODEM:    DB    YES        ; Yes=Smartmodem / \ referenced by MEX
  74. TPULSE:    DB    'P'        ; T=touch,P=pulse (not referenced by MEX)
  75. CLOCK:    DB    40        ; Clock speed x .1, up to 25.5 mhz.
  76. MSPEED:    DB    5        ; Sets display time for sending a file
  77.                 ; 0=110    1=300  2=450  3=600  4=710
  78.                 ; 5=1200 6=2400 7=4800 8=9600 9=19200
  79. BYTDLY:    DB    5        ; Default time to send character in
  80.                 ; terminal mode file transfer (0-9)
  81.                 ; 0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  82. CRDLY:    DB    5        ; End-of-line delay after CRLF in terminal
  83.                 ; mode file transfer for slow BBS systems
  84.                 ; 0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  85. COLUMS:    DB    5        ; Number of directory columns
  86. SETFL:    DB    YES        ; Yes=user-defined SET command
  87. SCRTST:    DB    YES        ; Yes=if home cursor and clear screen
  88.                 ; routine at CLRSCRN
  89.     DB    0        ; Was once ACKNAK,now spare
  90. BAKFLG:    DB    NO        ; Yes=make .BAK file
  91. CRCDFL:    DB    YES        ; Yes=default to CRC checking
  92.                 ; No=default to Checksum checking
  93. TOGCRC:    DB    YES        ; Yes=allow toggling of Checksum to CRC
  94. CVTBS:    DB    NO        ; Yes=convert backspace to rub
  95. TOGLBK:    DB    YES        ; Yes=allow toggling of bksp to rub
  96. ADDLF:    DB    NO        ; No=no LF after CR to send file in
  97.                 ; terminal mode (added by remote echo)
  98. TOGLF:    DB    YES        ; Yes=allow toggling of LF after CR
  99. TRNLOG:    DB    NO        ; Yes=allow transmission of logon
  100.                 ; write logon sequence at location LOGON
  101. SAVCCP:    DB    YES        ; Yes=do not overwrite CCP
  102. LOCNXT:    DB    NO        ; Yes=local cmd if EXTCHR precedes
  103.                 ; No=not local cmd if EXTCHR precedes
  104. TOGLOC:    DB    YES        ; Yes=allow toggling of LOCNXTCHR
  105. LSTTST:    DB    YES        ; Yes=allow toggling of printer on/off
  106.                 ; in terminal mode. Set to no if using
  107.                 ; the printer port for the modem
  108. XOFTST:    DB    NO        ; Yes=allow testing of XOFF from remote
  109.                 ; while sending a file in terminal mode
  110. XONWT:    DB    NO        ; Yes=wait for XON after sending CR while
  111.                 ; transmitting a file in terminal mode    
  112. TOGXOF:    DB    YES        ; Yes=allow toggling of XOFF testing
  113. IGNCTL:    DB    YES        ; Yes=do not send control characters
  114.                 ; above CTL-M to CRT in terminal mode
  115.                 ; no=send any incoming CTL-char to CRT
  116. EXTRA1:    DB    0        ; For future expansion
  117. EXTRA2:    DB    0        ; For future expansion
  118. BRKCHR:    DB    '@'-40H        ; ^@ = Send a 300 ms. break tone
  119. NOCONN:    DB    'N'-40H        ; ^N = Disconnect from phone line
  120. LOGCHR:    DB    'L'-40H        ; ^L = Send logon
  121. LSTCHR:    DB    'P'-40H        ; ^P = Toggle printer
  122. UNSVCH:    DB    'R'-40H        ; ^R = Close input text buffer
  123. TRNCHR:    DB    'T'-40H        ; ^T = Transmit file to remote
  124. SAVCHR:    DB    'Y'-40H        ; ^Y = Open input text buffer
  125. EXTCHR:    DB    '^'-40H        ; ^^ = Send next character
  126. ; 
  127. ; Equates used only by PMMI routines grouped together here.
  128. ; 
  129. PRATE:    DB    250        ; 125=20pps dialing, 250=10pps
  130.     DB    0        ; Not used
  131. ; 
  132. ; Low-level modem I/O routines: this will be replaced with
  133. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  134. ; routines if you'd like ... I'd recommend NOT putting part of
  135. ; a routine in this area,then jumping to the rest of the routine
  136. ; in the non-fixed area; that will complicate the 2.0 conversion)
  137. ; 
  138. INCTL1:    IN    MODCT1        ; In modem control port
  139.     RET
  140.     DB    0,0,0,0,0,0,0    ; Spares if needed for non-PMMI
  141. ; 
  142. OTDATA:    OUT    MODDAT        ; Out modem data port
  143.     RET
  144.     DB    0,0,0,0,0,0,0    ; Spares if needed for non=PMMI
  145. ; 
  146. INPORT:    IN    MODDAT        ; In modem data port
  147.     RET
  148.     DB    0,0,0,0,0,0,0    ; Spares if needed for non-PMMI
  149. ; 
  150. ; Bit-test routines.  These will be merged with the above
  151. ; routines in MEX 2.0 to provide a more reasonable format
  152. ; 
  153. MASKR:    ANI MDRCVB ! RET    ; Bit to test for receive ready
  154. TESTR:    CPI MDRCVR ! RET    ; Value of receive bit when ready
  155. MASKS:    ANI MDSNDB ! RET    ; Bit to test for send ready
  156. TESTS:    CPI MDSNDR ! RET    ; Value of send bit when ready
  157. ; 
  158. ; 
  159. ; Unused area: was once used for special PMMI functions,
  160. ; Now used only to retain compatibility with MDM overlays.
  161. ; You may use this area for any miscellaneous storage you'd
  162. ; like but the length of the area *must* be 12 bytes.
  163. ; 
  164.     DS    12
  165. ; 
  166. ; Special modem function jump table: if your overlay cannot handle
  167. ; some of these, change the jump to "DS 3", so the code present in
  168. ; MEX will be retained.  Thus, if your modem can't dial, change the
  169. ; JMP PDIAL at DIALV to DS 3, and MEX will print a "not-implemented"
  170. ; diagnostic for any commands that require dialing.
  171. ; 
  172. ; DIALV  dials the digit in A. See the comments at PDIAL for specs.
  173. ; 
  174. ; DISCV  disconnects the modem
  175. ; 
  176. ; GOODBV is called just before MEX exits to CP/M.  If your overlay
  177. ;        requires some exit cleanup, do it here.
  178. ; 
  179. ; INMODV is called when MEX starts up; use INMODV to initialize the modem.
  180. ; 
  181. ; NEWBDV is used for phone-number baud rates and is called with a baud-rate
  182. ;        code in the A register, value as follows:
  183. ; 
  184. ;      A=0:   110 baud       A=1:   300 baud      A=2:   450 baud
  185. ;      A=3:   600 baud       A=4:   710 baud      A=5:  1200 baud
  186. ;      A=6:  2400 baud       A=7:  4800 baud      A=8: 19200 baud
  187. ; 
  188. ;        If your overlay supports the passed baud rate,it should store the
  189. ;      value passed in A at MSPEED (107H), and set the requested rate. If
  190. ;      the value passed is not supported, you should simply return (with-
  191. ;      out modifying MSPEED) -or- optionally request a baud-rate from the
  192. ;      user interactively.
  193. ; 
  194. ; NOPARV is called at the end of each file transfer; your overlay may simply
  195. ;      return here, or you may want to restore parity if you set no-parity
  196. ;      in the following vector (this is the case with the PMMI overlay).
  197. ;      
  198. ; PARITV is called at the start of each file transfer; your overlay may simply
  199. ;      return here, or you may want to enable parity detection (this is the
  200. ;      case with the PMMI overlay).
  201. ; 
  202. ; SETUPV is the user-defined command ... to use this routine to build your own
  203. ;      MEX command, set the variable SETFL (117H) non-zero,and add your SET
  204. ;      code.  You can use the routine presented in the PMMI overlay as a 
  205. ;      guide for parsing, table lookup, etc.
  206. ; 
  207. ; SPMENU is provided only for MDM compatibility, and is not used by MEX 1.0 
  208. ;      for any purpose (it will be gone in MEX 2).
  209. ; 
  210. ; VERSNV is called immediately after MEX prints its sign-on message at cold
  211. ;      startup -- use this to identify your overlay in the sign-on message
  212. ;      (include overlay version number in the line).
  213. ; 
  214. ; BREAKV is provided for sending a BREAK (<ESC>-B in terminal mode).  If your
  215. ;      modem doesn't support BREAK, or you don't care to code a BREAK rou-
  216. ;      tine, you may simply execute a RET instruction.
  217. ; 
  218. LOGON:    DS    2        ; Needed for MDM compat, not ref'd by MEX
  219. DIALV:    DS    3        ; Dial digit in A 
  220. DISCV:    DS    3        ; Disconnect the modem
  221. GOODBV:    JMP    GOODBYE        ; Called before exit to CP/M
  222. INMODV:    JMP    NITMOD        ; Initialization. Called at cold-start
  223. NEWBDV:    JMP    PBAUD        ; Set baud rate
  224. NOPARV:    RET ! NOP ! NOP        ; Set modem for no-parity
  225. PARITV:    RET ! NOP ! NOP        ; Set modem parity
  226. SETUPV:    JMP    SETCMD        ; SET cmd
  227. SPMENV:    RET ! NOP ! NOP        ; Not used with MEX
  228. VERSNV:    JMP    SYSVER        ; Overlay's voice in the sign-on message
  229. BREAKV:    JMP    PBREAK        ; Send a break
  230. ; 
  231. ; The following jump vector provides the overlay with access to special
  232. ; routines in the main program (retained and supported in the main pro-
  233. ; gram for MDM overlay compatibility). These should not be modified by
  234. ; the overlay.
  235. ; 
  236. ; Note that for MEX 2.0 compatibility, you should not try to use these
  237. ; routines, since this table will go away with MEX 2.0 (use the MEX
  238. ; service call processor instead).
  239. ; 
  240. ILPRTV:    DS    3        ; Replace with MEX function 9
  241. INBUFV:    DS    3        ; Replace with MEX function 10
  242. ILCMPV:    DS    3        ; Replace with table lookup funct. 247
  243. INMDMV:    DS    3        ; Replace with MEX function 255
  244. NXSCRV:    DS    3        ; Not supported by MEX (returns w/no action)
  245. TIMERV:    DS    3        ; Replace with MEX function 254
  246. ; 
  247. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  248. ; SCRNTEST to YES at 010AH (above).  Each routine must use the
  249. ; full 9 bytes alloted (may be padded with nulls).
  250. ; 
  251. ; These routines (and other screen routines that MEX 2.0 will sup-
  252. ; port) will be accessed through a jump table in 2.0, and will be
  253. ; located in an area that won't tie the screen functions to the
  254. ; modem overlay (as the MDM format does).
  255. ; 
  256. CLREOS:    LXI    D,EOSMSG    ; Point to clear to EOS msg
  257.     MVI    C,PRINT        ; MEX print string funct #
  258.     CALL    MEX        ; Let MEX do it
  259.     RET
  260. ; 
  261. CLS:    LXI    D,CLSMSG    ; Point to clear screen msg
  262.     MVI    C,PRINT        ; MEX print string funct #
  263.     CALL    MEX        ; Let MEX do it
  264.     RET
  265. ; 
  266. ; The following routine sends a break "character" to the remote computer 
  267. ; for 300 ms.  The "MSPEED" value is needed to decide whether the modem 
  268. ; is at 300, 600, or 1200 baud.  The routine must know this because U.S.R. 
  269. ; sets up the RTS bit of the command register as a baud rate selection bit, 
  270. ; and this routine must be careful not to change it, or the user will end up 
  271. ; at a different baud rate after the break "character" is sent.  Note that 
  272. ; the "MVI A,01FH" does not change any flags.
  273. ; 
  274. PBREAK:    LDA    MSPEED        ; Get speed byte
  275.     CPI    3        ; Are we at 600 baud?
  276.     MVI    A,01FH        ; Set up for 600 (no flag changes)
  277.     JZ    PBRK2        ; And if we are, go do that
  278.     MVI    A,03FH        ; Otherwise,set up for 300/1200
  279. PBRK2:    OUT    MODCT1        ; Send break
  280.     PUSH    PSW        ; Save value
  281.     MVI    B,3        ; 300 ms delay value
  282.     MVI    C,TIMER        ; MEX service function #254
  283.     CALL    MEX        ; Wait that long
  284.     POP    PSW        ; Restore command byte
  285.     ANI    0F7H        ; Turn off break bit
  286.     OUT    MODCT1        ; Send command byte to UART
  287.     RET
  288. ; 
  289. ; The U.S.R. S-100 does not have a "quick-disconnect" feature like
  290. ; the Hayes does (by lowering DTR).  Therefore, "GOODBYE" is not
  291. ; implemented.  Yet control-N still works to hang up (see note
  292. ; above in introduction)
  293. ; 
  294. GOODBYE:    RET
  295. ; 
  296. ; *    *    *    *    *    *    *    *    *
  297. ;
  298. ; You can use this area for any special initialization or setup you may
  299. ; wish to include.  Each must stop with a RET.    This initialization
  300. ; sets up 1200 baud, 8 data bits, 1 stop bit, no parity.  Due to a
  301. ; quirk in the U.S.R. S-100 (it seems to have plenty of 'em), after
  302. ; you change baud rates, you should send an "AT" followed by a
  303. ; carriage return.  Therefore, this is done after every initialization
  304. ; when there is no carrier present.
  305. ; 
  306. ; NOTE: The U.S.R. S-100 does not operate too well at clock speeds of
  307. ;     over 4 MHz.  If you are running at that speed or higher,you
  308. ;     should uncomment (by removing the preceding semicolon) the
  309. ;     lines with XCHG.  These serve as time wasting routines to
  310. ;     let the U.S.R. S-100 catch up.  This is not a problem when
  311. ;     doing character I/O, as the program checks to see if the
  312. ;     modem is ready to accept a character.
  313. ; 
  314. NITMOD: MVI    A,0        ; Zero accumulator
  315.     OUT    MODCT1        ; Once
  316.     XCHG            ; For fast systems
  317.     XCHG            ; 
  318.     OUT    MODCT1        ; Twice
  319.     XCHG            ; For fast systems
  320.     XCHG            ; 
  321.     OUT    MODCT1        ; Three times,even
  322.     XCHG            ; For fast systems
  323.     XCHG            ; 
  324.     MVI    A,MRESET    ; Reset UART command
  325.     OUT    MODCT1        ; Send to control port
  326.     XCHG            ; For fast systems
  327.     XCHG            ; 
  328.     DB    3EH        ; "MVI,A" code
  329. MODEBT:    DB    MMODEB        ; Mode byte
  330.     OUT    MODCT1        ; Send to control port
  331.     XCHG            ; For fast systems
  332.     XCHG            ; 
  333.     DB    3EH        ; "MVI,A" code
  334. CMDBT:    DB    MMCMDA        ; Command byte
  335.     OUT    MODCT1        ; Send to control port
  336.     XCHG            ; For fast systems
  337.     XCHG            ; 
  338.     DB    3EH        ; "MVI,A" code
  339. BDCODE:    DB    5        ; Default baud rate code
  340.     STA    MSPEED        ; Stuff it
  341.     CALL    CARRCK        ; See if there is a carrier
  342.     RNZ            ; If so, don't do AT stuff
  343.     LXI    H,INISTR    ; Point to initialization string
  344. SNDL:    MOV    A,M        ; Get char to look at it
  345.     CPI    '$'        ; EOS char?
  346.     JZ    INITEX        ; Yes, exit
  347.     MOV    B,A        ; No, save char in B
  348.     CALL    OUTMOD        ; Output char to modem
  349.     INX    H        ; Point to next
  350.     JMP    SNDL        ; Loop 'til EOS
  351. ;
  352. INITEX:    MVI    B,15        ; Wait 1.5 sec
  353.     MVI    C,TIMER        ; MEX service function #254
  354.     CALL    MEX        ; Wait for USR to say "OK"
  355.     RET
  356. ;
  357. ; Command string sent to modem after I/O initialization
  358. ;
  359. INISTR:    DB    'AT'        ; Get modem's attention
  360.     DB    'X1'        ; Send extended result codes
  361. SPBYTE:    DB    'M1'        ; Speaker on 'til connect
  362.     DB    'S0=0'        ; Disable auto-answer
  363. WABYTE:    DB    'S7=30'        ; Wait 30 seconds for carrier
  364.     DB    'V1'        ; Set verbose result codes
  365.     DB    CR,'$'        ; End of command string
  366. ; 
  367. ; Output a character to the U.S.R. S-100
  368. ; (NOTE: This routine is not normally present in most overlays,
  369. ;      and is used by the NITMOD routine above.)
  370. ; 
  371. OUTMOD:    IN    MODCT1        ; Get status
  372.     ANI    MDSNDB        ; Mask for ready status
  373.     JZ    OUTMOD        ; Loop if not ready
  374.     MOV    A,B        ; Otherwise get the character
  375.     OUT    MODDAT        ; Output to the data port
  376.     RET            ; And return
  377. ; 
  378. PBAUD:    CPI    5        ; 5=1200 baud
  379.     JZ    OK1200        ; Set to 1200
  380.     CPI    3        ; 3=600 baud
  381.     JZ    OK600        ; Set to 600
  382.                 ; Else set to 300
  383. OK300:    CALL    WAIT60        ; Set longer wait for carrier
  384.     LXI    B,BD300        ; Point to initializers for 300 baud
  385.     MVI    A,1        ; 300 baud value
  386.     JMP    LOADBD        ; Go load it
  387. OK600:    CALL    WAIT60        ; Set longer wait for carrier
  388.     LXI    B,BD600        ; Point to initializers for 600 baud
  389.     MVI    A,3        ; 600 baud value
  390.     JMP    LOADBD        ; Go load it
  391. OK1200:    CALL    WAIT30        ; Set short wait for carrier
  392.     LXI    B,BD1200    ; Point to initializers for 1200 baud
  393.     MVI    A,5        ; 1200 baud value
  394. LOADBD:    STA    BDCODE        ; Change baud rate code value
  395.     LDAX    B        ; Get mode byte value
  396.     STA    MODEBT        ; Change mode byte
  397.     INX    B        ; Point to cmd byte
  398.     LDAX    B        ; Get cmd byte
  399.     STA    CMDBT        ; Change cmd byte
  400.     CALL    NITMOD        ; (Re)initialize modem
  401.     LDA    SETFLG        ; Get setflg
  402.     CPI    0FFH        ; Is it a 'SET'
  403.     JNZ    PBPSA        ; No, print bps in dial prompt
  404.     RET            ; Yes, just return
  405. PBPSA:    
  406.      IF    ATTRIB
  407.     LXI    D,INDVID    ; Set video attribute
  408.     CALL    PMSG        ; Issue attribute to term
  409.      ENDIF    ;ATTRIB
  410.     JMP    PBPS        ; Print bps rate
  411. ;
  412. ; Wait for carrier 30/60 seconds
  413. ;
  414. WAIT30:    MVI    A,'3'        ; Set up for short wait
  415.     JMP    SWAIT        ; Jump around
  416. WAIT60:    MVI    A,'6'        ; Set up for long wait
  417. SWAIT:    STA    WABYTE+3    ; store the wait msb value
  418.     MVI    A,'0'        ; fake lsbyte
  419.     STA    WABYTE+4    ; store the wait lsb value
  420.     RET
  421. ; 
  422. ; Baudrate parameters (mode byte, command byte)
  423. ; 
  424. BD300:    DB    MMODEA,MMCMDA    ; 300  baud, 8 bits, 2 stop, no parity.
  425. BD600:    DB    MMODEB,MMCMDB    ; 600  baud, 8 bits, 1 stop, no parity.
  426. BD1200:    DB    MMODEB,MMCMDA    ; 1200 baud, 8 bits, 1 stop, no parity.
  427. ; 
  428. ; Sign-on message
  429. ; 
  430. SYSVER:    
  431.      IF    ATTRIB
  432.     LXI    D,INVID        ; Set video attribute
  433.     CALL    PMSG        ; Issue attribute to term
  434.      ENDIF    ;ATTRIB
  435.     LXI    D,SOMESG    ; Point to signon message
  436.     CALL    PMSG        ; Print message on term
  437. CARRSH:    
  438.      IF    ATTRIB
  439.     LXI    D,NORVID    ; Reset video attribute
  440.     CALL    PMSG        ; Issue attribute to term
  441.      ENDIF    ;ATTRIB
  442.     LXI    D,NOMESG    ; Tell about carrier
  443.     CALL    CARRCK        ; Check for it
  444.     CZ    PMSG        ; Print the "No" if no carrier
  445.     LXI    D,CARMSG    ; Print "carrier present"
  446.     CALL    PMSG        ; Print message on term
  447.      IF    ATTRIB
  448.     LXI    D,NORVID    ; Reset video attribute
  449.      ENDIF    ;ATTRIB
  450.      IF    NOT ATTRIB
  451.     RET
  452.       ENDIF    ;NOT ATTRIB
  453. PMSG:    MVI    C,PRINT        ; Get print funct #
  454.     CALL    MEX        ; Let MEX do it
  455.     RET
  456. ;
  457. SOMESG:    DB    ' U. S. Robotics S-100 ',CR,LF
  458.     DB    ' Autodial Version '
  459.     DB    REV/10+'0','.'
  460.     DB    REV MOD 10+'0',' '
  461.     DB    CR,LF,'$'
  462. ; 
  463. NOMESG:    DB    'No$'
  464. CARMSG:    DB    ' carrier present '
  465.     DB    CR,LF,'$'
  466. ; 
  467. ; Strings to clear-to-end-of-screen, and clear-screen
  468. ; 
  469. EOSMSG:    DB    ESC,'[J$'    ; ANSI clear EOS
  470. CLSMSG:    DB    ESC,'[2J$'    ; ANSI clear screen
  471. ;
  472. ; Strings for setting video attributes
  473. ;
  474. UNVID:    DB    ESC,'[4m$'    ; ANSI underscore
  475. INDVID:    DB    ESC,'[7m$'    ; ANSI inverse
  476. INVID:    DB    ESC,'[1;7m$'    ; ANSI bold, inverse
  477. BLVID:    DB    ESC,'[1;5;7m$'    ; ANSI bold, inverse, blinking
  478. NORVID:    DB    ESC,'[0m$'    ; ANSI return to normal video
  479. ; 
  480. ; Check the USR for carrier-present (Z=no)
  481. ; 
  482. CARRCK:    IN    MODCT1        ; Get status byte
  483.     ANI    MDDCDB
  484.     RET
  485. ; 
  486. ; Newline on console
  487. ; 
  488. CRLF:    MVI    A,CR
  489.     CALL    TYPE
  490.     MVI    A,LF        ; Fall into TYPE
  491. ; 
  492. ; Type char in A on console
  493. ; 
  494. TYPE:    PUSH    H        ; Save 'em
  495.     PUSH    D
  496.     PUSH    B
  497.     MOV    E,A        ; Align output character
  498.     MVI    C,CONOUT    ; Print via MEX
  499.     CALL    MEX
  500.     POP    B
  501.     POP    D
  502.     POP    H
  503.     RET
  504. ; 
  505. ; The remainder of this overlay implements a very versatile
  506. ; SET command -- if you prefer not to write a SET for your
  507. ; modem, you may delete the code from here to the END statement.
  508. ; 
  509. ; Control is passed here after MEX parses a SET command.
  510. ; 
  511. SETCMD:    PUSH    PSW        ; Save modem speed code
  512.     MVI    A,0FFH        ; Get all ones
  513.     STA    SETFLG        ; Set setflg
  514.     POP    PSW        ; Get modem spd back
  515.     MVI    C,SBLANK    ; Any arguments?
  516.     CALL    MEX
  517.     JC    SETSHO        ; If not, go print out values
  518.     LXI    D,CMDTBL    ; Parse command
  519.     CALL    TSRCH        ; From table
  520.     PUSH    H        ; Any address on stack
  521.     RNC            ; If we have one, execute it
  522.     POP    H        ; Nope, fix stack
  523. SETERR:    
  524.      IF    ATTRIB
  525.     LXI    D,BLVID        ; Set video attribute
  526.     CALL    PMSG        ; Issue attribute to term
  527.      ENDIF    ;ATTRIB
  528.     LXI    D,SETEMS    ; Point to error msg
  529.     CALL    PMSG        ; Print message on term
  530.      IF    ATTRIB
  531.     LXI    D,NORVID    ; Reset video attribute
  532.     CALL    PMSG        ; Issue attribute to term
  533.      ENDIF    ;ATTRIB
  534.     CALL    STHELP        ; Print help on error
  535.     MVI    A,0        ; Clear acc
  536.     STA    SETFLG        ; Reset setflg
  537.     RET
  538. ; 
  539. SETEMS:    DB    CR,LF,' SET COMMAND ERROR ',CR,LF,BELL,'$'
  540. ; 
  541. ; SET command table ... note that tables are constructed of command-
  542. ; name (terminated by high bit=1) followed by word-data-value returned
  543. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  544. ; a binary zero.
  545. ; 
  546. ; Note that LOOKUP attempts to find the next item in the input stream
  547. ; in the table passed to it in HL ... if found, the table data item is
  548. ; returned in HL; if not found, LOOKUP returns carry set.
  549. ; 
  550. CMDTBL:    DB    '?'+80H        ; "set ?"
  551.     DW    STHELP
  552.     DB    'BAU','D'+80H    ; "set baud"
  553.     DW    STBAUD
  554.     DB    'PARIT','Y'+80H    ; "set parity"
  555.     DW    STPAR
  556.     DB    'SPK','R'+80H    ; "set spkr"
  557.     DW    STSPKR
  558.     DB    'WAI','T'+80H    ; "set wait"
  559.     DW    STWAIT
  560.     DB    'DIA','L'+80H    ; "set dial"
  561.     DW    STDIAL
  562.     DB    0        ; <<=== table terminator
  563. ; 
  564. ; SET <no-args>: print current statistics
  565. ; 
  566. SETSHO:    CALL    CARRSH        ; Show carrier present/not present
  567.     LXI    H,SHOTBL    ; Get table of SHOW subroutines
  568. SETSLP:    MOV    E,M        ; Get table address
  569.     INX    H
  570.     MOV    D,M
  571.     INX    H
  572.     MOV    A,D        ; End of table?
  573.     ORA    E
  574.     RZ            ; Exit if so
  575.     PUSH    H        ; Save table pointer
  576.     XCHG            ; Adrs to HL
  577.     CALL    GOHL        ; Do it
  578.     CALL    CRLF        ; Print newline
  579.     MVI    C,CHEKCC    ; Check for console abort
  580.     CALL    MEX
  581.     POP    H        ; It's done
  582.     JNZ    SETSLP        ; Continue if no abort
  583.     RET
  584. ; 
  585. GOHL:    PCHL
  586. ; 
  587. ; table of SHOW subroutines
  588. ; 
  589. SHOTBL:    DW    BDSHOW
  590.     DW    PASHOW
  591.     DW    SPSHOW
  592.     DW    WASHOW
  593.     DW    DISHOW
  594.     DW    0        ; <<== table terminator
  595. ; 
  596. ; SET ?  processor
  597. ; 
  598. STHELP:    
  599.      IF    ATTRIB
  600.     LXI    D,UNVID        ; Set video attribute
  601.     CALL    PMSG        ; Issue attribute to term
  602.      ENDIF    ;ATTRIB
  603.     LXI    D,HLPHDR    ; Point to HELP header
  604.     CALL    PMSG        ; Print message on term
  605.      IF    ATTRIB
  606.     LXI    D,NORVID    ; Reset video attribute
  607.     CALL    PMSG        ; Issue attribute to term
  608.      ENDIF    ;ATTRIB
  609.     LXI    D,HLPMSG    ; Point to HELP msg
  610.     CALL    PMSG        ; Print message on term
  611.      IF    ATTRIB
  612.     LXI    D,INDVID    ; Set video attribute
  613.     CALL    PMSG        ; Issue attribute to term
  614.      ENDIF    ;ATTRIB
  615.     LXI    D,HLPNOT    ; Point to HELP note
  616.     CALL    PMSG        ; Print message on term
  617.      IF    NOT ATTRIB
  618.     RET
  619.      ENDIF    ;NOT ATTRIB
  620.      IF    ATTRIB
  621.     LXI    D,NORVID    ; Reset video attribute
  622.     JMP    PMSG        ; Issue attribute to term
  623.      ENDIF    ;ATTRIB
  624. ; 
  625. ; The help message
  626. ; 
  627. HLPHDR:    DB    CR,LF,'THE FOLLOWING ARE VALID SET COMMANDS:$'
  628. HLPMSG:    DB    CR,LF,'SET BAUD <300> or <600> or <1200>'
  629.     DB    CR,LF,'SET PARITY <NONE> or <ODD> or <EVEN>'
  630.     DB    CR,LF,'SET SPKR <OFF> or <ON> or <DEBUG>'
  631.     DB    CR,LF,'SET WAIT <30> or <60> or <90>'
  632.     DB    CR,LF,'SET DIAL <TOUCH> or <PULSE>$'
  633. HLPNOT:    DB    CR,LF,LF,'NOTE: SET BAUD defaults to NO parity.'
  634.     DB    CR,LF,LF,'$'
  635. ;
  636. SETFLG:    DB    0        ; SET command flag
  637. ; 
  638. ; SET BAUD processor
  639. ; 
  640. STBAUD:    MVI    C,BDPARS    ; Function code
  641.     CALL    MEX        ; Let MEX look up code
  642.     JC    SETERR        ; Invalid code
  643.     CALL    PBAUD        ; No, try to set it
  644.     JC    SETERR        ; Not-supported code
  645.     JMP    SETSHO        ; review parameters
  646. ;
  647. BDSHOW:    LDA    SETFLG        ; Get setflg
  648.     CPI    0FFH        ; Is it a 'SET' operation?
  649.     JNZ    PBPS        ; No, must be dial - just display bps
  650.     CALL    ILPRT        ; Yes, display the 'Baud' prompt
  651.     DB    'Baud rate: ',0
  652. PBPS:    LDA    MSPEED        ; Load modem speed code
  653.     MVI    C,PRBAUD    ; Use MEX function #
  654.     CALL    MEX        ; To print bps
  655.     LXI    D,NORVID    ; Reset video attribute
  656.     CALL    PMSG        ; Issue attribute to term
  657.     MVI    E,' '        ; Followed by space
  658.     MVI    C,CONOUT    ; Use MEX function #
  659.     CALL    MEX        ; Let MEX do it
  660.     MVI    A,0        ; Clear acc
  661.     STA    SETFLG        ; Reset setflg
  662.     RET
  663. ;
  664. ; SET PARITY processor
  665. ;
  666. STPAR:    LXI    D,PARTBL    ; point to parity table
  667.     CALL    TSRCH        ; lookup next input item in table
  668.     JC    SETERR        ; if not found, error
  669.     PUSH    PSW        ; a=byte from table
  670.     LDA    MODEBT        ; get old mode byte
  671.     ANI    0C3H        ; strip off parity bits, word length
  672.     MOV    B,A        ; old modebt into b
  673.     POP    PSW        ; get table entry back
  674.     ANI    3CH        ; mask parity bits, word length
  675.     ADD    B        ; adjust new parity values
  676.     STA    MODEBT        ; store the new mode byte
  677.     CALL    NITMOD        ; (re)initialize modem
  678.     JMP    SETSHO        ; review parameters
  679. ;
  680. PASHOW:    CALL    ILPRT        ; show parity mode
  681.     DB    'Parity: ',0
  682.     LDA    MODEBT        ; get mode byte
  683.     ANI    30H        ; mask off parity bits
  684.     CPI    10H        ; bit 4 hi?
  685.     JZ    ODDPAR        ; yes, odd parity
  686.     CPI    30H        ; bits 5,4 hi?
  687.     JZ    EVPAR        ; yes, even parity
  688.                 ; else no parity
  689. NOPAR:    CALL    ILPRT        ; in-line print
  690.     DB    'NONE',0
  691.     RET
  692. EVPAR:    CALL    ILPRT        ; in-line print
  693.     DB    'EVEN',0
  694.     RET
  695. ODDPAR:    CALL    ILPRT        ; in-line print
  696.     DB    'ODD',0
  697.     RET
  698. ;
  699. PARTBL:    DB    'NON','E'+80H    ; set parity off
  700.     DB    0CH,0        ; 8 bit word length
  701.     DB    'EVE','N'+80H    ; set parity even
  702.     DB    38H,0        ; bits 5,4,3 hi (7 bit word length)
  703.     DB    'OD','D'+80H    ; set parity odd
  704.     DB    18H,0        ; bits 4,3 hi (7 bit word length)
  705.     DB    0        ; <<=== table terminator
  706. ;
  707. ; SET SPKR processor
  708. ;
  709. STSPKR:    LXI    D,SPKTBL    ; lookup next input item in table
  710.     CALL    TSRCH
  711.     JC    SETERR        ; if not found, error
  712.     STA    SPBYTE+1    ; store the spkr command
  713.     CALL    NITMOD        ; (re)initialize modem
  714.     JMP    SETSHO        ; review parameters
  715. ;
  716. SPSHOW:    CALL    ILPRT        ; show spkr mode
  717.     DB    'Speaker: ',0
  718.     LDA    SPBYTE+1    ; get spkr byte
  719.     CPI    '1'
  720.     JZ    SPONPT        ; spkr on part-time
  721.     CPI    '2'
  722.     JZ    SPON        ; spkr on continuously
  723. ;
  724. SPOFF:    CALL    ILPRT
  725.     DB    'OFF',0
  726.     RET
  727. ;
  728. SPONPT:    CALL    ILPRT
  729.     DB    'ON until connect',0
  730.     RET
  731. ;
  732. SPON:    CALL    ILPRT
  733.     DB    'ON always',0
  734.     RET
  735. ;
  736. SPKTBL:    DB    'OF','F'+80H    ; set spkr off
  737.     DB    '0',0
  738.     DB    'O','N'+80H    ; set spkr on 'til connect    
  739.     DB    '1',0
  740.     DB    'DEBU','G'+80H    ; set spkr on continuously
  741.     DB    '2',0
  742.     DB    0        ; <<=== table terminator
  743. ;
  744. ; SET WAIT processor
  745. ;
  746. STWAIT:    LXI    D,WAITBL    ; lookup next input item in table
  747.     CALL    TSRCH
  748.     JC    SETERR        ; if not found, error
  749.     STA    WABYTE+3    ; store the wait msb value
  750.     MVI    A,'0'        ; fake lsbyte
  751.     STA    WABYTE+4    ; store the wait lsb value
  752.     CALL    NITMOD        ; (re)initialize modem
  753.     JMP    SETSHO        ; review parameters
  754. ;
  755. WASHOW:    CALL    ILPRT
  756.     DB    'Wait: ',0
  757.     LDA    WABYTE+3
  758.     CALL    TYPE        ; show msb
  759.     LDA    WABYTE+4
  760.     CALL    TYPE        ; show lsb
  761.     CALL    ILPRT
  762.     DB    ' seconds for carrier',0
  763.     RET
  764. ;
  765. WAITBL:    DB    '3','0'+80H    ; "set wait 30"
  766.     DB    '3',0
  767.     DB    '6','0'+80H    ; "set wait 60"
  768.     DB    '6',0
  769.     DB    '9','0'+80H    ; "set wait 90"
  770.     DB    '9',0
  771.     DB    0        ; <<=== table terminator
  772. ;
  773. ; SET DIAL processor
  774. ;
  775. STDIAL:    LXI    D,DIATBL    ; lookup next input item in table
  776.     CALL    TSRCH
  777.     JC    SETERR        ; if not found, error
  778.     STA    TPULSE        ; store the dial command
  779.     CALL    NITMOD        ; (re)initialize modem
  780.     JMP    SETSHO        ; review parameters
  781. ;
  782. DISHOW:    CALL    ILPRT        ; show dial mode
  783.     DB    'Dial: ',0
  784.     LDA    TPULSE        ; get dial byte
  785.     CPI    'T'
  786.     JZ    TTONE        ; touch tone 
  787. ;
  788. PDIAL:    CALL    ILPRT
  789.     DB    'Pulse',0
  790.     RET
  791. ;
  792. TTONE:    CALL    ILPRT
  793.     DB    'Touch Tone',0
  794.     RET
  795. ;
  796. ; DIAL argument table
  797. ;
  798. DIATBL:    DB    'TOUC','H'+80H    ; touch tone
  799.     DB    'T',0
  800.     DB    'PULS','E'+80H    ; pulse dial
  801.     DB    'P',0
  802.     DB    0        ; <<=== table terminator
  803. ; 
  804. ; Compare next input-stream item in table @DE; CY=1
  805. ; if not found, else HL=matched data item
  806. ; 
  807. TSRCH:    MVI    C,LOOKUP    ; Get function code
  808.     JMP    MEX        ; Pass to MEX processor
  809. ; 
  810. ; Print in-line message ... blows away C register
  811. ; 
  812. ILPRT:    MVI    C,ILP        ; Get function code
  813.     JMP    MEX        ; Go do it
  814. ; 
  815. ; NOTE:  Must terminate prior to 0B00H 
  816. ; 
  817.       END
  818.