home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / mex / mxo-lb22.aqm / MXO-LB22.ASM
Assembly Source File  |  1986-10-06  |  22KB  |  789 lines
  1. ;MX0-LB22.ASM -- AMPRO 'LITTLE BOARD' OVERLAY FILE FOR MEX
  2. ;
  3. ;
  4.  
  5. VER    EQU    2    ; Version 
  6. REV    EQU    2    ; Revision Level
  7. ;
  8. ;
  9. ; Modified from Jerry Haigwood's M7LB-2.ASM with inserts from
  10. ;    MXO-KP41.ASM John Smith, et al.. 
  11. ;
  12. ; Modified from the general purpose overlay by Jerry Haigwood, KY4Z
  13. ;
  14. ; This overlay adapts the MEX program by Ronald Fowler to the 
  15. ;   AMPRO Series 100 computer, using the Z80 DART and the 
  16. ;   Z80 CTC.
  17. ;
  18. ; You will want to look this file over carefully. There are a number of
  19. ; options that you can use to configure the program to suit your taste.
  20. ; This file places particular emphasis on using the AMPRO Series 100 
  21. ; computer with the Z80 DART serial port "B" and the Z80 CTC baud rate
  22. ; generator.  If you are not using this equipment then you might still
  23. ; want to look over this file to gain knowledge on how to write your
  24. ; own version of this overlay.  Some other overlays which might help
  25. ; are:
  26. ;
  27. ;     "H8"  Heath H89 overlay for 8250 I/O and programmable baud rates
  28. ;     "HZ"  Zenith 120 overlay for 2661B initialization and baud rates
  29. ;     "XE"  Xerox 820II overlay for Z80-SIO intialization, etc.
  30. ;
  31. ; Edit this file for your preferences then follow the "TO USE:" example
  32. ; shown below.
  33. ;
  34. ;    TO USE: First edit this file filling in answers for your own
  35. ;        equipment.  Then assemble with ASM.COM or equivalent
  36. ;               assembler. Then use MLOADxx to overlay the relulting
  37. ;               .HEX file over the MEXxx.COM.
  38. ;
  39. ;    A>REN MEXxxx.OBJ=MEXxxx.COM <-- THIS PRESERVES THE UNINSTALLED
  40. ;                                       VERSION IN AN UNRUNABLE FORM.
  41. ;       A>ASM MXO-LB01
  42. ;       A>MLOADxx MEXXxx.COM=MEXXxx.OBJ,MXO-LB01.HEX
  43. ;
  44. ;
  45. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  46. ;
  47. ; 12/18/85 - Corrected 2400 Baud problem, 
  48. ;            Neatened up printing routines
  49. ;            Added jump so that SM overlays can set baud rate
  50. ;                                           - Mike Vore
  51. ;
  52. ; 10/02/85 - Cleaned up misc. trash
  53. ;            Added Version and Rev     - Mike Vore
  54. ;
  55. ;
  56. ;
  57. ; 09/30/85 - Added "FULL SETUP"  routines (5-6-7-8 bits
  58. ;                                          No, Even, Odd parity
  59. ;                                          1- 1.5- 2 stopbits)
  60. ;            "BREAK" sent with 'esc' @ in terminal mode.
  61. ;            Disconnects modem with 'esc' N in terminal mode 
  62. ;                 by lowering HSO (Hand Shake Out), J4-P4  (for DTR)
  63. ;                 
  64. ;                                           - Mike Vore, W3CCV
  65. ;
  66. ;
  67. ; 12/23/83 - First version of this file        - Jerry Haigwood
  68. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  69. ;
  70. BELL:        EQU    07H        ;bell
  71. CR:        EQU    0DH        ;carriage return
  72. ESC:        EQU    1BH        ;escape
  73. LF:        EQU    0AH        ;linefeed
  74. TAB:        EQU    09H        ;tab character
  75. ;
  76. YES:        EQU    0FFH
  77. NO:        EQU    0
  78. ;
  79. BRKWT        EQU    3        ;Break Wait Time Hundreds Of mSec
  80. GBYTME        EQU    3        ;Goodbye pause Hundreds of mSec
  81. HNGUPT        EQU    2        ;Hangup  pause Seconds
  82. ;
  83. ; Change the following information to match your equipment
  84. ; This is for the Little Board Serial Port B
  85. ;
  86. PORT:        EQU    8CH
  87. MODCTL1        EQU    PORT        ;MODEM CONTROL PORT
  88. MODDATP:    EQU    PORT-4        ;MODEM DATA IN PORT
  89. MODRCVB:    EQU    1        ;BIT TO TEST FOR RECEIVE
  90. MODRCVR:    EQU    1        ;VALUE WHEN READY
  91. MODSNDB:    EQU    4        ;BIT TO TEST FOR SEND
  92. MODSNDR:    EQU    4        ;VALUE WHEN READY
  93. CTC:        EQU    50H        ;CTC addr
  94. ;
  95. ;
  96. ;
  97. ; MEX SERVICE PROCESSOR
  98. ;
  99. MEX    EQU    0D00H        ;ADDRESS OF THE SERVICE PROCESSOR
  100. INMDM    EQU    255        ;GET CHAR FROM PORT TO A, CY=NO MORE IN 100 MS
  101. TIMER    EQU    254        ;DELAY 100MS * REG B
  102. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  103. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  104. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  105. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  106. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  107. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  108. LOOKUP    EQU    247        ;TABLE SEARCH: SEE CMDTBL COMMENTS FOR INFO
  109. PARSFN    EQU    246        ;PARSE FILENAME FROM INPUT STREAM
  110. BDPARS    EQU    245        ;PARSE BAUD-RATE FROM INPUT STREAM
  111. SBLANK    EQU    244        ;SCAN INPUT STREAM TO NEXT NON-BLANK
  112. EVALA    EQU    243        ;EVALUATE NUMERIC FROM INPUT STREAM
  113. LKAHED    EQU    242        ;GET NXT CHAR W/O REMOVING FROM INPUT
  114. GNC    EQU    241        ;GET CHAR FROM INPUT, CY=1 IF NONE
  115. ILP    EQU    240        ;INLINE PRINT
  116. DECOUT    EQU    239        ;DECIMAL OUTPUT
  117. PRBAUD    EQU    238        ;PRINT BAUD RATE
  118. ;
  119. CONOUT    EQU    2        ;SIMULATED BDOS FUNCTION 2: CONSOLE CHAR OUt
  120. PRINT    EQU    9        ;simulated BDOS function 9: print string
  121. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  122. ;
  123.         ORG    100H
  124. ;
  125. ;
  126. ; Change the clock speed if needed, to match your system
  127. ;
  128.         DS    3    ;(for  "JMP   START" instruction)
  129. ;
  130. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  131. SMARTMODEM:    DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  132. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  133. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  134.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  135. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  136.                 ;6=2400 7=4800 8=9600 9=19200 default
  137.                 ;This defines the DEFAULT SPEED when
  138.                 ;loading the program, REG4 and CTC1
  139.                 ;will be set at load time.
  140.                 ;
  141. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  142.                 ;default time to send character in ter-
  143.                 ;minal mode file transfer for slow BBS.
  144. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  145.                 ;default time for extra wait after CRLF
  146.                 ;in terminal mode file transfer
  147. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  148. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  149. SCRNTEST:    DB    NO    ;Cursor control routine         10CH
  150. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  151.                 ;no=resend a record after a valid-NAK
  152. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  153. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  154. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  155. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  156. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  157. ADDLF:        DB    YES    ;no=no LF after CR to send file in    113H
  158.                 ;terminal mode (added by remote echo)
  159. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  160. TRANLOGON:    DB    NO    ;yes=allow transmission of logon    115H
  161.                 ;write logon sequence at location LOGON
  162. SAVCCP:        DB    NO    ;yes=do not overwrite CCP        116H
  163.                                 ;no=overwrite CCP, Large ASCII captures
  164.                                 ; might need this set to NO
  165. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  166.                 ;no=external command if EXTCHR precedes
  167. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  168. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  169. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  170.                 ;sending a file in terminal mode
  171. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  172.                 ;sending a file in terminal mode
  173. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  174. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  175. EXTRA1:        DB    0    ;for future expansion            11EH
  176. EXTRA2:        DB    0    ;for future expansion            11FH
  177. ;
  178. ;
  179. ;    Next 8 DBs used in MDM7xx not by MEXxxx, kept here for 
  180. ;       reference only.
  181. ;         'esc'=Escape character defined with STAT ESC command.
  182. ;
  183. BRKCHR:        DB    '@' ;'esc'-@ = Send 300 ms. break tone        120H
  184. NOCONNCT:    DB    'N' ;'esc'-N = Disconnect from the phone line    121H
  185. LOGCHR:        DB    'x' ;'esc'-x = Send Key 'x' (defined by KEY)     122H
  186. LSTCHR:        DB    'P' ;'esc'-P = Toggle printer            123H
  187. UNSAVE:        DB    'U' ;'esc'-U = Unstart input text capture    124H
  188. TRANCHR:    DB    'T' ;'esc'-T = Transmit file to remote        125H
  189. SAVECHR:    DB    'S' ;'esc'-S = Start input text capture        126H
  190. EXTCHR:        DB    ' ' ;'esc' - 'esc'  = Send escape character    127H
  191. ;
  192. ;
  193.         DS    2        ;                128H
  194. ;
  195. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port             12AH
  196.         DS    7
  197. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  198.         DS    7
  199. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  200.         DS    7
  201. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  202. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rcv. bit when ready    14BH
  203. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH
  204. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  205.         DS    12        ;                156H
  206. ;
  207. ;
  208. LOGONPTR    DS    2        ;FOR USER MESSAGE, NOT USED
  209. ;
  210. ;  DIALV will be overwritten by SM overlays
  211. ;
  212. DIALV        DS    3        ;reserved for dial routine jump
  213. ;  DISCV May be modified by SM overlays, depending on method of disconnect.
  214. DISCV        JMP    DISCON        ;disconnect modem
  215. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  216. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  217. JMP$SETBAUD     JMP     STBAUD2        ;set baud from dial overlay
  218.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  219.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  220. JMP$SETUPR:    JMP    SETCMD        ;                177H
  221. JMP$SPCLMENU    RET ! NOP ! NOP        ;
  222. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  223. JMP$BREAK:    JMP    SENDBRK        ;                180H
  224. ;
  225. ;
  226. ; Do not change the following six lines.
  227. ;
  228. JMP$ILPRT:    DS    3        ;                183H
  229. JMP$INBUF    DS    3        ;                186H
  230. JMP$INLNCOMP:    DS    3        ;                189H
  231. JMP$INMODEM    DS    3        ;                18CH
  232. JMP$NXTSCRN:    DS    3        ;                18FH
  233. JMP$TIMER    DS    3        ;                192H
  234. ;
  235. ; 
  236. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  237. ; SCRNTEST to YES at 010AH (above).
  238. ;
  239. CLREOS:        LXI     D,CLRLIN     ; To clear to End Of Screen
  240.         MVI    C,PRINT            ; Put Terminal Data at CLRLIN
  241.         CALL    MEX
  242.         RET
  243. ;
  244. ;
  245. CLRSCN:        LXI    D,CLS        ; Put Terminal Sequence for
  246.         MVI    C,PRINT        ; Screen Clear at CLS
  247.         CALL    MEX
  248.         RET
  249. ;
  250. ; END OF FIXED ADDRESS ----------------------------------
  251. ;
  252.  
  253. SYSVER:        LXI    D,VERSMSG
  254.         MVI    C,PRINT
  255.         CALL    MEX
  256.         RET
  257. ;
  258. VERSMSG:
  259.         DB    'AMPRO LITTLE BOARD AND SERIES 100 COMPUTER'
  260.         DB    ' VERSION ',VER+'0','.', REV+'0',CR, LF,LF
  261.         DB    'FULL SET COMMANDS !',CR,LF,LF,'$'
  262. ;
  263. CLS          DB    0,0,0,0,0,'$'   ; <<- set this and the next for
  264.                     ;     your screen clear and line
  265.                     ;     clear sequences.
  266. CLRLIN        DB    0,0,0,0,0,'$'
  267. ;.....
  268. ;
  269. ;
  270. ;-----------------------------------------------------------------------
  271. ;.....
  272. ;
  273. ;
  274. ;
  275. SENDBRK:    MVI    A,5
  276.         OUT    PORT
  277.         MVI    A,0FAh    ; Send 'BREAK' command to DART
  278.         OUT    PORT
  279.         MVI    B,BRKWT    ; Wait 
  280.         CALL    MTIME
  281.         MVI    A,5
  282.         OUT    PORT
  283.         LDA    REG5    ; Send setup back to DART
  284.         OUT    PORT
  285.         RET
  286. ;.....
  287. ;
  288. ;
  289. ;
  290. ;.....
  291. ;
  292. ;
  293. ; The following is used to initialize the AMPRO Z80 DART port "B".
  294. ; Baud rate is initially set from MSPEED value
  295. ;
  296. INITMOD:  DI        ;no interupts during setup
  297.       LDA     MSPEED    ; get the initial MSPEED value and go
  298.             ; set the baud rate with it
  299.       CALL    PBAUD
  300. ;
  301. NITSIO:      DI        ; All DART sets go here
  302. ;
  303.       MVI    A,04H    ;write register 4 of DART 
  304.       OUT    PORT    ;contol port
  305.       LDA    REG4    ; mult, stop bits, parity bits
  306.       OUT    PORT    ;    
  307. ;
  308.       MVI    A,03H    ;write register 3 of DART
  309.       OUT     PORT    ;
  310.       LDA    REG3    ; rcv n bits/char, rcv enable
  311.       OUT    PORT    ;
  312. ;
  313.       MVI    A,05H    ;write register 5 of DART
  314.       OUT    PORT    ;
  315.       LDA    REG5    ; BITS/CHAR, TX ENABLE, RTS ENABLE
  316.       OUT    PORT    ;
  317. ;
  318.       MVI    A,45H    ;counter mode,contol word time constant follows
  319.       OUT    CTC    ;CTC channel 1
  320. ;
  321.       LDA    CTC1    ; MULTIPLIER
  322.       OUT    CTC    ;CTC channel 1
  323.       EI        ;
  324.       RET
  325. ;
  326. ;------------------------------------------------------------
  327. ;
  328. ;;
  329. ;
  330. ; Disconnect Routine
  331. ;
  332. ; Disconnects by lowering J4-P4 (Hand Shake Out) -connect
  333. ;  to DTR on semi-smart modems like Novation J-Cat
  334. ;
  335. ;  Hangs up modem for 2 seconds
  336. ;
  337. ;
  338. DISCON:      MVI    A,5        ;OUTPUT TXOFF,RXOFF,DTROFF TO 
  339.       OUT    PORT        ;TO DART PORT 5
  340.       MVI    A,0
  341.       OUT   PORT
  342.        MVI    B,HNGUPT*10        ; WAIT 2 SEC
  343.       CALL  MTIME
  344.       MVI    A,5        ; THEN RESET DART TO ORIGINAL STATUS
  345.       OUT    PORT
  346.       LDA    REG5
  347.       OUT    PORT
  348.       RET
  349. ;
  350. ;
  351. ;
  352. ; GOODBYE routines are called by MEX prior to exit to CP/M
  353. ;
  354. GOODBYE:  MVI    B,GBYTME        ;DELAY 300 MS.
  355.       CALL  MTIME
  356.       RET
  357. ;
  358. ;  SET COMMAND PROCESSOR
  359. ;
  360. SETCMD:      MVI    C,SBLANK    ;ANY ARGUMENTS?
  361.       CALL    MEX
  362.       JC    SETSHO        ;IF NOT, DISPLAY DEFAULTS
  363.       LXI    D,CMDTBL    
  364.       MVI    C,LOOKUP    
  365.       CALL  MEX        ;PARSE THE ARGUMENT
  366.       PUSH    H        ;SAVE ANY PARSED ARGUMENTS ON STACK
  367.       RNC            ;IF WE HAVE ONE, RETURN TO IT
  368.       POP    H        ;OOPS, INPUT NOT FOUND IN TABLE
  369. SETERR:      LXI    D,SETEMS
  370.       MVI    C,PRINT
  371.       CALL    MEX
  372.       CALL  CRLF
  373.       RET
  374. SETEMS:      DB    CR,LF,'SET command error',CR,LF,'$'
  375. ;
  376. SETBAD:      LXI    D,SETEMS
  377.       MVI    C,PRINT
  378.       CALL    MEX
  379. ;
  380. CMDTBL:   DB    '?'+80H            ; HELP
  381.       DW    SETHELP
  382.       DB    'BAU','D'+80H        ; SET BAUD
  383.       DW    STBAUD
  384.       DB    'PARIT','Y'+80H        ; SET PARITY
  385.       DW    STPRTY
  386.       DB    'STOPBIT','S'+80H    ; SET STOPBITS
  387.       DW    STSTOP
  388.       DB    'LENGT','H'+80H        ; SET LENGTH
  389.       DW    STBITS
  390.       DB     'PULS','E'+80H        ;SET PULSE FOR SM OVERLAY
  391.       DW    SWPULSE
  392.       DB    'TON','E'+80H        ;SET TONE FOR SM OVERLAY
  393.       DW    SWTONE
  394.       DB    '$'            ;TABLE TERMINATOR
  395. ;
  396. ;
  397. ;  "SET (no args): PRINT CURRENT STATISTICS
  398. ;
  399. SETSHO:      CALL  MILP
  400.       DB    CR,LF
  401.       DB    'SET values:',CR,LF,0
  402.           CALL    CRLF
  403.       CALL    MILP
  404.       DB    'Baud Rate: ',TAB,0
  405.       CALL    BDSHOW
  406.       CALL    CRLF
  407.       CALL  SHPRTY
  408.       CALL    CRLF
  409.       CALL    SHSTOP
  410.       CALL    CRLF
  411.       CALL  SHBITS
  412.       CALL    CRLF
  413.       CALL    SHDIAL
  414.       CALL  CRLF
  415.       CALL  CRLF
  416.       RET
  417. ;
  418. ; "SET ?" processor
  419. ;
  420. SETHELP:  CALL    MILP
  421.       DB    CR,LF,'SET PARITY    - OFF, EVEN or ODD'
  422.       DB    CR,LF,'SET STOPBITS  - 1, 1.5 or 2'
  423.       DB    CR,LF,'SET LENGTH    - 5, 6, 7 or 8'
  424.       DB    CR,LF,'SET BAUD      - 300, 450, 600, 1200, 2400, '
  425.       DB    '4800, 9600'
  426.       DB    CR,LF,'SET PULSE     - For Pulse Dialing'
  427.           DB    CR,LF,'SET TONE      - For Tone Dialing'
  428.       DB    CR,LF,CR,LF,0
  429.       RET
  430. ;
  431. ;
  432. ; "SET BAUD" processor
  433. ;
  434. STBAUD:    MVI    C,BDPARS    ;FUNCTION CODE: PARSE A BAUDRATE
  435.       CALL    MEX        ;LET MEX LOOK UP CODE
  436.       JC    SETERR        ;JUMP IF INVALID CODE
  437. STBAUD2      CALL    PBAUD        ;NO, TRY TO SET IT
  438.       JC    SETERR        ;IF NOT ONE OF OURS, BOMB OUT
  439.       CALL    NITSIO
  440. BDSHOW:      LDA    MSPEED        ;GET CURRENT BAUD RATE
  441.       MVI    C,PRBAUD    ;LET MEX PRINT IT
  442.       CALL    MEX
  443.       RET 
  444. ;
  445. ; This routine sets baud rate passed as MSPEED code in A.
  446. ; Returns CY=1 if baud rate not supported.
  447. ;
  448. PBAUD:      PUSH    H        ;DON'T ALTER ANYBODY
  449.       PUSH    D
  450.       PUSH     B
  451.       STA    TSPEED        ;put it in a safe spot
  452.       ADD    A        ;double it for offset into table
  453.       MOV    E,A        ;MSPEED CODE TO DE
  454.       MVI    D,0
  455.       LXI    H,BAUDTB    ;OFFSET INTO TABLE
  456.       DAD    D
  457.       MOV    A,M        ;FETCH CODE
  458.       ORA    A        ;0 MEANS UNSUPPORTED CODE
  459.       STC            ;PREP CARRY IN CASE UNSUPPORTED
  460.       JZ    PBEXIT        ;EXIT IF BAD
  461.       STA    CTC1        ;
  462.       INX    H
  463.       LDA    REG4
  464.       ANI    0FH
  465.       ORA    M
  466.       STA    REG4
  467.       LDA    TSPEED
  468.       STA    MSPEED
  469.       ORA    A        ;RETURN NO ERRORS
  470. PBEXIT:      POP    B
  471.       POP    D
  472.       POP    H
  473.       RET
  474. ;
  475. BAUDTB    DB    0,0        ;110 (NOT SUPPORTED)
  476.     DB    208,080H    ;300
  477.     DB    156,080h    ;450 
  478.     DB    208,040H    ;600
  479.     DB    0,0
  480.     DB    104,040H    ;1200
  481.     DB    52,040H        ;2400
  482.     DB    26,040H        ;4800
  483.     DB    13,040H        ;9600
  484.       DB    0FH        ;19200 (Not Supported) 
  485.       RET
  486. ;
  487. ;    SET PARITY command: reset transmit/receive parity
  488. ;
  489. ;        Parity is controlled by bits 0 and 1 of
  490. ;        the byte sent to the SIO write-register
  491. ;        4 as follows:
  492. ;
  493. ;           Parity    Bit 1       Bit 0
  494. ;                 Off          -          0
  495. ;              Odd      0         1
  496. ;             Even      1         1
  497. ;
  498. STPRTY:      MVI    C,SBLANK    ;check for parity code
  499.       CALL    MEX        ;
  500.       JC    SETERR        ;if none, print error
  501.       LXI    D,PARTBL    ;check for proper syntax
  502.       MVI    C,LOOKUP
  503.       CALL    MEX
  504.       PUSH    H        ;match found, go do it!
  505.       RNC            ;
  506.       POP    H        ;no match: fix stack and
  507.       JMP    SETERR        ;  print error
  508. ;
  509. PROFF:      LDA    REG4        ;get register 4 byte
  510.       ANI    0FEH        ;reset bit 0
  511.       JMP    PARTB1        ;
  512. PREVEN:      LDA    REG4        ;
  513.       ORI    003H        ;set bits 0 & 1
  514.       JMP    PARTB1        ;
  515. PRODD:      LDA    REG4        ;
  516.       ORI    001H        ;set bit 0
  517.       ANI    0FDH        ;reset bit 1
  518. PARTB1:      STA    REG4        ;
  519.       CALL    NITSIO        ;re-initialize the USART
  520.       CALL    SHPRTY        ;print the result
  521.       RET             ;
  522. SHPRTY:      CALL    MILP        ;display parity
  523.       DB    'Parity:  ',TAB,' ',0
  524.       LDA    REG4        ;
  525.       ANI    001H        ;test bit 0
  526.       CPI    0        ;if bit0=0 then parity off
  527.       JNZ    SHPRT1        ;
  528.       CALL    MILP        ;
  529.       DB    'Off',0        ;
  530.       RET
  531. SHPRT1:      LDA    REG4        ;
  532.       ANI    002H        ;test bit 1
  533.       CPI    0        ;if bit1=0 then parity odd
  534.       JNZ    SHPRT2        ;
  535.       CALL    MILP        ;
  536.       DB    'Odd',0        ;
  537.       RET            ;
  538. SHPRT2:      CALL    MILP        ;
  539.       DB    'Even',0    ;
  540.       RET
  541. ;
  542. ;    SET PARITY command table
  543. ;
  544. PARTBL:      DB    'OF','F'+80H    ;"set parity off"
  545.       DW    PROFF
  546.       DB    'EVE','N'+80H    ;"set parity even"
  547.       DW    PREVEN
  548.       DB    'OD','D'+80H    ;"set parity odd"
  549.       DW    PRODD
  550.       DB    0        ;<<== end of parity table
  551. ;
  552. ;    SET STOPBITS command: reset number of stop bits
  553. ;
  554. ;        The number of stop bits is controlled by bits
  555. ;        2 and 3 of the byte sent to the SIO write-
  556. ;        register 4, as follows:
  557. ;
  558. ;            Stop bits       Bit 3    Bit 2
  559. ;            1         0            1
  560. ;               1.5         1          0
  561. ;            2         1          1
  562. ;
  563. ;
  564. STSTOP:      MVI    C,SBLANK    ;check for stop bits
  565.       CALL    MEX        ;
  566.       JC    SETERR        ;if none, print error
  567.       LXI    D,STPTBL    ;check for proper syntax
  568.       MVI   C,LOOKUP
  569.       CALL    MEX        ;
  570.       PUSH    H        ;match found, go do it!
  571.       RNC            ;
  572.       POP    H        ;no match: fix stack and
  573.       JMP    SETERR        ;  print error
  574. ;
  575. STOP01:      LDA    REG4        ;get register 4 byte
  576.       ANI    0F7H        ;reset bit 3
  577.       ORI    004H        ;set bit 2
  578.       JMP    STSTP1        ;
  579. STOP02:      LDA    REG4        ;
  580.       ORI    00CH        ;set bits 2 and 3
  581.       JMP    STSTP1        ;
  582. STOP15:      LDA    REG4        ;
  583.       ORI    008H        ;set bit 3
  584.       ANI    0FBH        ;reset bit 2
  585. STSTP1:      STA    REG4        ;
  586.       CALL    NITSIO        ;
  587.       CALL    SHSTOP        ;print the result
  588.       RET
  589. SHSTOP:      CALL    MILP        ;display stop-bits
  590.       DB    'Stop bits:',TAB,' ',0
  591.       LDA    REG4        ;
  592.       ANI    004H        ;test bit 2
  593.       CPI    0        ;if bit2=0 then 1.5
  594.       JNZ    SHSTP1        ;
  595.       CALL    MILP        ;
  596.       DB    '1.5',0        ;
  597.       RET
  598. SHSTP1:      LDA    REG4        ;
  599.       ANI    008H        ;test bit 3
  600.       CPI    0        ;if bit3=0 then 1
  601.       JNZ    SHSTP2        ;
  602.       CALL    MILP        ;
  603.       DB    '1',0        ;
  604.       RET
  605. SHSTP2:      CALL    MILP        ;
  606.       DB    '2',0        ;
  607.       RET
  608. ;
  609. ;    SET STOPBITS command table
  610. ;
  611. STPTBL:      DB    '1'+80H        ;"set stop 1"
  612.       DW    STOP01
  613.       DB    '2'+80H        ;"set stop 2"
  614.       DW    STOP02
  615.       DB    '1.','5'+80H    ;"set stop 1.5"
  616.       DW    STOP15
  617.       DB    0        ;<<== End of stop-bits table
  618. ;
  619. ;    SET LENGTH command: set bits per character
  620. ;
  621. ;        The number of bits per character is controlled for
  622. ;        the receiver circuit by bits 6 and 7 of the byte
  623. ;        sent to the SIO write-register 3 and for the trans-
  624. ;        mitter circuit by bits 5 and 6 of the byte sent to
  625. ;        the SIO write-register 5.  The assumption has been
  626. ;        made here that both transmission and reception will
  627. ;        be carried on at the same number of bits per charac-
  628. ;        ter.  The bit configurations are shown for register
  629. ;        3 only, but are the same for register 5:
  630. ;
  631. ;                       REG5--->Bit 6           Bit 5
  632. ;            BPC    REG3--->Bit 7        Bit 6
  633. ;             5          0          0
  634. ;             6          1             0
  635. ;             7          0          1
  636. ;             8          1          1
  637. ;
  638. STBITS:      MVI    C,SBLANK    ;check for bits/char
  639.       CALL    MEX        ;
  640.       JC    SETERR        ;if none, print error
  641.       LXI    D,BITTBL    ;check for proper syntax
  642.       MVI    C,LOOKUP
  643.       CALL    MEX
  644.       PUSH    H        ;match found, go do it!
  645.       RNC            ;
  646.       POP    H        ;no match: fix stack and
  647.       JMP    SETERR        ;  print error
  648. ;
  649. BIT5:      LDA    REG3        ;
  650.       ANI    0BFH        ;reset bit 6
  651.       ANI    07FH        ;reset bit 7
  652.       STA    REG3        ;
  653.       LDA    REG5        ;
  654.       ANI    0DFH        ;reset bit 5
  655.       ANI    0BFH        ;reset bit 6
  656.       JMP    STBTS1        ;
  657. BIT6:      LDA    REG3        ;
  658.       ANI    0BFH        ;reset bit 6
  659.       ORI    080H        ;set bit 7
  660.       STA    REG3        ;
  661.       LDA    REG5        ;
  662.       ANI    0DFH        ;reset bit 5
  663.       ORI    040H        ;set bit 6
  664.       JMP    STBTS1        ;
  665. BIT7:      LDA    REG3        ;
  666.       ORI    040H        ;set bit 6
  667.       ANI    07FH        ;reset bit 7
  668.       STA    REG3        ;
  669.       LDA    REG5        ;
  670.       ORI    020H        ;set bit 5
  671.       ANI    0BFH        ;reset bit 6
  672.       JMP    STBTS1        ;
  673. BIT8:      LDA    REG3        ;
  674.       ORI    040H        ;set bit 6
  675.       ORI    080H        ;set bit 7
  676.       STA    REG3        ;
  677.       LDA    REG5        ;
  678.       ORI    020H        ;set bit 5
  679.       ORI    040H        ;set bit 6
  680. STBTS1:      STA    REG5        ;
  681.       CALL    NITSIO        ;
  682.       CALL    SHBITS        ;print the result
  683.       RET
  684. SHBITS:      CALL    MILP        ;display bits/char
  685.       DB    'Bits/char:',TAB,' ',0
  686.       LDA    REG5        ;
  687.       ANI    040H        ;test bit 6
  688.       CPI    0        ;if bit6=0 then 6 bpc
  689.       JNZ    SHBTS2        ;
  690.       LDA    REG5        ;
  691.       ANI    020H        ;test bit 5
  692.       CPI    0        ;if bit5=0 then 5 bpc
  693.       JNZ    SHBTS1        ;
  694.       CALL    MILP        ;
  695.       DB    '5',0        ;
  696.       RET            ;
  697. SHBTS1:      CALL    MILP        ;
  698.       DB    '7',0        ;
  699.       RET            ;
  700. SHBTS2:      LDA    REG5        ;
  701.       ANI    020H        ;test bit 5
  702.       CPI    0        ;if bit5=0 then 6 bpc
  703.       JNZ    SHBTS3        ;
  704.       CALL    MILP        ;
  705.       DB    '6',0        ;
  706.       RET            ;
  707. SHBTS3:      CALL    MILP        ;
  708.       DB    '8',0        ;
  709.       RET
  710. ;
  711. ;    SET LENGTH command table
  712. ;
  713. BITTBL:      DB    '5'+80H        ;"set bits 5"
  714.       DW    BIT5
  715.       DB    '6'+80H        ;"set bits 6"
  716.       DW    BIT6
  717.       DB    '7'+80H        ;"set bits 7"
  718.       DW    BIT7
  719.       DB    '8'+80H        ;"set bits 8"
  720.       DW    BIT8
  721.       DB    0        ;<<== end of bit table
  722. ;
  723.       RET
  724. ;
  725. ;
  726. ;
  727. SWPULSE:  MVI    A,'P'        ; Put 'P' into Touch/Pulse byte
  728.       STA    TOUCHPULSE    ; for SM Overlay to grab    
  729.       JMP    SHDIAL
  730. ;
  731. SWTONE      MVI    A,'T'        ; Or put 'T' there
  732.       STA    TOUCHPULSE
  733.       
  734. ;
  735. SHDIAL:      LDA    TOUCHPULSE    ; Grab Flag 
  736.       CPI    'T'        ; if Tone then say so
  737.       JZ    TONED
  738.       CPI    'P'        ; likewise if pulse
  739.       JZ    PULSED
  740.       LXI    D,BADFLA    ; But if bad say so
  741.       MVI   C,PRINT        ; should never get here, just for 
  742.       CALL    MEX        ; safety
  743.       RET
  744. TONED:      LXI    D,TONEFLF
  745.       MVI    C,PRINT
  746.       CALL    MEX
  747.       RET
  748. PULSED      LXI    D,PULSEF
  749.       MVI    C,PRINT
  750.       CALL    MEX
  751.       RET
  752. BADFLA:      DB    'BAD TOUCH/PULSE FLAG',CR,LF,'$'
  753. TONEFLF      DB    'Tone Dial','$'
  754. PULSEF    DB    'Pulse Dial','$'
  755. ;
  756. ; General utility routines
  757. ;
  758. MILP:      MVI    C,ILP        ;IN-LINE PRINT
  759.       JMP    MEX
  760.       RET
  761. ;
  762. MTIME:      MVI    C,TIMER        ;MEX TIMER
  763.       JMP    MEX
  764.       RET
  765. ;
  766. CRLF:      CALL    MILP        ;PRINT CARRIAGE RETURN, LINE FEED
  767.       DB    CR,LF,0
  768.       RET
  769. ;
  770. ;
  771. ;==========================================================================
  772. ;                            Data Area
  773. ;==========================================================================
  774. ;
  775. ; Default UART parameters (Initalized for  RS-232 port B)
  776. ;
  777. REG3:      DB    0C1H    ;ENABLE RECEIVE AT 8 BITS/CHAR
  778. REG4:      DB    004H    ;NO PARITY, 1 STOP, CLOCK RATE SET AT INITALIZE TIME
  779. REG5:      DB    06AH    ;ENABLE TRANSMIT AT 8 BITS/CHAR
  780. CTC1      DB     0    ;Also set at initalize time
  781. ;
  782. ; Miscellaneous Default Data
  783. ;
  784. ;
  785. TSPEED      DB    1        ;TEMP SPEED AREA
  786. ;
  787. ;
  788.       END
  789.