home *** CD-ROM | disk | FTP | other *** search
/ Sams Cobol 24 Hours / Sams_Cobol_24_Hours.iso / source / ch14 / CHAPT14C.COB < prev    next >
Text File  |  1998-09-14  |  8KB  |  199 lines
  1. 000010 @OPTIONS MAIN,TEST
  2. 000020 Identification Division.
  3. 000030 Program-Id.  Chapt14c.
  4. 000031* Dealer Data Entry
  5. 000041 Environment Division.
  6. 000050 Configuration Section.
  7. 000051 Special-Names.
  8. 000052       Crt Status Is Keyboard-Status
  9. 000053       Cursor Is Cursor-Position.
  10. 000054 Source-Computer.  IBM-PC.
  11. 000055 Object-Computer.  IBM-PC.
  12. 000056 Input-Output Section.
  13. 000057 File-Control.
  14. 000058     Select Dealer-File Assign To "Dealer.Dat"
  15. 000059            Organization Indexed
  16. 000060            Access Random
  17. 000061            Record Key Dealer-Number Of Dealer-Record
  18. 000062            Alternate Record Key Dealer-Name Of Dealer-Record
  19. 000063            File Status Dealer-Status.
  20. 000065 Data Division.
  21. 000066 File Section.
  22. 000067 Fd  Dealer-File.
  23. 000068 01  Dealer-Record.
  24. 000069     03  Dealer-Number         Pic X(8).
  25. 000070     03  Dealer-Name.
  26. 000071         05  Last-Name   Pic X(25).
  27. 000072         05  First-Name  Pic X(15).
  28. 000073         05  Middle-Name Pic X(10).
  29. 000083     03  Address-Line-1      Pic X(50).
  30. 000085     03  Address-Line-2      Pic X(50).
  31. 000086     03  City                Pic X(40).
  32. 000087     03  State-Or-Country    Pic X(20).
  33. 000088     03  Postal-Code         Pic X(15).
  34. 000089     03  Home-Phone          Pic X(20).
  35. 000090     03  Work-Phone          Pic X(20).
  36. 000091     03  Other-Phone         Pic X(20).
  37. 000092     03  Start-Date          Pic 9(8).
  38. 000093     03  Last-Rent-Paid-Date Pic 9(8).
  39. 000094     03  Next-Rent-Due-Date  Pic 9(8).
  40. 000095     03  Rent-Amount         Pic 9(4)v99.
  41. 000096     03  Consignment-Percent Pic 9(3).
  42. 000097     03  Filler              Pic X(50).
  43. 000098 Working-Storage Section.
  44. 000099 01  Keyboard-Status.
  45. 000100     03  Accept-Status Pic 9.
  46. 000101     03  Function-Key  Pic X.
  47. 000102         88  F1-Pressed Value X"01".
  48. 000103         88  F2-Pressed Value X"02".
  49. 000104     03  System-Use    Pic X.
  50. 000105 01  Cursor-Position.
  51. 000106     03  Cursor-Row    Pic 9(2) Value 1.
  52. 000107     03  Cursor-Column Pic 9(2) Value 1.
  53. 000116 01  Dealer-Status     Pic X(2) Value Spaces.
  54. 000240     88  Dealer-Success Value "00".
  55. 000250 01  Error-Message     Pic X(60) Value Spaces.
  56. 000251 01  Open-Error.
  57. 000252     03  Filler        Pic X(26)
  58. 000253         Value "Error Opening Dealer File ".
  59. 000254     03  Open-Error-Status  Pic X(2).
  60. 000255 01  Write-Error.
  61. 000256     03  Filler        Pic X(26)
  62. 000257         Value "Error Writing Dealer File ".
  63. 000258     03  Write-Error-Status Pic X(2).
  64. 000259 01  Work-Record.
  65. 000260     03  Dealer-Number         Pic X(8).
  66. 000261     03  Dealer-Name.
  67. 000262         05  Last-Name   Pic X(25).
  68. 000263         05  First-Name  Pic X(15).
  69. 000264         05  Middle-Name Pic X(10).
  70. 000265     03  Address-Line-1      Pic X(50).
  71. 000266     03  Address-Line-2      Pic X(50).
  72. 000267     03  City                Pic X(40).
  73. 000268     03  State-Or-Country    Pic X(20).
  74. 000269     03  Postal-Code         Pic X(15).
  75. 000270     03  Home-Phone          Pic X(20).
  76. 000271     03  Work-Phone          Pic X(20).
  77. 000272     03  Other-Phone         Pic X(20).
  78. 000273     03  Start-Date          Pic 9(8).
  79. 000274     03  Last-Rent-Paid-Date Pic 9(8).
  80. 000275     03  Next-Rent-Due-Date  Pic 9(8).
  81. 000276     03  Rent-Amount         Pic 9(4)v99.
  82. 000277     03  Consignment-Percent Pic 9(3).
  83. 000278
  84. 000279 Screen Section.
  85. 000387 01  Data-Entry-Screen
  86. 000388     Blank Screen, Auto
  87. 000389     Foreground-Color Is 7,
  88. 000390     Background-Color Is 1.
  89. 000391*
  90. 000392     03  Screen-Literal-Group.
  91. 000393         05  Line 01 Column 30 Value "Darlene's Treasures"
  92. 000394             Highlight Foreground-Color 4 Background-Color 1.
  93. 000395         05  Line 03 Column 30 Value "Tenant Entry Program"
  94. 000396             Highlight.
  95. 000397         05  Line 4  Column 01  Value "Number: ".
  96. 000398         05  Line 5  Column 01  Value "Name, Last: ".
  97. 000399         05  Line 5  Column 39  Value "First: ".
  98. 000400         05  Line 5  Column 62  Value "Middle: ".
  99. 000401         05  Line 6  Column 01  Value "Address 1: ".
  100. 000402         05  Line 7  Column 01  Value "Address 2: ".
  101. 000403         05  Line 8  Column 01  Value "City: ".
  102. 000404         05  Line 9  Column 01  Value "Country/State: ".
  103. 000405         05  Line 9  Column 36  Value "Postal Code: ".
  104. 000406         05  Line 11 Column 01  Value "Phone/Home: ".
  105. 000407         05  Line 11 Column 34  Value "Work: ".
  106. 000408         05  Line 12 Column 06  Value "Other: ".
  107. 000409         05  Line 14 Column 01  Value "Start Date: ".
  108. 000410         05  Line 14 Column 24  Value "Last Paid Date: ".
  109. 000411         05  Line 14 Column 51  Value "Next Rent Due on: ".
  110. 000412         05  Line 15 Column 01  Value "Rent Amount: ".
  111. 000413         05  Line 16 Column 01  Value "Consignment Percent: ".
  112. 000414         05  Line 22 Column 01  Value "F1-Exit    F2-Save".
  113. 000415*
  114. 000416     03  Required-Reverse-Group Reverse-Video Required.
  115. 000417         05  Line 4 Column 13  Pic X(8)  Using Dealer-Number
  116. 000418             Of Work-Record.
  117. 000419         05  Line 5 Column 13  Pic X(25) Using Last-Name
  118. 000420             Of Work-Record.
  119. 000421         05  Line 5 Column 46  Pic X(15) Using First-Name
  120. 000422             Of Work-Record.
  121. 000423*
  122. 000424     03  Reverse-Video-Group Reverse-Video.
  123. 000425         05  Line 5  Column 70 Pic X(10) Using Middle-Name
  124. 000426             Of Work-Record.
  125. 000427         05  Line 6  Column 15 Pic X(50) Using Address-Line-1
  126. 000428             Of Work-Record.
  127. 000429         05  Line 7  Column 15 Pic X(50) Using Address-Line-2
  128. 000430             Of Work-Record.
  129. 000431         05  Line 8  Column 15 Pic X(40) Using City
  130. 000432             Of Work-Record.
  131. 000433         05  Line 9  Column 15 Pic X(20) Using State-Or-Country
  132. 000434             Of Work-Record.
  133. 000435         05  Line 9  Column 50 Pic X(15) Using Postal-Code
  134. 000436             Of Work-Record.
  135. 000437         05  Line 11 Column 13 Pic X(20) Using Home-Phone
  136. 000438             Of Work-Record.
  137. 000439         05  Line 11 Column 41 Pic X(20) Using Work-Phone
  138. 000440             Of Work-Record.
  139. 000441         05  Line 12 Column 13 Pic X(20) Using Other-Phone
  140. 000442             Of Work-Record.
  141. 000443         05  Line 14 Column 13 Pic 99/99/9999 Using Start-Date
  142. 000444             Of Work-Record.
  143. 000445         05  Line 14 Column 40 Pic 99/99/9999
  144. 000446             Using Last-Rent-Paid-Date Of Work-Record.
  145. 000447         05  Line 14 Column 69 Pic 99/99/9999
  146. 000448             Using Next-Rent-Due-Date Of Work-Record.
  147. 000449         05  Line 15 Column 14 Pic Z,ZZZ.99 Using Rent-Amount
  148. 000450             Of Work-Record.
  149. 000451         05  Line 16 Column 22 Pic ZZ9 Using Consignment-Percent
  150. 000452             Of Work-Record.
  151. 000453     03  Blink-Group Highlight Blink.
  152. 000454         05  Line 20 Column 01 Pic X(60) From Error-Message.
  153. 000455*
  154. 000457 Procedure Division.
  155. 000458 Chapt14c-Start.
  156. 000459     Perform Open-File
  157. 000460     If Dealer-Success
  158. 000461        Initialize Work-Record
  159. 000462        Perform Process-Screen Until F1-Pressed Or
  160. 000463                                 Not Dealer-Success
  161. 000464        Perform Close-File
  162. 000465     End-If
  163. 000466     Stop Run
  164. 000467     .
  165. 000468  Process-Screen.
  166. 000469     Display Data-Entry-Screen
  167. 000470     Accept Data-Entry-Screen
  168. 000471     If F2-Pressed
  169. 000472        Perform Save-Record
  170. 000473     End-If
  171. 000474     .
  172. 000475 Save-Record.
  173. 000476     Move Corresponding Work-Record To Dealer-Record
  174. 000477     Write Dealer-Record
  175. 000478     If Not Dealer-Success
  176. 000479        Move Dealer-Status To Write-Error-Status
  177. 000480        Move Write-Error To Error-Message
  178. 000481        Perform Display-And-Accept-Error
  179. 000482     Else
  180. 000483        Initialize Work-Record
  181. 000484        Move 1 To Cursor-Row
  182. 000485                  Cursor-Column
  183. 000486     End-If
  184. 000487     .
  185. 000488 Open-File.
  186. 000489     Open Output Dealer-File
  187. 000490     If Not Dealer-Success
  188. 000491        Move Dealer-Status To Open-Error-Status
  189. 000492        Move Open-Error To Error-Message
  190. 000493        Perform Display-And-Accept-Error
  191. 000494     End-If
  192. 000495     .
  193. 000496 Close-File.
  194. 000497     Close Dealer-File
  195. 000498     .
  196. 000499 Display-And-Accept-Error.
  197. 000500     Display Data-Entry-Screen
  198. 000501     Accept Data-Entry-Screen
  199. 000502     .