home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / sigmv084.ark / MBOOT3-A.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  7KB  |  465 lines
  1. ;
  2. ; MBOOT.ASM ver 3.1
  3. ; (revised 8 Jun 82 by Bill Bolton)
  4. ;
  5. ;MODEM BOOT PROGRAM by Keith Petersen, W8SDZ.
  6. ;Thanks to John Taylor for idea of incorporating
  7. ;simple terminal routine.  Based on MODEM.ASM V2.0,
  8. ;by Ward Christensen with enhancements from MODEM527.
  9. ;
  10. ;CP/M - CP/M file transfer program (receive-only)
  11. ;
  12. ;This program is intended for use as a way to
  13. ;initially transfer MODEM.COM or MODEM.ASM to
  14. ;a new user.  It may be used with almost any
  15. ;modem (see equates).
  16. ;
  17. ;A simple terminal routine at start of program allows
  18. ;user to communicate with a remote system prior to
  19. ;receiving a file to make it possible to down-load
  20. ;a file without intervention on the part of the host
  21. ;system's operator.
  22. ;
  23. ;COMMANDS:  MBOOT FILENAME.FILETYPE
  24. ; or  MBOOT A:FILENAME.FILETYPE
  25. ; or  MBOOT B:FILENAME.FILETYPE
  26. ;
  27. ;The program will operate as a dumb terminal until
  28. ;an 'ESC' key is typed (ctrl-[).  It then branches
  29. ;to the receive routine.  The user may also exit
  30. ;to CP/M without opening the receive file by typing
  31. ;ctrl-E from the terminal.  The values for the escape
  32. ;and exit keys may be changed in accordance with the
  33. ;needs of the user - some keyboards do not have the
  34. ;'ESC' key and/or provision for control characters.
  35. ;See equates.
  36. ;
  37. ;NOTE: Comments for the source code and tabs have been
  38. ;removed to make this file easier to transport from one
  39. ;system to another. It may look strange but will assemble
  40. ;OK (KBP)
  41. ;
  42. FALSE EQU 0
  43. TRUE  EQU NOT FALSE
  44. ;
  45. STDCPM EQU TRUE  ;TRUE, IS STANDARD CP/M
  46. ALTCPM EQU FALSE ;TRUE, IS ALTERNATE CP/M FOR H8 OR TRS80
  47. ;
  48.  IF STDCPM
  49. BASE EQU 0
  50.  ENDIF
  51. ;
  52.  IF ALTCPM
  53. BASE EQU 4200H
  54.  ENDIF
  55. ;
  56. EXITCHR EQU 05H ;CTL-E TO EXIT TERM MODE TO CP/M
  57. ESC     EQU 1BH ;ESCAPE TO EXIT TERM MODE TO FILE RCVE
  58. ;
  59. SPEED EQU 6    ;CPU speed in Mhz (to nearest Mhz)
  60. ;
  61. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  62. ;
  63. INITREQ EQU FALSE ;TRUE, IF MODEM PORT INITIALISATION REQUIRED
  64. ;
  65. MODSTAT EQU 5DH ;PUT YOUR MODEM STATUS PORT HERE
  66. MODSNDB EQU 01H ;YOUR BIT TO TEST FOR SEND
  67. MODSNDR EQU 01H ;YOUR VALUE WHEN READY
  68. MODRCVB EQU 02H ;YOUR BIT TO TEST FOR RECEIVE
  69. MODRCVR EQU 02H ;YOUR VALUE WHEN READY
  70. MODDATA EQU 5CH ;YOUR MODEM DATA PORT
  71. ;
  72. ;
  73. ERRLIM EQU 10
  74. ;
  75. SOH EQU 1
  76. EOT EQU 4
  77. ACK EQU 6
  78. NAK EQU 15H
  79. CAN EQU 18H
  80. LF  EQU 10
  81. CR  EQU 13
  82. ; 
  83. BDOS EQU BASE+5
  84. FCB  EQU BASE+5CH
  85. ;
  86.  ORG BASE+100H
  87. ;
  88.  LXI H,0
  89.  DAD SP
  90.  SHLD STACK
  91.  LXI SP,STACK
  92.  CALL INITADR
  93.  CALL ILPRT
  94.  DB 'MBOOT 3.1 as of '
  95.  DB '08/Jun/82',CR,LF,0
  96.  LDA FCB+1
  97.  CPI ' '
  98.  JNZ TERMI
  99.  CALL ILPRT
  100.  DB '++NO FILE NAME SPECIFIED++',CR,LF,0
  101.  JMP EXIT
  102. ;
  103. TERMI CALL INITMOD
  104.  IN MODDATA
  105.  IN MODDATA
  106.  CALL ILPRT
  107.  DB CR,LF,'TERMINAL MODE',CR,LF
  108.  DB 'CTL-E exits to CP/M, ESC starts file transfer'
  109.  DB CR,LF,0
  110. ;
  111. TERM CALL STAT
  112.  JZ TERML
  113.  CALL KEYIN
  114.  CPI EXITCHR
  115.  JZ EXIT
  116.  CPI ESC
  117.  JZ RCVFIL
  118.  OUT MODDATA
  119. ;
  120. TERML IN MODSTAT
  121.  ANI MODRCVB
  122.  CPI MODRCVR
  123.  JNZ TERM
  124.  IN MODDATA
  125.  ANI 7FH
  126.  CALL TYPE
  127.  JMP TERM
  128. ;
  129. RCVFIL CALL ERASFIL
  130.  CALL MAKEFIL
  131.  CALL ILPRT
  132.  DB 'FILE OPEN, READY TO RECEIVE',CR,LF,0
  133. ;
  134. RCVLP CALL RCVSECT
  135.  JC RCVEOT
  136.  CALL WRSECT
  137.  CALL INCRSNO
  138.  CALL SENDACK
  139.  JMP RCVLP
  140. ;
  141. RCVEOT CALL WRBLOCK
  142.  CALL SENDACK
  143.  CALL CLOSFIL
  144.  CALL ERXIT
  145.  DB CR,LF,'TRANSFER COMPLETE$' 
  146. ;
  147. RCVSECT XRA A
  148.  STA ERRCT
  149. ;
  150. RCVRPT MVI B,SPEED*10
  151.  CALL RECV
  152.  JC RCVSERR
  153.  CPI SOH
  154.  JZ RCVSOH
  155.  ORA A
  156.  JZ RCVRPT
  157.  CPI EOT
  158.  STC
  159.  RZ
  160. ;
  161. RCVSERR MVI B,SPEED
  162.  CALL RECV
  163.  JNC RCVSERR
  164.  MVI A,NAK
  165.  CALL SEND
  166.  LDA ERRCT
  167.  INR A
  168.  STA ERRCT
  169.  CPI ERRLIM
  170.  JC RCVRPT
  171. ;
  172. RCVSABT CALL CLOSFIL
  173.  CALL ERXIT
  174.  DB '++UNABLE TO RECEIVE BLOCK'
  175.  DB CR,LF,'++ABORTING++$'
  176. ;
  177. RCVSOH MVI B,SPEED
  178.  CALL RECV
  179.  JC RCVSERR
  180.  MOV D,A
  181.  MVI B,SPEED
  182.  CALL RECV
  183.  JC RCVSERR
  184.  CMA
  185.  CMP D
  186.  JZ RCVDATA
  187.  JMP RCVSERR
  188. ;
  189. RCVDATA MOV A,D
  190.  STA RCVSNO
  191.  MVI C,0
  192.  LXI H,BASE+80H
  193. ;
  194. RCVCHR MVI B,SPEED
  195.  CALL RECV
  196.  JC RCVSERR
  197.  MOV M,A
  198.  INR L
  199.  JNZ RCVCHR
  200.  MOV D,C
  201.  MVI B,SPEED
  202.  CALL RECV
  203.  JC RCVSERR
  204.  CMP D
  205.  JNZ RCVSERR
  206.  LDA RCVSNO
  207.  MOV B,A
  208.  LDA SECTNO
  209.  CMP B
  210.  JZ RECVACK
  211.  INR A
  212.  CMP B
  213.  JNZ ABORT
  214.  RET
  215. ;
  216. RECVACK CALL SENDACK
  217.  JMP RCVSECT
  218. ;
  219. SENDACK MVI A,ACK
  220. ;
  221. SEND PUSH PSW
  222.  ADD C
  223.  MOV C,A
  224. ;
  225. SENDW IN MODSTAT
  226.  ANI MODSNDB
  227.  CPI MODSNDR
  228.  JNZ SENDW
  229.  POP PSW
  230.  OUT MODDATA
  231.  RET
  232. ;
  233. ABORT LXI SP,STACK
  234. ;
  235. ABORTL MVI B,SPEED
  236.  CALL RECV
  237.  JNC ABORTL
  238.  MVI A,CAN
  239.  CALL SEND
  240. ;
  241. ABORTW MVI B,1
  242.  CALL RECV
  243.  JNC ABORTW
  244.  MVI A,' '
  245.  CALL SEND
  246.  CALL ERXIT
  247.  DB 'MBOOT PROGRAM CANCELLED$'
  248. ;
  249. INCRSNO LDA SECTNO
  250.  INR A
  251.  STA SECTNO
  252.  RET
  253. ;
  254. ERASFIL LXI D,FCB
  255.  MVI C,17
  256.  CALL BDOS
  257.  INR A
  258.  RZ
  259.  CALL ILPRT
  260.  DB '++FILE EXISTS, TYPE Y TO ERASE: ',0
  261.  CALL KEYIN
  262.  PUSH PSW
  263.  CALL TYPE
  264.  CALL CRLF
  265.  POP PSW
  266.  ANI 5FH
  267.  CPI 'Y'
  268.  JNZ MXIT
  269.  LXI D,FCB
  270.  MVI C,19
  271.  JMP BDOS
  272. ;
  273. MAKEFIL LXI D,FCB
  274.  MVI C,22
  275.  CALL BDOS
  276.  INR A
  277.  RNZ
  278.  CALL ERXIT
  279.  DB '++ERROR - CAN''T MAKE FILE',CR,LF
  280.  DB '++DIRECTORY MUST BE FULL$'
  281. ;
  282. CLOSFIL LXI D,FCB
  283.  MVI C,16
  284.  CALL BDOS
  285.  INR A
  286.  RNZ
  287.  CALL ERXIT
  288.  DB '++CAN''T CLOSE FILE$'
  289. ;
  290. WRSECT LHLD SECPTR
  291.  XCHG
  292.  LXI H,BASE+80H
  293.  CALL MOVE128
  294.  XCHG
  295.  SHLD SECPTR
  296.  LDA SECINBF
  297.  INR A
  298.  STA SECINBF
  299.  CPI 16
  300.  RNZ
  301. ;
  302. WRBLOCK LDA SECINBF
  303.  ORA A
  304.  RZ
  305.  MOV C,A
  306.  LXI D,DBUF
  307. ;
  308. DKWRLP PUSH H
  309.  PUSH D
  310.  PUSH B
  311.  MVI C,26
  312.  CALL BDOS
  313.  LXI D,FCB
  314.  MVI C,21
  315.  CALL BDOS
  316.  POP B
  317.  POP D
  318.  POP H
  319.  ORA A
  320.  JNZ WRERR
  321.  LXI H,80H
  322.  DAD D
  323.  XCHG
  324.  DCR C
  325.  JNZ DKWRLP
  326.  XRA A
  327.  STA SECINBF
  328.  LXI H,DBUF
  329.  SHLD SECPTR
  330. ;
  331. RSDMA LXI D,BASE+80H
  332.  MVI C,26
  333.  JMP BDOS
  334. ;
  335. WRERR CALL RSDMA
  336.  CALL ILPRT
  337.  DB '++ERROR WRITING FILE',CR,LF,0
  338.  JMP ABORT
  339. ;
  340. RECV PUSH D
  341. MSEC LXI D,12500
  342. ;
  343. MWTI IN MODSTAT
  344.  ANI MODRCVB
  345.  CPI MODRCVR
  346.  JZ MCHAR
  347.  DCR E
  348.  JNZ MWTI
  349.  DCR D
  350.  JNZ MWTI
  351.  DCR B
  352.  JNZ MSEC
  353.  POP D
  354.  STC
  355.  RET
  356. ;
  357. MCHAR IN MODDATA
  358.  POP D
  359.  PUSH PSW
  360.  ADD C
  361.  MOV C,A
  362.  POP PSW
  363.  ORA A
  364.  RET
  365. ;
  366. INITADR LHLD BASE+1
  367.  LXI D,3
  368.  DAD D
  369.  SHLD VSTAT+1
  370.  DAD D
  371.  SHLD VKEYIN+1
  372.  DAD D
  373.  SHLD VTYPE+1
  374.  RET
  375. ;
  376. INITMOD EQU $
  377. ;
  378.  IF INITREQ     ;Insert any UART initialisation code here
  379.  ENDIF
  380. ;
  381. ;
  382.  RET  ;<--THIS RET MUST BE HERE
  383. ;
  384. CRLF MVI A,CR
  385.  CALL TYPE
  386.  MVI A,LF
  387. ;
  388. TYPE PUSH PSW
  389.  PUSH B
  390.  PUSH D
  391.  PUSH H
  392.  MOV C,A
  393. VTYPE CALL $-$
  394.  POP H
  395.  POP D
  396.  POP B
  397.  POP PSW
  398.  RET
  399. ;
  400. STAT PUSH B
  401.  PUSH D
  402.  PUSH H
  403. VSTAT CALL $-$
  404.  POP H
  405.  POP D
  406.  POP B
  407.  ORA A
  408.  RET
  409. ;
  410. KEYIN PUSH B
  411.  PUSH D
  412.  PUSH H
  413. VKEYIN CALL $-$
  414.  POP H
  415.  POP D
  416.  POP B
  417.  ANI 7FH
  418.  RET
  419. ;
  420. ILPRT XTHL
  421. ;
  422. ILPLP MOV A,M
  423.  ORA A
  424.  JZ ILPRET
  425.  CALL TYPE
  426.  INX H
  427.  JMP ILPLP
  428. ;
  429. ILPRET XTHL
  430.  RET
  431. ;
  432. ERXIT POP D
  433.  MVI C,9
  434.  CALL BDOS
  435. ;
  436. MXIT CALL ILPRT
  437.  DB CR,LF,'DON''T FORGET TO DISCONNECT MODEM'
  438.  DB CR,LF,0
  439. ;
  440. EXIT LHLD STACK
  441.  SPHL
  442.  RET
  443. ;
  444. MOVE128 MVI B,128
  445. ;
  446. MOVE MOV A,M
  447.  STAX D
  448.  INX H
  449.  INX D
  450.  DCR B
  451.  JNZ MOVE
  452.  RET
  453. ;
  454. RCVSNO DB 0
  455. SECTNO DB 0
  456. ERRCT DB 0
  457. EOFLG DB 0
  458. SECPTR DW DBUF
  459. SECINBF DB 0
  460.  DS 60
  461. STACK DS 2
  462. DBUF EQU $
  463. ;
  464.  END
  465.