home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / mex / mxo-ap31.aqm / MXO-AP31.ASM
Assembly Source File  |  1985-08-05  |  46KB  |  1,473 lines
  1. ;    TITLE  'MEX Overlay for Apple ][ / Applicard / Smartmodem'
  2. ;
  3. ;  MXO-AP30.ASM created 01/28/85   by   Henry Middlebrook
  4. ;
  5. REV    EQU    31        ; 03 Feb 1985
  6. ;
  7. ; This overlay file enables Apple ][ computers to use the following
  8. ; Apple hardware configuration with MEX112:
  9. ;
  10. ;    > Mountain CPS Multi-Function and 6 MHz PCPI AppliCard <
  11. ; 
  12. ;            - Henry Middlebrook [70766,766]
  13. ;                January 28, 1985
  14. ;
  15. ; This overlay is written in three distinct parts as a "MIXED" type of
  16. ; overlay for MEX.  The parts follow the guidelines available in the
  17. ; MEX OVERLAY LIST #2 (01/06/85 -- Ron Fowler, NightOwl Sofware) with
  18. ; reference to the PORT, MODEM, and PATCH overlay types.  Thus, you
  19. ; should be able to remove or add any one of the three parts without
  20. ; severely affecting the overlay operation.  Naturally, removing the
  21. ; first section (PORT) will completely disable MEX; however, removing
  22. ; or changing the the MODEM (derived from MXO-SM13.ASM) section or
  23. ; the PATCH (MEXPAT11.ASM) will minimally affect operation (see LSTST
  24. ; and SSET).
  25. ;
  26. ; The three part in order are:
  27. ;
  28. ;    1. PORT -- Supports Apple ][+/e with PCPI Applicard and
  29. ;           Mountain Computer cards.  Contains all vectors
  30. ;           and equates from MDM7xx series as updated for MEX.
  31. ;
  32. ;    2. MODEM - This is basically the "officially sanctioned" version
  33. ;           of the Hayes Smartmodem 1200 overlay, MXO-SM13.ASM.
  34. ;           Several redundant EQUs and Conditionals have been
  35. ;           removed or commented out of the source code.
  36. ;
  37. ;    3. PATCH - The MEXPAT11.ASM file was pulled into this overlay
  38. ;           and modified to suit the author's needs and whims.
  39. ;           Using the patch file as listed adds vector for a
  40. ;           precise LSTST vector.
  41. ;
  42. ; >>>>  NOTE:      Previous versions of MXO-APxx do NOT properly support
  43. ;        the PCPI Applicard.  You may not like this overlay;
  44. ;        however, you can use it as a reliable guide.
  45. ;
  46. ; This overlay includes many comments and instructional lines from
  47. ; the `full' overlays.  These may be commented out or passed along
  48. ; as you see fit.
  49. ;                HM    02/04/85
  50. ;
  51. ;----------------------------------------------------------------------
  52. ;            Overlay Update History
  53. ;
  54. ; 02/03/85 - Added TIME and SET functions -AP31    - Henry Middlebrook
  55. ; 01/28/85 - Created MXO original overlay -AP30    - Henry Middlebrook
  56. ;
  57. ;======================================================================
  58.  
  59. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  60. ;
  61. ;            PORT OVERLAY SECTION
  62. ;
  63. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  64. ;
  65. ;
  66. BELL        EQU    07H    ;bell
  67. CR        EQU    0DH    ;carriage return
  68. ESC        EQU    1BH    ;escape
  69. LF        EQU    0AH    ;linefeed
  70. TAB        EQU    09H    ;tab
  71. YES        EQU    0FFH
  72. NO        EQU    0
  73. ;
  74. ;
  75. ;----------------------------------------------------------------------
  76. ;
  77. ;        Equates for BIOS LISTST correction
  78. ;        ----------------------------------
  79. ;
  80. ; MEX support LST and LSTST vectors to custom routines in this
  81. ; overlay.  The EQUs must be properly set in MEXPAT section at
  82. ; end of this code and the routines equates below are for printer
  83. ; I/O specific routines at the end of the modem overlay (WR$PRT).
  84. ;
  85. ; Equates for optional printer routine (for SUPER-MX parallel Epson)
  86. ;
  87. USERPRINTER    EQU    YES
  88. ;
  89. PSLOT        EQU    1    ;Printer slot
  90. PTRSTATP    EQU    0C081H + (PSLOT * 10H)    ;Printer stat address
  91. PTRDATP        EQU    0C081H + (PSLOT * 10H)    ;Printer data out addr
  92. PTRSTBP1    EQU    0C082H + (PSLOT * 10H)    ;Strobe address #1
  93. PTRSTBP2    EQU    0C080H + (PSLOT * 10H)    ;Strobe address #2
  94. PTR$RDY        EQU    01H            ;Printer ready mask
  95. ;
  96. ;----------------------------------------------------------------------
  97. ;
  98. ;    Mountain CPS Serial I/O and Clock equates and routines
  99. ;    ------------------------------------------------------
  100. ;
  101. CPSLOT        EQU    2
  102. ;
  103. MODDATP        EQU    0C0FAH + (CPSLOT*100H)    ;serial port of CPS card
  104. MODCTLP        EQU    0C0FBH + (CPSLOT*100H)    ;status port of CPS card
  105. MODCTLP2    EQU    0C0FEH + (CPSLOT*100H)    ;control port of CPS card
  106. ;
  107. CLKPORT        EQU    0C0FEH + (CPSLOT*100H)    ;control port for Clock
  108. CLKDATA        EQU    0C0F9H + (CPSLOT*100H)    ;data port for Clock
  109. CLKHOLD        EQU    040H            ;stop clock for read
  110. CLKREAD        EQU    050H            ;set clock read mode
  111. ;
  112. RDBYTE        EQU    0FFE0H    ;Read a Byte from Apple (A = BYTE)
  113. WRBYTE        EQU    0FFE3H    ;Write a Byte to Apple (C = BYTE)
  114. RDWORD        EQU    0FFE6H    ;Read 2 Bytes from Apple (DE = BYTES)
  115. WRWORD        EQU    0FFE9H    ;Write 2 Bytes to Apple (DE = BYTES)
  116. RDNBYTS        EQU    0FFECH    ;Read N Bytes (DE = COUNT, HL = BUFFER)
  117. WRNBYTS        EQU    0FFEFH    ;Write N Bytes (DE = COUNT, HL = BUFFER)
  118. ;
  119. PEEK1BYTE    EQU    6    ;Command to Peek 1 Byte in the Apple
  120. POKE1BYTE    EQU    7    ;Command to Poke 1 Byte to the Apple
  121. ;
  122. ; Status bit equates for CPS serial port
  123. ;
  124. MDSNDB        EQU    01H
  125. MDSNDR        EQU    01H
  126. MDRCVB        EQU    02H
  127. MDRCVR        EQU    02H
  128. ;
  129. ; Equates for PSW (Parity, Stop Bit, Word Length) used by CPS UART
  130. ;
  131. P8N1        EQU    04EH    ;8 NONE 1
  132. P7E1        EQU    0EAH    ;7 EVEN 1
  133. P7O1        EQU    055H    ;7 ODD 1
  134. P7N1        EQU    045H    ;7 NONE 1
  135. ;
  136. ;----------------------------------------------------------------------
  137. ;
  138. ;            MEX OVERLAY INFORMATION
  139. ;
  140. ; This is a general purpose MEX modem overlay file. You can use it as
  141. ; a model for designing your own modem overlay (or you can use any
  142. ; existing MDM7 overlay, if available).
  143. ;
  144. ; If you use this as a template for writing your own overlay, and
  145. ; distribute it to others, please pare down these comments as much
  146. ; as possible (to keep the overlays small). I'll maintain this file
  147. ; with as many notes and references as possible, but this will hope-
  148. ; fully be the only "big" overlay.
  149. ;
  150. ; There are advantages to recoding your overlay to conform to the
  151. ; techniques presented here: MEX 2.0 will likely have a much simpler
  152. ; overlay structure; if you stick to the label names and coding
  153. ; suggestions used here, you'll easily be able to follow the overlay
  154. ; upgrade instructions when MEX 2.0 hits the streets. Also, you can
  155. ; make use of the MEX service processor to write a very versatile
  156. ; SET command (as done here).
  157. ;
  158. ; Note that all overlays may freely use memory up to 0CFFH.  If your
  159. ; overlay must work with the MEX Smartmodem overlay (MXO-SMxx.ASM),
  160. ; the physical modem overlay should terminate by 0AFFH.
  161. ;
  162. ; For purposes of example, this is a "full-featured" MEX overlay.  In
  163. ; practice, your overlay may be much simpler (all that is really re-
  164. ; quired is the modem I/O code; fancy stuff like the SET command, and
  165. ; even the disconnect routine, may be left open.  You will need DIAL
  166. ; code, though, unless your modem doesn't support autodialing).
  167. ;
  168. ;
  169. ;    MEX Service Processor Calls  (User's Guide - Appendix #4)
  170. ;    ---------------------------------------------------------
  171. ;
  172. ; MEX service processor stuff ... MEX supports an overlay service
  173. ; processor, located at 0D00H (and maintained at this address from
  174. ; version to version).  If your overlay needs to call BDOS for any
  175. ; reason, it should call MEX instead; function calls below about
  176. ; 240 are simply passed on to the BDOS (console and list I/O calls
  177. ; are specially handled to allow modem port queueing, which is why
  178. ; you should call MEX instead of BDOS).  MEX uses function calls
  179. ; above about 244 for special overlay services (described below).
  180. ;
  181. ; Some sophisticated overlays may need to do file I/O; if so, use
  182. ; the PARSFN MEX call with a pointer to the FCB in DE to parse out
  183. ; the name.  This FCB should support a spare byte immediately pre-
  184. ; ceeding the actual FCB (to contain user # information).  If you've
  185. ; used MEX-10 for input instead of BDOS-10 (or you're parsing part
  186. ; of a SET command line that's already been input), then MEX will
  187. ; take care of DU specs, and set up the FCB accordingly.  There-
  188. ; after all file I/O calls done through the MEX service processor
  189. ; will handle drive and user with no further effort necessary on
  190. ; the part of the programmer.
  191. ;
  192. MEX    EQU    0D00H    ;address of the service processor
  193. INMDM    EQU    255    ;get char from port to A, CY=no more in 100 ms
  194. TIMER    EQU    254    ;delay 100ms * reg B
  195. TMDINP    EQU    253    ;B=# secs to wait for char, cy=no char
  196. CHEKCC    EQU    252    ;check for ^C from KBD, Z=present
  197. SNDRDY    EQU    251    ;test for modem-send ready
  198. RCVRDY    EQU    250    ;test for modem-receive ready
  199. SNDCHR    EQU    249    ;send a character to the modem (after sndrdy)
  200. RCVCHR    EQU    248    ;recv a char from modem (after rcvrdy)
  201. LOOKUP    EQU    247    ;table search: see CMDTBL comments for info
  202. PARSFN    EQU    246    ;parse filename from input stream
  203. BDPARS    EQU    245    ;parse baud-rate from input stream
  204. SBLANK    EQU    244    ;scan input stream to next non-blank
  205. EVALA    EQU    243    ;evaluate numeric from input stream
  206. LKAHED    EQU    242    ;get nxt char w/o removing from input
  207. GNC    EQU    241    ;get char from input, cy=1 if none
  208. ILP    EQU    240    ;inline print
  209. DECOUT    EQU    239    ;decimal output
  210. PRBAUD    EQU    238    ;print baud rate
  211. PRNTBL    EQU    237    ;print command table in columns (HL=addr)
  212. PRID    EQU    236    ;print MEX ID string on console
  213. ;
  214. CONOUT    EQU    2    ;simulated BDOS function 2: console char out
  215. PRINT    EQU    9    ;simulated BDOS function 9: print string
  216. INBUF    EQU    10    ;input buffer, same structure as BDOS 10
  217. ;
  218. ;
  219. ;======================================================================
  220. ;
  221.     ORG    100H    ;we begin
  222. ;
  223.     DS    3    ;MEX has a JMP START here            100H
  224. ;
  225. ; The following variables are located at the beginning of the program
  226. ; to facilitate modification without the need of re-assembly. They will
  227. ; be moved in MEX 2.0.
  228. ;
  229. PMODEM:    DB    YES    ;\ / These two locations are            103H
  230. SMODEM:    DB    NO    ;/ \ not referenced by MEX.            104H
  231. TPULSE:    DB    'T'    ;Tone/Pulse (used only in Smodem overlay)    105H
  232. CLOCK:    DB    60    ;clock speed x .1, up to 25.5 mhz.        106H
  233. MSPEED:    DB    5    ;sets display time for sending a file        107H
  234.             ;0=110    1=300  2=450  3=600  4=710
  235.             ;5=1200 6=2400 7=4800 8=9600 9=19200
  236. BYTDLY:    DB    1    ;default time to send character in        108H
  237.             ;terminal mode file transfer (0-9)
  238.             ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  239. CRDLY:    DB    1    ;end-of-line delay in terminal            109H
  240.             ;mode file transfer for slow BBS systems
  241.             ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  242. COLUMS:    DB    5    ;number of directory columns            10AH
  243. SETFL:    DB    YES    ;yes=user-defined SET command            10BH
  244. SCRTST:    DB    YES    ;yes=if home cursor and clear screen        10CH
  245.             ;routine at CLRSCRN
  246.     DB    0    ;was once ACKNAK, now spare            10DH
  247. BAKFLG:    DB    NO    ;yes=make .BAK file                10EH
  248. CRCDFL:    DB    YES    ;yes=default to CRC checking            10FH
  249.             ;no=default to Checksum checking
  250. TOGCRC:    DB    YES    ;yes=allow toggling of Checksum to CRC        110H
  251. CVTBS:    DB    NO    ;yes=convert backspace to rub            111H
  252. TOGLBK:    DB    YES    ;yes=allow toggling of bksp to rub        112H
  253. ADDLF:    DB    NO    ;no=no LF after CR to send file in        113H
  254.             ;terminal mode (added by remote echo)
  255. TOGLF:    DB    YES    ;yes=allow toggling of LF after CR        114H
  256. TRNLOG:    DB    NO    ;yes=allow transmission of logon        115H
  257.             ;write logon sequence at location LOGON
  258. SAVCCP:    DB    YES    ;yes=do not overwrite CCP            116H
  259. LOCNXT:    DB    NO    ;yes=local cmd if EXTCHR precedes        117H
  260.             ;no=not local cmd if EXTCHR precedes
  261. TOGLOC:    DB    YES    ;yes=allow toggling of LOCNXTCHR        118H
  262. LSTTST:    DB    YES    ;yes=allow toggling of printer on/off        119H
  263.             ;in terminal mode. Set to no if using
  264.             ;the printer port for the modem
  265. XOFTST:    DB    YES    ;yes=allow testing of XOFF from remote        11AH
  266.             ;while sending a file in terminal mode
  267. XONWT:    DB    NO    ;yes=wait for XON after sending CR while    11BH
  268.             ;transmitting a file in terminal mode    
  269. TOGXOF:    DB    YES    ;yes=allow toggling of XOFF testing        11CH
  270. IGNCTL:    DB    NO    ;yes=do not send control characters        11DH
  271.             ;above CTL-M to CRT in terminal mode
  272.             ;no=send any incoming CTL-char to CRT
  273. EXTRA1:    DB    0    ;for future expansion                11EH
  274. EXTRA2:    DB    0    ;for future expansion                11FH
  275. BRKCHR:    DB    '@'-40H    ;^@ = Send a 300 ms. break tone            120H
  276. NOCONN:    DB    'N'-40H    ;^N = Disconnect from phone line        121H
  277. LOGCHR:    DB    'L'-40H    ;^L = Send logon                122H
  278. LSTCHR:    DB    'P'-40H    ;^P = Toggle printer                123H
  279. UNSVCH:    DB    'R'-40H    ;^R = Close input text buffer            124H
  280. TRNCHR:    DB    'T'-40H    ;^T = Transmit file to remote            125H
  281. SAVCHR:    DB    'Y'-40H    ;^Y = Open input text buffer            126H
  282. EXTCHR:    DB    '^'-40H    ;^^ = Send next character            127H
  283. ;
  284. ; Equates used only by PMMI routines grouped together here.
  285. ;
  286. PRATE:    DB    125    ;125=20pps dialing, 250=10pps            128H
  287.     DB    0    ;not used                    129H
  288. ;
  289. ; Low-level modem I/O routines: this will be replaced with
  290. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  291. ; routines if you'd like ... I'd recommend NOT putting part of
  292. ; a routine in this area, then jumping to the rest of the routine
  293. ; in the non-fixed area; that will complicate the 2.0 conversion)
  294. ;
  295. IN$MODCTLP:    JMP    RD$MODCTLP     ;                12AH
  296.         DS    7
  297. OUT$MODDATP:    JMP    WR$MODDATP    ;                134H
  298.         DS    7
  299. IN$MODDATP:    JMP    RD$MODDATP    ;                13EH
  300.         DS    7
  301. ;
  302. ; Bit-test routines.  These will be merged with the above
  303. ; routines in MEX 2.0 to provide a more reasonable format
  304. ;
  305. MASKR:        ANI    MDRCVB ! RET    ;bit to test for receive ready    148H
  306. TESTR:        CPI    MDRCVR ! RET    ;value of rcv. bit when ready    14BH
  307. MASKS:        ANI    MDSNDB ! RET    ;bit to test for send ready    14EH
  308. TESTS:        CPI    MDSNDR ! RET    ;value of send bit when ready    151H
  309. ;
  310. ; Unused area: was once used for special PMMI functions, now used only
  311. ; to retain compatibility with MDM overlays. You may use this area for
  312. ; any miscellaneous storage you'd like but the length of the area
  313. ; >> MUST << be 12 bytes.
  314. ;
  315.         DS    12        ;PMMI only calls        154H
  316. ;
  317. ; Special modem function jump table: if your overlay cannot handle
  318. ; some of these, change the jump to "DS 3", so the code present in
  319. ; MEX will be retained.  Thus, if your modem can't dial, change the
  320. ; JMP PDIAL at DIALV to DS 3, and MEX will print a "not-implemented"
  321. ; diagnostic for any commands that require dialing.
  322. ;
  323. ; DIALV  dials the digit in A. See the comments at PDIAL for specs.
  324. ;
  325. ; DISCV  disconnects the modem
  326. ;
  327. ; GOODBV is called just before MEX exits to CP/M.  If your overlay
  328. ;        requires some exit cleanup, do it here.
  329. ;
  330. ; INMODV is called when MEX starts up; use INMODV to initialize the modem.
  331. ;
  332. ; NEWBDV is used for phone-number baud rates and is called with a baud-rate
  333. ;        code in the A register, value as follows:
  334. ;
  335. ;     A=0:   110 baud       A=1:   300 baud      A=2:   450 baud
  336. ;     A=3:   600 baud       A=4:   710 baud      A=5:  1200 baud
  337. ;     A=6:  2400 baud       A=7:  4800 baud      A=8: 19200 baud
  338. ;
  339. ;        If your overlay supports the passed baud rate, it should store the
  340. ;     value passed in A at MSPEED (107H), and set the requested rate. If
  341. ;     the value passed is not supported, you should simply return (with-
  342. ;     out modifying MSPEED) -or- optionally request a baud-rate from the
  343. ;     user interactively.
  344. ;
  345. ; NOPARV is called at the end of each file transfer; your overlay may simply
  346. ;     return here, or you may want to restore parity if you set no-parity
  347. ;     in the following vector (this is the case with the PMMI overlay).
  348. ;     
  349. ; PARITV is called at the start of each file transfer; your overlay may 
  350. ;     simply return here, or you may want to enable parity detection
  351. ;     (this is the case with the PMMI overlay).
  352. ;
  353. ; SETUPV is the user-defined command ... to use this routine to build your
  354. ;     own MEX command, set the variable SETFL (117H) non-zero, and add
  355. ;     your SET code.  You can use the routine presented in the PMMI
  356. ;     overlay as a guide for parsing, table lookup, etc.
  357. ;
  358. ; SPMENU is provided only for MDM compatibility, and is not used by
  359. ;      MEX 1.0 for any purpose (it will be gone in MEX 2).
  360. ;
  361. ; VERSNV is called immediately after MEX prints its sign-on message at cold
  362. ;     startup -- use this to identify your overlay in the sign-on message
  363. ;     (include overlay version number in the line).
  364. ;
  365. ; BREAKV is provided for sending a BREAK (<ESC>-B in terminal mode).  If
  366. ;     your modem doesn't support BREAK, or you don't care to code a
  367. ;     BREAK routine, you may simply execute a RET instruction.
  368. ;
  369. ;
  370. LOGON:        DS    2        ;not used by MEX          160H
  371. DIALV:        JMP    DIAL        ;dial a digit in A (ref SMOVL)    162H
  372. DISCV:        JMP    DISCON        ;drops DTR to hang-up fast!    165H
  373. GOODBV:        JMP    GOODBYE        ;called before exit to CPM    168H
  374. INMODV:        JMP    INITMOD        ;go to user written routine    16BH
  375. NEWBDV:        JMP    PBAUD        ;changes baud with phone #    16EH
  376. NOPARV:        RET  !    NOP  !    NOP    ;set modem for no-parity     171H
  377. PARITV:        RET  !    NOP  !    NOP    ;set modem parity             174H
  378. SETUPV:        JMP    SETCMD        ;                177H
  379. SPMENV:        DS     3        ;not used by MEX        17AH
  380. VERSNV:        JMP    SYSVER        ;                17DH
  381. BREAKV:        JMP    SENDBRK        ;                180H
  382. ;
  383. ; The following jump vector provides the overlay with access to special
  384. ; routines in the main program (retained and supported in the main pro-
  385. ; gram for MDM overlay compatibility). These should not be modified by
  386. ; the overlay.
  387. ;
  388. ; Note that for MEX 2.0 compatibility, you should not try to use these
  389. ; routines, since this table will go away with MEX 2.0 (use the MEX
  390. ; service call processor instead).
  391. ;
  392. ILPRTV:        DS    3    ;replace with MEX function 9         183H
  393. INBUFV:        DS    3    ;replace with MEX functin 10        186H
  394. ILCMPV:        DS    3    ;replace with table lookup funct 247    189H
  395. INMDMV:        DS    3    ;replace with MEX function 255        18CH
  396. NXSCRV:        DS    3    ;not supported by MEX            18FH
  397. TIMERV:        DS    3    ;replace with MEX function 254        192H
  398. ;
  399. ; Clear/screen and clear/end-of-screen. Each routine must use the
  400. ; full 9 bytes alloted (may be padded with nulls).
  401. ;
  402. ; These routines (and other screen routines that MEX 2.0 will sup-
  403. ; port) will be accessed through a jump table in 2.0, and will be
  404. ; located in an area that won't tie the screen functions to the
  405. ; modem overlay (as the MDM format does).
  406. ;
  407. CLREOS:        LXI    D,EOSMSG    ;                195H
  408.         MVI    C,PRINT
  409.         CALL    MEX
  410.         RET            ;                19DH
  411. ;
  412. CLS:        LXI    D,CLSMSG    ;                19EH
  413.         MVI    C,PRINT
  414.         CALL    MEX
  415.         RET            ;                1A6H
  416. ;
  417. ;
  418. ;
  419. ;        *** END OF FIXED FORMAT AREA ***
  420. ;
  421. ;**********************************************************************
  422. ;
  423. ; These routines a specific to the Apple ][+ with Applicard.  The
  424. ; routines read modem hardware (CPS Serial I/O and Clock) directly from
  425. ; the Applicard.
  426. ;
  427. ; Read the Serial Status Port of UART
  428. ;
  429. RD$MODCTLP:    PUSH    D
  430.         LXI    D,MODCTLP
  431.         CALL    PEEK
  432.         POP    D
  433.         RET
  434. ;
  435. ;
  436. ; Write to the Serial Status Port of UART
  437. ;
  438. WR$MODCTLP:    PUSH    D
  439.         LXI    D,MODCTLP
  440.         CALL    POKE
  441.         POP    D
  442.         RET
  443. ;
  444. ;
  445. ; Write to the CPS Card SCR to activate secondary UART functions
  446. ;
  447. WR$MODCTLP2:    PUSH    D
  448.         LXI    D,MODCTLP2
  449.         CALL    POKE
  450.         POP    D
  451.         RET
  452. ;
  453. ;
  454. ; Read the Serial Data from the UART
  455. ;
  456. RD$MODDATP:    PUSH    D
  457.         LXI    D,MODDATP
  458.         CALL    PEEK
  459.         POP    D
  460.         RET
  461. ;
  462. ;
  463. ; Write to the Serial Data Port of the UART
  464. ;
  465. WR$MODDATP:    PUSH    D
  466.         LXI    D,MODDATP
  467.         CALL    POKE
  468.         POP    D
  469.         RET
  470. ;
  471. ;
  472. ; Write to CPS hardware to activate card for CLOCK functions
  473. ; (duplicates WR$MODCTLP2 routine above).
  474. ;
  475. WR$CLKSTAT:    PUSH    D
  476.         LXI    D,CLKPORT
  477.         CALL    POKE
  478.         POP    D
  479.         RET
  480. ;
  481. ;
  482. ; Read a single byte from the CPS Card OKI 5832 clock chip
  483. ;
  484. RD$CLKDATA:    PUSH    D
  485.         LXI    D,CLKDATA
  486.         CALL    PEEK
  487.         POP    D
  488.         RET
  489. ;
  490. ;
  491. ; Peek at 1 byte from Apple 6502 address space
  492. ; ENTRY: DE = Address in Apple
  493. ; EXIT:    A = Data
  494. ;
  495. PEEK:    PUSH    B
  496.     MVI    C,PEEK1BYTE
  497.     CALL    WRBYTE
  498.     CALL    WRWORD
  499.     CALL    RDBYTE
  500.     POP    B
  501.     RET
  502. ;
  503. ;
  504. ; Poke 1 byte to Apple 6502 address space
  505. ; ENTRY: DE = Address in Apple
  506. ; EXIT:    A = Data
  507. ;
  508. POKE:    PUSH    B
  509.     MOV    B,A
  510.     MVI    C,POKE1BYTE
  511.     CALL    WRBYTE
  512.     CALL    WRWORD
  513.     MOV    C,B
  514.     CALL    WRBYTE
  515.     POP    B
  516.     RET
  517. ;
  518. ;----------------------------------------------------------------------
  519. ;
  520. ; This routine sends a timed (1 second) Break to modem from CPS card.
  521. ;
  522. SENDBRK:    CALL    OPENCMD        ;open the command register
  523.         MVI    A,3FH        ;BREAK byte for CPS CR register    
  524.         CALL    WR$MODCTLP    ;send to CPS cmd reg
  525.         MVI    B,10
  526.         MVI    C,TIMER
  527.         CALL    MEX        ;send BREAK for 1 second
  528.         MVI    A,37H
  529.         CALL    WR$MODCTLP    ;back to normal operation
  530.         CALL    CLOSECMD    ;close the command register
  531.         RET
  532. ;
  533. ;.....
  534. ;
  535. ; You can add your own routine here to set DTR low and/or send a break
  536. ; tone to disconnect.
  537. ;
  538. GOODBYE:    RET        ;just return for MEX to allow return
  539.                 ;to system w/o dropping line
  540. ;
  541. ;.....
  542. ;
  543. ; The following may be used to initialize the Mountain Hardware CPS
  544. ; Multifunction Card for eight bits, no parity, one stop bit, and
  545. ; 1200 baud.  This does not alter the CPS defaults outside of MEX
  546. ;
  547. INITMOD: 
  548.     MVI    A,5        ;set default baud rate to 1200
  549.     CALL     PBAUD
  550.     MVI    A,P8N1        ;set PSW default to 8N1
  551.     STA    PSWSET        ;save for future reference
  552. ;
  553. INITMOD1:
  554.     CALL    OPENCMD        ;Open CPS command register
  555.     MVI    A,37H        ;initialize the serial chip
  556.     CALL    WR$MODCTLP    ;by storing 37H in CPS Cmd Reg
  557.     LDA    PSWSET        ;get current PSW value (def = 04EH) 
  558.     CALL    WR$MODDATP    ;store in CPS Mode Reg 1
  559.     LDA     BDSET           ;set baud rate at BDSET by storing
  560.     CALL    WR$MODDATP    ;in CPS Mode Reg 2 -- (the two
  561.                 ;registers cycle with each write)
  562.     CALL    CLOSECMD    ;Close CPS command register
  563.     LDA    BDSET        ;also return with current Baud setting
  564.     RET
  565. ;
  566. ;.....
  567. ;
  568. ; Routines used to open and close CPS command register.  If OPEN, then
  569. ; UART CR register (DTR, RTS, Break) and Mode 1 and 2 Registers (FSW
  570. ; and Baud) are selected for write. (Note that Mode 1/2 are accessed
  571. ; sequentially by writing to MODDATP -- modem data address in Apple).
  572. ; The CR register is accessed with WR$MODCTLP and the Mode 1/2 registers
  573. ; are accessed (for WRITE only) with WR$MODDATP.
  574. ;
  575. ; If CLOSED, then UART status register may be read (RxRDY, TxRDY, PE,
  576. ; FE, DCD, DSR) with RD$MODCTLP.  Also Serial Data can be sent to
  577. ; and from the CPS card with WR$MODDATP and RD$MODDATP.
  578. ;
  579. OPENCMD:            ;Open the CPS command register
  580.     MVI    A,80H
  581.     JMP    WR$MODCTLP2
  582. ;
  583. ;
  584. CLOSECMD:            ;Close the CPS command register
  585.     MVI    A,0
  586.     JMP    WR$MODCTLP2
  587. ;
  588. ;.....
  589. ;
  590. ; This routine drops DTR to force modem to disconnect.  Does NOT do
  591. ; any initialization.
  592. ;
  593. DISCON:    CALL    OPENCMD        ;Open the command register
  594.     MVI    A,05H        ;Turn off DTR
  595.     CALL    WR$MODCTLP
  596.     MVI    B,10        ;Wait 1 second
  597.     MVI     C,TIMER
  598.     CALL    MEX
  599.     MVI    A,37H        ;Turn everything back on
  600.     CALL    WR$MODCTLP
  601.     CALL    CLOSECMD    ;Close the cmd register
  602.     MVI    B,10        ;Wait 1 second air to clear
  603.     MVI    C,TIMER
  604.     CALL    MEX
  605.     RET
  606. ;
  607. ;.....
  608. ;
  609. ; This routine changes the modem baud rate with phone list entry
  610. ;
  611. ; Set baud-rate code in A (if supported by your modem overlay).  PMMI
  612. ; supports only five rates, which are validated here. NOTE: this routine
  613. ; (ie, the one vectored through NEWBDV) should update MSPEED with the
  614. ; passed code, but ONLY if that rate is supported by the hardware.
  615. ;
  616. PBAUD:    PUSH    H        ;don't alter anybody
  617.     PUSH    D
  618.     PUSH    B
  619.     MOV    E,A        ;code to DE
  620.     MVI    D,0
  621.     LXI    H,BAUDTB    ;offset into table
  622.     DAD    D
  623.     MOV    A,M        ;fetch code
  624.     ORA    A        ;0? (means unsupported code)
  625.     JZ    PBEXIT        ;exit if so
  626.     STA    BDSET         ;good rate, set it
  627.     MVI    A,P8N1        ;need to get default PSW
  628.     STA    PSWSET        ;and save it
  629.     CALL    INITMOD1    ;Baud set, returns w/ A = Baud byte
  630.     STA    BAUDSV        ;save it
  631.     MOV    A,E        ;get speed code back
  632.     STA    MSPEED        ;make it current
  633.     JMP    PBEXIT + 1    ;jump error flag set
  634. PBEXIT:    STC            ;set return error for STBAUD caller
  635.     POP    B        ;all done
  636.     POP    D
  637.     POP    H
  638.     RET
  639. ;
  640. ; Table of baud rate parameters for supported rates
  641. ;
  642. BAUDTB:    DB    032H,035H,0,036H,0        ;110,300,450,610,710
  643.     DB    037H,03AH,03CH,03EH,03FH    ;1200,2400,4800,9600,19200
  644. BAUDSV: DB    037H            ;current baud byte
  645. BDSET:    DB    037H            ;current and default baud byte
  646. ;
  647. ;.....
  648. ;
  649. ; Sign-on message
  650. ;
  651. SYSVER:    LXI    D,VERMSG
  652.     MVI    C,PRINT
  653.     CALL    MEX
  654.     CALL    TIMMSG        ;prints 'current time is .... '
  655.     CALL    CRLF
  656.     RET
  657. ;
  658. ;.....
  659. ;
  660. ; Newline on console
  661. ;
  662. CRLF:    MVI    A,CR
  663.     CALL    TYPE
  664.     MVI    A,LF        ;fall into TYPE
  665. ;
  666. ; type char in A on console
  667. ;
  668. TYPE:    PUSH    H        ;save 'em
  669.     PUSH    D
  670.     PUSH    B
  671.     MOV    E,A        ;align output character
  672.     MVI    C,CONOUT    ;print via MEX
  673.     CALL    MEX
  674.     POP    B
  675.     POP    D
  676.     POP    H
  677.     RET
  678. ;
  679. ;----------------------------------------------------------------------
  680. ;
  681. ; The remainder of this overlay implements a very versatile SET command
  682. ; -- if you prefer not to write a SET for your modem, you may delete the
  683. ; code from here to the END statement. Control is passed here after
  684. ; MEX parses a SET command.
  685. ;
  686. ;
  687. SETCMD:    MVI    C,SBLANK    ;any arguments?
  688.     CALL    MEX
  689.     JC    SETSHO        ;if not, go print out values
  690.     LXI    D,CMDTBL    ;parse command
  691.     CALL    TSRCH        ;from table
  692.     PUSH    H        ;any address on stack
  693.     RNC            ;if we have one, execute it
  694.     POP    H        ;nope, fix stack
  695. SETERR:    LXI    D,SETEMS    ;print error
  696.     MVI    C,PRINT
  697.     CALL    MEX
  698.     RET
  699. ;
  700. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  701. ;
  702. ; SET command table ... note that tables are constructed of command-
  703. ; name (terminated by high bit=1) followed by word-data-value returned
  704. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  705. ; a binary zero.
  706. ;
  707. ; Note that LOOKUP attempts to find the next item in the input stream
  708. ; in the table passed to it in HL ... if found, the table data item is
  709. ; returned in HL; if not found, LOOKUP returns carry set.
  710. ;
  711. CMDTBL:    DB    '?'+80H            ;"set ?"
  712.     DW    STHELP
  713.     DB    'BAU','D'+80H        ;"set baud"
  714.     DW    STBAUD
  715.     DB    'PS','W'+80H        ;"set PSW"
  716.     DW    STPSW
  717.     DB    'TIM','E'+80H        ;"set TIME" -- just displays time
  718.     DW    TIMMSG
  719.     DB    'TON','E'+80H        ;'set TONE/PULSE byte to 'T'
  720.     DW    STTONE
  721.     DB    'PULS','E'+80H        ;'set TONE/PULSE byte to 'P'
  722.     DW    STPULSE
  723.     DB    0            ;<<=== table terminator
  724. ;
  725. ; SET <no-args>: print current statistics
  726. ;
  727. SETSHO:    LXI    H,SHOTBL    ;get table of SHOW subroutines
  728. SETSLP:    MOV    E,M        ;get table address
  729.     INX    H
  730.     MOV    D,M
  731.     INX    H
  732.     MOV    A,D        ;end of table?
  733.     ORA    E
  734.     RZ            ;exit if so
  735.     PUSH    H        ;save table pointer
  736.     XCHG            ;adrs to HL
  737.     CALL    GOHL        ;do it
  738.     CALL    CRLF        ;print newline
  739.     MVI    C,CHEKCC    ;check for console abort
  740.     CALL    MEX
  741.     POP    H        ;it's done
  742.     JNZ    SETSLP        ;continue if no abort
  743.     RET
  744. ;
  745. GOHL:    PCHL
  746. ;
  747. ; Table of SHOW subroutines
  748. ;
  749. SHOTBL:    DW    TIMMSG        ;displays time
  750.     DW    BDSHOW        ;displays current baud
  751.     DW    PSWSHOW        ;displays current PSW
  752.     DW    TPSHOW        ;displays current TPULSE byte (0105H)
  753.     DW    CRLF
  754.     DW    0        ;<<== table terminator
  755. ;
  756. ; SET ?  processor
  757. ;
  758. STHELP:    CALL     CLS            ;clear screen
  759.     CALL    TIMMSG
  760.     LXI    D,HLPMSG
  761.     MVI    C,PRINT
  762.     CALL    MEX
  763.     RET
  764. ;
  765. ; The help message
  766. ;
  767. HLPMSG:    DB    CR,LF,'SET Commands available are:',CR,LF,LF
  768.     DB    'SET BAUD  <110, 300, 600, 1200, 2400, 4800,'
  769.     DB    ' 9600, or 19200>',CR,LF
  770.     DB    'SET PSW   <8N1, 7E1, 7O1, or 7N1> -- Word Length,'
  771.     DB    ' Parity, Stop Bits',CR,LF
  772.     DB    'SET TIME  (Displays current time of day)',CR,LF
  773.     DB    'SET TONE  (Sets flag for TONE  dialing)',CR,LF
  774.     DB    'SET PULSE (Sets flag for PULSE dialing)'
  775.     DB    CR,LF,LF,'$'
  776. ;
  777. ; SET BAUD processor
  778. ;
  779. STBAUD:    MVI    C,BDPARS    ;function code
  780.     CALL    MEX    
  781.     JC    SETERR        ;invalid code
  782.     CALL    PBAUD        ;try to set it
  783.     JC    SETERR        ;unsupported code
  784. BDSHOW:    CALL    ILPRT        ;display baud
  785.     DB    'Baud rate:',TAB,' ',0
  786.     LDA    MSPEED
  787.     MVI    C,PRBAUD    ;use MEX routine
  788.     CALL    MEX
  789.     RET
  790. ;
  791. ; SET PSW processor
  792. ;
  793. STPSW:    MVI    C,SBLANK
  794.     CALL    MEX
  795.     JC    SETERR        ;SET PSW should have had argument
  796.     LXI    D,PSWTBL    ;look for PSW match in table
  797.     CALL    TSRCH
  798.     JC    SETERR        ;not there, so report error
  799.     MOV    A,L        ;get UART PSW byte from table in HL
  800.     STA    PSWSET        ;save it
  801.     CALL    INITMOD1    ;set CPS card w/ PSW and BAUD
  802. ;
  803. PSWSHOW:
  804.     CALL    ILPRT
  805.     DB    'PSW setting:',TAB,' ',0
  806.     LDA    PSWSET
  807.     CPI    P8N1
  808.     JNZ    PSW1
  809.     CALL    ILPRT
  810.     DB    '8N1',0
  811.     RET
  812. PSW1:    CPI    P7E1
  813.     JNZ    PSW2
  814.     CALL    ILPRT
  815.     DB    '7E1',0
  816.     RET
  817. PSW2:    CPI    P7O1
  818.     JNZ    PSW3
  819.     CALL    ILPRT
  820.     DB    '7O1',0
  821.     RET
  822. PSW3:    CPI    P7N1
  823.     JNZ    PSW4
  824.     CALL    ILPRT
  825.     DB    '7N1',0
  826.     RET
  827. PSW4:    CALL    ILPRT
  828.     DB    '<< ERROR >>',0
  829.     RET
  830. ;
  831. ;
  832. PSWSET:    DB    04EH            ;storage and default (8N1)
  833. ;
  834. ;
  835. PSWTBL:    DB    '8N','1'+80H
  836.     DW    P8N1
  837.     DB    '7E','1'+80H
  838.     DW    P7E1
  839.     DB    '7O','1'+80H
  840.     DW    P7O1
  841.     DB    '7N','1'+80H
  842.     DW    P7N1
  843.     DB    0
  844. ;
  845. ;.....
  846. ;
  847. ; These routines set TPULSE flag at 0105H to either 'T' or 'P' so that
  848. ; MODEM (specifically MXO-SM13.ASM) overlay will dial in TONE or PULSE
  849. ; mode.  The settings are mutually exclusive.
  850. ;
  851. STTONE:    MVI    A,'T'        ;get T flag
  852.     STA    TPULSE        ;put into proper place
  853.     JMP    TPSHOW        ;display dial mode
  854. ;
  855. STPULSE:
  856.     MVI    A,'P'        ;get P flag
  857.     STA    TPULSE
  858. ;
  859. TPSHOW:    CALL    ILPRT
  860.     DB    'Dial Mode:',TAB,' ',0
  861.     LDA    TPULSE
  862.     CPI    'T'
  863.     JNZ    TP1
  864.     CALL    ILPRT
  865.     DB    'TONE',0
  866.     RET
  867. TP1:    CPI    'P'
  868.     JNZ    TP2
  869.     CALL    ILPRT
  870.     DB    'PULSE',0
  871.     RET
  872. TP2:    CALL    ILPRT
  873.     DB    '<< ERROR >>',0
  874.     RET
  875. ;
  876. ;......
  877. ;
  878. ; Compare next input-stream item in table @DE; CY=1
  879. ; if not found, else HL=matched data item
  880. ;
  881. TSRCH:    MVI    C,LOOKUP    ;get function code
  882.     JMP    MEX        ;pass to MEX processor
  883. ;
  884. ; Print in-line message ... blows away C register
  885. ;
  886. ILPRT:    MVI    C,ILP        ;get function code
  887.     JMP    MEX        ;go do it
  888. ;
  889. ;------------------------------------------------------------
  890. ;
  891. ;        MEX  Fixed  Messages  Area
  892. ;
  893. ;
  894. EOSMSG:    DB    ESC,0D9H,0,0,'$'    ;clear to end of screen message
  895.                     ;for Videx Videoterm / SOROC
  896. ;
  897. CLSMSG:    DB    ESC,0AAH,0,0,'$'    ;clear screen message
  898.                     ;for Videx Videoterm / SOROC
  899. ;
  900. VERMSG:    DB    CR,LF,TAB,TAB,'Version for Apple ][ / Applicard'
  901.     DB    CR,LF
  902.     DB    TAB,TAB,' CPS card   '
  903.     DB    'Overlay Version ',REV/10+'0','.'
  904.     DB    REV MOD 10+'0'
  905.     DB    CR,LF,TAB,TAB,'    ','$'
  906. ;
  907. ;
  908. ;----------------------------------------------------------------------
  909. ;
  910. ;    Clock reading routines taken from TIME13.ASM
  911. ;
  912. ;                7/10/84   (H. Middlebrook)
  913. ;
  914. ; The program is specific to the following hardware:
  915. ;
  916. ;        Apple ][+
  917. ;        PCPI Applicard
  918. ;        Mountain Computer CPS Multifunction Card
  919. ;
  920. ; Program created as Version 1.0    7/10/84    - Henry Middlebrook
  921. ;
  922. ;.....
  923. ;
  924. TIMMSG:    CALL    ILPRT        ;Use MEX Inline Print
  925.     DB    'Current time is ',0
  926.     CALL    GET$TIME    ;routine to read CPS clock
  927.     CALL    PRT$TIME    ;print time of day
  928.     CALL    CRLF        ;final CR/LF
  929.     RET            ;...all done
  930. ;
  931. ;.....
  932. ;
  933. ; PCHAR -->    Prints as ASCII character BCD number in low nibble.
  934. ;        Routine falls through to CTYPE.
  935. ; CTYPE -->    Prints single character to CONSOLE through BDOS.
  936. ;
  937. PCHAR:    ANI    0FH    ;mask garbage in upper for bits
  938.     ADI    '0'    ;convert to ASCII
  939. CTYPE:    JMP    TYPE    ;use MEX routine
  940. ;
  941. ;.....
  942. ;
  943. ; GET$TIME -->    Reads CPS clock byte at a time and stores time in
  944. ;        CLKTBL.
  945. ;
  946. GET$TIME:
  947.     MVI    A,CLKHOLD    ;get byte to stop clock
  948.     CALL    WR$CLKSTAT    ;send to CPS card
  949.     MVI    A,100        ;short little delay
  950. DLOOP:    DCR    A        ;allows clock to settle
  951.     JNZ    DLOOP
  952.     LXI    D,CLKTBL    ;put CLKTBL address in DE
  953.     MVI    B,0        ;set clock index to 0
  954. ;
  955. TIME$LOOP:
  956.     MVI    A,CLKREAD    ;get byte to read clock
  957.     ORA    B        ;add clock index to read (50H - 5CH)
  958.     CALL    WR$CLKSTAT    ;send to CPS card
  959.     CALL    RD$CLKDATA    ;read clock (SEC1 --> YEAR10)
  960.     ANI    0FH        ;mask garbage in high nibble
  961.     STAX    D        ;save value read in CLKTBL
  962.     INX    D        ;bump CLKTBL address value in DE
  963.     INR    B        ;bump clock index in BC
  964.     MVI    A,0DH        ;fetch table length + 1
  965.     CMP    B        ;are we beyond end of table...
  966.     JNZ    TIME$LOOP    ;no, then go back again
  967.     XRA    A        ;yes, then zero A reg to turn on clock
  968.     CALL    WR$CLKSTAT
  969.     RET
  970. ;
  971. ;......
  972. ;
  973. ; PRT$TIME -->  Reads CLKTBL byte by byte to print time.  This code
  974. ;        converts 24hr time to 12hr format.  This code is extract
  975. ;        from TIME13 and prints on HH:MM aM using MEX print
  976. ;        routines.
  977. ;
  978. PRT$TIME:
  979.     XRA    A        ;set AMPM flag to AM
  980.     STA    AMPM
  981.     LDA    CLKTBL + 5    ;get H10 -- start BCD to Binary convert
  982.     ANI    03H        ;mask AM/PM garbage
  983.                 ;and mask off low nibble
  984.     RLC            ;A = A * 2
  985.     MOV    C,A        ;save A
  986.     RLC            ;A = A * 4
  987.     RLC            ;A = A * 8
  988.     ADD    C        ;A = (A * 2) + (A * 8) = A * 10
  989.                 ;A = H10 * 10
  990.     LXI    H,CLKTBL+4    ;get address of H1
  991.     ADD    M        ;Now we have binary hour in A
  992.     JZ    TIME5        ;if 00:00 -- 00:59 AM jmp to fix
  993.     CPI    0CH        ;is it afternoon (PM)
  994.     JC    TIME0        ;no, then enter at std entry point
  995.     STA    AMPM        ;yes, then make AMPM non-zero (=PM)
  996.     CPI    0DH        ;is it 13:00:00 (1:00 PM) yet?
  997.     JC    TIME0        ;no, then normal print entry
  998.     SUI    0CH        ;yes, then subtract 12hrs
  999.     MVI    B,0FFH
  1000. TIME3:    INR    B        ;divide hr by 10
  1001.     SUI    0AH
  1002.     JNC    TIME3
  1003.     ADI    0AH
  1004.     MOV    M,A        ;and put H1 back
  1005.     INX    H
  1006.     MOV    M,B        ;put H10 back
  1007.     JMP    TIME0
  1008. TIME5:    MVI    M,2        ;kludge to print 12:xx AM
  1009.     INX    H
  1010.     MVI    M,1
  1011. TIME0:    LDA    CLKTBL + 5    ;get H10
  1012.     ANI    03H        ;mask garbage
  1013.     ORA    A
  1014.     JZ    TIME1        ;skip print if H10 = 0
  1015.     CALL    PCHAR
  1016. TIME1:    LDA    CLKTBL + 4    ;get H1
  1017.     CALL    PCHAR
  1018.     MVI    A,':'        ;delimiter
  1019.     CALL    CTYPE
  1020.     LDA    CLKTBL + 3    ;get M10
  1021.     CALL    PCHAR
  1022.     LDA    CLKTBL + 2    ;get M1
  1023.     CALL    PCHAR
  1024.     LDA    AMPM        ;AM=00H,  PM=anything else
  1025.     ORA    A        ;set flags
  1026.     JNZ    TIME2        ;print AM
  1027.     CALL    ILPRT
  1028.     DB    ' AM',0
  1029.     RET
  1030. TIME2:    CALL    ILPRT
  1031.     DB    ' PM',0        ;print PM message
  1032.     RET
  1033. ;
  1034. ;.........
  1035. ;
  1036. ;    FIXED DATA AREA FOR CLOCK FUNCTION
  1037. ;
  1038. ; The CLKTBL is fixed, initialized area used to store time as
  1039. ; read from CPS clock hardware.
  1040. ;
  1041. CLKTBL:    DB    0        ;S1
  1042.     DB    0        ;S10
  1043.     DB    0        ;MIN1
  1044.     DB    0        ;MIN10
  1045.     DB    0        ;H1
  1046.     DB    0        ;H10
  1047.     DB    0        ;Day of Week
  1048.     DB    0        ;D1
  1049.     DB    0        ;D10
  1050.     DB    0        ;MON1
  1051.     DB    0        ;MON10
  1052.     DB    0        ;Y1
  1053.     DB    0        ;Y10
  1054. ;
  1055. AMPM:    DB    0        ;flag --> 00H = AM,  else = PM
  1056. ;
  1057. ;----------------------------------------------------------------------
  1058. ;
  1059. ; >>>>     Note that the following routines can only be used if the
  1060. ; >>>>    appropriate patches are made in MEX using the MEXPATxx file.
  1061. ;
  1062.     IF    USERPRINTER
  1063. ;
  1064. ; The BIOS implementation in the AppliCard and the BDOS print
  1065. ; routines interfere with data reception if the printer function is
  1066. ; enabled. The following routine for a Super-MX parallel printer card
  1067. ; can  be used as a guide for the writing of an appropriate printer
  1068. ; driver called as a vector from the program.
  1069. ;
  1070. ;
  1071. ; This routine replaces the MEX PRTSTS routine in the main program.
  1072. ; It returns with A = 0 if NOT ready.  If printer is ready return
  1073. ; with A = 0FFH.  These vectors are EQU'd in MEXPAT section of code.
  1074. ;
  1075. PRTSTS:    PUSH    D
  1076.     LXI    D,PTRSTATP
  1077.     CALL    PEEK        ;get byte from printer status address
  1078.     POP    D
  1079.     ANI    PTR$RDY        ;mask for printer status byte
  1080.     SUI    PTR$RDY        ;return A = 0 if NOT ready
  1081.     RET            ;else return A = 0FFH IF ready
  1082. ;
  1083. ; The following routine is called via the MEX LVEC in MEXPAT.
  1084. ;
  1085. ; This routine is entered with byte to print in 'A' register. All
  1086. ; characters (printable or not) will be sent to printer data port.
  1087. ; Parallel printer strobe line is then toggled by writing to the
  1088. ; the two strobe addresses.
  1089. ;
  1090. WR$PRT:    ANI    07FH        ;clear Hi-bit
  1091.     PUSH    D
  1092.     LXI    D,PTRDATP
  1093.     CALL    POKE        ;put data on printer o/p lines
  1094.     LXI    D,PTRSTBP1
  1095.     CALL    POKE        ;strobe hi...
  1096.     LXI    D,PTRSTBP2
  1097.     CALL    POKE        ;...then low
  1098.     POP    D
  1099.     RET
  1100. ;
  1101.     ENDIF            ;USERPRINTER
  1102. ;
  1103. ;
  1104. ;    >>>>   End of PORT specific overlay section   <<<<
  1105.  
  1106. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  1107. ;
  1108. ;        MODEM SPECIFIC OVERLAY SECTION
  1109. ;
  1110. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  1111. ;
  1112. ;        MEX SMARTMODEM OVERLAY V1.3
  1113. ;
  1114. ; Smartmodem overlay for MEX: revision 1.3
  1115. ;
  1116. ; Adapted for MXO-AP31 Overlay by Henry Middlebrook (1/85)
  1117. ;
  1118. ; NOTE: Some redundant parts of the V1.3 overlay were removed when this
  1119. ;    section was pulled into MXO-AP31.  See the original overlay for
  1120. ;    additional information on the history and use of this MODEM
  1121. ;    specific overlay.        -HM-    2/4/85
  1122. ;
  1123. ; Written 04/16/84 by Ronald G. Fowler (V1.0)
  1124. ;
  1125. ; 06/06/84: Fixed problem for Anchor users, where, when the modem
  1126. ;        returned "DIAL TONE", the "N" in "TONE" was being regarded
  1127. ;        as a NO-CONNECT code.  Now we flush the entire result line
  1128. ;        before reading another. Also added code for numeric version
  1129. ;        of "CONNECT 1200".  --RGF
  1130. ;
  1131. ; This modules adapts MEX for the DC Hayes Smartmodem (as well as many
  1132. ; others -- including US Robotics -- that use a similar command language).
  1133. ; The main function of this module is to provide dialing capability;
  1134. ; the disconnect vector is ancillary. You may use this module as a model
  1135. ; to develop dialing routines for non-standard modems. The only pertinent
  1136. ; entry point is the DIAL routine; you'll find entry specs for that below.
  1137. ;
  1138. ;
  1139. ; This overlay will work separately with any modem overlay that terminates
  1140. ; prior to 0B00H or which combines this module with I/O routine overlay
  1141. ; and together they terminate prior to 0D00H.
  1142. ;
  1143. ;
  1144. ; This is the DIAL routine called by MEX to dial a digit. The digit
  1145. ; to be dialed is passed in the A register.  Note that two special
  1146. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  1147. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  1148. ; in the accumulator prior to dialing a number.  Mex will also call
  1149. ; dial with 255 in A as an indication that dialing is complete. Thus,
  1150. ; the overlay may use these values to "block" the number, holding it
  1151. ; in a buffer until it is completely assembled (we don't do this with
  1152. ; the PMMI, however; we just dial the digits as they come in).
  1153. ;
  1154. ; After the 254-start-dial sequence, MEX will call the overlay with
  1155. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  1156. ; its, and will send each to the DIAL routine un-inspected (some modems,
  1157. ; like the Smartmodem, allow special non-numeric characters in the
  1158. ; phone number, and MEX may make no assumptions about these). This
  1159. ; dialing routine validates digits, and ignores any except 0-9 and
  1160. ; comma (uses comma to simulate Smartmodem delay).
  1161. ;
  1162. ; After receiving the end-dial sequence (255) the overlay must take
  1163. ; whatever end-of-dial actions are necessary *including* waiting for
  1164. ; carrier at the distant end.  The overlay should monitor the keyboard
  1165. ; during this wait (using the MEX keystat service call), and return
  1166. ; an exit code to MEX in the A register, as follows:
  1167. ;
  1168. ;    0 - Carrier detected, connection established
  1169. ;    1 - Far end busy (only for modems that can detect this condition)
  1170. ;    2 - No answer (or timed out waiting for modem response)
  1171. ;    3 - Keyboard abort (^C only: all others should be ignored)
  1172. ;    4 - Error reported by modem
  1173. ;    5 - No ring
  1174. ;    6 - No dialtone
  1175. ;
  1176. ; <No other codes should be returned after an end-dial sequence>
  1177. ;
  1178. ; The overlay should not loop forever in the carrier-wait routine, but
  1179. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  1180. ; ms character wait) service call routine.
  1181. ;
  1182. ; The DIAL routine is free to use any of the registers, but must return
  1183. ; the above code after an end-dial sequence
  1184. ;
  1185. ;
  1186.     ORG    0B00H        ;maintain official MEX origin
  1187. ;
  1188. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  1189.     CPI    254        ;START DIAL?
  1190.     JZ    STDIAL        ;JUMP IF SO
  1191.     CPI    255        ;END DIAL?
  1192.     JZ    ENDIAL        ;JUMP IF SO
  1193. ;
  1194. ; Not start or end sequence, must be a digit to be sent to the modem
  1195. ;
  1196.     MOV    M,A        ;PUT CHAR IN BUFFER
  1197.     INX    H        ;ADVANCE POINTER
  1198.     SHLD    DIALPT        ;STUFF PNTR
  1199.     RET            ;ALL DONE
  1200. ;
  1201. ; Here on a start-dial sequence
  1202. ;
  1203. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  1204.     SHLD    DIALPT
  1205.     RET
  1206. ;
  1207. ; Here on an end-dial sequence
  1208. ;
  1209. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  1210.     INX    H        ;FOLLOWED BY TERMINATOR
  1211.     MVI    M,0
  1212.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  1213.     STA    SMDIAL+3    ;PUT INTO STRING
  1214.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  1215.     CALL    SMSEND        ;SEND IT
  1216. WAITSM:    MVI    C,INMDM
  1217.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  1218.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  1219. ;
  1220. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  1221. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  1222. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  1223. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  1224. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  1225. ; WAIT TO 20 SECONDS).
  1226. ;
  1227. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  1228. SMWLP:    PUSH    B
  1229.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  1230.     MVI    C,TMDINP    ;DO TIMED INPUT
  1231.     CALL    MEX
  1232.     POP    B
  1233.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  1234.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  1235.     MVI    C,CHEKCC
  1236.     CALL    MEX
  1237.     POP    B
  1238.     JNZ    SMNEXT        ;IF NOT, JUMP
  1239.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  1240.     MVI    C,SNDCHR
  1241.     CALL    MEX
  1242.     MVI    A,3        ;RETURN ABORT CODE
  1243.     RET
  1244. SMNEXT:    DCR    C        ;NO
  1245.     JNZ    SMWLP        ;CONTINUE
  1246. ;
  1247. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  1248. ;
  1249. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  1250.     RET
  1251. ;
  1252. ; MODEM GAVE US A RESULT, CHECK IT
  1253. ;
  1254. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  1255.     CALL    SMANAL        ;TEST THE RESULT
  1256.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  1257.     PUSH    PSW        ;SAVE IT
  1258. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  1259.     CALL    MEX
  1260.     JC    SMCHEK        ;JUMP IF NO INPUT
  1261.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  1262.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  1263. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  1264.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  1265.     RET
  1266. ;
  1267. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  1268.     CPI    'C'        ;"CONNECT"?
  1269.     RZ
  1270.     CPI    '1'        ;NUMERIC VERSION OF "CONNECT"
  1271.     RZ
  1272.     CPI    '5'        ;NUMERIC VERSION OF "CONNECT 1200"
  1273.     RZ
  1274.     INR    B        ;PREP BUSY CODE B=1
  1275.     CPI    'B'
  1276.     RZ
  1277.     INR    B        ;PREP NO CONNECT MSG B=2
  1278.     CPI    'N'        ;N=NO CONNECT
  1279.     RZ
  1280.     CPI    '3'        ;NUMERIC VERSION OF "NO CONNECT"
  1281.     RZ
  1282.     MVI    B,4        ;PREP MODEM ERROR
  1283.     CPI    'E'        ;E=ERROR
  1284.     RZ
  1285.     CPI    '4'        ;NUMERIC VERSION OF "ERROR"
  1286.     RZ
  1287.     STC            ;UNKNOWN...
  1288.     RET
  1289. ;
  1290. ;.....
  1291. ;
  1292. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  1293. ;
  1294. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  1295.     CALL    MEX
  1296.     JNZ    SMSEND
  1297.     MOV    A,M        ;FETCH NEXT CHARACTER
  1298.     INX    H
  1299.     ORA    A        ;END?
  1300.     RZ            ;DONE IF SO
  1301.     MOV    B,A        ;NO, POSITION FOR SENDING
  1302.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  1303.     CALL    MEX
  1304.     JMP    SMSEND
  1305. ;
  1306. ; DATA AREA
  1307. ;
  1308. SMDIAL:    DB    'ATDT '
  1309. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  1310. DIALPT:    DS    2        ;DIAL POSITION POINTER
  1311. ;
  1312. ;
  1313. ;    >>>>    End of MODEM Specific Overlay
  1314.  
  1315. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  1316. ;
  1317. ;        MEXPAT11.ASM    --    Patch file
  1318. ;
  1319. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  1320. ;
  1321. ; 02/04/85  --    Patches in this file were for the convenience of the
  1322. ;        author as well as to support a new LSTVEC and LVEC
  1323. ;        which is in PORT section of this overlay, MXO-AP3x.
  1324. ;                    -- H. Middlebrook
  1325. ;
  1326. ; This is the patch file for MEX 1.1 -- you may edit this file to change
  1327. ; various initial variables. Assemble with ASM or MAC, then use MLOAD
  1328. ; to patch the changes into MEX:
  1329. ;
  1330. ;    ASM MEXPAT11.AAZ            ;assemble the edited file
  1331. ;    MLOAD NEWMEX.COM=MEX.OBJ,MEXPAT10    ;patch MEX
  1332. ;
  1333. ; You may also pull this file into your modem overlay (be sure you in-
  1334. ; clude the ORG statement below).
  1335. ;
  1336. ; The order of the patch variables supported here will not change from
  1337. ; version to version (i.e., new items will be added on to the end).
  1338. ;
  1339. ;
  1340.     ORG    0D00H        ;location of patch variables
  1341. ;
  1342. ;
  1343. ;
  1344. ; The following line defines the MEX service call entry point, and
  1345. ; is not meant to be changed by the user
  1346. ;
  1347. MEXSTART:    DS    3        ;MEX service call processor
  1348.         DS    3        ;reserved
  1349.         DS    1        ;reserved
  1350. ;
  1351. ; The following line contains the initial free-memory pointer for
  1352. ; MEX.  Sophisticated modem overlays requiring additional space may change
  1353. ; this pointer (ie, move it higher), and thus "protect" an area of RAM.
  1354. ;
  1355. MEMRY:    DS    2        ;first free memory pointer
  1356. ;
  1357. ; Following are the lowest-level vectors for console and list I/O used
  1358. ; by MEX.  These normally point to routines that save the registers and
  1359. ; vector to the appropriate BIOS routines.  Complex applications may
  1360. ; need to intercept (or even replace) these routines.  If you do this,
  1361. ; be sure to preserve DE, HL and BC.
  1362. ;
  1363. STSVEC:    DS    2        ;console status vector
  1364. INVEC:    DS    2        ;console input vector
  1365. OUTVEC:    DS    2        ;console output vector
  1366. ;
  1367. ; NOTE: The USERPRINTER Equate must be set TRUE or FALSE and the routines
  1368. ;    must be provided.  The original MEXPAT11 overlay just uses DS 2.
  1369. ;
  1370.     IF    USERPRINTER
  1371. LVEC:    DW    WR$PRT        ;list output vector
  1372. LSTVEC:    DW    PRTSTS        ;list status vector
  1373.     ENDIF            ;USERPRINTER
  1374. ;
  1375.     IF    NOT USERPRINTER
  1376. LVEC:    DS    2        ;list output vector
  1377. LSTVEC:    DS    2        ;list status vector
  1378.     ENDIF            ;NOT USERPRINTER
  1379.  
  1380. ;
  1381. ; The following line defines the location of the default MEX prompt.
  1382. ; If you'd like to provide your own initial prompt, add a DW statement
  1383. ; pointing to a prompt buffer structured as follows:
  1384. ;
  1385. ;        DB <max size of buffer>
  1386. ;        DB <length of actual prompt>
  1387. ;        DB <prompt string>
  1388. ;
  1389. ; <maxsize> and <length> may be equal (especially if you disable the
  1390. ; ID command by setting CHGPMT, below to 0); the ID command will, if
  1391. ; left enabled, be limited to the <max size> value.
  1392. ;
  1393. PROMPT:    DS    2        ;prompt location
  1394.     DS    1        ;reserved
  1395. TYPLIN:    DB    22        ;for TYPE command: # lines/screen
  1396. PAUSFL:    DB    1        ;for TYPE cmd: 1=pause 0=no pause
  1397. SEPCHR:    DB    ';'        ;multiple command-line separator
  1398. ;
  1399. ; following five for SENDOUT command
  1400. ;
  1401. SOWAIT:    DB    4        ;# seconds waiting for a sendout echo
  1402. SOREPL:    DB    8        ;# seconds waiting for initial reply
  1403. SOTRIG:    DB    '>'        ;sendout trigger char from remote
  1404. CANCHR:    DB    'U'-64        ;sendout char to cancel line to remote
  1405. SORTRY:    DB    6        ;sendout # retries
  1406. ;
  1407. ;
  1408. HEXFLG:    DB    0        ;hex/decimal mode
  1409. ESCCHR:    DB    1BH        ;terminal mode escape char (1BH = ESC)
  1410. NOBELL:    DB    0        ;set to 1 to disable bell
  1411. ;
  1412. ; Buffer variables.  See BUFFERS.DOC for setup information
  1413. ;
  1414. PSIZE:    DB    2        ;default=2k
  1415. ASIZE:    DB    255        ;"big" capture buffer
  1416. XSIZE:    DB    16        ;16K transfer buffer
  1417. NSIZE:    DB    1        ;1k for 85 batch files
  1418. PRELEN:    DB    40        ;maximum length of PREFIX string
  1419. SUFLEN:    DB    40        ;maximum length of SUFFIX string
  1420. ;
  1421. ; Misc. stuff
  1422. ;
  1423. CDOSFL:    DB    0        ;non-zero for CDOS
  1424. WTECHO:    DB    0        ;non-zero sets "wait-for-echo"
  1425. KYSIZE:    DW    400        ;size of keystring area, in bytes
  1426. CISFLG:    DB    1        ;non-zero allows CIS file transfers
  1427. CISOK:    DB    1        ;non zero allows STAT CIS ON or OFF
  1428. CHGPMT:    DB    1        ;non-zero allows ID (prompt chg) command
  1429. ERRID:    DB    1        ;non-zero prints ID msg in err msgs
  1430. ;
  1431. ; by setting the following DB to 0, you can disable the HELP
  1432. ; command, freeing up space used by the help file index.
  1433. ;
  1434. HELPOK:    DB    1        ;non-zero allows HELP command
  1435. MEXDU:    DB    0        ;user \/  alt. area for READ,LOAD,INI.MEX
  1436.     DB    0        ;drive/\  & HELP.MEX (if SEARCH <>0)
  1437. DEBUG:    DB    0        ;debugging in term-mode if non-zero
  1438. EXCLSY:    DB    1        ;non-0 excludes $SYS from batchsend, dir
  1439. INIMEX:    DB    0        ;non-zero runs INI.MEX at startup
  1440. RTIMER:    DB    1        ;receiver wait: # seconds [Plouff patch]
  1441. PQSIZE:    DW    150        ;size of the modem-port queue
  1442. PHSIZE:    DB    30        ;phone library size (# entries)
  1443. SILENT:    DB    0FFH        ;0=silence multi-line & READ cmd echo
  1444. ALERT:    DB    255        ;alert-bell count on CALL complete
  1445. EXTEND:    DB    0        ;non-zero: unk cmds goto READ processor
  1446. SPLIT:    DB    1        ;non-zero: phonelib printout, shows baud
  1447. SEARCH:    DB    0        ;search mode 0,1,2,3
  1448. ;
  1449. ; Following is the GLOBAL secondary options table.  To
  1450. ; set an option to global, change its ASCII character to a 0.
  1451. ;
  1452. RESTT:    DB    'ABDELQRSTVX'
  1453.     DS    8        ;room for option expansion
  1454. ;
  1455. ;
  1456. ; added on release 1.10:
  1457. ;
  1458. queue:    db    1        ;1=allow queueing, 0=no
  1459. timbas:    dw    208        ;timing constant
  1460. mode:    db    0        ;mode of modem I/O
  1461. sminit:    ds    2        ;Smartmodem INIT routine adrs
  1462. ssetv:    ds    2        ;SSET command: defaulted off
  1463. smexit:    ds    2        ;Smartmodem EXIT routine adrs
  1464.     ds    4        ;internal to MEX
  1465. sodflg:    db    0        ;1=tie SENDOUT to time delay if no WTECHO
  1466. autosv:    db    1        ;0=initial term mode, save off
  1467. tabflg:    db    0ffh        ;non-zero=expand tabs within MEX
  1468. ;
  1469. ;
  1470. ;        >>>> End of PATCH Overlay Section <<<<
  1471. ;
  1472.     END
  1473.