home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol169 / m7tv-1.aqm / M7TV-1.ASM
Assembly Source File  |  1985-02-09  |  11KB  |  341 lines
  1.  
  2. ; M7TV-1.ASM -- TeleVideo TS-802 overlay file for MDM7xx.  11/11/83
  3. ;
  4. ; You will want to look this file over carefully. There are a number of
  5. ; options that you can use to configure the program to suit your taste.
  6. ; This file adapts the modem port on the TeleVideo TS-802 to the modem
  7. ; program.  Much of the information contained here is not in the main
  8. ; file.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Use the "SET" command to change the baudrate when desired.  It starts
  14. ; out at 300 baud when the program is first called up.
  15. ;
  16. ;    TO USE: First edit this file filling in answers for your own
  17. ;        equipment.  Then assemble with ASM.COM or equivalent
  18. ;        assembler.  Then use DDT to overlay the the results
  19. ;        of this program to the original .COM file:
  20. ;
  21. ;        A>DDT MDM7xx.COM
  22. ;        DDT VERS 2.2
  23. ;        NEXT  PC
  24. ;        4300 0100
  25. ;        -IM7TV-1.HEX        (note the "I" command)
  26. ;        -R            ("R" loads in the .HEX file)
  27. ;        NEXT  PC
  28. ;        4300 0000
  29. ;        -G0            (return to CP/M)
  30. ;        A>SAVE 66 MDM7xx.COM    (now have a modified .COM file)
  31. ;
  32. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  33. ;
  34. ; 11/11/83 - Renamed to M7TV-1.ASM, no changes    - Irv Hoff
  35. ; 07/27/83 - Renamed to work with MDM711    - Irv Hoff
  36. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  37. ; 06/22/83 - Revised to work with MDM711    - Irv Hoff
  38. ; 05/27/83 - Updated to work with MDM709    - Irv Hoff
  39. ; 05/15/83 - Revised to work with MDM708    - Irv Hoff
  40. ; 04/27/83 - Revised to work with TV802        - Irv Hoff
  41. ; 02/17/83 - Modified MDM703CF for Datapoint
  42. ;         1560 computers using an external
  43. ;         modem                - Irv Hoff
  44. ;
  45. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  46. ;
  47. BELL:        EQU    07H        ;bell
  48. CR:        EQU    0DH        ;carriage return
  49. ESC:        EQU    1BH        ;escape
  50. LF:        EQU    0AH        ;linefeed
  51. ;
  52. YES:        EQU    0FFH
  53. NO:        EQU    0
  54. ;
  55. ;
  56. PORT:        EQU    20H        ;TeleVideo ST-802 data port
  57. ;
  58. BAUDRP:        EQU    08H        ;CTC port for baud rate
  59. MODCTL1:    EQU    PORT+2        ;Modem control port
  60. MODCTL2:    EQU    PORT+2        ;Modem control port
  61. MODDATP:    EQU    PORT        ;Modem data port
  62. MODDCDB:    EQU    4        ;carrier detect bit
  63. MODDCDA:    EQU    0        ;value when active
  64. MODRCVB:    EQU    1        ;bit to test for receive ready
  65. MODRCVR:    EQU    1        ;value when ready
  66. MODSNDB:    EQU    4        ;bit to test for send ready
  67. MODSNDR:    EQU    4        ;value when ready
  68. ;
  69. ;
  70.         ORG    100H
  71. ;
  72.         DS    3    ;(for  "JMP   START" instruction)
  73. ;
  74. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  75. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  76. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  77. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  78.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  79. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  80.                 ;6=2400 7=4800 8=9600 9=19200 default
  81. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  82.                 ;default time to send character in ter-
  83.                 ;minal mode file transfer for slow BBS.
  84. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  85.                 ;default time for extra wait after CRLF
  86.                 ;in terminal mode file transfer
  87. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  88. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  89. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  90. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  91.                 ;no=resend a record after a valid NAK
  92. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  93. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  94. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  95. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  96. TOGGLEBK:    DB    NO    ;yes=allow toggling of bksp to rub    112H
  97. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  98.                 ;terminal mode (added by remote echo)
  99. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  100. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  101.                 ;write logon sequence at location LOGON
  102. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  103. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  104.                 ;no=external command if EXTCHR precedes
  105. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  106. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  107. XOFFTST:    DB    NO    ;yes=check for XOFF from remote while    11AH
  108.                 ;sending a file in terminal mode
  109. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  110.                 ;sending a file in terminal mode
  111. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  112. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  113. EXTRA1:        DB    0    ;for future expansion            11EH
  114. EXTRA2:        DB    0    ;for future expansion            11FH
  115. BRKCHR:        DB    '@'-40H    ;^@ = Send a 300 ms. break tone        120H
  116. NOCONNCT:    DB    'L'-40H    ;^L = Disconnect from the phone line    121H
  117. LOGCHR:        DB    'N'-40H    ;^N = Send logon            122H
  118. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  119. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  120. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  121. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  122. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  123. ;
  124. ;
  125.         DS    2        ;                128H
  126. ;
  127. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port        12AH
  128.         DS    7
  129. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  130.         DS    7
  131. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  132.         DS    7
  133. ;
  134. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  135. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rec. bit when ready    14BH
  136. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH    
  137. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  138.         DS    6        ;                154H
  139. OUT$MODCTL1:    OUT    MODCTL1    ! RET    ;out modem control port #2    15AH
  140. OUT$MODCTL2:    OUT    MODCTL2    ! RET    ;out modem control port #1    15DH
  141. ;
  142. LOGONPTR:    DW    LOGON        ;for user message.        160H
  143.         DS    6
  144. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  145. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  146.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    16EH
  147.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  148.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  149. JMP$SETUPR:    JMP    SETUPR        ;                177H
  150. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  151. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  152. JMP$BREAK:    JMP    SENDBRK        ;                180H
  153. ;
  154. ;
  155. ; Do not change the following six lines
  156. ;
  157. JMP$ILPRT:    DS    3        ;                183H
  158. JMP$INBUF:    DS    3        ;                186H
  159. JMP$INLNCOMP:    DS    3        ;                189H
  160. JMP$INMODEM:    DS    3        ;                18CH
  161. JMP$NXTSCRN:    DS    3        ;                18FH
  162. JMP$TIMER:    DS    3        ;                192H
  163. ;
  164. ;
  165. ; Clear sequences -- CLREOS is clear to end of screen, CLRSCRN is clear
  166. ; entire screen.  Last entry must be 0.  Any other 0's act as NOP's.
  167. ;
  168. CLREOS:        CALL    JMP$ILPRT    ;                195H
  169.         DB    ESC,79H,0,0,0    ;ESC y - clear to end of screen    198H
  170.         RET            ;                19DH
  171. ;
  172. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  173.         DB    ESC,2AH,0,0,0    ;ESC * clear CRT, home cursor    11AH
  174.         RET            ;                1A6H            
  175. ;
  176. ;
  177. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  178.         DB    'Version for TeleVideo TS-802, modem port 20H'
  179.         DB    CR,LF,0
  180.         RET
  181. ;.....
  182. ;
  183. ;
  184. ;-----------------------------------------------------------------------
  185. ;
  186. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  187. ;     end of your last routine should terminate by 0400H (601 bytes
  188. ;     available after start of SYSVER) if using the Hayes Smartmodem
  189. ;     or by address 0C00H (2659 bytes) otherwise.
  190. ;
  191. ;-----------------------------------------------------------------------
  192. ;
  193. ; You can put in a message at this location which can be called up with
  194. ; CTL-O if TRANLOGON has been set YES.    You can put in several lines if
  195. ; desired.  End with a 0.
  196. ;
  197. ;
  198. LOGON:      DB    'Greetings from a TeleVideo user',CR,LF,0
  199. ;
  200. ;=======================================================================
  201. ;
  202. ;
  203. ; This routine allows a 300 ms. break tone to be sent to reset some
  204. ; time-share computers.
  205. ;
  206. SENDBRK:  MVI    A,5
  207.       OUT    MODCTL1
  208.       MVI    A,0F8H        ;SEND A BREAK TONE
  209.       JMP    GOODBYE1
  210. ;.....
  211. ;
  212. ;
  213. ; This routine sends a 300 ms. break tone and sets DTR low for the same
  214. ; length of time to disconnect some modems such as the Bell 212A, etc.    
  215. ;
  216. GOODBYE:  MVI    A,5
  217.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  218.       MVI    A,068H        ;TURN OFF DTR, SEND BREAK
  219. ;
  220. GOODBYE1: OUT    MODCTL1    
  221.       MVI    B,3        ;WAIT 300 MS.
  222.       CALL    JMP$TIMER
  223.       MVI    A,5
  224.       OUT    MODCTL1
  225.       MVI    A,0E8H        ;RESTORE TO NORMAL, 8 BITS, DTR ON, ETC.
  226.       OUT    MODCTL1
  227.       RET
  228. ;.....
  229. ;
  230. ;
  231. ; TeleVideo TS-802 baud rate change.  Sets CTC at port 08H for baudrate
  232. ; in/out.
  233. ;
  234. ;
  235. INITMOD:  MVI    A,0        ;SELECT REG.
  236.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  237.       MVI    A,18H        ;RESET THE Z8SIO CHIP
  238.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  239.       MVI    A,4        ;SELECT REG.
  240.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  241.       MVI    A,44H        ;16X, 1-STOP, NO PARITY
  242.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  243.       MVI    A,3        ;SELECT REG.
  244.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  245.       MVI    A,0C1H        ;ENABLE RECEIVE SECTION
  246.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  247.       MVI    A,5        ;SELECT REG.
  248.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  249.       MVI    A,0EAH        ;DTR, RTS, 8-BITS, ENABLE SEND SECTION
  250.       OUT    MODCTL1        ;SEND TO THE STATUS PORT
  251. ;
  252. INITMOD1: MVI    A,1        ;DEFAULT TRANSFER TIME TO 300 BAUD
  253.       STA    MSPEED
  254.       MVI    A,47H
  255.       OUT    BAUDRP
  256. ;
  257. INITMOD2: MVI    A,80H        ;DEFAULT TO 300 BAUD
  258.       OUT    BAUDRP
  259.       RET
  260. ;.....
  261. ;
  262. ;
  263. SETUPR:      LXI    D,BAUDBUF    ;POINT TO NEW INPUT BUFFER
  264.       CALL    JMP$ILPRT
  265.       DB    'Input Baud Rate (300, 450, 600, 1200, 9600): ',0
  266.       CALL    JMP$INBUF
  267.       LXI    D,BAUDBUF+2
  268.       CALL    JMP$INLNCOMP    ;COMPARE BAUDBUF+2 WITH CHARACTERS BELOW
  269.       DB    '300',0
  270.       JNC    OK300        ;GO IF GOT MATCH
  271.       CALL    JMP$INLNCOMP
  272.       DB    '450',0
  273.       JNC    OK450
  274.       CALL    JMP$INLNCOMP
  275.       DB    '600',0
  276.       JNC    OK600
  277.       CALL    JMP$INLNCOMP
  278.       DB    '1200',0
  279.       JNC    OK1200
  280.       CALL    JMP$INLNCOMP
  281.       DB    '9600',0
  282.       JNC    OK9600
  283.       CALL    JMP$ILPRT    ;ALL MATCHES FAILED, TELL OPERATOR
  284.       DB    '++ Incorrect entry ++',CR,LF,BELL,0
  285.       JMP    SETUPR        ;TRY AGAIN
  286. ;
  287. OK300:      MVI    A,1        ;MSPEED 300 BAUD VALUE
  288.       LHLD    BD300        ;GET 300 BAUD PARAMETERS IN 'HL'
  289.       JMP    LOADBD        ;GO LOAD THEM
  290. ;
  291. OK450:      MVI    A,2
  292.       LHLD    BD450
  293.       JMP    LOADBD
  294. ;
  295. OK600:      MVI    A,3
  296.       LHLD    BD600
  297.       JMP    LOADBD
  298. ;
  299. OK1200:      MVI    A,5
  300.       LHLD    BD1200
  301.       JMP    LOADBD
  302. ;
  303. OK9600:      MVI    A,8
  304.       LHLD    BD9600
  305. ;
  306. LOADBD:      STA    INITMOD1+1    ;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
  307.       MOV    A,L        ;GET BAUDRATE BYTE
  308.       STA    INITMOD2+1    ;STORE IN INITMOD
  309.       JMP    INITMOD1    ;REINITIALIZE TO NEW BAUDRATE, THEN DONE
  310. ;
  311. ;
  312. ; TABLE OF BAUDRATE PARAMETERS
  313. ;
  314. BD300:      DW    0080H        ;38400/300  CONVERTED TO HEX VALUE
  315. BD450:      DW    0055H        ;38400/450  CONVERTED TO HEX VALUE
  316. BD600:      DW    0040H        ;38400/600  CONVERTED TO HEX VALUE
  317. BD1200:      DW    0020H        ;38400/1200 CONVERTED TO HEX VALUE
  318. BD9600:      DW    0004H        ;38400/9600 CONVERTED TO HEX VALUE    
  319. ;
  320. BAUDBUF:  DB    10,0
  321.       DS    10
  322. ;
  323. ;           (END OF INITMOD AND SETUP ROUTINES)
  324. ;-----------------------------------------------------------------------
  325. ;
  326. ; These routines can be used for your equipment, be sure to end with RET
  327. ; If using the Hayes Smartmodem this is unavailable without a special
  328. ; address change.
  329. ;
  330. SPCLMENU: RET
  331. ;
  332. ;-----------------------------------------------------------------------
  333. ;
  334. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  335. ;                 0C00H (without Smartmodem)    
  336. ;
  337.       END
  338. ;
  339. NITMOD1+1    ;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
  340.       MOV    A,L        ;GET BAUDRATE BYTE
  341.       STA    INITMOD2+1    ;STORE IN