home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / sigmv066.ark / MODEM3.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  34KB  |  1,537 lines
  1. ;
  2. ;MODEM.ASM V2.0, BY WARD CHRISTENSEN
  3. ;    (revised 12/6/79)
  4. ;
  5. ;CP/M - CP/M FILE TRANSFER PROGRAM, AND
  6. ;TERMINAL PROGRAM.
  7. ;
  8. ;NOTE: THIS FILE WILL ASSEMBLE, WITHOUT NEED FOR
  9. ;EDITING, TO WORK WITH A PMMI MM-103 MODEM.  SEE
  10. ;EQUATES FOR OTHER OPTIONS INCLUDING SYSTEM CLOCK
  11. ;FREQUENCY.
  12. ;
  13. * * * * * * * * * * * * * * * * * * * * * * * * *
  14. *                        *
  15. *    THIS PROGRAM DOCUMENTED IN "MODEM.DOC"    *
  16. *                        *
  17. * * * * * * * * * * * * * * * * * * * * * * * * *
  18. * THIS PROGRAM WAS "MODEM.ASM" BUT IS         *
  19. * TEMPORARILY NAMED "MODEM2.ASM" SO PEOPLE    *
  20. * WILL REALIZE IT IS AN ENHANCEMENT OF        *
  21. * THE ORIGINAL PROGRAM "MODEM.ASM" ON CP/M    *
  22. * USER'S GROUP DISK 25.                *
  23. * * * * * * * * * * * * * * * * * * * * * * * * *
  24. ;
  25. ;PLEASE PASS ON MODS, BUGS, ETC, SO YOUR
  26. ;FIXES OR ENHANCEMENTS MAY BE SHARED BY ALL,
  27. ;         TO:
  28. ;    Ward Christensen
  29. ;    688 E. 154th St. #5D
  30. ;    Dolton, Il. 60419
  31. ;
  32. ;    (312) 849-6279
  33. ;
  34. ;You may send a self-addressed stamped postcard
  35. ;to be informed of changes/bugs as they become
  36. ;known.
  37. ;
  38. ;    --------------
  39. ;
  40. ;    09/23/77
  41. ;ORIGINALLY WRITTEN BY WARD CHRISTENSEN
  42. ;
  43. ;    04/26/79
  44. ;REWRITTEN BY WARD CHRISTENSEN TO COMBINE
  45. ;IMPROVEMENTS TO THE ORIGINAL MADE BY WARD
  46. ;AND BY KEITH PETERSEN, W8SDZ, AND SUGGESTIONS
  47. ;BY JIM BELL WHICH KEITH IMPLEMENTED.  SEE
  48. ;MODEM.DOC FOR ADDITIONAL HISTORICAL
  49. ;INFORMATION AND DOCUMENTATION.
  50. ;
  51. ;    05/09/79
  52. ;ALLOW 'T' AND 'E' SUB-OPTIONS TO GO TO TERMINAL
  53. ;OR ECHO MODEM AFTER TRANSFERRING A FILE.  (WLC)
  54. ;
  55. ;    05/22/79
  56. ;ADD FEATURE TO MAKE RECEIVE FILE ROUTINE SAY
  57. ;FILE SUCCESSFULLY OPENED, WHEN IN QUIET MODE.
  58. ;MOVE INITIAL GOBBLE GARBAGE INPUTS TO BEFORE
  59. ;COMMAND CPI'S SO ALL MODES ARE CLEARED. CHANGE
  60. ;INITIAL SEND WAIT TO 80 SECS TO ALLOW MORE TIME
  61. ;FOR RECEIVING END TO COME UP. ADD 'H' AFTER MSG
  62. ;THAT SHOWS NUMBER OF SECTORS IN EXTENT ABOUT TO
  63. ;BE SENT.  (KBP)
  64. ;
  65. ;    05/24/79
  66. ;FIX MISSING RETURN INSTRUCTION AT END OF
  67. ;INITIALIZATION ROUTINE.  (KBP)
  68. ;
  69. ;    07/01/79
  70. ;MODIFIED PROGRAM TO ALLOW FOR NON-STANDARD VERSIONS OF
  71. ;CP/M. ALL REFERENCES TO ENTRIES INTO CP/M SHOULD BE MADE
  72. ;RELATIVE TO THE VARIABLE SYMBOL CALL "BASE". FOR EXAMPLE,
  73. ;THE EQUATE TO BDOS SHOULD BE BASE+5 INSTEAD OF 5. BASE
  74. ;WILL BE SET TO 0 WHEN THE VARIABLE STDCPM IS SET TO TRUE.
  75. ;(BOB MATHIAS).
  76. ;
  77. ;    07/24/79
  78. ;MOVE INITIALIZE LOCAL STACK TO BEGINNING OF PROGRAM
  79. ;SO DEFAULT STACK IS NOT USED. ADD CONDITIONAL ASSEMBLY
  80. ;OPTION TO TERMINAL ROUTINE FOR TIMESHARE SYSTEMS.
  81. ;CORRECT ERROR IN LOCAL ABORT ROUTINE (WAS LOOKING FOR
  82. ;CONTROL E - NOW CORRECTLY LOOKS FOR CONTROL X). ADD
  83. ;REGISTER SAVES TO CONOUT, KEYIN AND AND KEYBOARD STATUS
  84. ;ROUTINES, AS SOME CBIOS ROUTINES CLOBBER THEM. (KBP)
  85. ;
  86. ;    08/05/79
  87. ;ADDED D. C. HAYES MODEM SUPPORT BY JIM BELL  (KBP)
  88. ;
  89. ;    08/06/79
  90. ;ADDED EQUATES FOR EXTERNAL MODEM (NOT S-100 PLUG-IN)
  91. ;(KBP)
  92. ;
  93. ;    12/06/79
  94. ;CORRECTED ERROR IN HELP FILE. SAID T.110, NOW SAYS
  95. ;TO.110. BY WARD CHRISTENSEN. CORRECTED RECEIVE FILE
  96. ;ROUTINE SO TERMINAL OR ECHO MODE WORKS AFTER FILE
  97. ;TRANSFER IN QUIET MODE. MOVED CHECKS FOR "H" AND
  98. ;"X" OPTIONS SO MODEM IS NOT REINITIALIZED. (KBP)
  99. ;
  100. ;    01/02/80
  101. ;THIS NOW WILL SUPPORT THE INTEL 8251 CHIP AS A INTERFACE
  102. ;TO THE MODEM. IT WILL DO ALL SET UP AND READY OF THE
  103. ;8251 BEFORE CONTACT AND IF THE MODEM IS ALREADY CON-
  104. ;NECTED TO A STATION IT WILL ASUME THAT THE CHIP IS READY.
  105. ;    THESE MODIFACATIONS MAKE IT COMPATABLE WITH THE 
  106. ;DIGITAL GROUP COMMUNICATIONS BOARD. (BILL NADZAM)
  107. ;
  108. ;
  109. STDCPM    EQU    1    ;TRUE, IS STANDARD CP/M
  110. H8CPM    EQU    0    ;TRUE, IS HEATH H8 CP/M
  111. ;
  112. BASE    EQU    0    ;CP/M BASE ADDRESS
  113. ;
  114. ;
  115. USART    EQU    1    ;TRUE,IS 8251 CHIP AS MODEM INTF.
  116. ;
  117. PMMI    EQU    0    ;TRUE, IS PMMI
  118. ;
  119. DCH    EQU    0    ;TRUE, IS D.C. HAYES
  120. ;
  121. ;IF YOU ARE USING AN EXTERNAL MODEM (NOT S-100 PLUG-IN)
  122. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  123. ;
  124. INITREQ EQU    1    ;TRUE,IF MODEM PORT INIT. REQ'D
  125. INITC1    EQU    4EH    ;FIRST INIT CHAR TO CTL PORT
  126. INITC2    EQU    27H    ;2ND INIT CHAR TO CTL PORT
  127. ;
  128. ;
  129. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS
  130. EXITCHR    EQU    'E'-40H ;CTL-E EXIT FROM T OR C
  131. DISCCHR    EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM T/C
  132. ;
  133. FASTCLK    EQU    0    ;PUT 1 HERE FOR 4 MHZ CLOCK
  134. ;
  135. ;SOME TIME-SHARE COMPUTERS REQUIRE TERMINALS TO
  136. ;HAVE BIT 7 HIGH (MARKING), SO IN THE TERMINAL
  137. ;MODE WE FORCE IT TO HIGH IF THE FOLLOWING OPTION
  138. ;IS SELECTED:
  139. ;
  140. TIMESHR    EQU    0    ;PUT 1 HERE TO MAKE BIT 7 HIGH
  141. ;
  142. ;
  143. ;DEFINE ASCII CHARACTERS USED
  144. ;
  145. SOH    EQU    1    ;START OF HEADER
  146. EOT    EQU    4    ;END OF TRANSMISSION
  147. ACK    EQU    6    ;ACKNOWLEDGE
  148. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  149. CAN    EQU    18H    ;CANCEL
  150. LF    EQU    10    ;LINEFEED
  151. CR    EQU    13    ;CARRIAGE RETURN
  152. ; 
  153.     ORG    BASE+100H
  154. ;
  155. ;INIT PRIVATE STACK
  156.     LXI    H,0    ;HL=0
  157.     DAD    SP    ;HL=STACK FROM CP/M
  158.     SHLD    STACK    ;..SAVE IT
  159.     LXI    SP,STACK ;SP=MY STACK
  160. ;
  161. ;
  162.     CALL    START    ;GO PRINT ID
  163.     DB    'MODEM PROGRAM as of '
  164.     DB    '01/04/80',CR,LF,'$'
  165. ; 
  166. START    POP    D    ;GET ID MESSAGE
  167.     MVI    C,PRINT
  168.     CALL    BDOS    ;PRINT ID MESSAGE
  169. ;
  170. ;INITIALIZE THE JMPS TO CP/M BIOS
  171. ;
  172.     CALL    INITADR
  173. ;
  174.     LDA    FCB+1    ;GET PRIMARY OPTION
  175.     CPI    'H'    ;MODEM H(ELP)?
  176.     JZ    HELP    ;..YES, GIVE HELP
  177.     CPI    'X'    ;MODEM X(AMPLES)?
  178.     JZ    EXAM    ;GIVE EXAMPLES
  179. ;
  180. ;SAVE PRIMARY OPTION, VALIDATE SECONDARY OPT.
  181. ;
  182.     CALL    PROCOPT
  183. ;
  184. ;INIT THE MODEM OR SERIAL PORT
  185. ;
  186.     CALL    INITMOD
  187. ;
  188. ;MOVE THE FILENAME FROM FCB 2 TO FCB 1
  189. ;
  190.     CALL    MOVEFCB
  191. ;
  192. ;GOBBLE UP GARBAGE CHARS FROM THE LINE
  193. ;PRIOR TO RECEIVE OR SEND
  194. ;
  195. ;
  196. ;JMP TO APPROPRIATE FUNCTION
  197. ;
  198.     LDA    OPTION    ;GET PRIMARY OPTION
  199. ;
  200.     CPI    'C'    ;(COMPAT W/EARLIER
  201.     JZ    TRMECHO    ;OPTION "COMPUTER")
  202. ;
  203.     CPI    'E'    ;TERMINAL IN ECHO
  204.     JZ    TRMECHO    ;..MODE?
  205. ;
  206.     CPI    'T'    ;TERMINAL..
  207.     JZ    TERM    ;..MODE?
  208. ;
  209.     CPI    'D'
  210.     JZ    DISCONN
  211. ;
  212.            CPI    'S'    ;SEND..
  213.     JZ    SENDFIL    ;..A FILE?
  214. ;
  215.     CPI    'R'    ;RECEIVE..
  216.     JZ    RCVFIL    ;..A FILE?
  217. ;
  218. ;INVALID OPTION
  219. ;
  220.     JMP    BADOPT
  221.     org    base+4000h    ;modified for osbornese
  222. * * * * * * * * * * * * * * * * * * * * *
  223. *                    *
  224. *    TERM: TERMINAL MODE        *
  225. *                    *
  226. * * * * * * * * * * * * * * * * * * * * *
  227. ;
  228. ;THIS PROGRAM SIMPLY SENDS KEYED CHARACTERS
  229. ;DOWN THE LINE, AND DISPLAYS CHARACTERS
  230. ;RECEIVED FROM THE LINE.  THIS MAKES IT
  231. ;SUITABLE FOR COMMUNICATION WITH TIME SHARING
  232. ;COMPUTERS, CBBS'S, OR ANOTHER PROGRAM
  233. ;RUNING "MODEM E" (ECHO MODE)
  234. ;
  235. ;TYPE THE "EXITCHR" (ORIGINALLY CTL-E) TO EXIT.
  236. ;OR THE "DISCCHR" (ORIGINALLY CTL-D) TO DISCONN.
  237. ;
  238. ;A FUTURE ENHANCEMENT WILL BE TO WRITE THE
  239. ;RECEIVED DATA IN MEMORY, AND ALLOW IT TO
  240. ;BE WRITTEN TO DISK
  241. ;
  242. TERM    CALL    STAT    ;LOCAL CHAR KEYED?
  243.     JZ    TERML    ;..NO, CHECK LINE
  244.     CALL    KEYIN    ;GET CHAR
  245.     CPI    EXITCHR    ;TIME TO END?
  246.     JZ    CKDIS    ;YES, CK DISCONN
  247.     CPI    DISCCHR    ;DISCONNECT REQUEST?
  248.     JZ    DISCONN    ;YES, DO IT
  249.     call    acsend    ;send the char
  250. ;
  251. ;SEE IF CHAR FROM LINE
  252. ;
  253. terml:    di
  254.     out    0
  255.     mvi    a,0
  256.     sta    0ef08h
  257.     lda    2a00h
  258.     sta    xyz
  259.     out    1
  260.     mvi    a,1
  261.     sta    0ef08h
  262.     ei
  263.     lda    xyz
  264.     ani    01h
  265.     cpi    00h
  266.     jz    term
  267.     di
  268.     out    0
  269.     mvi    a,0
  270.     sta    0ef08h
  271.     lda    2a01h
  272.     sta    xyz
  273.     out    1
  274.     mvi    a,1
  275.     sta    0ef08h
  276.     ei
  277.     lda    xyz
  278.     ani    7fh
  279.     CALL    TYPE    ;TYPE IT
  280.     JMP    TERM    ;LOOP
  281. ;
  282. * * * * * * * * * * * * * * * * * * * * *
  283. *                    *
  284. *    TRMECHO: TERMINAL WITH ECHO    *
  285. *                    *
  286. * * * * * * * * * * * * * * * * * * * * *
  287. ;
  288. ;TERMINAL PROGRAM WITH ECHO - SEE NOTES
  289. ;UNDER "TERM" ABOVE
  290. ;
  291. ;C A U T I O N   DON'T RUN WITH BOTH COMPUTERS
  292. ;IN "ECHO" MODE - LINE ERRORS (OR ANY CHAR)
  293. ;WILL BE ECHOED BACK AND FORTH AD INFINITUM.
  294. ;
  295. trmecho: di
  296.     out    0
  297.     mvi    a,0
  298.     sta    0ef08h
  299.     lda    2a00h
  300.     sta    xyz
  301.     out    1
  302.     mvi    a,1
  303.     sta    0ef08h
  304.     ei
  305.     lda    xyz
  306.     ani    01h
  307.     cpi    00h
  308.     jnz    linechr
  309.     CALL    STAT    ;CHECK LOCAL KB
  310.     JZ    TRMECHO    ;..NO CHAR
  311.     CALL    KEYIN    ;GET LOCAL CHAR
  312.     CPI    EXITCHR    ;END?
  313.     JZ    CKDIS    ;YES, CK DISCONN, EXIT
  314.     CPI    DISCCHR    ;DISCONN?
  315.     JZ    DISCONN    ;..YES, DO IT.
  316.     di
  317.     sta    xyz
  318.     out    0
  319.     mvi    a,0
  320.     sta    0ef08h
  321.     lda    2a01h
  322.     out    1
  323.     mvi    a,1
  324.     sta    0ef08h
  325.     ei
  326.     CALL    TYPE    ;ECHO IT LOCALLY
  327.     JMP    TRMECHO    ;..AND LOOP
  328. ;
  329. ;GOT CHAR FROM LINE
  330. ;
  331. linechr:di
  332.     out    0
  333.     mvi    a,0
  334.     sta    0ef08h
  335.     lda    2a00h
  336.     sta    xyz
  337.     out    1
  338.     mvi    a,1
  339.     sta    0ef08h
  340.     ei
  341.     lda    xyz
  342.     ani    01h
  343.     cpi    00h
  344.     jz    linechr
  345.     di
  346.     out    0
  347.     mvi    a,0
  348.     sta    0ef08h
  349.     lda    2a01h
  350.     sta    xyz
  351.     lda    2a01h
  352.     out    1
  353.     mvi    a,1
  354.     sta    0ef08h
  355.     ei
  356.     lda    xyz
  357.     CALL    TYPE    ;TYPE IT
  358.     JMP    TRMECHO    ;LOOP
  359. ;
  360. * * * * * * * * * * * * * * * * * * * * *
  361. *                    *
  362. *    SENDFIL: SENDS A CP/M FILE    *
  363. *                    *
  364. * * * * * * * * * * * * * * * * * * * * *
  365. ;
  366. ;THE CP/M FILE SPECIFIED IN THE MODEM COMMAND
  367. ;IS TRANSFERRED OVER THE PHONE TO ANOTHER
  368. ;COMPUTER RUNNING MODEM WITH THE "R" (RECEIVE)
  369. ;OPTION.  THE DATA IS SENT ONE SECTOR AT A
  370. ;TIME WITH HEADERS AND CHECKSUMS, AND RE-
  371. ;TRANSMISSION ON ERRORS.  
  372. ;
  373. SENDFIL    CALL    OPENFIL    ;OPEN THE FILE
  374.     MVI    E,80    ;WAIT 80 SEC..
  375.     CALL    WAITNAK    ;..FOR INITIAL NAK
  376. SENDLP    CALL    RDSECT    ;READ A SECTOR
  377.     JC    SENDEOF    ;SEND EOF IF DONE
  378.     CALL    INCRSNO    ;BUMP SECTOR #
  379.     XRA    A    ;ZERO ERROR..
  380.     STA    ERRCT    ;..COUNT
  381. SENDRPT    CALL    SENDHDR    ;SEND A HEADER
  382.     CALL    SENDSEC    ;SEND DATA SECTOR
  383.     CALL    SENDCKS    ;SEND CKSUM
  384.     CALL    GETACK    ;GET THE ACK
  385.     JC    SENDRPT    ;REPEAT IF NO ACK
  386.     JMP    SENDLP    ;LOOP UNTIL EOF
  387. ;
  388. ;FILE SENT, SEND EOT'S
  389. ;
  390. SENDEOF    MVI    A,EOT    ;SEND..
  391.     CALL    SEND    ;..AN EOT
  392.     CALL    GETACK    ;GET THE ACK
  393.     JC    SENDEOF    ;LOOP IF NO ACK
  394.     JMP    DONE    ;ALL DONE
  395. ;
  396. * * * * * * * * * * * * * * * * * * * * *
  397. *                    *
  398. *    RCVFIL: RECEIVE A FILE        *
  399. *                    *
  400. * * * * * * * * * * * * * * * * * * * * *
  401. ;
  402. ;RECEIVES A FILE IN BLOCK FORMAT AS SENT
  403. ;BY ANOTHER PERSON DOING "MODEM S FN.FT".
  404. ;
  405. RCVFIL    CALL    ERASFIL    ;ERASE THE FILE
  406.     CALL    MAKEFIL    ;..THEN MAKE NEW
  407.     LDA    QFLG    ;SEE IF IN QUIET MODE
  408.     ORA    A
  409.     JNZ    RCVLP    ;NOT IN QUIET MODE, SKIP MSG
  410.     CALL    ILPRT    ;PRINT:
  411.     DB    'FILE OPEN, READY TO RECEIVE',CR,LF,0
  412. RCVLP    CALL    RCVSECT    ;GET A SECTOR
  413.     JC    RCVEOT    ;GOT EOT
  414.     CALL    WRSECT    ;WRITE THE SECTOR
  415.     CALL    INCRSNO    ;BUMP SECTOR #
  416.     CALL    SENDACK    ;ACK THE SECTOR
  417.     JMP    RCVLP    ;LOOP UNTIL EOF
  418. ;
  419. ;GOT EOT ON SECTOR - FLUSH BUFFERS, END
  420. ;
  421. RCVEOT    CALL    WRBLOCK    ;WRITE THE LAST BLOCK
  422.     CALL    SENDACK    ;ACK THE SECTOR
  423.     CALL    CLOSFIL    ;CLOSE THE FILE
  424.     JMP    DONE    ;ALL DONE
  425. ;
  426. * * * * * * * * * * * * * * * * * * * * *
  427. *                    *
  428. *        SUBROUTINES        *
  429. *                    *
  430. * * * * * * * * * * * * * * * * * * * * *
  431. ;
  432. ;
  433. ;---->    RCVSECT: RECEIVE A SECTOR
  434. ;
  435. ;RETURNS WITH CARRY SET IF EOT RECEIVED.
  436. ;
  437. RCVSECT    XRA    A    ;GET 0
  438.     STA    ERRCT    ;INIT ERROR COUNT
  439. RCVRPT    LDA    QFLG    ;QUIET?
  440.     ORA    A
  441.     JZ    RCVSQ    ;YES, NO STAT MSG.
  442.     CALL    ILPRT    ;PRINT:
  443.     DB    'AWAITING #',0
  444.     LDA    SECTNO    ;GET SECTOR #
  445.     INR    A    ;(REAL INR LATER)
  446.     CALL    HEXO    ;PRINT IN HEX
  447.     CALL    CRLF    ;..THEN CRLF
  448. ;
  449. RCVSQ    MVI    B,10    ;10 SEC TIMEOUT
  450.     CALL    RECV    ;GET SOH/EOT
  451.     JC    RCVSTOT    ;TIMEOUT
  452.     CPI    SOH    ;GET SOH?
  453.     JZ    RCVSOH    ;..YES
  454. ;
  455. ;EARLIER VERS. OF MODEM PROG SENT SOME NULLS -
  456. ;IGNORE THEM
  457. ;
  458.     ORA    A    ;00 FROM SPEED CHECK?
  459.     JZ    RCVSQ    ;YES, IGNORE IT
  460.     CPI    EOT    ;END OF TRANSFER?
  461.     STC        ;RETURN WITH CARRY..
  462.     RZ        ;..SET IF EOT
  463. ;
  464. ;DIDN'T GET SOH  OR EOT - 
  465. ;
  466.     MOV    B,A    ;SAVE CHAR
  467.     LDA    VSEEFLG    ;VIEWING..
  468.     ORA    A    ;..MODE?
  469.     JZ    RCVSEH    ;YES, PRT.MSG
  470.     LDA    QFLG    ;QUIET..
  471.     ORA    A    ;..MODE?
  472.     JZ    RCVSERR    ;YES, SKIP MSG
  473. RCVSEH    MOV    A,B    ;GET CHAR
  474.     CALL    HEXO    ;SHOW IN HEX
  475.     CALL    ILPRT    ;PRINT:
  476.     DB    'H RCD, NOT SOH',CR,LF,0
  477. ;
  478. ;DIDN'T GET VALID HEADER - PURGE THE LINE,
  479. ;THEN SEND NAK.
  480. ;
  481. RCVSERR    MVI    B,1    ;WAIT FOR 1 SEC..
  482.     CALL    RECV    ;..WITH NO CHARS
  483.     JNC    RCVSERR    ;LOOP UNTIL SENDER DONE
  484.     MVI    A,NAK    ;SEND..
  485.     CALL    SEND    ;..THE NAK
  486.     LDA    ERRCT    ;ABORT IF..
  487.     INR    A    ;..WE HAVE REACHED..
  488.     STA    ERRCT    ;..THE ERROR..
  489.     CPI    ERRLIM    ;..LIMIT?
  490.     JC    RCVRPT    ;..NO, TRY AGAIN
  491. ;
  492. ;10 ERRORS IN A ROW - 
  493. ;
  494.     LDA    VSEEFLG    ;VIEWING..
  495.     ORA    A    ;..FILE?
  496.     JZ    RCVCKQ    ;YES, ASK RETRY/QUIT
  497.     LDA    QFLG    ;QUIET..
  498.     ORA    A    ;..MODE?
  499.     JZ    RCVSABT    ;ABORT
  500. RCVCKQ    CALL    CKQUIT    ;RETRY/QUIT?
  501.     JZ    RCVSECT    ;TRY AGAIN
  502. ;
  503. RCVSABT    CALL    CLOSFIL    ;KEEP WHATEVER WE GOT
  504.     CALL    ERXIT
  505.     DB    '++UNABLE TO RECEIVE BLOCK'
  506.     DB    CR,LF,'++ABORTING++$'
  507. ;
  508. ;TIMEDOUT ON RECEIVE
  509. ;
  510. RCVSTOT    LDA    VSEEFLG    ;VIEWING..
  511.     ORA    A    ;..MODE?
  512.     JZ    RCVSPT    ;YES, PRT MSG
  513.     LDA    QFLG    ;QUIET..
  514.     ORA    A    ;..MODE?
  515.     JZ    RCVSERR    ;YES, NO MSG
  516. RCVSPT    CALL    ILPRT
  517.     DB    '++TIMEOUT++ ',0
  518. RCVPRN    LDA    ERRCT    ;PRINT ERROR..
  519.     CALL    HEXO    ;..COUNT
  520.     CALL    CRLF
  521.     JMP    RCVSERR    ;BUMP ERR CT, ETC.
  522. ;
  523. ;GOT SOH - GET BLOCK #, BLOCK # COMPLEMENTED
  524. ;
  525. RCVSOH    MVI    B,1    ;TIMEOUT = 1 SEC
  526.     CALL    RECV    ;GET SECTOR
  527.     JC    RCVSTOT    ;GOT TIMEOUT
  528.     MOV    D,A    ;D=BLK #
  529.     MVI    B,1    ;TIMEOUT = 1 SEC
  530.     CALL    RECV    ;GET CMA'D SECT #
  531.     JC    RCVSTOT    ;TIMEOUT
  532.     CMA        ;CALC COMPLEMENT
  533.     CMP    D    ;GOOD SECTOR #?
  534.     JZ    RCVDATA    ;YES, GET DATA
  535. ;
  536. ;GOT BAD SECTOR #
  537. ;
  538.     LDA    VSEEFLG    ;VIEWING..
  539.     ORA    A    ;..MODE?
  540.     JZ    RCVBSE    ;..YES, PRT MSG
  541.     LDA    QFLG    ;QUIET..
  542.     ORA    A    ;..MODE?
  543.     JZ    RCVSERR    ;..YES, NO MSG
  544. ;
  545. RCVBSE    CALL    ILPRT    ;PRINT:
  546.     DB    '++BAD SECTOR # IN HDR',CR,LF,0
  547.     JMP    RCVSERR    ;BUMP ERROR CT.
  548. ;
  549. RCVDATA    MOV    A,D    ;GET SECTOR #
  550.     STA    RCVSNO    ;SAVE IT
  551.     MVI    A,1    ;SHOW..
  552.     STA    DATAFLG    ;GETTING DATA
  553.     MVI    C,0    ;INIT CKSUM
  554.     LXI    H,BASE+80H    ;POINT TO BUFFER
  555. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  556.     CALL    RECV    ;GET CHAR
  557.     JC    RCVSTOT    ;TIMEOUT
  558.     MOV    M,A    ;STORE CHAR
  559.     INR    L    ;DONE?
  560.     JNZ    RCVCHR    ;NO, LOOP
  561. ;
  562. ;VERIFY CHECKSUM
  563. ;
  564.     MOV    D,C    ;SAVE CHECKSUM
  565.     XRA    A    ;SHOW..
  566.     STA    DATAFLG    ;..END OF DATA
  567.     MVI    B,1    ;TIMEOUT LEN.
  568.     CALL    RECV    ;GET CHECKSUM
  569.     JC    RCVSTOT    ;TIMEOUT
  570.     CMP    D    ;CHECKSUM OK?
  571.     JNZ    RCVCERR    ;NO, ERROR
  572. ;
  573. ;GOT A SECTOR, IT'S A DUP IF = PREV,
  574. ;    OR OK IF = 1 + PREV SECTOR
  575. ;
  576.     LDA    RCVSNO    ;GET RECEIVED
  577.     MOV    B,A    ;SAVE IT
  578.     LDA    SECTNO    ;GET PREV
  579.     CMP    B    ;PREV REPEATED?
  580.     JZ    RECVACK    ;ACK TO CATCH UP
  581.     INR    A    ;CALC NEXT SECTOR #
  582.     CMP    B    ;MATCH?
  583.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  584.     RET        ;CARRY OFF - NO ERRORS
  585. ;
  586. ;GOT CKSUM
  587. ;
  588. RCVCERR    LDA    VSEEFLG    ;VIEWING..
  589.     ORA    A    ;..MODE?
  590.     JZ    RCVCPR    ;..YES, PRT MSG
  591.     LDA    QFLG    ;QUIET..
  592.     ORA    A    ;..MODE?
  593.     JZ    RCVSERR    ;YES, NO MSG
  594. RCVCPR    CALL    ILPRT
  595.     DB    '++CKSUM++ ',0
  596.     JMP    RCVPRN    ;PRINT ERROR #
  597. ;
  598. ;PREV SECT REPEATED, DUE TO THE LAST ACK
  599. ;BEING GARBAGED.  ACK IT SO SENDER WILL CATCH UP 
  600. ;
  601. RECVACK    CALL    SENDACK    ;SEND THE ACK,
  602.     JMP    RCVSECT    ;GET NEXT BLOCK
  603. ;
  604. ;SEND AN ACK FOR THE SECTOR
  605. ;
  606. SENDACK    MVI    A,ACK    ;GET ACK
  607.     CALL    SEND    ;..AND SEND IT
  608.     RET
  609. ;
  610. ;---->    SENDHDR: SEND THE SECTOR HEADER
  611. ;
  612. ;SEND: (SOH) (BLOCK #) (COMPLEMENTED BLOCK #)
  613. ;
  614. SENDHDR    LDA    QFLG    ;QUIET..
  615.     ORA    A    ;..MODE?
  616.     JZ    SENDHNM    ;YES, SKIP STATUS MSG.
  617.     CALL    ILPRT    ;PRINT:
  618.     DB    'SEND # ',0
  619.     LDA    SECTNO    ;PRINT..
  620.     CALL    HEXO    ;..SECT #
  621.     CALL    CRLF    ;..THEN CR/LF
  622. ;
  623. SENDHNM    MVI    A,SOH    ;SEND..
  624.     CALL    SEND    ;..SOH,
  625.     LDA    SECTNO    ;THEN SEND..
  626.     CALL    SEND    ;..SECTOR #
  627.     LDA    SECTNO    ;THEN SECTOR #
  628.     CMA        ;..COMPLEMENTED..
  629.     CALL    SEND    ;..SECTOR #
  630.     RET        ;FROM SENDHDR
  631. ;
  632. ;---->    SENDSEC: SEND THE DATA SECTOR
  633. ;
  634. ;WHILE SENDING THE SECTOR, THE "DATAFLG" IS SET
  635. ;SUCH THAT IF "V" (VIEW THE FILE) WAS REQUESTED,
  636. ;THE "SHOW" ROUTINE WILL PRINT THE DATA, BUT NOT
  637. ;THE HDR OR CKSUM, OR ANY NON-FATAL MSGS.
  638. ;
  639. SENDSEC    MVI    A,1    ;SHOW NOW AT DATA..
  640.     STA    DATAFLG    ;..FOR VIEW COMMAND
  641.     MVI    C,0    ;INIT CKSUM
  642.     LXI    H,BASE+80H    ;POINT TO BUFFER
  643. SENDC    MOV    A,M    ;GET A CHAR
  644.     CALL    SEND    ;SEND IT
  645.     INR    L    ;POINT TO NEXT CHAR
  646.     JNZ    SENDC    ;LOOP IF <100H
  647.     XRA    A    ;SHOW NOT INTO DATA..
  648.     STA    DATAFLG    ;..FOR VIEW COMMAND
  649.     RET        ;FROM SENDSEC
  650. ;
  651. ;---->    SENDCKS: SEND THE CHECKSUM
  652. ;
  653. SENDCKS    MOV    A,C    ;SEND THE..
  654.     CALL    SEND    ;..CHECKSUM
  655.     RET        ;FROM SENDCKS
  656. ;
  657. ;---->    GETACK: GET THE ACK ON THE SECTOR
  658. ;
  659. ;RETURNS WITH CARRY CLEAR IF ACK RECEIVED.
  660. ;IF AN ACK IS NOT RECEIVED, THE ERROR COUNT
  661. ;IS INCREMENTED, AND IF LESS THAN "ERRLIM",
  662. ;CARRY IS SET AND CONTROL RETURNS.  IF THE
  663. ;ERROR COUNT IS AT "ERRLIM", THE PROGRAM
  664. ;ABORTS IF IN "QUIET" MODE, OR ASKS THE
  665. ;USER FOR QUIT/RETRY IF NOT.
  666. ;
  667. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  668.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  669.     JC    GETATOT    ;TIMED OUT
  670.     CPI    ACK    ;OK? (CARRY OFF IF =)
  671.     RZ        ;YES, RET FROM GETACK
  672.     MOV    B,A    ;SAVE CHAR
  673.     ANI    7FH    ;STRIP PARITY BIT
  674.     CPI    CAN    ;CANCEL TRANSMISSION?
  675.     JZ    ABORT    ;..YES
  676.     LDA    QFLG    ;QUIET..
  677.     ORA    A    ;..MODE?
  678.     JZ    ACKERR    ;..YES, NO MSG
  679.     MOV    A,B    ;GET CHAR
  680.     CALL    HEXO    ;PRINT IN HEX
  681.     CALL    ILPRT    ;PRINT:
  682.     DB    'H RCD, NOT ACK',CR,LF,0
  683. ;
  684. ;TIMEOUT OR ERROR ON ACK - BUMP ERROR COUNT
  685. ;
  686. ACKERR    LDA    ERRCT    ;GET COUNT
  687.     INR    A    ;BUMP IT
  688.     STA    ERRCT    ;SAVE BACK
  689.     CPI    ERRLIM    ;AT LIMIT?
  690.     RC        ;NOT AT LIMIT
  691. ;
  692. ;REACHED ERROR LIMIT
  693. ;
  694.     LDA    VSEEFLG    ;VIEWING..
  695.     ORA    A    ;..FILE?
  696.     JZ    GACKV    ;YES, ASK QUIT/RETRY
  697.     LDA    QFLG    ;QUIET..
  698.     ORA    A    ;..MODE?
  699.     JZ    CSABORT ;..YES, NO MSG
  700. GACKV    CALL    CKQUIT    ;SEE IF WANT TO QUIT
  701.     STC        ;TO SHOW NO ACK
  702.     RZ        ;KEEP ON TRYIN'
  703. CSABORT    CALL    ERXIT
  704.     DB    'CAN''T SEND SECTOR '
  705.     DB    '- ABORTING',CR,LF,'$'
  706. ;
  707. ;TIMEOUT GETTING ACK
  708. ;
  709. GETATOT    LDA    QFLG    ;QUIET..
  710.     ORA    A    ;..MODE?
  711.     JZ    ACKERR    ;YES, NO MSG
  712.     CALL    ILPRT    ;PRINT:
  713.     DB    'TIMEOUT ON ACK',CR,LF,0
  714.     JMP    ACKERR
  715. ; 
  716. ;---->    CKABORT: CHECK FOR LOCAL ABORT
  717. ;
  718. ;IF THE USER WANTS TO CANCEL THE TRANSMISSION,
  719. ;TYPING CTL-X WILL ABORT IT.  NOTE THIS TEST
  720. ;IS NOT MADE IF IN QUIET (NO CONSOLE I/O) MODE.
  721. ;
  722. CKABORT    LDA    VSEEFLG    ;VIEWING?
  723.     ORA    A
  724.     JZ    CKABGO    ;YES, CHECK
  725.     LDA    QFLG    ;SUPPRESSED..
  726.     ORA    A    ;..CONSOLE I/O?
  727.     RZ        ;YES, NO TEST
  728. CKABGO    CALL    STAT    ;KEY PRESSED?
  729.     RZ        ;NOTHING FROM KEYBOARD
  730.     CALL    KEYIN    ;GET DATA
  731.     CPI    CAN    ;TIME TO END?
  732.     RNZ        ;NO, CONTINUE
  733. ; 
  734. ABORT    LXI    SP,STACK
  735. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  736.     CALL    RECV
  737.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  738.     MVI    A,CAN    ;CONTROL X
  739.     CALL    SEND    ;STOP SENDING END
  740. ABORTW    MVI    B,1    ;1 SEC W/O CHARS.
  741.     CALL    RECV
  742.     JNC    ABORTW    ;LOOP UNTIL SENDER DONE
  743.     MVI    A,' '    ;GET A SPACE...
  744.     CALL    SEND    ;TO CLEAR OUT CONTROL X
  745.     CALL    ILPRT    ;EXIT WITH ABORT MSG
  746.     DB    'MODEM PROGRAM CANCELLED',CR,LF,0
  747.     JMP    CKDIS    ;CHECK FOR DISCONN.
  748. ;
  749. ;---->    INCRSNO: INCREMENT SECTOR #
  750. ;
  751. INCRSNO    LDA    SECTNO    ;INCR..
  752.     INR    A    ;..SECT..
  753.     STA    SECTNO    ;..NUMBER
  754.     RET
  755. ;
  756. ;---->    ERASFIL: ERASE THE INCOMING FILE.
  757. ;
  758. ;IF IT EXISTS, ASK IF IT MAY BE ERASED.
  759. ;
  760. ERASFIL    LXI    D,FCB    ;POINT TO CTL BLOCK
  761.     MVI    C,SRCHF ;SEE IF IT..
  762.     CALL    BDOS    ;..EXISTS
  763.     INR    A    ;FOUND?
  764.     RZ        ;..NO, RETURN
  765.     CALL    ILPRT    ;PRINT:
  766.     DB    '++FILE EXISTS, TYPE Y TO ERASE: ',0
  767.     CALL    KEYIN    ;GET CHAR
  768.     PUSH    PSW
  769.     CALL    TYPE    ;ECHO
  770.     CALL    CRLF    ;BACK TO START OF LINE
  771.     POP    PSW
  772.     ANI    5FH    ;MAKE UPPER CASE
  773.     CPI    'Y'    ;WANT ERASED?
  774.     JNZ    CKDIS    ;QUIT IF NOT ERASE
  775. ;
  776. ;ERASE OLD FILE
  777. ;
  778.     LXI    D,FCB    ;POINT TO FCB
  779.     MVI    C,ERASE    ;GET BDOS FNC
  780.     CALL    BDOS    ;DO THE ERASE
  781.     RET        ;FROM "ERASFIL"
  782. ;
  783. ;---->    MAKEFIL: MAKES THE FILE TO BE RECEIVED
  784. ;
  785. MAKEFIL    LXI    D,FCB    ;POINT TO FCB
  786.     MVI    C,MAKE    ;GET BDOS FNC
  787.     CALL    BDOS    ;TO THE MAKE
  788.     INR    A    ;FF=BAD?
  789.     RNZ        ;OPEN OK
  790. ;DIRECTORY FULL - CAN'T MAKE FILE
  791.     CALL    ERXIT
  792.     DB    '++ERROR - CAN''T MAKE FILE',CR,LF
  793.     DB    '++DIRECTORY MUST BE FULL',CR,LF,'$'
  794. ;
  795. ;---->    OPENFIL: OPENS THE FILE TO BE SENT
  796. ;
  797. OPENFIL    LXI    D,FCB    ;POINT TO FILE
  798.     MVI    C,OPEN    ;GET FUNCTION
  799.     CALL    BDOS    ;OPEN IT
  800.     INR    A    ;OPEN OK?
  801.     JNZ    OPENOK    ;..YES
  802.     CALL    ERXIT    ;..NO, ABORT
  803.     DB    'CAN''T OPEN FILE$'
  804. ;
  805. OPENOK    CALL    ILPRT    ;PRINT:
  806.     DB    'FILE OPEN, EXTENT LENGTH: ',0
  807.     LDA    FCB+15    ;GET # SECTORS
  808.     CALL    HEXO    ;PRINT IN HEX
  809.     MVI    A,'H'
  810.     CALL    TYPE    ;PRINT 'H' AFTER NUMBER
  811.     CALL    CRLF    ;..THEN CRLF
  812.     RET
  813. ;
  814. ;---->    CLOSFIL: CLOSES THE RECEIVED FILE
  815. ;
  816. CLOSFIL    LXI    D,FCB    ;POINT TO FILE
  817.     MVI    C,CLOSE    ;GET FUNCTION
  818.     CALL    BDOS    ;CLOSE IT
  819.     INR    A    ;CLOSE OK?
  820.     RNZ        ;..YES, RETURN
  821.     CALL    ERXIT    ;..NO, ABORT
  822.     DB    'CAN''T CLOSE FILE$'
  823. ;
  824. ;---->    RDSECT: READS A SECTOR
  825. ;
  826. ;FOR SPEED, THIS ROUTINE BUFFERS UP 16
  827. ;SECTORS AT A TIME.
  828. ;
  829. RDSECT    LDA    SECINBF    ;GET # SECT IN BUFF.
  830.     DCR    A    ;DECREMENT..
  831.     STA    SECINBF    ;..IT
  832.     JM    RDBLOCK    ;EXHAUSTED?  NEED MORE.
  833.     LHLD    SECPTR    ;GET POINTER
  834.     LXI    D,BASE+80H    ;TO DATA
  835.     CALL    MOVE128    ;MOVE TO BUFFER
  836.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  837.     RET        ;FROM "READSEC"
  838. ;
  839. ;BUFFER IS EMPTY - READ IN ANOTHER BLOCK OF 16
  840. ;
  841. RDBLOCK    LDA    EOFLG    ;GET EOF FLAG
  842.     CPI    1    ;IS IT SET/
  843.     STC        ;TO SHOW EOF
  844.     RZ        ;GOT EOF
  845.     MVI    C,0    ;SECTORS IN BLOCK
  846.     LXI    D,DBUF    ;TO DISK BUFFER
  847. RDSECLP    PUSH    B
  848.     PUSH    D
  849.     MVI    C,STDMA    ;SET DMA..
  850.     CALL    BDOS    ;..ADDR
  851.     LXI    D,FCB
  852.     MVI    C,READ
  853.     CALL    BDOS
  854.     POP    D
  855.     POP    B
  856.     ORA    A    ;READ OK?
  857.     JZ    RDSECOK    ;YES
  858.     DCR    A    ;EOF?
  859.     JZ    REOF    ;GOT EOF
  860. ;
  861. ;READ ERROR
  862. ;
  863.     CALL    ERXIT
  864.     DB    '++FILE READ ERROR$'
  865. ;
  866. RDSECOK    LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  867.     DAD    D    ;...TO NEXT BUFF
  868.     XCHG        ;BUFF TO DE
  869.     INR    C    ;MORE SECTORS?
  870.     MOV    A,C    ;GET COUNT
  871.     CPI    16    ;DONE?
  872.     JZ    RDBFULL    ;..YES, BUFF IS FULL
  873.     JMP    RDSECLP    ;READ MORE
  874. ;
  875. REOF    MVI    A,1
  876.     STA    EOFLG    ;SET EOF FLAG
  877.     MOV    A,C
  878. ;
  879. ;BUFFER IS FULL, OR GOT EOF
  880. ;
  881. RDBFULL    STA    SECINBF    ;STORE SECTOR COUNT
  882.     LXI    H,DBUF    ;INIT BUFFER..
  883.     SHLD    SECPTR    ;..POINTER
  884.     LXI    D,BASE+80H    ;RESET..
  885.     MVI    C,STDMA    ;..DMA..
  886.     CALL    BDOS    ;..ADDR
  887.     JMP    RDSECT    ;PASS SECT TO CALLER
  888. ;
  889. ;---->    WRSECT: WRITE A SECTOR
  890. ;
  891. ;WRITES THE SECTOR INTO A BUFFER.  WHEN 16
  892. ;HAVE BEEN WRITTEN, WRITES THE BLOCK TO DISK.
  893. ;
  894. ;ENTRY POINT "WRBLOCK" FLUSHES THE BUFFER AT EOF.
  895. ;
  896. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  897.     XCHG        ;TO DE FOR MOVE
  898.     LXI    H,BASE+80H    ;FROM HERE
  899.     CALL    MOVE128    ;MOVE TO BUFFER
  900.     XCHG        ;SAVE NEXT..
  901.     SHLD    SECPTR    ;..BLOCK POINTER
  902.     LDA    SECINBF    ;BUMP THE..
  903.     INR    A    ;..SECTOR #..
  904.     STA    SECINBF    ;..IN THE BUFF
  905.     CPI    16    ;HAVE WE 16?
  906.     RNZ        ;NO, RETURN
  907. ;
  908. ;---->    WRBLOCK: WRITES A BLOCK TO DISK
  909. ;
  910. WRBLOCK    LDA    SECINBF    ;# SECT IN BUFFER
  911.     ORA    A    ;0 MEANS END OF FILE
  912.     RZ        ;NONE TO WRITE
  913.     MOV    C,A    ;SAVE COUNT
  914.     LXI    D,DBUF    ;POINT TO DISK BUFF
  915. DKWRLP    PUSH    H
  916.     PUSH    D
  917.     PUSH    B
  918.     MVI    C,STDMA    ;SET DMA
  919.     CALL    BDOS    ;TO BUFFER
  920.     LXI    D,FCB    ;THEN WRITE
  921.     MVI    C,WRITE    ;..THE..
  922.     CALL    BDOS    ;..BLOCK
  923.     POP    B
  924.     POP    D
  925.     POP    H
  926.     ORA    A
  927.     JNZ    WRERR    ;OOPS, ERROR
  928.     LXI    H,80H    ;LENGTH OF 1 SECT
  929.     DAD    D    ;HL= NEXT BUFF
  930.     XCHG        ;TO DE FOR SETDMA
  931.     DCR    C    ;MORE SECTORS?
  932.     JNZ    DKWRLP    ;..YES, LOOP
  933.     XRA    A    ;GET A ZERO
  934.     STA    SECINBF    ;RESET # OF SECTORS
  935.     LXI    H,DBUF    ;RESET BUFFER..
  936.     SHLD    SECPTR    ;..POINTER
  937. RSDMA    LXI    D,BASE+80H ;RESET..
  938.     MVI    C,STDMA    ;..DMA..
  939.     CALL    BDOS    ;..ADDR
  940.     RET
  941. ;
  942. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  943.     MVI    C,CAN    ;CANCEL..
  944.     CALL    SEND    ;..SENDER
  945.     CALL    ERXIT    ;EXIT W/MSG:
  946.     DB    '++ERROR WRITING FILE',CR,LF,'$'
  947. ;
  948. ;---->    RECV: RECEIVE A CHARACTER
  949. ;
  950. ;TIMEOUT TIME IS IN B, IN SECONDS.  ENTRY VIA
  951. ;"RECVDG" DELETES GARBAGE CHARACTERS ON THE
  952. ;LINE.  FOR EXAMPLE, HAVING JUST SENT A SECTOR,
  953. ;CALLING RECVDG WILL DELETE ANY LINE-NOISE-INDUCED
  954. ;CHARACTERS "LONG" BEFORE THE ACK/NAK WOULD
  955. ;BE RECEIVED.
  956. ;
  957. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  958. ;
  959. RECV    PUSH    D    ;SAVE
  960. ;
  961. ;
  962. MSEC    LXI    D,50000    ;1 SEC DCR COUNT
  963.     CALL    CKABORT    ;CHECK FOR EXIT REQUEST
  964. mwti:    di
  965.     out    0
  966.     mvi    a,0
  967.     sta    0ef08h
  968.     lda    2a00h
  969.     sta    xyz
  970.     out    1
  971.     mvi    a,1
  972.     sta    0ef08h
  973.     ei
  974.     lda    xyz
  975.     ani    01h
  976.     cpi    00h
  977.     jnz    mchar
  978.     DCR    E    ;COUNT..
  979.     JNZ    MWTI    ;..DOWN..
  980.     DCR    D    ;..FOR..
  981.     JNZ    MWTI    ;..TIMEOUT
  982.     DCR    B    ;MORE SECONDS?
  983.     JNZ    MSEC    ;YES, WAIT
  984. ;
  985. ;MODEM TIMED OUT RECEIVING
  986. ;
  987.     POP    D    ;RESTORE D,E
  988.     STC        ;CARRY SHOWS TIMEOUT
  989.     RET
  990. ;
  991. ;GOT CHAR FROM MODEM
  992. ;
  993. mchar:    di
  994.     out    0
  995.     mvi    a,0
  996.     sta    0ef08h
  997.     lda    2a01h
  998.     sta    xyz    
  999.     out    1
  1000.     mvi    a,1
  1001.     sta    0ef08h
  1002.     ei
  1003.     lda    xyz
  1004.     POP    D    ;RESTORE DE
  1005. ;
  1006. ;CALC CHECKSUM
  1007. ;
  1008.     PUSH    PSW    ;SAVE THE CHAR
  1009.     ADD    C    ;ADD TO CHECKSUM
  1010.     MOV    C,A    ;SAVE CHECKSUM
  1011. ;
  1012. ;CHECK IF MONITORING REC'D DATA
  1013. ;
  1014.     LDA    RSEEFLG    ;SEE RECEIVED..
  1015.     ORA    A    ;..DATA?
  1016.     JZ    MONIN    ;..YES
  1017. ;
  1018. ;CHECK IF "VIEWING" AND THIS IS A DATA CHAR
  1019. ;
  1020.     LDA    VSEEFLG    ;VIEWING..
  1021.     ORA    A    ;..DATA?
  1022.     JNZ    NOMONIN    ;..NO
  1023. ;
  1024. ;"VIEW" REQUESTED.  SHOW THE CHAR IT IS DATA
  1025. ;
  1026.     LDA    DATAFLG    ;GET DATA FLAG
  1027.     ORA    A    ;TEST IT
  1028.     JZ    NOMONIN    ;..OFF, NOT DATA
  1029. MONIN    POP    PSW    ;..IS DATA,
  1030.     PUSH    PSW    ;GET IT,
  1031.     CALL    SHOW    ;..AND SHOW IT
  1032. NOMONIN    POP    PSW    ;RESTORE CHAR
  1033.     ORA    A    ;CARRY OFF: NO ERROR
  1034.     RET        ;FROM "RECV"
  1035. ;
  1036. ;---->    SEND: SEND A CHARACTER TO THE MODEM
  1037. ;
  1038. SEND    PUSH    PSW    ;SAVE THE CHAR
  1039. ;
  1040. ;CHECK IF MONITORING SENT DATA
  1041. ;
  1042.     LDA    SSEEFLG    ;CHECK IF MONITORING..
  1043.     ORA    A    ;..SENT DATA
  1044.     JZ    MONOUT    ;..YES
  1045. ;
  1046. ;CHECK IF "VIEWING" THE FILE
  1047. ;
  1048.     LDA    VSEEFLG    ;GET VIEW FLAG
  1049.     ORA    A    ;TEST IT
  1050.     JNZ    NOMONOT    ;NO
  1051.     LDA    DATAFLG    ;IS THIS
  1052.     ORA    A    ;..DATA?
  1053.     JZ    NOMONOT    ;..NO.
  1054. MONOUT    POP    PSW    ;GET THE CHAR
  1055.     PUSH    PSW    ;SAVE IT
  1056.     CALL    SHOW    ;SHOW IT
  1057. NOMONOT    POP    PSW    ;RESTORE CHAR
  1058.     PUSH    PSW    ;SAVE IT
  1059.     ADD    C    ;CALC CKSUM
  1060.     MOV    C,A    ;SAVE CKSUM
  1061. sendw:    di
  1062.     out    0    
  1063.     mvi    a,0
  1064.     sta    0ef08h
  1065.     lda    2a00h
  1066.     sta    xyz
  1067.     out    1
  1068.     mvi    a,1
  1069.     sta    0ef08h
  1070.     ei
  1071.     lda    xyz
  1072.     ani    02h
  1073.     cpi    00h
  1074.     jz    sendw
  1075.     POP    PSW    ;GET CHAR
  1076. acsend:    sta    xyz
  1077.     di
  1078.     out    0
  1079.     mvi    a,0
  1080.     sta    0ef08h
  1081.     lda    xyz
  1082.     sta    2a01h
  1083.     out    1
  1084.     mvi    a,1
  1085.     sta    0ef08h
  1086.     ei
  1087.     RET        ;FROM "SEND"
  1088. ;
  1089. ;---->    WAITNAK: WAITS FOR INITIAL NAK
  1090. ;
  1091. ;TO ENSURE NO DATA IS SENT UNTIL THE RECEIVING
  1092. ;PROGRAM IS READY, THIS ROUTINE WAITS FOR THE
  1093. ;THE FIRST TIMEOUT-NAK FROM THE RECEIVER.
  1094. ;(E) CONTAINS THE # OF SECONDS TO WAIT.
  1095. ;
  1096. WAITNAK    LDA    VSEEFLG    ;VIEWING?
  1097.     ORA    A
  1098.     JZ    WAITNPR    ;PRINT MSG
  1099.     LDA    QFLG    ;QUIET..
  1100.     ORA    A    ;..MODE?
  1101.     JZ    WAITNLP    ;YES, SKIP MSG
  1102. WAITNPR    CALL    ILPRT    ;PRINT:
  1103.     DB    'AWAITING INITIAL NAK',CR,LF,0
  1104. WAITNLP    CALL    CKABORT    ;ABORT IF LOCAL CTL-X
  1105.     MVI    B,1    ;TIMEOUT DELAY
  1106.     CALL    RECV    ;DID WE GET..
  1107.     CPI    NAK    ;..A NAK?
  1108.     RZ        ;YES, SEND BLOCK
  1109.     ANI    7FH    ;STRIP PARITY BIT
  1110.     CPI    CAN    ;CTL-X FROM REMOTE?
  1111.     JZ    ABORT    ;..YES, ABORT
  1112.     DCR    E    ;80 TRIES?
  1113.     JZ    ABORT    ;YES, ABORT
  1114.     JMP    WAITNLP    ;NO, LOOP
  1115. ;
  1116. ;---->    INITADR: INIT'S CP/M BDOS ADDRESSES
  1117. ;
  1118. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  1119. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  1120. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  1121. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  1122. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  1123. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  1124. ;
  1125. INITADR    LHLD    BASE+1    ;GET WARM BOOT ADDR
  1126.     LXI    D,3    ;LENGTH OF A 'JMP'
  1127.     DAD    D    ;TO CONSOLE STAT
  1128.     SHLD    VSTAT+1    ;MODIFY CALL
  1129.     DAD    D    ;TO CONSOLE IN
  1130.     SHLD    VKEYIN+1 ;MODIFY CALL
  1131.     DAD    D    ;TO CONSOLE OUT
  1132.     SHLD    VTYPE+1    ;MODIFY CALL
  1133.     RET
  1134. ;
  1135. ;---->    PROCOPT: PROCESS COMMAND OPTIONS
  1136. ; 
  1137. ;1) SAVES THE PRIMARY OPTION IN 'OPTION';
  1138. ;2) SCANS THE SUB-OPTION CHARACTERS, AND FOR
  1139. ;EACH FOUND, ZEROS THE APPROPRIATE ENTRY IN
  1140. ;THE OPTION TABLE.  FOR EXAMPLE, IF 'D' IS 
  1141. ;CODED (DISCONNECT) THEN THE 'D' STORED AT
  1142. ;'DISCFLG' IS SET TO 0 SO IT CAN BE TESTED
  1143. ;LATER.
  1144. ;
  1145. PROCOPT    LXI    D,FCB+1    ;TO PRIMARY OPT.
  1146.     LDAX    D    ;GET PRIMARY
  1147.     STA    OPTION    ;SAVE IT
  1148. ;
  1149. OPTLP    INX    D    ;TO SECONDARY OPTION
  1150.     LDAX    D    ;GET CHAR
  1151. ;
  1152. ;IF YOU MOD THIS PROGRAM FOR >7 OPTIONS,
  1153. ;YOU MUST CHANGE THE FOLLOWING, SINCE
  1154. ;THERE WON'T BE A ' ' AFTER THE OPTION
  1155. ;IF A BAUD RATE WAS SPECIFIED.
  1156. ;
  1157.     CPI    ' '    ;NO MORE OPT'NS?
  1158.     JZ    ENDOPT    ;..YES
  1159. ;SET THE APPROP. OPT: STORE 0 IN IT
  1160.     LXI    H,OPTBL    ;HL = ADDR OF 'OAQDSRV'
  1161.     MVI    B,OPTBE-OPTBL ;OPT TABLE LEN
  1162. OPTCK    CMP    M    ;FOUND THE OPTION?
  1163.     JNZ    OPTNO    ;NO, DON'T SET IT
  1164.     MVI    M,0    ;SET THE OPTION
  1165.     JMP    OPTLP    ;GET NEXT OPTION
  1166. OPTNO    INX    H    ;TO NEXT
  1167.     DCR    B    ;MORE?
  1168.     JNZ    OPTCK
  1169. ;OPTION NOT IN TABLE
  1170.     JMP    BADOPT    ;SHOW BAD SUB OPTION
  1171. ;
  1172. ;IF "VIEW" WAS ASKED FOR, SET QUIET FLAG
  1173. ;
  1174. ENDOPT    LDA    VSEEFLG    ;VIEW..
  1175.     ORA    A    ;..ASKED FOR?
  1176.     RNZ        ;..NO, RET FROM 'PROCOPT'
  1177.     STA    QFLG    ;YES, NO HDR/CKSUM PRT
  1178.     RET        ;FROM 'PROCOPT'
  1179. ;
  1180. ;DONE - CLOSE UP SHOP
  1181. ;
  1182. DONE    LDA    VSEEFLG    ;VIEWING?
  1183.     ORA    A
  1184.     JZ    DONETC    ;SHOW MSG
  1185.     LDA    QFLG    ;QUIET
  1186.     ORA    A    ;..MODE?
  1187.     JZ    DONECTE    ;YES, CK TERM/ECHO
  1188. DONETC    CALL    ILPRT
  1189.     DB    CR,LF,'TRANSFER COMPLETE' 
  1190.     DB    CR,LF,0
  1191. ;
  1192. ;CHECK IF TERMINAL OR ECHO SUB COMMAND
  1193. ;WAS SPECIFIED
  1194. ;
  1195. DONECTE    LDA    TERMFLG    ;TERM?
  1196.     ORA    A
  1197.     JZ    TERM    ;..YES
  1198.     LDA    ECHOFLG    ;ECHO?
  1199.     ORA    A
  1200.     JZ    TRMECHO    ;..YES
  1201. ;
  1202. ;FALL INTO 'CKDIS'
  1203. ;
  1204. ;---->    CKDIS: CHECK IF DISCONNECT REQUESTED
  1205. ;
  1206. ;THIS ROUTINE IS JUMPED TO AT THE END OF
  1207. ;PROCESSING, AND DISCONNECTS THE PHONE IF
  1208. ;'D' WAS SPECIFIED AS A SUB-OPTION.
  1209. ;
  1210. CKDIS    LDA    DISCFLG    ;CHECK 'D' FLAG
  1211. disconn:    nop
  1212.     JMP    EXIT
  1213. ;
  1214. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  1215. ;OFF HOOK
  1216. ;
  1217. ;
  1218. ;---->    INITMOD: INITIALIZES THE MODEM
  1219. ;
  1220. ;THIS ROUTINE IS USED TO INITIALIZE SERIAL
  1221. ;BOARDS, OR SETUP S-100 MODEM BOARDS.
  1222. ;JUST RETURNS IF NO INITIALIZATION REQUIRED.
  1223. ;
  1224. INITMOD:
  1225. ;
  1226. ;
  1227.     RET        ;**THIS MUST BE HERE**
  1228. ;
  1229. ;---->    MOVEFCB: MOVES FCB(2) TO FCB
  1230. ;
  1231. ;I ATTEMPTED TO MAKE THE MODEM COMMAND 'NATURAL',
  1232. ;I.E. MODEM SEND FILENAME (MODEM S FN.FT) RATHER
  1233. ;THAT MODEM FILENAME SEND (MODEM FN.FT S) SO THIS
  1234. ;ROUTINE MOVES THE FILENAME FROM THE SECOND FCB
  1235. ;TO THE FIRST
  1236. ;
  1237. MOVEFCB    LXI    H,FCB+16 ;FROM
  1238.     LXI    D,FCB    ;TO
  1239.     MVI    B,16    ;LEN
  1240.     CALL    MOVE    ;DO THE MOVE
  1241.     XRA    A    ;GET 0
  1242.     STA    FCBSNO    ;ZERO SECTOR #
  1243.     STA    FCBEXT    ;..AND EXTENT
  1244.     RET
  1245. ;
  1246. ;---->    SHOW: SHOWS CHAR SENT/RECEIVED
  1247. ;
  1248. ;CR, LF, AND TAB ARE SHOWN.  ALL OTHER
  1249. ;NON-PRINTABLE CHARACTERS ARE SHOWN IN
  1250. ;HEX AS (XX)
  1251. ;
  1252. SHOW    CPI    LF    ;LF?
  1253.     JZ    CTYPE    ;..YES, TYPE IT
  1254.     CPI    CR    ;CR?
  1255.     JZ    CTYPE    ;..YES, TYPE IT
  1256.     CPI    09    ;TAB
  1257.     JZ    CTYPE    ;..YES, TYPE IT
  1258.     CPI    ' '    ;CTL-CHR?
  1259.     JC    SHOWHEX    ;YES, SHOW IN HEX
  1260.     CPI    7FH    ;DEL?
  1261.     JC    CTYPE    ;NO, TYPE THE CHAR
  1262. SHOWHEX    PUSH    PSW    ;SAVE THE CHAR
  1263.     MVI    A,'('    ;TYPE..
  1264.     CALL    CTYPE    ;..'('
  1265.     POP    PSW    ;THEN..
  1266.     CALL    HEXO    ;..THE CHAR
  1267.     MVI    A,')'    ;THEN..
  1268.     JMP    CTYPE    ;..')' AND RETURN.
  1269. ;
  1270. ;---->    CTYPE: TYPES VIA CP/M SO TABS ARE EXPANDED
  1271. ;
  1272. CTYPE    PUSH    B    ;SAVE..
  1273.     PUSH    D    ;..ALL..
  1274.     PUSH    H    ;..REGS
  1275.     MOV    E,A    ;CHAR TO E
  1276.     MVI    C,WRCON    ;GET BDOS FNC
  1277.     CALL    BDOS    ;PRIN THE CHR
  1278.     POP    H    ;RESTORE..
  1279.     POP    D    ;..ALL..
  1280.     POP    B    ;..REGS
  1281.     RET        ;FROM "CTYPE"
  1282. ;
  1283. CRLF    MVI    A,CR
  1284.     CALL    TYPE
  1285.     MVI    A,LF
  1286. ;
  1287. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  1288. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  1289. ;SO SAVE THEM ALL.
  1290. ;
  1291. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  1292. ;TESTS.
  1293. ;
  1294. TYPE    PUSH    PSW    ;SAVE CHAR
  1295.     PUSH    B    ;AND OTHER REGISTERS
  1296.     PUSH    D
  1297.     PUSH    H
  1298.     MOV    C,A    ;FOR BIOS
  1299. VTYPE    CALL    $-$    ;MODIFIED AT INIT
  1300.     POP    H    ;RESTORE REGISTERS
  1301.     POP    D
  1302.     POP    B
  1303.     POP    PSW    ;..AND CHAR
  1304.     RET        ;FROM "TYPE"
  1305. ;
  1306. ;---->  STAT: KEYBOARD STATUS
  1307. ;
  1308. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1309. ;CBIOS CLOBBERS THEM.
  1310. ;
  1311. STAT    PUSH    B
  1312.     PUSH    D
  1313.     PUSH    H
  1314. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  1315.     POP    H
  1316.     POP    D
  1317.     POP    B
  1318.     ORA    A    ;0 => NOT READY
  1319.     RET
  1320. ;
  1321. ;---->  KEYIN: KEYBOARD INPUT
  1322. ;
  1323. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1324. ;CBIOS CLOBBERS THEM.
  1325. ;
  1326. KEYIN    PUSH    B
  1327.     PUSH    D
  1328.     PUSH    H
  1329. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  1330.     POP    H
  1331.     POP    D
  1332.     POP    B
  1333.     ANI    7FH    ;STRIP PARITY IF THERE
  1334.     RET        ;FROM KEYIN
  1335. ;
  1336. ;---->  HEXO: HEX OUTPUT
  1337. ;
  1338. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1339.     RAR        ;RIGHT..
  1340.     RAR        ;..JUSTIFY..
  1341.     RAR        ;..LEFT..
  1342.     RAR        ;..DIGIT..
  1343.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1344.     POP    PSW    ;RESTORE RIGHT
  1345. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1346.     CPI    10    ;IS IS <10?
  1347.     JC    ISNUM    ;YES, NOT ALPHA
  1348.     ADI    7    ;ADD ALPHA BIAS
  1349. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1350.     JMP    TYPE    ;..THEN TYPE IT
  1351. ;
  1352. ;---->    CKQUIT: QUIT/RETRY AFTER MULTIPLE ERRS.
  1353. ;
  1354. ;RETURNS W/ ZERO SET IF "RETRY" ASKED FOR
  1355. ;
  1356. CKQUIT    XRA    A    ;ZERO..
  1357.     STA    ERRCT    ;..ERROR COUNT
  1358.     CALL    ILPRT    ;PRINT:
  1359.     DB    'MULTIPLE ERRORS ENCOUNTERED.  '
  1360.     DB    'TYPE Q TO QUIT, R TO RETRY: ',0
  1361.     CALL    KEYIN    ;QUIT/RETRY
  1362.     PUSH    PSW
  1363.     CALL    TYPE
  1364.     CALL    CRLF
  1365.     POP    PSW
  1366.     ANI    5FH    ;MAKE UPPER CASE
  1367.     CPI    'R'    ;RETRY?
  1368.     RZ        ;'KEEP ON TRUCKIN'
  1369.     CPI    'Q'    ;QUIT?
  1370.     JNZ    CKQUIT    ;NO, ASK AGAIN
  1371.     ORA    A    ;SET NON-ZERO
  1372.     RET
  1373. ;
  1374. ;---->    ILPRT: INLINE PRINT OF MSG
  1375. ;
  1376. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  1377. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  1378. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  1379. ;
  1380. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1381. ILPLP    MOV    A,M    ;GET CHAR
  1382.     ORA    A    ;END OF MSG?
  1383.     JZ    ILPRET    ;..YES, RETURN
  1384.     CPI    1    ;PAUSE?
  1385.     JZ    ILPAUSE    ;..YES
  1386.     CALL    CTYPE    ;TYPE THE MSG
  1387. ILPNEXT    INX    H    ;TO NEXT CHAR
  1388.     JMP    ILPLP    ;LOOP
  1389. ;
  1390. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  1391. ;    SCROLL OFF OF VIDEO SCREENS
  1392. ;
  1393. ILPAUSE    CALL    ILPRT    ;PRINT:
  1394.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  1395.     DB    CR,LF,0
  1396.     CALL    KEYIN    ;GET ANY CHAR
  1397.     CPI    'C'-40H    ;REBOOT?
  1398.     JZ    EXIT    ;YES.
  1399.     JMP    ILPNEXT    ;LOOP
  1400. ;
  1401. ILPRET    XTHL        ;RESTORE HL
  1402.     RET        ;PAST MSG
  1403. ;
  1404. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  1405. ;
  1406. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  1407. ;NO REGISTERS SAVED.
  1408. ;
  1409. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  1410.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  1411. ;
  1412. ;---->    ERXIT: EXIT PRINTING MSG FOLLOWING CALL
  1413. ;
  1414. ERXIT    POP    D    ;GET MESSAGE
  1415.     CALL    PRTMSG    ;PRINT IT
  1416.     CALL    CKDIS    ;DISCONNECT?
  1417. ;
  1418. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1419.     SPHL        ;RESTORE IT
  1420.     RET        ;--EXIT-- TO CP/M
  1421. ;
  1422. ;MOVE 128 CHARACTERS
  1423. ;
  1424. MOVE128    MVI    B,128    ;SET MOVE COUNT
  1425. ;
  1426. ;MOVE FROM (HL) TO (DE) LENGTH IN (B)
  1427. ;
  1428. MOVE    MOV    A,M    ;GET A CHAR
  1429.     STAX    D    ;STORE IT
  1430.     INX    H    ;TO NEXT "FROM"
  1431.     INX    D    ;TO NEXT "TO"
  1432.     DCR    B    ;MORE?
  1433.     JNZ    MOVE    ;..YES, LOOP
  1434.     RET        ;..NO, RETURN
  1435. ;    ----------------
  1436. OPTION    DB    0    ;PRIMARY OPTION
  1437. ;
  1438. ;DATAFLG IS USED BY THE "V" SUBCOMMAND -
  1439. ;IT IS 0 WHEN A HEADER OR CKSUM IS BEING
  1440. ;SENT/RCD, AND 1 IF "VIEWABLE" DATA (THE
  1441. ;SECTOR ITSELF) IS
  1442. ;
  1443. DATAFLG    DB    0    ;AT HEADER, FIRST
  1444. ;
  1445. ;
  1446. ;SUB-OPTION TABLE.  IF AN OPTION IS IN EFFECT,
  1447. ;    THE CHARACTER IS SET TO BINARY 0
  1448. ;
  1449. OPTBL    EQU    $
  1450. ANSWFLG    DB    'A'    ;ANSWER MODE
  1451. DISCFLG    DB    'D'    ;DISCONNECT WHEN DONE
  1452. ECHOFLG    DB    'E'    ;TO ECHO AFTER XFER
  1453. ORIGFLG    DB    'O'    ;ORIGINATE MODE
  1454. QFLG    DB    'Q'    ;QUIET TRANSFER (NO MSGS)
  1455. RSEEFLG    DB    'R'    ;SEE WHAT'S RECEIVED
  1456. SSEEFLG    DB    'S'    ;SEE WHAT'S SENT
  1457. TERMFLG    DB    'T'    ;TO TERM AFTER XFER
  1458. VSEEFLG    DB    'V'    ;VIEW MESSAGES (NO HDR, ETC)
  1459. OPTBE    EQU    $    ;END OF OPTIONS
  1460. ;
  1461. RCVSNO    DB    0    ;SECT # RECEIVED
  1462. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1463. ERRCT    DB    0    ;ERROR COUNT
  1464. HOLDD    DB    86H    ;HOLD AREA - LAST DC HAYES CONT CHAR.
  1465. ;FOLLOWING 3 USED BY DISK BUFFERING ROUTINES
  1466. xyz    db    0
  1467. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1468. SECPTR    DW    DBUF
  1469. SECINBF    DB    0    ;# OF SECTORS IN BUFFER
  1470.     DS    60    ;STACK AREA
  1471. STACK    DS    2    ;STACK POINTER
  1472. ;
  1473. ;16 SECTOR DISK BUFFER (OVERLAYS HELP MSGS)
  1474. ;
  1475. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1476. ;
  1477. ;INVALID COMMAND
  1478. ;
  1479. BADOPT    CALL    TYPE
  1480.     CALL    ILPRT    ;EXIT W/ERROR
  1481.     DB    ': INVALID OPTION ON MODEM '
  1482.     DB    'COMMAND - ',CR,LF
  1483.  DB 'PRESS RETURN FOR HELP, CTL-C IF NOT',CR,LF,1,0
  1484. ;
  1485. HELP    CALL    ILPRT
  1486.  DB 'Format for command is:',cr,lf,cr,lf
  1487.  DB 'MODEM # FILENAME',CR,LF,CR,LF
  1488.  DB 'Where # is a 1 character primary option,',cr,lf
  1489.  DB ' which may be followed by sub-options,',cr,lf
  1490.  DB ' and by ".xxx" to set baud rate to xxx'
  1491.  DB cr,lf,cr,lf,1
  1492.  DB 'Primary Options:',cr,lf
  1493.  DB '    S to send a file',cr,lf
  1494.  DB '    R to receive a file',cr,lf
  1495.  DB '    T to act as a terminal',cr,lf
  1496.  DB '    E to act as a computer (echo data)',cr,lf
  1497.  DB '    H to print this help file'
  1498.  DB cr,lf,cr,lf,1
  1499.  DB 'Secondary options:',cr,lf
  1500.  DB '    T go to terminal mode after file xfer',cr,lf
  1501.  DB '    E go to echo mode after file xfer',cr,lf
  1502.  DB '    Q quiet mode - no status msgs',cr,lf
  1503.  DB '    R show chars received',cr,lf
  1504.  DB '    S show chars sent',cr,lf
  1505.  DB '    V view file sent/received (no status)',cr,lf
  1506.  DB CR,LF,'FOR EXAMPLES, TYPE: MODEM X',cr,lf,0
  1507.     JMP    EXIT
  1508. ;
  1509. EXAM    CALL    ILPRT
  1510.  DB 'Send another file:',CR,LF
  1511.  DB '    MODEM S fn.ft',cr,lf
  1512. JMP EXIT
  1513. ;
  1514. ; BDOS EQUATES (VERSION 2)
  1515. ;
  1516. RDCON    EQU    1
  1517. WRCON    EQU    2
  1518. PRINT    EQU    9
  1519. CONST    EQU    11    ;CONSOLE STAT
  1520. OPEN    EQU    15    ;0FFH=NOT FOUND
  1521. CLOSE    EQU    16    ;    "    "
  1522. SRCHF    EQU    17    ;    "    "
  1523. SRCHN    EQU    18    ;    "    "
  1524. ERASE    EQU    19    ;NO RET CODE
  1525. READ    EQU    20    ;0=OK, 1=EOF
  1526. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1527. MAKE    EQU    22    ;0FFH=BAD
  1528. REN    EQU    23    ;0FFH=BAD
  1529. STDMA    EQU    26    ;SET DMA
  1530. BDOS    EQU    BASE+5
  1531. REIPL    EQU    BASE
  1532. FCB    EQU    BASE+5CH    ;SYSTEM FCB
  1533. FCBEXT    EQU    FCB+12        ;FILE EXTENT
  1534. FCBSNO    EQU    FCB+32        ;SECTOR #
  1535. FCB2    EQU    BASE+6CH    ;SECOND FCB
  1536.     END
  1537.