home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol274 / i2vi-1.aqm / I2VI-1.ASM
Assembly Source File  |  1986-06-11  |  14KB  |  483 lines
  1.  
  2. ; I2VI-1.ASM  -  Visual 1050 overlay for IMP  -  02/07/86
  3. ;
  4. ;        USES 8251A I/O and 8253 ?? baudrate generator
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts the Visual 1050 computer to IMP.COM.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  14. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  15. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  16. ; (The ESC will automatically be typed with no CTL-character present.)
  17. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  18. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  19. ; looking at the function key table, typing CTL-Z in command mode, etc.
  20. ;
  21. ; Use the "SET" command to change the baudrate when desired.  The value
  22. ; at MSPEED controls the baudrate when the program is first called up.
  23. ;
  24. ;    TO USE: First edit this file filling in answers for your own
  25. ;        equipment.  Then assemble with ASM.COM or equivalent
  26. ;        assembler.  Then use MLOAD to merge into the main file:
  27. ;
  28. ;        MLOAD IMP.COM=IMP.COM,I2VI-x.HEX
  29. ;
  30. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  31. ;
  32. ; 10/27/85 - Written to work with IMP, adapted portions of M7VI-2.ASM.
  33. ;                    - Irv Hoff
  34. ;
  35. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  36. ;
  37. ;
  38. YES    EQU    0FFH
  39. NO    EQU    0
  40. ;
  41. ;
  42. BDOS    EQU    0005H
  43. RDRIN    EQU    3        ; Reader input function
  44. PNCHOUT    EQU    4        ; Punch output function
  45. GETIO    EQU    7        ; Get I/O byte
  46. SETIO    EQU    8        ; Set I/O byte
  47. DIRBIOS    EQU    50        ; Direct BIOS call
  48. ;
  49. ;
  50. ; Values shown are for a 8251A
  51. ;
  52. PORT    EQU    8CH    ; Your base port (data or status)
  53. MDCTL1    EQU    PORT+1    ; Modem control port
  54. MDDATP    EQU    PORT    ; Modem data port
  55. MDRCV    EQU    02H    ; Modem receive ready
  56. MDSND    EQU    01H    ; Modem send ready bit
  57. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  58. ;
  59. BDPORT    EQU    92H    ; Port for setting baudrate
  60. ;
  61. MDMODE    EQU    82H    ; Insures 8251 is out of mode with DTR high
  62. MDRSET    EQU    42H    ; Resets USART for additional commands
  63. MDSET1    EQU    4EH    ; 1 stop bit, no parity, 8 bits, x16
  64. MDSET2    EQU    0CEH    ; 2 stop bits, no parity, 8 bits, x16
  65. MDCOM    EQU    17H    ; Reset error flags, RCV, DTR, TX ready
  66. ;
  67. ;
  68. ; Table of baudrate parameters
  69. ;
  70. BD300    EQU    4F00H
  71. BD1200    EQU    4E00H
  72. BD2400    EQU    4E04H
  73. BD9600    EQU    4E08H
  74. BD19200    EQU    4E0CH
  75. ;.....
  76. ;
  77. ;
  78. ;-----------------------------------------------------------------------
  79. ;
  80. ESC    EQU    '['-40H    ; ^[ = Escape
  81. BELL    EQU    'G'-40H    ; ^G = Bell character
  82. LF    EQU    'J'-40H    ; ^J = Linefeed
  83. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  84. CR    EQU    'M'-40H    ; ^M = Carriage return
  85. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode only
  86. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  87. ;
  88. ;
  89. ;-----------------------------------------------------------------------
  90. ;
  91. ;
  92.     ORG    0100H
  93. ;
  94. ;
  95.     DS    3        ; Skip the data area below
  96. ;
  97. ;
  98. ; These routines and equates are at the beginning of the program so
  99. ; they can be patched by a monitor or overlay file without re-assembling
  100. ; the program.
  101. ;
  102. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  103.             ; 6=2400 7=4800 8=9600 9=19200 default
  104. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  105. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  106. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  107. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  108. RESVD1:     DB    NO    ; Reserved for special modems            108H
  109. RESVD2:     DB    NO    ; Reserved for special modems            109H
  110. ;
  111. ;
  112. CLEAR:     DB    1AH    ; Clear screen character (ESC not needed)    10AH
  113. CLOCK:     DB    37    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  114.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  115. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  116.             ;   default time to send character in ter-
  117.             ;   minal mode file transfer for slow BBS
  118. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  119.             ;   default time for extra wait after CRLF
  120.             ;   in terminal mode file transfer
  121. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  122. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  123. ;.....
  124. ;
  125. ;
  126. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  127.             ;   mode (normally added by remote echo)
  128. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  129. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  130. IGNRCTL: DB    NO    ; Yes=CTL-chars above ^M not displayed        113H
  131. ;.....
  132. ;
  133. ;
  134. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  135. EXITCHR: DB    'E'    ; Exit character                115H
  136. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  137. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  138. LOGCHR:     DB    'L'    ; Send logon                    118H
  139. LSTCHR:     DB    'P'    ; Toggle printer                119H
  140. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  141. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  142. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  143. SPARE1:     DB    0    ; For future development            11DH
  144. NODTR:     DB    NO    ; Yes if no DTR and need +++ to disconnect    11EH
  145. ;.....
  146. ;
  147. ;
  148. ; Handles in/out ports for data and status
  149. ;
  150. I$MDCTL1: RET            ; Status port not used            11FH
  151.       DB    0,0,0,0,0    ; Spares if needed            120H
  152.       DB    0,0,0,0        ; Spares if needed            125H
  153. ;
  154. I$MDTXE:  RET            ; (Needed for SIO or DART register 1    129H
  155.       DB    0,0,0,0,0    ;                    12AH
  156.       DB    0,0,0,0        ;                    12FH
  157. ;
  158. I$MDDATP: JMP    BDOS3        ;                    133H
  159.       DB    0,0,0,0,0,0,0    ; Spares if needed            136H
  160. ;
  161. O$MDDATP: JMP    BDOS4        ;                    13DH
  162.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  163. ;.....
  164. ;
  165. ;
  166. A$MDRCV:  RET            ; BDOS7 tests receive ready        147H
  167.       DB    0,0        ; Spares if needed            148H
  168. ;
  169. C$MDRCV:  JMP    BDOS7        ;                    14AH
  170. ;
  171. A$MDSND:  RET            ; BDOS8 tests send ready        14DH
  172.       DB    0,0
  173. ;
  174. C$MDSND:  JMP    BDOS8        ; BDOS8 checks for send ready        150H
  175. ;
  176. A$MDTXE:  ANI    MDTXE        ;                    153H
  177.       RET            ;                    155H
  178. ;
  179. C$MDTXE:  CPI    MDTXE        ;                    156H
  180.       RET            ;                    158H
  181. ;.....
  182. ;
  183. ;
  184. ; Special exit vector, used by some computers to reset interrupt vectors
  185. ;
  186. J$EXITVEC:RET            ;                    159H
  187.       DB    0,0        ;                    15AH
  188. ;.....
  189. ;
  190. ;
  191. ; Jump vectors needed by each overlay
  192. ;
  193. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  194. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  195. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  196. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  197. ;.....
  198. ;
  199. ;
  200. ; "AT" command strings, can be replaced in individual overlay if needed
  201. ;
  202. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  203. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  204. ;
  205. ;
  206. ; Next fourteen lines should not be changed by user overlay as these go
  207. ; to specific locations in the main program, not in the overlay.
  208. ;
  209. ;
  210. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  211. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  212. J$DIAL:      DS    3        ; Start of dialing routine        174H
  213. J$DSCONT: DS    3        ; Terminates modem use            177H
  214. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  215. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  216. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  217. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  218. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  219. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  220. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  221. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  222. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  223. J$NEW1:      DB    0,0,0        ; For future needs            195H
  224. J$NEW2:      DB    0,0,0        ; For future needs            198H
  225. ;.....
  226. ;
  227. ;
  228. ; For 2400 bps auto-stepdown units
  229. ;
  230. MANUAL:      DB    0        ; For manual selection flag        19BH
  231. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  232. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  233. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  234. ;.....
  235. ;
  236. ;
  237. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  238. ;
  239. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  240.       DB    'Version for Visual 1050 modem port 8CH' ;        1AAH
  241.       DB    CR,LF,0
  242.       RET
  243. ;.....
  244. ;
  245. ;
  246. ;-----------------------------------------------------------------------
  247. ;
  248. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  249. ;     end of your last routine should terminate by 0400H (601 bytes
  250. ;     available after start of SYSVER).
  251. ;
  252. ;-----------------------------------------------------------------------
  253. ;
  254. ; You can put in a message at this location which can be called up with
  255. ; (special character-L).  You can put in several lines.  End with a 0.
  256. ;
  257. LOGON:    DB    'This is a Visual 1050 Computer....  ',0
  258. ;
  259. ;-----------------------------------------------------------------------
  260. ;
  261. ; This routine sets DTR low for 300 ms to disonnect the phone
  262. ;
  263. GOODBYE:MVI    B,'S'-40H    ; X-off to stop host if needed
  264.     CALL    J$SNDCHR
  265.     MVI    B,1        ; Wait a moment to let it react
  266.     CALL    J$TIMER
  267.     MVI    A,3DH        ; Send break, turn off DTR
  268.     CALL    SETMCTL        ; Send to status port
  269.     MVI    B,3        ; Delay 300 ms to hang up phone
  270.     CALL    J$TIMER
  271.     MVI    A,37H        ; Normal send/receive with DTR
  272.     JMP    SETMCTL        ; Send to status port, finished
  273. ;.....
  274. ;
  275. ;
  276. INITMOD:LDA    MSPEED        ; Get the selected value
  277.     CPI    1        ; 300 bps
  278.     JZ    OK300
  279.     CPI    5        ; 1200 bps
  280.     JZ    OK1200
  281.     CPI    6        ; 2400 bps
  282.     JZ    OK2400
  283.     CPI    8        ; 9600 bps
  284.     JZ    OK9600
  285.     CPI    9        ; 19200
  286.     JZ    OK19200
  287.     JMP    STUPR1        ; Else ask what is wanted
  288. ;.....
  289. ;
  290. ;
  291. ; The following routines replace direct modem port I/O with BDOS calls.
  292. ; The Visual 1050 BIOS uses interrupt-driven I/O with ring buffers.
  293. ; This solves the problem of losing modem input while the console dis-
  294. ; play does a carriage return.
  295. ;
  296. ; Check for input character (receive ready)
  297. ;
  298. BDOS7:    PUSH    B        ; Save the registers
  299.     MVI    C,GETIO        ; BDOS function number
  300.     JMP    BDOS78        ; Common routine for BDOS 7 & 8
  301. ;
  302. ;
  303. ; Check for output character (send ready)
  304. ;
  305. BDOS8:    PUSH    B        ; Save the registers
  306.     MVI    C,SETIO        ; BDOS function number
  307. ;
  308. BDOS78:    PUSH    D
  309.     PUSH    H
  310.     CALL    BDOS
  311.     POP    H        ; Restore the registers
  312.     POP    D
  313.     POP    B
  314.     ORA    A        ; Bdos returns A=0 if not ready
  315.     JZ    CLRZ        ; Return Z flag off if not ready
  316.     XRA    A        ; Set Z flag if ready
  317.     RET
  318. ;
  319. CLRZ:    INR    A        ; Clear Z flag (make a non-zero)
  320.     RET
  321. ;.....
  322. ;
  323. ;
  324. ; Input a character from modem via BIOS ring buffer
  325. ;
  326. BDOS3:    PUSH    B        ; Save the registers
  327.     PUSH    D
  328.     PUSH    H
  329.     MVI    C,RDRIN        ; BDOS function number
  330.     CALL    BDOS
  331.     POP    H        ; Restore the registers
  332.     POP    D
  333.     POP    B
  334.     RET            ; Input character is in 'A' register
  335. ;.....
  336. ;
  337. ;
  338. ; Ouput a character to modem via BIOS ring buffer
  339. ;
  340. BDOS4:    PUSH    B        ; Save the registers
  341.     PUSH    D
  342.     PUSH    H
  343.     MVI    C,PNCHOUT    ; BDOS function number
  344.     MOV    E,A        ; Character to output must be in 'E'
  345.     CALL    BDOS
  346.     POP    H        ; Restore the registers
  347.     POP    D
  348.     POP    B
  349.     RET
  350. ;.....
  351. ;
  352. ;
  353. ; The Visual 1050 BIOS keeps the current value of the modem control
  354. ; register in a special byte.  We must modify this byte whenever we
  355. ; change the value of this register, or the BIOS will clobber it when-
  356. ; ever it gets an interrupt from the modem port.
  357. ;
  358. SETMCTL:PUSH    H
  359.     LHLD    RSPAR        ; Address of BIOS byte
  360.     MOV    M,A        ; Save new value there
  361.     OUT    MDCTL1        ; Output to modem control register
  362.     POP    H
  363.     RET
  364. ;.....
  365. ;
  366. ;
  367. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  368.     JNC    STUPR2
  369. ;
  370. STUPR1:    CALL    J$ILPRT
  371.     DB    'Input Baud Rate (300, 1200, 2400, 9600, 19200): ',0
  372.     LXI    D,BAUDBUF    ; Point to new input buffer
  373.     CALL    J$INBUF
  374.     CALL    J$CRLF
  375.     LXI    D,BAUDBUF+2
  376. ;
  377. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  378.     DB    '300',0
  379.     JNC    OK300        ; Go if got match
  380.     CALL    J$INLNCP
  381.     DB    '1200',0
  382.     JNC    OK1200
  383.     CALL    J$INLNCP
  384.     DB    '2400',0
  385.     JNC    OK2400
  386.     CALL    J$INLNCP
  387.     DB    '9600',0
  388.     JNC    OK9600
  389.     CALL    J$INLNCP
  390.     DB    '19200',0
  391.     JNC    OK19200
  392.     CALL    J$ILPRT        ; All matches failed, tell operator
  393.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  394.     JMP    STUPR1        ; Try again
  395. ;
  396. OK300:    MVI    A,1
  397.     LXI    H,BD300
  398.     JMP    LOADBD
  399. ;
  400. OK1200:    MVI    A,5
  401.     LXI    H,BD1200
  402.     JMP    LOADBD
  403. ;
  404. OK2400:    XRA    A
  405.     STA    MANUAL        ; Reset to maximum auto-speed
  406.     MVI    A,6
  407.     LXI    H,BD2400
  408.     JMP    LOADBD
  409. ;
  410. OK9600:    MVI    A,8
  411.     LXI    H,BD9600
  412.     JMP    LOADBD
  413. ;
  414. OK19200:MVI    A,9
  415.     LXI    H,BD19200
  416. ;
  417. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  418.     SHLD    STASPD
  419.     MVI    A,3FH        ; Get byte to enable interrupts
  420.     OUT    9DH        ; Enable them...
  421. ;
  422. ;
  423. ; The Visual 1050 provides a special function which returns the address
  424. ; of the byte where the BIOS keeps the current value of the modem con-
  425. ; trol register.  We must modify this byte whenever we change the value
  426. ; of this register, or the BIOS will clobber it whenever it gets an in-
  427. ; terrupt from the modem port.
  428. ;
  429.     LXI    D,BIOSPB    ; Parameter block for BIOS call
  430.     MVI    C,DIRBIOS    ; BDIS function for direct BIOS call
  431.     CALL    BDOS
  432.     SHLD    RSPAR        ; Save the returned address
  433. ;
  434. ;
  435. ; Sets 8251 to 8 bits, DTR, RCV and TX ready
  436. ;
  437.     MVI    A,MDMODE    ; Insure 8251 is out of mode
  438.     OUT    MDCTL1
  439.     XTHL            ; Small delay to complete command
  440.     XTHL
  441.     MVI    A,MDRSET    ; Reset the 8251A for new command
  442.     OUT    MDCTL1
  443.     XTHL            ; Small delay to complete command
  444.     XTHL
  445. ;
  446. ;
  447. ; Set the 8251A to x16 or x64
  448. ;
  449.     LDA    STASPD        ; Get the x16 or x64 value
  450.     OUT    MDCTL1        ; Modem status port (mode word)
  451.     MVI    A,MDCOM        ; DTR, RCV, XMT, error reset
  452.     CALL    SETMCTL        ; Modem status port
  453. ;
  454. ;
  455. ; Now set the baud rate
  456. ;
  457.     LDA    STASPD+1    ; Get the timer speed
  458.     STA    BAUD+1
  459.     IN    BDPORT        ; Get what was there
  460.     ANI    0F3H        ; Clear out the old baud rates
  461. ;
  462. BAUD:    ORI    0        ; Set new default to 1200
  463.     OUT    BDPORT        ; New baud rate now set
  464.     RET
  465. ;.....
  466. ;
  467. ;
  468. ; Data area
  469. ;
  470. BAUDBUF:DB    10,0,0,0,0,0
  471.     DB    0,0,0,0,0,0
  472. BIOSPB:    DB    30,3
  473. RSPAR:    DB    0,0        ; Address of BIOS
  474. STASPD:    DB    0,0        ; Store the requested baud rate temp.
  475. ;.....
  476. ;
  477. ;                   end
  478. ;-----------------------------------------------------------------------
  479. ;
  480. ;NOTE:    Must terminate by 0400H
  481. ;
  482.     END
  483.