home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / mex / mxo-gs10.azm / MXO-GS10.ASM
Assembly Source File  |  1988-11-18  |  27KB  |  1,017 lines
  1. ;    TITLE  'MEX Overlay for Apple ][ / IIgs port / Smartmodem'
  2. ;
  3. ;  MXO-GS10.ASM created 11/11/88   by   Nick Sayer
  4. ;
  5. REV    EQU    10        ; Nov 11, 1988
  6. ;
  7. ; 
  8. ; This overlay is specific for the following hardware:
  9. ;
  10. ;    Apple ][ +/e  with PCPI Applicard
  11. ;    Apple IIgs Modem Port
  12. ;    Hayes compatible intelligent modem
  13. ;
  14. ;            - Nick Sayer (N6QQQ)
  15. ;                November 11, 1988
  16. ;
  17. ; Kudos to Henry Middlebrook for this overlay. I used his overlay outline,
  18. ; deleted his most of the hardware specific code and replaced it with a
  19. ; fleshed out version of a similar overlay I wrote for IMP245.COM.
  20. ;
  21. ; This overlay is written in three distinct parts as a "MIXED" type of
  22. ; overlay for MEX.  The parts follow the guidelines available in the
  23. ; MEX OVERLAY LIST #2 (01/06/85 -- Ron Fowler, NightOwl Software) with
  24. ; reference to the PORT, MODEM, and PATCH overlay types.  Thus, you
  25. ; should be able to remove or add any one of the three parts without
  26. ; severely affecting the overlay operation.  Naturally, removing the
  27. ; first section (PORT) will completely disable MEX; however, removing
  28. ; or changing the the MODEM (derived from MXO-SM13.ASM) section or
  29. ; the PATCH (MEXPAT11.ASM) will minimally affect operation (see LSTST
  30. ; and SSET).
  31. ;
  32. ; >>>>  NOTE:      Previous versions of MXO-APxx do NOT properly support
  33. ;        the PCPI Applicard.  You may not like this overlay;
  34. ;        however, you can use it as a reliable guide.
  35. ;
  36. ;                HM    02/04/85
  37. ;
  38. ; To use this overlay just set equates as you see fit, assemble with
  39. ; ASM.COM then using MLOAD21.COM and MEX112.COM create running MEX:
  40. ;
  41. ;    A>MLOAD21 MEX.COM=MEX112.COM,MXO-AP50
  42. ;
  43. ;----------------------------------------------------------------------
  44. ;
  45. ;            Overlay Update History
  46. ;
  47. ; 11/11/88 - Coded for Apple IIgs I/O     -GS10 - Nick Sayer
  48. ; 02/06/85 - Coded for Apple SSC I/O      -AP50 - Henry Middlebrook
  49. ; 01/28/85 - Created MXO original overlay -AP30    - Henry Middlebrook
  50. ;
  51. ;======================================================================
  52.  
  53. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  54. ;
  55. ;            PORT OVERLAY SECTION
  56. ;
  57. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  58. ;
  59. BELL        EQU    07H    ;bell
  60. CR        EQU    0DH    ;carriage return
  61. ESC        EQU    1BH    ;escape
  62. LF        EQU    0AH    ;linefeed
  63. TAB        EQU    09H    ;tab
  64. YES        EQU    0FFH
  65. NO        EQU    0
  66. ;
  67. ;----------------------------------------------------------------------
  68. ;
  69. ;    MEX Service Processor Calls
  70. ;
  71. MEX    EQU    0D00H    ;address of the service processor
  72. INMDM    EQU    255    ;get char from port to A, CY=no more in 100 ms
  73. TIMER    EQU    254    ;delay 100ms * reg B
  74. TMDINP    EQU    253    ;B=# secs to wait for char, cy=no char
  75. CHEKCC    EQU    252    ;check for ^C from KBD, Z=present
  76. SNDRDY    EQU    251    ;test for modem-send ready
  77. RCVRDY    EQU    250    ;test for modem-receive ready
  78. SNDCHR    EQU    249    ;send a character to the modem (after sndrdy)
  79. RCVCHR    EQU    248    ;recv a char from modem (after rcvrdy)
  80. LOOKUP    EQU    247    ;table search: see CMDTBL comments for info
  81. PARSFN    EQU    246    ;parse filename from input stream
  82. BDPARS    EQU    245    ;parse baud-rate from input stream
  83. SBLANK    EQU    244    ;scan input stream to next non-blank
  84. EVALA    EQU    243    ;evaluate numeric from input stream
  85. LKAHED    EQU    242    ;get nxt char w/o removing from input
  86. GNC    EQU    241    ;get char from input, cy=1 if none
  87. ILP    EQU    240    ;inline print
  88. DECOUT    EQU    239    ;decimal output
  89. PRBAUD    EQU    238    ;print baud rate
  90. PRNTBL    EQU    237    ;print command table in columns (HL=addr)
  91. PRID    EQU    236    ;print MEX ID string on console
  92. ;
  93. CONOUT    EQU    2    ;simulated BDOS function 2: console char out
  94. PRINT    EQU    9    ;simulated BDOS function 9: print string
  95. INBUF    EQU    10    ;input buffer, same structure as BDOS 10
  96. ;
  97. ;
  98. ;======================================================================
  99. ;
  100.     ORG    100H    ;we begin
  101. ;
  102.     DS    3    ;MEX has a JMP START here            100H
  103. ;
  104. ; The following variables are located at the beginning of the program
  105. ; to facilitate modification without the need of re-assembly. They will
  106. ; be moved in MEX 2.0.
  107. ;
  108. PMODEM:    DB    YES    ;\ / These two locations are            103H
  109. SMODEM:    DB    NO    ;/ \ not referenced by MEX.            104H
  110. TPULSE:    DB    'T'    ;Tone/Pulse (used only in Smodem overlay)    105H
  111. CLOCK:    DB    60    ;clock speed x .1, up to 25.5 mhz.        106H
  112. MSPEED:    DB    6    ;sets display time for sending a file        107H
  113.             ;0=110    1=300  2=450  3=600  4=710
  114.             ;5=1200 6=2400 7=4800 8=9600 9=19200
  115. BYTDLY:    DB    1    ;default time to send character in        108H
  116.             ;terminal mode file transfer (0-9)
  117.             ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  118. CRDLY:    DB    1    ;end-of-line delay in terminal            109H
  119.             ;mode file transfer for slow BBS systems
  120.             ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  121. COLUMS:    DB    5    ;number of directory columns            10AH
  122. SETFL:    DB    YES    ;yes=user-defined SET command            10BH
  123. SCRTST:    DB    YES    ;yes=if home cursor and clear screen        10CH
  124.             ;routine at CLRSCRN
  125.     DB    0    ;was once ACKNAK, now spare            10DH
  126. BAKFLG:    DB    NO    ;yes=make .BAK file                10EH
  127. CRCDFL:    DB    YES    ;yes=default to CRC checking            10FH
  128.             ;no=default to Checksum checking
  129. TOGCRC:    DB    YES    ;yes=allow toggling of Checksum to CRC        110H
  130. CVTBS:    DB    NO    ;yes=convert backspace to rub            111H
  131. TOGLBK:    DB    YES    ;yes=allow toggling of bksp to rub        112H
  132. ADDLF:    DB    NO    ;no=no LF after CR to send file in        113H
  133.             ;terminal mode (added by remote echo)
  134. TOGLF:    DB    YES    ;yes=allow toggling of LF after CR        114H
  135. TRNLOG:    DB    NO    ;yes=allow transmission of logon        115H
  136.             ;write logon sequence at location LOGON
  137. SAVCCP:    DB    YES    ;yes=do not overwrite CCP            116H
  138. LOCNXT:    DB    NO    ;yes=local cmd if EXTCHR precedes        117H
  139.             ;no=not local cmd if EXTCHR precedes
  140. TOGLOC:    DB    YES    ;yes=allow toggling of LOCNXTCHR        118H
  141. LSTTST:    DB    YES    ;yes=allow toggling of printer on/off        119H
  142.             ;in terminal mode. Set to no if using
  143.             ;the printer port for the modem
  144. XOFTST:    DB    YES    ;yes=allow testing of XOFF from remote        11AH
  145.             ;while sending a file in terminal mode
  146. XONWT:    DB    NO    ;yes=wait for XON after sending CR while    11BH
  147.             ;transmitting a file in terminal mode    
  148. TOGXOF:    DB    YES    ;yes=allow toggling of XOFF testing        11CH
  149. IGNCTL:    DB    NO    ;yes=do not send control characters        11DH
  150.             ;above CTL-M to CRT in terminal mode
  151.             ;no=send any incoming CTL-char to CRT
  152. EXTRA1:    DB    0    ;for future expansion                11EH
  153. EXTRA2:    DB    0    ;for future expansion                11FH
  154. BRKCHR:    DB    'B'-40H    ;^@ = Send a 300 ms. break tone            120H
  155. NOCONN:    DB    'N'-40H    ;^N = Disconnect from phone line        121H
  156. LOGCHR:    DB    'L'-40H    ;^L = Send logon                122H
  157. LSTCHR:    DB    'P'-40H    ;^P = Toggle printer                123H
  158. UNSVCH:    DB    'R'-40H    ;^R = Close input text buffer            124H
  159. TRNCHR:    DB    'T'-40H    ;^T = Transmit file to remote            125H
  160. SAVCHR:    DB    'Y'-40H    ;^Y = Open input text buffer            126H
  161. EXTCHR:    DB    '^'-40H    ;^^ = Send next character            127H
  162. ;
  163. ; Equates used only by PMMI routines grouped together here.
  164. ;
  165. PRATE:    DB    125    ;125=20pps dialing, 250=10pps            128H
  166.     DB    0    ;not used                    129H
  167. ;
  168. ; Jump table accessed by MEX to write/read serial port
  169. ;
  170. IN$MODSTAP:    JMP    RD$MODSTAP     ;read ACIA status port        12AH
  171.         DS    7
  172. OUT$MODDATP:    JMP    WR$MODDATP    ;send character to ACIA        134H
  173.         DS    7
  174. IN$MODDATP:    JMP    RD$MODDATP    ;read character from ACIA    13EH
  175.         DS    7
  176. ;
  177. ; Bit-test routines.  These will be merged with the above
  178. ; routines in MEX 2.0 to provide a more reasonable format
  179. ;
  180. MASKR:        ANI    MDRCVB ! RET    ;bit to test for receive ready    148H
  181. TESTR:        CPI    MDRCVR ! RET    ;value of rcv. bit when ready    14BH
  182. MASKS:        ANI    MDSNDB ! RET    ;bit to test for send ready    14EH
  183. TESTS:        CPI    MDSNDR ! RET    ;value of send bit when ready    151H
  184. ;
  185. ; Unused area: was once used for special PMMI functions, now used only
  186. ; to retain compatibility with MDM overlays. You may use this area for
  187. ; any miscellaneous storage you'd like but the length of the area
  188. ; >> MUST << be 12 bytes.
  189. ;
  190.         DS    12        ;PMMI only calls        154H
  191. ;
  192. ; Special modem function jump table: if your overlay cannot handle
  193. ; some of these, change the jump to "DS 3", so the code present in
  194. ; MEX will be retained.  Thus, if your modem can't dial, change the
  195. ; JMP PDIAL at DIALV to DS 3, and MEX will print a "not-implemented"
  196. ; diagnostic for any commands that require dialing.
  197. ;
  198. ;
  199. LOGON:        DS    2        ;not used by MEX          160H
  200. DIALV:        JMP    DIAL        ;dial a digit in A (ref SMOVL)    162H
  201. DISCV:        JMP    DISCON        ;drops DTR to hang-up fast!    165H
  202. GOODBV:        JMP    GOODBYE        ;called before exit to CPM    168H
  203. INMODV:        JMP    INITMOD        ;go to user written routine    16BH
  204. NEWBDV:        JMP    PBAUD        ;changes baud with phone #    16EH
  205. NOPARV:        RET  !    NOP  !    NOP    ;set modem for no-parity     171H
  206. PARITV:        RET  !    NOP  !    NOP    ;set modem parity             174H
  207. SETUPV:        JMP    SETCMD        ;                177H
  208. SPMENV:        DS     3        ;not used by MEX        17AH
  209. VERSNV:        JMP    SYSVER        ;                17DH
  210. BREAKV:        JMP    SENDBRK        ;                180H
  211. ;
  212. ; The following jump vector provides the overlay with access to special
  213. ; routines in the main program (retained and supported in the main pro-
  214. ; gram for MDM overlay compatibility). These should not be modified by
  215. ; the overlay.
  216. ;
  217. ; Note that for MEX 2.0 compatibility, you should not try to use these
  218. ; routines, since this table will go away with MEX 2.0 (use the MEX
  219. ; service call processor instead).
  220. ;
  221. ILPRTV:        DS    3    ;replace with MEX function 9         183H
  222. INBUFV:        DS    3    ;replace with MEX functin 10        186H
  223. ILCMPV:        DS    3    ;replace with table lookup funct 247    189H
  224. INMDMV:        DS    3    ;replace with MEX function 255        18CH
  225. NXSCRV:        DS    3    ;not supported by MEX            18FH
  226. TIMERV:        DS    3    ;replace with MEX function 254        192H
  227. ;
  228. ; Clear/screen and clear/end-of-screen. Each routine must use the
  229. ; full 9 bytes alloted (may be padded with nulls).
  230. ;
  231. ;
  232. CLREOS:        LXI    D,EOSMSG    ;                195H
  233.         MVI    C,PRINT
  234.         CALL    MEX
  235.         RET            ;                19DH
  236. ;
  237. CLS:        LXI    D,CLSMSG    ;                19EH
  238.         MVI    C,PRINT
  239.         CALL    MEX
  240.         RET            ;                1A6H
  241. ;
  242. ;
  243. ;        *** END OF FIXED FORMAT AREA ***
  244. ;
  245. ;**********************************************************************
  246. ;
  247. ;        Overlay  Fixed  Messages  Area
  248. ;
  249. EOSMSG:    DB    ESC,0D9H,0,0,'$'    ;clear to end of screen message
  250.                     ;for Videx Videoterm / SOROC
  251. ;
  252. CLSMSG:    DB    ESC,0AAH,0,0,'$'    ;clear screen message
  253.                     ;for Videx Videoterm / SOROC
  254. ;
  255. VERMSG:    DB    CR,LF,TAB,TAB,'  Version for Apple ][ / Applicard'
  256.     DB    CR,LF
  257.     DB    TAB,TAB,'IIgs modem port  '
  258.     DB    'Overlay Version ',REV/10+'0','.'
  259.     DB    REV MOD 10+'0'
  260.     DB    CR,LF,LF,'$'
  261.     DB    0,'Overlay by Nick Sayer (N6QQQ)',0,'$'
  262. ;
  263. ;----------------------------------------------------------------------
  264. ;
  265. ; These routines are specific to the Apple ][+ with Applicard.  The
  266. ; routines read modem hardware (Apple Super Serial Card ACIA) directly
  267. ; from the Applicard.
  268. ;
  269.  
  270. ;====================== CUSTOMIZATION EQUATES ==========================
  271. ;
  272. SLOT    EQU    2        ; Slot of serial interface
  273. SLOTOFF    EQU    16*SLOT        ; Hardware offset for $C0(8+n)0
  274. SLOTOF2    EQU    256*SLOT    ; Firmware offset for $Cn00
  275. ;
  276. MDRCVR    EQU    1        ; Bit to test for char present
  277. MDRCVB    EQU    1        ; Compare mask to test for char present
  278. MDSNDR    EQU    4        ; Bit to test for send ready
  279. MDSNDB    EQU    4        ; Compare mask to test for send ready
  280. ;-----------------------------------------------------------------------
  281. ;
  282. ; This routine sends a break tone for 300 ms
  283. ;
  284. SENDBRK:
  285.     MVI    B,0        ; Param doesn't matter
  286.     MVI    C,'S'        ; Ctrl-A + S is send break
  287.     JMP    GSCMD        ; Send it out
  288. ;
  289. ;    CALL    CMDENA        ; Enable Ctrl-A commands
  290. ;    MVI    A,01H        ; Ctrl-A
  291. ;    CALL    GSSEND        ; Send it out
  292. ;    MVI    A,'S'        ; Ctrl-A + S is send-break command
  293. ;    CALL    GSSEND        ; Send it out
  294. ;    JMP    CMDDIS        ; Disable Ctrl-A commands and return
  295. ;
  296. ;
  297. ; This routine sets DTR low for 300 ms to disconnect the phone
  298. ;
  299. DISCON:
  300.     MVI    A,0FFH        ; Lower DTR
  301.     CALL    CMDDTR        ; Set DTR status
  302.     MVI    B,3
  303.     MVI    C,TIMER        ; Delay 300 ms
  304.     CALL    MEX
  305.     MVI    A,00H        ; Bring DTR back
  306.     CALL    CMDDTR        ; Set DTR status
  307.     RET
  308. ;
  309. ;.....
  310. ;
  311. GOODBYE:
  312.     RET            ; Nothing to do when exiting
  313. ;
  314. ;.....
  315. ;
  316. ;
  317. ;=========================== INITMOD ===================================
  318. ;
  319. ;
  320. INITMOD:
  321.     CALL    GSINIT        ; Init via 6502 routines
  322. ;
  323.     MVI    A,0
  324.     STA    PARSV
  325.     STA    WRDSV        ; 8N1
  326.     LDA    MSPEED        ; Get default speed
  327.     JMP    PBAUD        ; Let PBAUD do the work
  328. ;
  329. INITMOD1:
  330.     LDA    BAUDSV        ; Get baud chars
  331.     MOV    B,A
  332.     MVI    C,'B'        ; Baud setting char
  333.     CALL    GSCMD        ; Do it
  334.     LDA    PARSV        ; Get parity value
  335.     MOV    B,A
  336.     MVI    C,'P'        ; Parity command
  337.     CALL    GSCMD        ; Do it
  338.     LDA    WRDSV        ; Get word format char
  339.     MOV    B,A
  340.     MVI    C,'D'        ; Fall into GSCMD
  341. ;
  342. ; GSCMD takes a BCD number in B and an ascii character in C and sends
  343. ; them out with a ctrl-A and enabled commands.
  344. ;
  345. GSCMD:    PUSH    H
  346.     PUSH    D
  347.     PUSH    B
  348.     CALL    CMDENA        ; Enable Ctrl-A commands
  349.     MVI    A,81H        ; Send a Ctrl-A
  350.     CALL    GSSEND        ; Send it
  351.     POP    B        ; Get Char back
  352.     PUSH    B        ; And save it again
  353.     MOV    A,B
  354.     RAR
  355.     RAR
  356.     RAR
  357.     RAR
  358.     CALL    SENDHX
  359.     POP    B
  360.     PUSH    B
  361.     MOV    A,B
  362.     CALL    SENDHX
  363.     POP    B
  364.     PUSH    B
  365.     MOV    A,C
  366.     CALL    GSSEND
  367.     CALL    CMDDIS        ; Disable Ctrl-A cmds and return
  368.     POP    B
  369.     POP    D
  370.     POP    H
  371.     RET
  372. SENDHX:    ANI    0FH
  373.     ORI    0B0H        ; Make it a number
  374.     JMP    GSSEND        ; Send it and ret
  375. ;
  376. ;.....
  377. ;
  378. ;
  379. ;========================== APPLE I/O ==================================
  380. ;
  381. RDBYTE:    EQU    0FFE0H        ; Read 1 byte from Apple (A = byte)
  382. WRBYTE:    EQU    0FFE3H        ; Write 1 byte to Apple (C = byte)
  383. RDWORD:    EQU    0FFE6H        ; Read 2 bytes from Apple (DE = word)
  384. WRWORD:    EQU    0FFE9H        ; Write 2 bytes to Apple (DE = word)
  385. WRLOTS:    EQU    0FFEFH        ; FROM (HL), SEND NUM BYTES IN DE TO HOST
  386. POKLOT:    EQU    2
  387. CALL1:    EQU    3
  388. PEEK1:    EQU    6        ; Command
  389. POKE1:    EQU    7        ; Command
  390. ;
  391. POKE:    MOV    B,A
  392.     MVI    C,POKE1
  393.     CALL    WRBYTE
  394.     CALL    WRWORD
  395.     MOV    C,B
  396.     CALL    WRBYTE
  397.     RET
  398. ;
  399. PEEK:    MVI    C,PEEK1
  400.     CALL    WRBYTE
  401.     CALL    WRWORD
  402.     CALL    RDBYTE
  403.     RET
  404. ;
  405. CALL65:    MVI    C,CALL1
  406.     CALL    WRBYTE
  407.     CALL    WRWORD
  408.     RET
  409. ;
  410. GSINIT:                ; Initialize and move 6502 code in
  411. ;
  412.     LXI    D,0C00DH+SLOTOF2
  413.     CALL    PEEK
  414.     STA    INITPT
  415. ;
  416.     LXI    D,0C00FH+SLOTOF2
  417.     CALL    PEEK
  418.     STA    WRITPT
  419. ;
  420.     LXI    D,0C00EH+SLOTOF2
  421.     CALL    PEEK
  422.     STA    READPT
  423. ;
  424.     LXI    D,0C012H+SLOTOF2
  425.     CALL    PEEK
  426.     STA    EXTPT
  427. ;
  428.     MVI    C,POKLOT    ; Going to put the 6502 code in place
  429.     CALL    WRBYTE
  430.     LXI    D,0300H        ; Put it at 300H
  431.     CALL    WRWORD
  432.     LXI    D,END65-ST65+1    ; Length
  433.     CALL    WRWORD
  434.     LXI    H,ST65
  435.     LXI    D,END65-ST65+1
  436.     CALL    WRLOTS        ; Put it in place
  437. ;
  438.     LXI    D,INIT65
  439.     CALL    CALL65
  440.     RET
  441. ;
  442. ST65:
  443.     DB    04CH,013H,003H    ;     JMP    INIT
  444.     DB    04CH,01AH,003H    ;     JMP    READ
  445.     DB    04CH,024H,003H    ;     JMP    WRITE
  446.     DB    04CH,02FH,003H    ;     JMP    SETDTR
  447.     DB    04CH,03EH,003H    ;     JMP    SETCMD
  448.     DB    04CH,06AH,003H    ;     JMP    STATUS
  449.     DS    1        ; DATA    DFS    1
  450.     DB    0A2H,0C0H+SLOT    ; INIT    LDX    #Cn
  451.     DB    0A0H,SLOTOFF    ;    LDY    #n0
  452.     DB    04CH
  453. INITPT    DS    1        ;
  454.     DB    0C0H+SLOT    ;    JMP    CARD_INIT
  455.     DB    0ADH,012H,003H    ; WRITE    LDA    DATA
  456.     DB    0A2H,0C0H+SLOT    ;    LDX    #Cn
  457.     DB    0A0H,SLOTOFF    ;    LDY    #n0
  458.     DB    04CH
  459. WRITPT    DS    1
  460.     DB    0C0H+SLOT    ;    JMP    CARD_WRIT
  461.     DB    0A2H,0C0H+SLOT    ; READ    LDX    #Cn
  462.     DB    0A0H,SLOTOFF    ;    LDY    #n0
  463.     DB    020H
  464. READPT    DS    1
  465.     DB    0C0H+SLOT    ;    JSR    CARD_READ
  466.     DB    08DH,012H,003H    ;    STA    DATA
  467.     DB    060H        ;    RTS
  468.     DB    0ADH,012H,003H    ;SETDTR    LDA    DATA
  469.     DB    08DH,07EH,003H    ;    STA    DTRBYT
  470.     DB    0A9H,07AH    ;    LDA    #>DTRBUF
  471.     DB    0A2H,003H    ;    LDX    #<DTRBUF
  472.     DB    0A0H,000H    ;    LDY    #00
  473.     DB    04CH
  474. EXTPT    DS    1
  475.     DB    0C0H+SLOT    ;EXTJMP    JMP    CARD_EXT
  476.     DB    0A9H,000H    ;SETCMD    LDA    #00
  477.     DB    08DH,081H,003H    ;    STA    CMDSPOT
  478.     DB    0A9H,080H    ;    LDA    #>CMDBUF
  479.     DB    0A2H,003H    ;    LDX    #<CMDBUF
  480.     DB    0A0H,000H    ;    LDY    #00
  481.     DB    020H,03BH,003H    ;    JSR    EXTJMP
  482.     DB    0ADH,086H,003H    ;    LDA    CMDBYT
  483.     DB    02CH,012H,003H    ;    BIT    DATA
  484.     DB    010H,003H    ;    BPL    SKIP
  485.     DB    029H,07FH    ;    AND    #7F
  486.     DB    02CH        ;    DFB    $2CH    ;SKIP 2 BYTES
  487.     DB    009H,080H    ; SKIP    ORA    #80
  488.     DB    08DH,086H,003H    ;    STA    CMDBYT
  489.     DB    0A9H,001H    ;    LDA    #01
  490.     DB    08DH,081H,003H    ;    STA    CMDSPOT
  491.     DB    0A9H,080H    ;    LDA    #>CMDBUF
  492.     DB    0A2H,003H    ;    LDX    #<CMDBUF
  493.     DB    0A0H,000H    ;    LDY    #00
  494.     DB    04CH,03BH,003H    ;    JMP    EXTJMP
  495.     DB    0A9H,088H    ;STATUS    LDA    #>STATBUF
  496.     DB    0A2H,003H    ;    LDX    #<STATBUF
  497.     DB    0A0H,000H    ;    LDY    #0
  498.     DB    020H,03BH,003H    ;    JSR    EXTJMP
  499.     DB    0ADH,08CH,003H    ;    LDA    STATBYT
  500.     DB    08DH,012H,003H    ;    STA    DATA
  501.     DB    060H        ;    RTS
  502.     DB    003H,00BH    ;    DFB    03,0B
  503.     DS    4        ;    DFS    4
  504.     DB    003H,001H    ;    DFB    03,01
  505.     DS    6        ;    DFS    6
  506.     DB    003H,006H    ;    DFB    03,06
  507.     DS    4        ;    DFS    4
  508. END65:    DS    1
  509. ;
  510. INIT65:    EQU    0300H
  511. WRIT65:    EQU    0303H
  512. READ65:    EQU    0306H
  513. SDTR65:    EQU    0309H
  514. SCMD65:    EQU    030CH
  515. STAT65:    EQU    030FH
  516. DATA65:    EQU    0312H
  517. ;
  518. RD$MODDATP:            ; Read a character
  519.     PUSH    B
  520.     PUSH    D
  521.     PUSH    H
  522.     LXI    D,READ65
  523.     CALL    CALL65
  524.     LXI    D,DATA65
  525.     CALL    PEEK
  526.     POP    H
  527.     POP    D
  528.     POP    B
  529.     RET
  530. WR$MODDATP:            ; Write a character, or a command byte
  531. GSSEND: PUSH    B
  532.     PUSH    D
  533.     PUSH    H
  534.     LXI    D,DATA65
  535.     CALL    POKE
  536.     CALL    CALL65
  537.     POP    H
  538.     POP    D    
  539.     POP    B
  540.     RET
  541. RD$MODSTAP:            ; Get status byte
  542.     PUSH    B
  543.     PUSH    D
  544.     PUSH    H
  545.     LXI    D,STAT65
  546.     CALL    CALL65
  547.     LXI    D,DATA65
  548.     CALL    PEEK
  549.     POP    H
  550.     POP    D
  551.     POP    B
  552.     RET
  553. CMDENA:                ; Enable Ctrl-A cmds in out stream
  554.     MVI    A,0FFH
  555.     LXI    D,DATA65
  556.     CALL    POKE
  557.     LXI    D,SCMD65
  558.     JMP    CALL65
  559. CMDDIS:                ; Disable Ctrl-A cmds in out stream
  560.     MVI    A,000H
  561.     LXI    D,DATA65
  562.     CALL    POKE
  563.     LXI    D,SCMD65
  564.     JMP    CALL65
  565. CMDDTR:                ; Bit 7 of A is new DTR state
  566.     LXI    D,DATA65
  567.     CALL    POKE
  568.     LXI    D,SDTR65
  569.     JMP    CALL65
  570. ;
  571. ;-----------------------------------------------------------------------
  572. ;
  573. ;.....
  574. ;
  575. ;
  576. ; This routine changes the modem baud rate with phone list entry
  577. ;
  578. ; Set baud-rate code in A (if supported by your modem overlay).  PMMI
  579. ; supports only five rates, which are validated here. NOTE: this routine
  580. ; (ie, the one vectored through NEWBDV) should update MSPEED with the
  581. ; passed code, but ONLY if that rate is supported by the hardware.
  582. ;
  583. PBAUD:    PUSH    H        ;don't alter anybody
  584.     PUSH    D
  585.     PUSH    B
  586.     MOV    E,A        ;code to DE
  587.     MVI    D,0
  588.     LXI    H,BAUDTB    ;offset into table
  589.     DAD    D
  590.     MOV    A,M        ;fetch code
  591.     ORA    A        ;0 means unsupported code
  592.     JZ    PBEXIT        ;exit if so
  593.     STA    BAUDSV         ;good rate, save it for INITMOD1
  594.     CALL    INITMOD1    ;set baud (and PSW)
  595.     MOV    A,E        ;get speed code back
  596.     STA    MSPEED        ;make it current
  597.     JMP    PBEXIT + 1    ;jump error flag set
  598. PBEXIT:    STC            ;set return error for STBAUD caller
  599.     POP    B        ;all done
  600.     POP    D
  601.     POP    H
  602.     RET
  603. ;
  604. ; Table of baud rate parameters for supported rates
  605. ;
  606. BAUDTB:    DB    03H,06H,0,07H,0        ;110,300,450,610,710
  607.     DB    08H,10H,12H,14H,15H    ;1200,2400,4800,9600,19200
  608. BAUDSV: DB    10H            ;current baud byte
  609. ;
  610. ; Parity/wordlen table equates
  611. ;
  612. P8N1        EQU    000H    ;8 NONE 1
  613. P7E1        EQU    013H    ;7 EVEN 1
  614. P7O1        EQU    011H    ;7 ODD 1
  615. P7N1        EQU    010H    ;7 NONE 1
  616. ;
  617. ;----------------------------------------------------------------------
  618. ;
  619. ; Sign-on message
  620. ;
  621. SYSVER:    LXI    D,VERMSG
  622.     MVI    C,PRINT
  623.     CALL    MEX
  624.     RET
  625. ;
  626. ;.....
  627. ;
  628. ; Newline on console
  629. ;
  630. CRLF:    MVI    A,CR
  631.     CALL    TYPE
  632.     MVI    A,LF        ;fall into TYPE
  633. ;
  634. ; type char in A on console
  635. ;
  636. TYPE:    PUSH    H        ;save 'em
  637.     PUSH    D
  638.     PUSH    B
  639.     MOV    E,A        ;align output character
  640.     MVI    C,CONOUT    ;print via MEX
  641.     CALL    MEX
  642.     POP    B
  643.     POP    D
  644.     POP    H
  645.     RET
  646. ;
  647. ;----------------------------------------------------------------------
  648. ;
  649. ; The remainder of this overlay implements a very versatile SET command
  650. ; -- if you prefer not to write a SET for your modem, you may delete the
  651. ; code from here to the END statement. Control is passed here after
  652. ; MEX parses a SET command.
  653. ;
  654. ;
  655. SETCMD:    MVI    C,SBLANK    ;any arguments?
  656.     CALL    MEX
  657.     JC    SETSHO        ;if not, go print out values
  658.     LXI    D,CMDTBL    ;parse command
  659.     CALL    TSRCH        ;from table
  660.     PUSH    H        ;any address on stack
  661.     RNC            ;if we have one, execute it
  662.     POP    H        ;nope, fix stack
  663. SETERR:    LXI    D,SETEMS    ;print error
  664.     MVI    C,PRINT
  665.     CALL    MEX
  666.     RET
  667. ;
  668. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  669. ;
  670. ; SET command table ... note that tables are constructed of command-
  671. ; name (terminated by high bit=1) followed by word-data-value returned
  672. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  673. ; a binary zero.
  674. ;
  675. ; Note that LOOKUP attempts to find the next item in the input stream
  676. ; in the table passed to it in HL ... if found, the table data item is
  677. ; returned in HL; if not found, LOOKUP returns carry set.
  678. ;
  679. CMDTBL:    DB    '?'+80H            ;"set ?"
  680.     DW    STHELP
  681.     DB    'BAU','D'+80H        ;"set baud"
  682.     DW    STBAUD
  683.     DB    'PS','W'+80H        ;"set PSW"
  684.     DW    STPSW
  685.     DB    'TON','E'+80H        ;'set TONE/PULSE byte to 'T'
  686.     DW    STTONE
  687.     DB    'PULS','E'+80H        ;'set TONE/PULSE byte to 'P'
  688.     DW    STPULSE
  689.     DB    0            ;<<=== table terminator
  690. ;
  691. ; SET <no-args>: print current statistics
  692. ;
  693. SETSHO:    LXI    H,SHOTBL    ;get table of SHOW subroutines
  694. SETSLP:    MOV    E,M        ;get table address
  695.     INX    H
  696.     MOV    D,M
  697.     INX    H
  698.     MOV    A,D        ;end of table?
  699.     ORA    E
  700.     RZ            ;exit if so
  701.     PUSH    H        ;save table pointer
  702.     XCHG            ;adrs to HL
  703.     CALL    GOHL        ;do it
  704.     CALL    CRLF        ;print newline
  705.     MVI    C,CHEKCC    ;check for console abort
  706.     CALL    MEX
  707.     POP    H        ;it's done
  708.     JNZ    SETSLP        ;continue if no abort
  709.     RET
  710. ;
  711. GOHL:    PCHL
  712. ;
  713. ; Table of SHOW subroutines
  714. ;
  715. SHOTBL:    
  716.     DW    BDSHOW        ;displays current baud
  717.     DW    PSWSHOW        ;displays current PSW
  718.     DW    TPSHOW        ;displays current TPULSE byte (0105H)
  719.     DW    CRLF
  720.     DW    0        ;<<== table terminator
  721. ;
  722. ; SET ?  processor
  723. ;
  724. STHELP:    CALL     CLS            ;clear screen
  725.     LXI    D,HLPMSG
  726.     MVI    C,PRINT
  727.     CALL    MEX
  728.     RET
  729. ;
  730. ; The help message
  731. ;
  732. HLPMSG:    DB    CR,LF,'SET Commands available are:',CR,LF,LF
  733.     DB    'SET BAUD  <110, 300, 600, 1200, 2400, 4800,'
  734.     DB    ' 9600, or 19200>',CR,LF
  735.     DB    'SET PSW   <8N1, 7E1, 7O1, or 7N1> -- Word Length,'
  736.     DB    ' Parity, Stop Bits',CR,LF
  737.     DB    'SET TONE  (Sets flag for TONE  dialing)',CR,LF
  738.     DB    'SET PULSE (Sets flag for PULSE dialing)'
  739.     DB    CR,LF,LF,'$'
  740. ;
  741. ; SET BAUD processor
  742. ;
  743. STBAUD:    MVI    C,BDPARS    ;function code
  744.     CALL    MEX    
  745.     JC    SETERR        ;invalid code
  746.     CALL    PBAUD        ;try to set it
  747.     JC    SETERR        ;unsupported code
  748. BDSHOW:    CALL    ILPRT        ;display baud
  749.     DB    'Baud rate:',TAB,' ',0
  750.     LDA    MSPEED
  751.     MVI    C,PRBAUD    ;use MEX routine
  752.     CALL    MEX
  753.     RET
  754. ;
  755. ; SET PSW processor
  756. ;
  757. STPSW:    MVI    C,SBLANK
  758.     CALL    MEX
  759.     JC    SETERR        ;SET PSW should have had argument
  760.     LXI    D,PSWTBL    ;look for PSW match in table
  761.     CALL    TSRCH
  762.     JC    SETERR        ;not there, so report error
  763.     CALL    FIXPSW        ;routine to set PARSV and WRDSV
  764.     CALL    INITMOD1    ;now fix ACIA registers
  765. ;
  766. PSWSHOW:
  767.     CALL    ILPRT
  768.     DB    'PSW setting:',TAB,' ',0
  769.     LDA    PSWSET
  770.     CPI    P8N1
  771.     JNZ    PSW1
  772.     CALL    ILPRT
  773.     DB    '8N1',0
  774.     RET
  775. PSW1:    CPI    P7E1
  776.     JNZ    PSW2
  777.     CALL    ILPRT
  778.     DB    '7E1',0
  779.     RET
  780. PSW2:    CPI    P7O1
  781.     JNZ    PSW3
  782.     CALL    ILPRT
  783.     DB    '7O1',0
  784.     RET
  785. PSW3:    CPI    P7N1
  786.     JNZ    PSW4
  787.     CALL    ILPRT
  788.     DB    '7N1',0
  789.     RET
  790. PSW4:    CALL    ILPRT
  791.     DB    '<< ERROR >>',0
  792.     RET
  793. ;
  794. ;
  795. PSWSET:    DB    00H        ;storage and default (8N1)
  796. PARSV:    DB    00H        ;storage and default (no parity)
  797. WRDSV:    DB    00H        ;storage and default (8 data, 1 stop bits)
  798. ;
  799. FIXPSW:    MOV    A,L        ;PSW byte from table
  800.     STA    PSWSET        ;save it
  801.     ANI    0FH        ;mask low for parity bits
  802.     STA    PARSV        ;put in storage
  803.     LDA    PSWSET        ;get back PSW byte
  804.     RAR            ;first shift into lower nibble..
  805.     RAR            ;...away we go...
  806.     RAR            ;.....and go...
  807.     RAR            ;......and done
  808.     ANI    0FH        ;mask for word bits
  809.     STA    WRDSV        ;put in storage
  810.     RET
  811. ;
  812. PSWTBL:    DB    '8N','1'+80H
  813.     DW    P8N1        ;filled in with equ's
  814.     DB    '7E','1'+80H
  815.     DW    P7E1        ; - ditto -
  816.     DB    '7O','1'+80H
  817.     DW    P7O1        ; - ditto -
  818.     DB    '7N','1'+80H
  819.     DW    P7N1        ; - ditto -
  820.     DB    0        ;<<==== table terminator
  821. ;
  822. ;.....
  823. ;
  824. ; These routines set TPULSE flag at 0105H to either 'T' or 'P' so that
  825. ; MODEM (specifically MXO-SM13.ASM) overlay will dial in TONE or PULSE
  826. ; mode.  The settings are mutually exclusive.
  827. ;
  828. STTONE:    MVI    A,'T'        ;get T flag
  829.     STA    TPULSE        ;put into proper place
  830.     JMP    TPSHOW        ;display dial mode
  831. ;
  832. STPULSE:
  833.     MVI    A,'P'        ;get P flag
  834.     STA    TPULSE
  835. ;
  836. TPSHOW:    CALL    ILPRT
  837.     DB    'Dial Mode:',TAB,' ',0
  838.     LDA    TPULSE
  839.     CPI    'T'
  840.     JNZ    TP1
  841.     CALL    ILPRT
  842.     DB    'TONE',0
  843.     RET
  844. TP1:    CPI    'P'
  845.     JNZ    TP2
  846.     CALL    ILPRT
  847.     DB    'PULSE',0
  848.     RET
  849. TP2:    CALL    ILPRT
  850.     DB    '<< ERROR >>',0
  851.     RET
  852. ;
  853. ;......
  854. ;
  855. ; Compare next input-stream item in table @DE; CY=1 if not found,
  856. ; else HL = matched data item
  857. ;
  858. TSRCH:    MVI    C,LOOKUP    ;get function code
  859.     JMP    MEX        ;pass to MEX processor
  860. ;
  861. ; Print in-line message ... blows away C register
  862. ;
  863. ILPRT:    MVI    C,ILP        ;get function code
  864.     JMP    MEX        ;go do it
  865. ;
  866. ;
  867. ;    >>>>   End of PORT specific overlay section   <<<<
  868.  
  869. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  870. ;
  871. ;        MODEM SPECIFIC OVERLAY SECTION
  872. ;
  873. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  874. ;
  875. ;        MEX SMARTMODEM OVERLAY V1.3
  876. ;
  877. ; Smartmodem overlay for MEX: revision 1.3
  878. ;
  879. ; Adapted by Henry Middlebrook (1/85)
  880. ;
  881. ; NOTE: Some redundant parts of the V1.3 overlay were removed when this
  882. ;    section was pulled into MXO-SS30.  See the original overlay for
  883. ;    additional information on the history and use of this MODEM
  884. ;    specific overlay.        -HM-    2/4/85
  885. ;
  886. ; Written 04/16/84 by Ronald G. Fowler (V1.0)
  887. ;
  888. ;
  889.     ORG    0B00H        ;maintain official MEX origin
  890. ;
  891. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  892.     CPI    254        ;START DIAL?
  893.     JZ    STDIAL        ;JUMP IF SO
  894.     CPI    255        ;END DIAL?
  895.     JZ    ENDIAL        ;JUMP IF SO
  896. ;
  897. ; Not start or end sequence, must be a digit to be sent to the modem
  898. ;
  899.     MOV    M,A        ;PUT CHAR IN BUFFER
  900.     INX    H        ;ADVANCE POINTER
  901.     SHLD    DIALPT        ;STUFF PNTR
  902.     RET            ;ALL DONE
  903. ;
  904. ; Here on a start-dial sequence
  905. ;
  906. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  907.     SHLD    DIALPT
  908.     RET
  909. ;
  910. ; Here on an end-dial sequence
  911. ;
  912. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  913.     INX    H        ;FOLLOWED BY TERMINATOR
  914.     MVI    M,0
  915.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  916.     STA    SMDIAL+3    ;PUT INTO STRING
  917.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  918.     CALL    SMSEND        ;SEND IT
  919. WAITSM:    MVI    C,INMDM
  920.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  921.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  922. ;
  923. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  924. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  925. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  926. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  927. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  928. ; WAIT TO 20 SECONDS).
  929. ;
  930. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  931. SMWLP:    PUSH    B
  932.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  933.     MVI    C,TMDINP    ;DO TIMED INPUT
  934.     CALL    MEX
  935.     POP    B
  936.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  937.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  938.     MVI    C,CHEKCC
  939.     CALL    MEX
  940.     POP    B
  941.     JNZ    SMNEXT        ;IF NOT, JUMP
  942.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  943.     MVI    C,SNDCHR
  944.     CALL    MEX
  945.     MVI    A,3        ;RETURN ABORT CODE
  946.     RET
  947. SMNEXT:    DCR    C        ;NO
  948.     JNZ    SMWLP        ;CONTINUE
  949. ;
  950. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  951. ;
  952. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  953.     RET
  954. ;
  955. ; MODEM GAVE US A RESULT, CHECK IT
  956. ;
  957. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  958.     CALL    SMANAL        ;TEST THE RESULT
  959.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  960.     PUSH    PSW        ;SAVE IT
  961. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  962.     CALL    MEX
  963.     JC    SMCHEK        ;JUMP IF NO INPUT
  964.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  965.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  966. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  967.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  968.     RET
  969. ;
  970. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  971.     CPI    'C'        ;"CONNECT"?
  972.     RZ
  973.     CPI    '1'        ;NUMERIC VERSION OF "CONNECT"
  974.     RZ
  975.     CPI    '5'        ;NUMERIC VERSION OF "CONNECT 1200"
  976.     RZ
  977.     INR    B        ;PREP BUSY CODE B=1
  978.     CPI    'B'
  979.     RZ
  980.     INR    B        ;PREP NO CONNECT MSG B=2
  981.     CPI    'N'        ;N=NO CONNECT
  982.     RZ
  983.     CPI    '3'        ;NUMERIC VERSION OF "NO CONNECT"
  984.     RZ
  985.     MVI    B,4        ;PREP MODEM ERROR
  986.     CPI    'E'        ;E=ERROR
  987.     RZ
  988.     CPI    '4'        ;NUMERIC VERSION OF "ERROR"
  989.     RZ
  990.     STC            ;UNKNOWN...
  991.     RET
  992. ;
  993. ;.....
  994. ;
  995. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  996. ;
  997. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  998.     CALL    MEX
  999.     JNZ    SMSEND
  1000.     MOV    A,M        ;FETCH NEXT CHARACTER
  1001.     INX    H
  1002.     ORA    A        ;END?
  1003.     RZ            ;DONE IF SO
  1004.     MOV    B,A        ;NO, POSITION FOR SENDING
  1005.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  1006.     CALL    MEX
  1007.     JMP    SMSEND
  1008. ;
  1009. ; DATA AREA
  1010. ;
  1011. SMDIAL:    DB    'ATDT '
  1012. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  1013. DIALPT:    DS    2        ;DIAL POSITION POINTER
  1014. ;
  1015. ;
  1016. ;    >>>>    End of MODEM Specific Overlay
  1017.