home *** CD-ROM | disk | FTP | other *** search
/ Set of Apple II Hard Drive Images / eric.hdv / SOURCE / AUXMIDI.SR.txt < prev    next >
Text File  |  2020-08-13  |  28KB  |  990 lines
  1. ; ********************************************
  2. ; * AUXMIDI.SRC - BACKGROUND MIDI MUSIC QUEUE
  3. ; * (C) 1994, ERIC RANGELL
  4. ; ********************************************
  5. ;
  6.          ORG $2000
  7. ;
  8. ; *** CONSTANTS ***
  9. ;
  10. JMPINST  EQU $4C             ; JMP INSTRUCTION
  11. RTSINST  EQU $60             ; RTS INSTRUCTION
  12. OFFSET   EQU $06             ; BYTES FROM BEGINNING OF PGM ON STACK
  13. MAXSUBS  EQU $40             ; MAX ENTRIES IN SUBROUTINE TABLE (64*2=128)
  14. ; 
  15. ;
  16. ; *** ZERO PAGE ***
  17. ;
  18. MYADRS   EQU $06             ;POINTER TO MY CODE
  19. MEMPTR   EQU $08             ;POINTER TO MEMORY ADDRESS FOR RELOCATION
  20. ;
  21. USRVECT  EQU $0A             ;APPLESOFT USR VECTOR
  22. BASL     EQU $0B             ;WILL HOLD POINTER TO
  23. BASH     EQU $0C             ;BEGINNING OF RELOCATED PROGRAM
  24. ;
  25. OLDSTRT  EQU $3C             ;START ADRS FOR MOVE
  26. OLDEND   EQU $3E             ;END ADRS FOR MOVE
  27. NEWSTRT  EQU $42             ;DESTINATION FOR MOVE
  28. ;
  29. LINNUM   EQU $50             ;CONVERTED USR ARGUMENT
  30. ;
  31. ;*** PARM AREA FOR CALLING SUBROUTINES ***
  32. ADRS1L   EQU $FA
  33. ADRS1H   EQU $FB
  34. ADRS2L   EQU $FC
  35. ADRS2H   EQU $FD
  36. FUNCTION EQU $FE
  37. RETCODE  EQU $FE
  38. FLAG     EQU $FF
  39. ;
  40. ; *** ADDRESSES ***
  41. ;
  42. STACK    EQU $100
  43. MLIALLOC EQU $BEF5           ;MEMORY ALLOCATION
  44. PRINTHEX EQU $FDDA           ;PRINT ACCUM IN HEX
  45. MOVE     EQU $FE2C           ;MONITOR MOVE ROUTINE
  46. MLI      EQU $BF00           ;MLI INTERFACE
  47. GETADR   EQU $E752           ;FIX FAC TO LINNUM ($50,$51)
  48. GIVAYF   EQU $E2F2           ;FLOAT A,Y TO FAC
  49. AUXMOVE  EQU $C311           ;AUX MEMORY MOVE ROUTINE
  50. ;
  51. ;
  52. ; *** BEGINNING OF CODE ***
  53. ;
  54. ; FIND OUT WHERE THIS CODE IS LOCATED IN MEMORY
  55. ;
  56. START    LDA #RTSINST        ;STORE AN RTS IN
  57.          STA MYADRS          ;ZERO PG LOCATION
  58.          JSR MYADRS
  59.          TSX                 ;CHECK STACK
  60.          DEX
  61.          LDA STACK,X         ;GET LOW BYTE OF ADRS
  62.          SEC
  63.          SBC #OFFSET         ;ADJUST IT
  64.          STA MYADRS          ;SET UP POINTER LO
  65.          LDA STACK+1,X
  66.          STA MYADRS+1        ;AND HI
  67. ;
  68. ; CALL PRODOS ROUTINE TO ALLOCATE MEMORY FOR RELOCATED PORTION
  69. ;
  70.          LDA #<EOF           ;CALC # PAGES TO MOVE: EOF-ROUTER+1
  71.          SEC
  72.          SBC #<ROUTER
  73.          CLC
  74.          ADC #1
  75.          STA PAGES
  76.          LDA PAGES
  77.          JSR MLIALLOC        ;ALLOCATE MEMORY
  78.          BCS ALLOCERR
  79.          STA MEMPTR+1        ;SAVE HI BYTE OF ADDRESS
  80.          LDA #00
  81.          STA MEMPTR          ;LO BYTE = 0
  82. ;
  83. ;
  84. ; USE RETURNED ADDRESS TO ADJUST HARDCODED ADDRESSES FOR INTERRUPT ROUTINES
  85. ;
  86.          LDA MEMPTR+1        ;A=HI BYTE OF RELOCATED PROGRAM
  87.          STA ALLPTRH         ;-->HI BYTE OF ADRS IN MLI ALLOC CALL
  88.          STA DEALPTRH        ;-->HI BYTE OF ADRS IN MLI DEALLOC CALL
  89.          LDA #>INTHAND        ;A=LO ADDRESS OF INT HANDLER
  90.          STA ALLADRSL        ;-->PARM LO BYTE OF ADRS OF INT HANDLER
  91.          LDA MEMPTR+1        ;A=HI ADRS WHERE INT HANDLER WILL BE RELOCATED
  92.          STA ALLADRSH        ;-->PARM HI BYTE OF ADRS OF INT HANDLER
  93. ;
  94. ; MOVE THE ADJUSTED CODE INTO THE ALLOCATED MEMORY AREA
  95. ;
  96.          LDA MYADRS          ;PREPARE FOR MEMORY MOVE
  97.          STA OLDSTRT
  98.          LDX MYADRS+1
  99.          INX
  100.          STX OLDSTRT+1       ;FROM MYADRS
  101.          LDA MYADRS
  102.          CLC
  103.          ADC #$FF
  104.          STA OLDEND
  105.          LDA PAGES           ;TO MYADRS + PAGES*256 + $FF
  106.          ADC MYADRS+1
  107.          STA OLDEND+1
  108.          LDA MEMPTR          ;MOVE TO ADRS RETURNED BY MEMORY ALLOCATOR
  109.          STA NEWSTRT
  110.          LDA MEMPTR+1
  111.          STA NEWSTRT+1
  112.          LDY #$00
  113.          JSR MOVE            ;MOVE COMPLETED
  114. ;
  115. ; SET UP USER VECTOR AND PREPARE INTERRUPT ROUTINES, THEN EXIT
  116. ;
  117.          LDA MEMPTR+1        ;GET OUR NEW ADDRESS
  118.          STA MYADRS+1
  119.          LDA MEMPTR          
  120.          STA MYADRS   
  121.          LDA #JMPINST        ;SET UP USR VECTOR      
  122.          STA USRVECT         ;TO POINT TO NEW ADDRESS
  123.          LDA MYADRS
  124.          STA BASL            ;BASL AND BASH ARE OUR NEW HOOKS TO THE ROUTINES
  125.          LDA MYADRS+1
  126.          STA BASH
  127. ;
  128.          LDA #STOPSONG        ;DEACTIVATE MIDI INTERRUPTS
  129.          STA FUNCTION
  130.          JSR USRVECT         ;(CALL SUBROUTINE ROUTER)
  131. ;
  132.          LDA #ALLOCINT       ;ALLOCATE INTERRUPTS
  133.          STA FUNCTION
  134.          JSR USRVECT
  135.          RTS
  136. ;
  137. PAGES    DFB $05             ;LENGTH OF ALLOCATION (RECALCULATED BY PGM)
  138. ;
  139. ALLOCERR JSR PRINTHEX        ;PRINT ERROR CODE
  140.          BRK                 ;AND STOP
  141. ;
  142. ;
  143. ;
  144. ;****************************************
  145. ;* SUBROUTINE ROUTER & PSEUDO ZERO PAGE
  146. ;****************************************
  147. ;
  148.          ORG START+$100
  149. ;
  150. ; THIS IS THE CODE THAT WILL BE RELOCATED TO HIGH MEMORY
  151. ;
  152. ROUTER   CLV
  153.          BVC ROUTER1
  154. ;
  155. ; MAKE SPACE FOR VARIABLES THAT CAN BE CONTROLLED BY CALLER
  156. ;
  157. ;
  158. MIDISLOT DFB $20             ;SLOT # TIMES 16
  159. TIMERLO  DFB $88             ;SEED FOR TIMER - SEE ACTIVATE SUBROUTINE
  160. TIMERHI  DFB $08
  161. ;
  162. QINSREG  DFB $00
  163. QOUTREG  DFB $00             ;OUTPUT DATA REGISTER
  164. ;
  165. COUNTHI  DFB $00
  166. COUNTLO  DFB $00
  167. ;
  168. QBEGIN   DFB $00,$08         ;AUX MEM BEGIN OF QUEUE
  169. QEND     DFB $00,$C0         ;AUX MEM END OF QUEUE + 1
  170. QSTAT    DFB $00             ;QUEUE STATUS: 0=EMPTY, FF=FULL, 1=IN USE
  171. QHEAD    DFB $00,$08         ;HEAD POINTER
  172. QTAIL    DFB $00,$08         ;TAIL POINTER
  173. DLYSTAT  DFB $00             ;FF=DELAY IN PROGRESS, 00=NO DELAY,
  174. ;                            ;1,2=DELAY BEING READ
  175. ;
  176. LASTSTAT DFB $90             ;LAST STATUS BYTE READ
  177. LASTDATA DFB $90             ;LAST DATA BYTE PROCESSED
  178. CODEFLAG DFB $00             ;FLAG TO DETERMINE WHETHER TO EXECUTE USER CODE
  179. CODEHOOK DFB $00,$00         ;IF CODEFLAG IS NON-ZERO, PROGRAM WILL USE THIS
  180. ;                            ;ADDRESS AS A JUMP VECTOR WHENEVER A MIDI BYTE
  181. ;                            ;IS TRANSMITTED
  182. MIDIBYTE DFB $00             ;MIDI OUTPUT REGISTER.  
  183. TEMPREQ  DFB $00             ;TO REQUEST TEMPO CHANGE, POPULATE TIMERLO AND HI
  184. ;                            ;THEN PUT NON-ZERO VALUE IN TEMPREQ
  185. USERFLAG DFB $FF             ;FOR BASIC PROGRAMS, TO DETECT WHEN NOTES PLAYED.
  186. ;
  187. FORMAT   DFB $00             ;$00 TO PLAY ALBUM FILES, $01 TO PLAY MFF0 FILES
  188. ;
  189. ;
  190. ; *** PARM AREAS ***
  191. ;
  192. ALLOCPRM DFB $02   ;PARM AREA FOR ALLOC INTERRUPT
  193. ALINTNUM DFB $00   ;INTERRUPT NUMBER
  194. ALLADRSL DFB >INTHAND   ;LOW BYTE OF INTERRUPT HANDLER ADRS
  195. ALLADRSH DFB <INTHAND   ;HI BYTE OF INTERRUPT HANDLER ADRS
  196. ;
  197. DEALPRM  DFB $01   ;PARM AREA FOR DEALLOC INTERRUPT
  198. DEINTNUM DFB $00
  199. ;
  200. ;                            ;offset = $22
  201. ROUTER1  LDA FUNCTION
  202.          ASL A               ;MULTIPLY SUB # BY 2
  203.          ADC #>SUBTABLE      ;ADD OFFSET OF SUBROUTINE TABLE
  204.          PHA                 ;SAVE ON STACK
  205.          TAY                 
  206.          LDA (BASL),Y        ;GET LO BYTE OFFSET OF SUB FROM TABLE
  207.          LDY #>SUBJMPL
  208.          STA (BASL),Y        ;STORE AT SUB JUMP VECTOR LOW
  209.          PLA                 ;GET OFFSET
  210.          TAY
  211.          INY                 ;ADD 1
  212.          LDA (BASL),Y        ;GET HI BYTE OFFSET OF SUB FROM TABLE
  213.          SEC
  214.          SBC #<ROUTER        ;SUBTRACT ROUTER HI ADDRESS TO GET PURE OFFSET
  215.          CLC
  216.          ADC BASH            ;ADD BASE ADDRESS TO GET RELOC ADRS OF SUBROUTINE
  217.          LDY #>SUBJMPH       ;STORE AT SUB VECTOR HIGH
  218.          STA (BASL),Y
  219.          DFB $4C             ;JMP TO SPECIFIED ADRS
  220. SUBJMPL  DFB $00
  221. SUBJMPH  DFB $00
  222. ;
  223. ; *** SUBROUTINE - ALLOCATE INTERRUPT (#4)
  224. ; offset=$41
  225. ALLOCIN1 JSR MLI             ;ALLOCATE INTERRUPT
  226.          DFB $40             
  227. ALLPTRL  DFB >ALLOCPRM       ;ADRS OF PARM LIST
  228. ALLPTRH  DFB <ALLOCPRM       ;HI BYTE WILL BE MODIFIED BY PGM        
  229.          BCS ERRBRK          ;IF ERROR - BREAK OUT
  230.          LDY #>ALINTNUM       ;GET LO BYTE OF ADRS OF INTERRUPT NUMBER
  231.          LDA (BASL),Y        ;GET THE INTERRUPT NUMBER
  232.          LDY #>DEINTNUM       ;GET LO BYTE OF ADRS OF DEALLOC INT NUMBER
  233.          STA (BASL),Y        ;STORE INT NUMBER AT THAT ADDRESS (PSEUDO ZP)
  234.          RTS
  235. ;
  236. ERRBRK   JSR PRINTHEX        ;ANY ERROR - BREAK OUT
  237.          BRK
  238. ;
  239. ; *** SUBROUTINE: DEALLOCATE INTERRUPT  (#5)
  240. ;offset = $55
  241. DEALLIN1 JSR MLI             ;MLI DEALLOC
  242.          DFB $41             ;CODE FOR DEALLOC
  243. DEALPTRL DFB >DEALPRM        ;ADRS OF PARM LIST
  244. DEALPTRH DFB <DEALPRM
  245.          BCS ERRBRK          ;ERRORS? BREAK OUT
  246.          RTS
  247. ;offset=$5e
  248. INTHAND  CLD                 ; FOR PRODOS
  249.          LDA #INTHANDL       ; GET SUBROUTINE # OF INTERRUPT HANDLER
  250.          STA FUNCTION
  251.          JMP USRVECT
  252. ;offset=$66
  253. ;
  254. ;
  255. ; DEFINE SUBROUTINE NUMBERS RECOGNIZED BY USR VECTOR
  256. USRHOOK  EQU $00   
  257. INTHANDL EQU $01
  258. ;
  259. ACTMIDI  EQU $02
  260. STOPSONG EQU $03
  261. ALLOCINT EQU $04
  262. DEALLINT EQU $05
  263. ;
  264. ENQBYTE  EQU $06
  265. DEQBYTE  EQU $07
  266. INCHEAD  EQU $08
  267. INCTAIL  EQU $09
  268. CMPHDTL  EQU $0A
  269. STORHEAD EQU $0B
  270. GETTAIL  EQU $0C
  271. ;
  272. XMITHOOK EQU $0D
  273. SENDMIDI EQU $0E
  274. OUTHOOK  EQU $0F
  275. ;
  276. MIDIOUT  EQU $10
  277. AUXPEEK  EQU $11
  278. AUXPOKE  EQU $12
  279. ;
  280. ENQEVENT EQU $13
  281. ENQDELTA EQU $14
  282. DEQDELTA EQU $15
  283. DEQINSTR EQU $16
  284. NOTEOFF  EQU $17
  285. NOTEON   EQU $18
  286. AFTERTO  EQU $19
  287. CTRLCHG  EQU $20
  288. PROGCHG  EQU $21
  289. PRESSUR  EQU $22
  290. BENDER   EQU $23
  291. SYSEXF0  EQU $24
  292. SYSEXF7  EQU $25
  293. META     EQU $26
  294. CONVDLTA EQU $27
  295. PLAYEVNT EQU $28
  296. PLAYSONG EQU $29
  297. ;
  298. ;
  299. SUBTABLE DFB >USRHOOK1,<USRHOOK1                
  300.          DFB >INTHAND1,<INTHAND1                   
  301.          DFB >ACTMIDI1,<ACTMIDI1        
  302.          DFB >STOPSON1,<STOPSON1          
  303.          DFB >ALLOCIN1,<ALLOCIN1        
  304.          DFB >DEALLIN1,<DEALLIN1        
  305.          DFB >ENQBYTE1,<ENQBYTE1
  306.          DFB >DEQBYTE1,<DEQBYTE1
  307.          DFB >INCHEAD1,<INCHEAD1
  308.          DFB >INCTAIL1,<INCTAIL1
  309.          DFB >CMPHDTL1,<CMPHDTL1
  310.          DFB >STORHEA1,<STORHEA1
  311.          DFB >GETTAIL1,<GETTAIL1
  312.          DFB >XMITHOO1,<XMITHOO1
  313.          DFB >SENDMID1,<SENDMID1
  314.          DFB >OUTHOOK1,<OUTHOOK1
  315. ; 
  316.          DFB >MIDIOUT1,<MIDIOUT1
  317.          DFB >AUXPEEK1,<AUXPEEK1
  318.          DFB >AUXPOKE1,<AUXPOKE1
  319.          DFB >ENQEVEN1,<ENQEVEN1
  320.          DFB >ENQDELT1,<ENQDELT1
  321.          DFB >DEQDELT1,<DEQDELT1
  322.          DFB >DEQINST1,<DEQINST1 
  323.          DFB >NOTEOFF1,<NOTEOFF1
  324.          DFB >NOTEON1,<NOTEON1
  325.          DFB >AFTERTO1,<AFTERTO1
  326.          DFB >CTRLCHG1,<CTRLCHG1
  327.          DFB >PROGCHG1,<PROGCHG1
  328.          DFB >PRESSUR1,<PRESSUR1
  329.          DFB >BENDER1,<BENDER1
  330.          DFB >SYSEXF01,<SYSEXF01
  331.          DFB >SYSEXF71,<SYSEXF71
  332.          DFB >META1,<META1
  333.          DFB >CONVDLT1,<CONVDLT1
  334.          DFB >PLAYEVN1,<PLAYEVN1
  335.          DFB >PLAYSON1,<PLAYSON1
  336. ;
  337. ;
  338. ; SUBROUTINE: SENDMIDI - TRANSMITS MIDI BYTE TO MIDI OUT
  339. ;
  340. SENDMID1 LDY #>MIDISLOT      ;GET MIDI SLOT IN X
  341.          LDA (BASL),Y
  342.          TAX
  343.          LDA FLAG            ;GET BYTE TO XMIT IN A
  344.          STA $C089,X         ;SEND BYTE OUT VIA MIDI
  345. WAITTDRE LDA $C088,X
  346.          AND #$02
  347.          BEQ WAITTDRE
  348.          RTS
  349. ;
  350. ; *** SUBROUTINE: MIDIOUT - SEND SEVERAL BYTES OUT TO MIDIOUT
  351. ;
  352. ; ADRS1 = START ADRS, ADRS2=END ADRS OR 0 TO XMIT UNTIL FF REACHED
  353. ;
  354. MIDIOUT1 LDA ADRS2H
  355.          CMP ADRS1H
  356.          BCC MIDIOUT2
  357.          LDA ADRS2H
  358.          CMP ADRS1H
  359.          BCC MIDIOUT2        ;IF HI < LO ADRS, USE MIDIOUT2 ROUTINE
  360. ;
  361. MIDILOOP LDY #$00
  362.          LDA (ADRS1L),Y      ;SEND BYTE AT ADDRESS 1
  363.          STA FLAG
  364.          LDA #SENDMIDI
  365.          STA FUNCTION
  366.          JSR USRVECT
  367. ;
  368.          LDA ADRS1L          ;ADD 1 TO ADDRESS 1
  369.          ADC #$01
  370.          STA ADRS1L
  371.          LDA ADRS1H
  372.          ADC #$00
  373.          STA ADRS1H
  374. ;
  375.          LDA ADRS1H          ;IF ADDRESS1 <= ADDRESS2, LOOP AGAIN
  376.          CMP ADRS2H
  377.          BCC MIDILOOP
  378.          LDA ADRS1L
  379.          CMP ADRS2L
  380.          BCC MIDILOOP
  381.          BEQ MIDILOOP
  382. MIDIDONE RTS
  383. ;
  384. MIDIOUT2 LDY #$00            ;IF ADDRESS1 = FF, GET OUT
  385.          LDA (ADRS1L),Y
  386.          CMP #$FF
  387.          BEQ MIDIDONE
  388.          STA FLAG            ;ELSE SEND THE BYTE
  389.          LDA #SENDMIDI
  390.          STA FUNCTION
  391.          JSR USRVECT
  392. ;
  393.          LDA ADRS1L          ;ADD 1 AND LOOP AGAIN
  394.          ADC #$01
  395.          STA ADRS1L
  396.          LDA ADRS1H
  397.          ADC #$00
  398.          STA ADRS1H
  399.          CLV
  400.          BVC MIDIOUT2
  401. ;
  402. ;
  403. ; *** AUXPEEK ***
  404. ;
  405. AUXPEEK1 LDA ADRS1L
  406.          STA OLDSTRT
  407.          STA OLDEND
  408.          LDA ADRS1H
  409.          STA OLDSTRT+1
  410.          STA OLDEND+1
  411.          LDA #>FLAG
  412.          STA NEWSTRT
  413.          LDA #<FLAG
  414.          STA NEWSTRT+1
  415.          CLC
  416.          JSR AUXMOVE
  417.          RTS
  418. ;
  419. ; *** AUXPOKE ***
  420. ;
  421. AUXPOKE1 LDA #>FLAG
  422.          STA OLDSTRT
  423.          STA OLDEND
  424.          LDA #<FLAG
  425.          STA OLDSTRT+1
  426.          STA OLDEND+1
  427.          LDA ADRS1L
  428.          STA NEWSTRT
  429.          LDA ADRS1H
  430.          STA NEWSTRT+1
  431.          SEC
  432.          JSR AUXMOVE
  433.          RTS
  434. ;
  435. ; 
  436. ; *** SUBROUTINE: STOPSONG: DEACTIVATE INTERRUPTS 
  437. ;
  438. STOPSON1 SEI                 ;STOP INTERRUPTS
  439.          LDY #>MIDISLOT       ;X=SLOT * 16
  440.          LDA (BASL),Y
  441.          TAX
  442.          LDA #$01            ;PLUG THE TIMER
  443.          STA $C080,X
  444.          LDA #$13            ;RESET THE MIDI PORTS (MASTER RESET)
  445.          STA $C088,X         ;  8 BITS NO PARITY 2 STOP BITS
  446.          LDA #$11            ;
  447.          STA $C088,X
  448.          CLI                 ;RESUME BUSINESS
  449.          RTS
  450. ;
  451. ; *** SUBROUTINE: ACTIVATE INTERRUPTS
  452. ;
  453. ACTMIDI1 LDY #>MIDISLOT
  454.          LDA (BASL),Y        ;GET SLOT*16 IN X
  455.          TAX
  456.          LDA #$01            ;STOP TIMER
  457.          STA $C080,X
  458.          SEI                 ;STOP INTERRUPTS
  459.          LDA #$43            ;RESET THE 6840 PTM
  460.          STA $C081,X         ;INITIALIZE TIMER
  461.          LDA #$04 
  462.          STA $C080,X         ;REGISTER=4
  463.          LDY #>TIMERHI       ;WRITE HI BYTE
  464.          LDA (BASL),Y
  465.          STA $C084,X
  466.          LDA #$05            ;REGISTER=5
  467.          STA $C080,X         
  468.          LDY #>TIMERLO       ;WRITE LO BYTE
  469.          LDA (BASL),Y
  470.          STA $C085,X
  471.          LDA #$1             ;WRITE CONTROL REG 2
  472.          STA $C080,X
  473.          LDA #$C3            ;CONTINUOUS, IRQ AND TIMER OUTPUT ENABLED
  474.          STA $C080,X         ;
  475. ;         LDA #$31            ;TDRE INT?
  476. ;         STA $C088,X
  477.          CLI                 ;GET READY
  478.          LDA #$0             ;TO ACTIVATE (ZERO IN CTRL REG 1)
  479.          STA $C080,X         ;NOW!
  480.          RTS
  481. ;
  482. ; SUBROUTINE 0: USER HOOK
  483. ;
  484. USRHOOK1 JSR GETADR          ;CONVERT USR ARGUMENT TO INTEGER
  485.          LDA LINNUM+1        ;CHECK HI BYTE
  486.          BEQ GOODBYT
  487. BADBYT   LDY BASL            ;IF >255, RETURN BASE ADDRESS
  488.          LDA BASH
  489.          JSR GIVAYF
  490.          RTS   
  491. GOODBYT  LDA LINNUM
  492.          BEQ BADBYT           ;IF OUT OF RANGE, RETURN BASE ADRS
  493.          CMP #MAXSUBS
  494.          BCS BADBYT
  495.          STA FUNCTION
  496.          JMP USRVECT
  497. ;
  498. ;SUBROUTINE #1: INTERRUPT HANDLER
  499. ;  
  500. INTHAND1 CLD                 ;FOR PRODOS
  501.          LDY #>MIDISLOT      
  502.          LDA (BASL),Y
  503.          TAX
  504.          LDA $C081,X         ;CHECK CLOCK INTERRUPT FLAG
  505.          BPL NOTCLOCK
  506.          LDA #$01            ;STOP CLOCK AND PROCESS THE PULSE
  507.          STA $C080,X
  508.          CLV
  509.          BVC PULSENOW
  510. ;
  511. NOTCLOCK LDA $C088,X         ;CHECK BIT 2 OF ACIA CONTROL REG
  512.          AND #$02            ;TO SEE IF TDRE CONDITION EXISTS
  513.          BNE TDRE
  514.          LDA #$00            ;NOT OUR INTERRUPT - GET OUT
  515.          STA $C080,X
  516.          SEC                 ;DON'T CLAIM IT
  517.          RTS
  518. ;
  519. GETOUT   LDY #>MIDISLOT
  520.          LDA (BASL),Y
  521.          TAX
  522.          LDA #$00            ;START THE CLOCK AGAIN
  523.          STA $C080,X
  524.          CLC                 ;CLAIM THE INTERRUPT
  525.          RTS
  526. ;
  527. PULSENOW LDY #>DLYSTAT       ;FIND OUT WHERE TO GO 
  528.          LDA (BASL),Y        
  529.          BPL TDRE            ;IF DLYSTAT >= $80 
  530.          LDY #>COUNTLO       ;DELAY IS IN PROGRESS
  531.          LDA (BASL),Y        ;SO COUNT DOWN YOUR DELTA TIME
  532.          SEC
  533.          SBC #$01
  534.          STA (BASL),Y
  535.          CMP #$FF
  536.          BNE GETOUT          
  537. ;
  538.          LDY #>COUNTHI
  539.          LDA (BASL),Y
  540.          SEC
  541.          SBC #$01
  542.          STA (BASL),Y
  543.          CMP #$FF
  544.          BNE GETOUT
  545. ;
  546.          LDA #$00            ;DONE COUNTING-DLYSTAT=0
  547.          LDY #>DLYSTAT
  548.          STA (BASL),Y
  549.          LDY #>COUNTHI
  550.          STA (BASL),Y
  551.          LDY #>COUNTLO
  552.          STA (BASL),Y
  553. ;
  554.          LDY #>USERFLAG
  555.          STA (BASL),Y
  556.          CLV
  557.          BVC GETOUT
  558. ;
  559. TDRE     LDY #>FORMAT
  560.          LDA (BASL),Y
  561.          BEQ OLDFORM
  562. ;                            ; NEW FORMAT: TO PLAY MIDI FORMAT 0
  563.          LDA #PLAYEVNT
  564.          STA FUNCTION
  565.          JSR USRVECT
  566.          BCS GETOUT
  567. ;
  568.          LDA #DEQDELTA
  569.          STA FUNCTION
  570.          JSR USRVECT
  571.          BCS GETOUT
  572. ;
  573.          LDA #CONVDLTA
  574.          STA FUNCTION
  575.          JSR USRVECT
  576. ;
  577.          LDA ADRS2L          ;SET COUNTER BASED ON NEW DELTA TIME
  578.          LDY #>COUNTHI
  579.          STA (BASL),Y
  580.          LDA ADRSH
  581.          LDY #>COUNTLO
  582.          STA (BASL),Y
  583.          LDA #$FF            ;SET MODE TO COUNTING
  584.          LDY #>DLYSTAT
  585.          STA (BASL),Y
  586.          RTS
  587. ;
  588. OLDFORM  LDY #>DLYSTAT       ;DLYSTAT < $80.  
  589.          LDA (BASL),Y
  590.          BNE CHKDLY          ;IF DLYSTAT <> 0, SET UP THE DELAY
  591. ;                            ; ELSE IT IS TIME TO XMIT THE DATA
  592.          LDA #DEQBYTE            ;GET BYTE FROM QUEUE
  593.          STA FUNCTION
  594.          JSR USRVECT
  595.          BCS GETOUT          ;IF ERROR, TRY LATER
  596.          LDY #>QOUTREG
  597.          LDA (BASL),Y        ;GET THE BYTE
  598.          CMP #$FD            ;IS IT >= $FD?
  599.          BCS SIGNAL          ;YES - CHECK FOR TEMPO OR DURATION CHANGE
  600.          LDA #XMITHOOK       ;NO - CALL SUB13 TO PROCESS TRANSMISSION
  601.          STA FUNCTION
  602.          JSR USRVECT         ;     
  603.          CLV
  604.          BVC TDRE            ;REPEAT UNTIL STATUS CHANGES
  605. BOOST    CLV
  606.          BVC GETOUT
  607. ;
  608. CHKDLY   LDY #>DLYSTAT       
  609.          LDA (BASL),Y
  610.          CMP #$02            ;ARE WE READING THE SECOND BYTE?
  611.          BEQ TWO
  612.          LDA #DEQBYTE            ;NO - READ QUEUE
  613.          STA FUNCTION
  614.          JSR USRVECT
  615.          BCC GOTIT           ;IF EMPTY QUEUE
  616.          LDA #$01            ;DLYSTAT = 1
  617.          LDY #>DLYSTAT       ;GET OUT
  618.          STA (BASL),Y
  619.          CLV
  620.          BVC BOOST
  621. GOTIT    LDA #$02
  622.          LDY #>DLYSTAT       ;DLYSTAT = 2
  623.          STA (BASL),Y
  624.          LDY #>QOUTREG       ;GET THE BYTE
  625.          LDA (BASL),Y
  626.          LDY #>COUNTHI       ;FOR THE HI COUNTER
  627.          STA (BASL),Y
  628. TWO      LDA #DEQBYTE            ; READ QUEUE
  629.          STA FUNCTION
  630.          JSR USRVECT
  631.          BCS BOOST
  632.          LDY #>QOUTREG       ;PUT THE DATA
  633.          LDA (BASL),Y
  634.          LDY #>COUNTLO       ;INTO COUNTLO
  635.          STA (BASL),Y
  636.          LDA #$FF            ;SET DLYSTAT = FF
  637.          LDY #>DLYSTAT
  638.          STA (BASL),Y
  639.          CLV
  640.          BVC BOOST
  641. ;
  642. DURATION CMP #$FF            ;TWO BYTE DURATION (FF)
  643.          BEQ CHKDLY          ;  CONTINUE NORMALLY
  644. ;                            ;ONE BYTE DURATION (FD)
  645.          LDA #$00            ;  ZERO OUT HI COUNTER
  646.          LDY #>COUNTHI       
  647.          STA (BASL),Y           
  648.          LDA #$02            ;SET DLYSTAT = 2
  649.          LDY #>DLYSTAT
  650.          STA (BASL),Y                 
  651.          CLV
  652.          BVC TWO             ;PROCESS THE ONE BYTE
  653. ;
  654. SIGNAL   CMP #$FE
  655.          BNE DURATION
  656.          LDY #>DLYSTAT       ;TEMPO CHANGE (FE).  
  657.          LDA (BASL),Y        ;DOES DLYSTAT = 2?
  658.          CMP #$02
  659.          BEQ TEMPO2 
  660.          LDA #DEQBYTE
  661.          STA FUNCTION
  662.          JSR USRVECT
  663.          BCC GOODQ
  664.          LDA #$01            ;IF ERR READING Q, DLYSTAT=1 AND EXIT
  665.          LDY #>DLYSTAT
  666.          STA (BASL),Y
  667. BOOST1   CLV
  668.          BVC BOOST
  669. GOODQ    LDA #$02            ;DLYSTAT=2        
  670.          LDY #>DLYSTAT
  671.          STA (BASL),Y
  672.          LDY #>QOUTREG       ;PUT BYTE IN TIMER HI REGISTER
  673.          LDA (BASL),Y
  674.          LDY #>TIMERHI
  675.          STA (BASL),Y
  676. TEMPO2   LDA #DEQBYTE
  677.          STA FUNCTION
  678.          JSR USRVECT
  679.          BCS BOOST1
  680.          LDY #>QOUTREG
  681.          LDA (BASL),Y
  682.          LDY #>TIMERLO
  683.          STA (BASL),Y
  684.          LDA #$00
  685.          LDY #>DLYSTAT
  686.          STA (BASL),Y
  687.          LDA #ACTMIDI
  688.          STA FUNCTION
  689.          JSR USRVECT
  690.          CLV
  691.          BVC BOOST1
  692. ;
  693.          CHN INTRUPT.SRC2
  694. ; ********************************************
  695. ; * INTRUPT.SRC2 - BACKGROUND MIDI MUSIC QUEUE
  696. ; * (C) 1992, ERIC RANGELL
  697. ; ********************************************
  698. ;
  699. ;
  700. ; SUBROUTINE - XMITHOOK
  701. ;
  702. XMITHOO1 LDY #>DLYSTAT       ;SET DLYSTAT = 0
  703.          LDA #$00
  704.          STA (BASL),Y
  705.          LDY #>QOUTREG       
  706.          LDA (BASL),Y
  707.          BPL RUNSTAT         ;CHECK IF STATUS BYTE
  708.          LDY #>LASTSTAT      ;IF YES - STORE IT AS LAST STATUS BYTE
  709.          STA (BASL),Y
  710. RUNSTAT  LDY #>LASTDATA      ;STORE CURR BYTE AS LAST DATA BYTE
  711.          STA (BASL),Y
  712.          LDY #>MIDIBYTE
  713.          STA (BASL),Y        ;FOR MIDI OUTPUT SUBROUTINE
  714.          LDA #OUTHOOK        ;PROCESS THE MIDI BYTE
  715.          STA FUNCTION
  716.          JSR USRVECT
  717.          RTS
  718. ;                  
  719. ENQBYTE1            LDY   #>QSTAT
  720.                     LDA   (BASL),Y
  721.                     BPL   DOENQ
  722.                     LDA   #$FF
  723.                     STA   RETCODE
  724.                     SEC   
  725.                     RTS   
  726. ;
  727. DOENQ               SEI   
  728.                     LDA   FLAG
  729.                     LDY   #>QINSREG
  730.                     STA   (BASL),Y
  731. ;
  732.                     LDA   #INCHEAD
  733.                     STA   FUNCTION
  734.                     JSR   USRVECT
  735. ;
  736.                     LDA   #STORHEAD
  737.                     STA   FUNCTION
  738.                     JSR   USRVECT
  739. ;
  740.                     LDA   #$01         ;SET QSTAT = 1 (IN USE)
  741.                     LDY   #>QSTAT
  742.                     STA   (BASL),Y
  743. ;
  744.                     LDA   #CMPHDTL
  745.                     STA   FUNCTION
  746.                     JSR   USRVECT
  747. ;
  748.                     BCC   QNOTFULL
  749.                     LDA   #$FF         ;SET QSTAT = FF (FULL)
  750.                     LDY   #>QSTAT
  751.                     STA   (BASL),Y
  752. ;
  753. QNOTFULL            CLC   
  754.                     CLI   
  755.                     RTS   
  756. ;
  757. ;
  758. DEQBYTE1            LDY   #>QSTAT
  759.                     LDA   (BASL),Y
  760.                     BNE   DODEQ
  761.                     LDA   #$01
  762.                     STA   RETCODE
  763.                     SEC   
  764.                     RTS   
  765. DODEQ               SEI   
  766.                     LDA   #INCTAIL
  767.                     STA   FUNCTION
  768.                     JSR   USRVECT
  769. ;
  770.                     LDA   #GETTAIL
  771.                     STA   FUNCTION
  772.                     JSR   USRVECT
  773. ;
  774.                     LDA   #$01         ;SET QSTAT=1
  775.                     LDY   #>QSTAT
  776.                     STA   (BASL),Y
  777. ;
  778.                     LDA   #CMPHDTL
  779.                     STA   FUNCTION
  780.                     JSR   USRVECT
  781. ;
  782.                     BCC   QNOTEMTY
  783.                     LDA   #$00         ;SET QSTAT = 0 (EMPTY)
  784.                     LDY   #>QSTAT
  785.                     STA   (BASL),Y
  786. ;
  787. QNOTEMTY            CLC   
  788.                     CLI   
  789.                     RTS   
  790. ;
  791. ;
  792. INCHEAD1            LDY   #>QHEAD
  793.                     LDA   (BASL),Y
  794.                     CLC   
  795.                     ADC   #$01
  796.                     STA   (BASL),Y
  797.                     LDY   #>QHEAD+1
  798.                     LDA   (BASL),Y
  799.                     ADC   #$00
  800.                     STA   (BASL),Y
  801.                     LDY   #>QEND+1
  802.                     LDA   (BASL),Y
  803.                     LDY   #>QHEAD+1
  804.                     CMP   (BASL),Y
  805.                     BNE   EXITHD
  806.                     LDY   #>QEND
  807.                     LDA   (BASL),Y
  808.                     LDY   #>QHEAD
  809.                     CMP   (BASL),Y
  810.                     BNE   EXITHD
  811.                     LDY   #>QBEGIN
  812.                     LDA   (BASL),Y
  813.                     LDY   #>QHEAD
  814.                     STA   (BASL),Y
  815.                     LDY   #>QBEGIN+1
  816.                     LDA   (BASL),Y
  817.                     LDY   #>QHEAD+1
  818.                     STA   (BASL),Y
  819. EXITHD              RTS   
  820. ;
  821. ;
  822. INCTAIL1            LDY   #>QTAIL
  823.                     LDA   (BASL),Y
  824.                     CLC   
  825.                     ADC   #$01
  826.                     STA   (BASL),Y
  827.                     LDY   #>QTAIL+1
  828.                     LDA   (BASL),Y
  829.                     ADC   #$00
  830.                     STA   (BASL),Y
  831.                     LDY   #>QEND+1
  832.                     LDA   (BASL),Y
  833.                     LDY   #>QTAIL+1
  834.                     CMP   (BASL),Y
  835.                     BNE   EXITTL
  836.                     LDY   #>QEND
  837.                     LDA   (BASL),Y
  838.                     LDY   #>QTAIL
  839.                     CMP   (BASL),Y
  840.                     BNE   EXITTL
  841.                     LDY   #>QBEGIN
  842.                     LDA   (BASL),Y
  843.                     LDY   #>QTAIL
  844.                     STA   (BASL),Y
  845.                     LDY   #>QBEGIN+1
  846.                     LDA   (BASL),Y
  847.                     LDY   #>QTAIL+1
  848.                     STA   (BASL),Y
  849. EXITTL              RTS   
  850. ;
  851. ;
  852. CMPHDTL1            LDY   #>QHEAD+1
  853.                     LDA   (BASL),Y
  854.                     LDY   #>QTAIL+1
  855.                     CMP   (BASL),Y
  856.                     BNE   GOODCMP
  857.                     LDY   #>QHEAD
  858.                     LDA   (BASL),Y
  859.                     LDY   #>QTAIL
  860.                     CMP   (BASL),Y
  861.                     BNE   GOODCMP
  862.                     SEC   
  863.                     RTS   
  864. GOODCMP             CLC   
  865.                     RTS   
  866. ;
  867. ;
  868. STORHEAD            LDY   #>QINSREG
  869.                     LDA   (BASL),Y
  870.                     STA   FLAG
  871.                     LDY   #>QHEAD
  872.                     LDA   (BASL),Y
  873.                     STA   ADRS1L
  874.                     LDY   #>QHEAD+1
  875.                     LDA   (BASL),Y
  876.                     STA   ADRS1H
  877.                     LDA   #AUXPOKE
  878.                     STA   FUNCTION
  879.                     JSR   USRVECT
  880.                     RTS   
  881. ;                  
  882. ;
  883. GETTAIL1            LDY   #>QTAIL
  884.                     LDA   (BASL),Y
  885.                     STA   ADRS1L
  886.                     LDY   #>QTAIL+1
  887.                     LDA   (BASL),Y
  888.                     STA   ADRS1H
  889.                     LDA   #AUXPEEK
  890.                     STA   FUNCTION
  891.                     JSR   USRVECT
  892.                     LDA   FLAG
  893.                     LDY   #>QOUTREG
  894.                     STA   (BASL),Y
  895.                     RTS
  896. ;                                      
  897.                     CHN   INTRUPT.SRC3
  898. ; ********************************************
  899. ; * INTRUPT.SRC3-  MIDI FILTERING ROUTINE
  900. ; ********************************************
  901. ;
  902. ;
  903. ; SUBROUTINE: OUTHOOK - LOOK AT MIDI STREAM AND PROCESS ACCORDINGLY
  904. ;             CALL THE SENDMIDI SUBROUTINE IF WANT TO XMIT THE BYTE
  905. ;
  906. OUTHOOK1 LDY #>CODEFLAG      ;CHECK IF USER SET UP OWN CODE
  907.          LDA (BASL),Y
  908.          BEQ SENDIT          ;IF NO CHECK FOR TEMPO REQUEST
  909.          LDA #JMPINST        ;STORE A JMP IN ZERO PAGE VECTOR
  910.          STA MYADRS
  911.          LDY #>CODEHOOK      ;STORE LO BYTE OF USER'S ADRS
  912.          LDA (BASL),Y
  913.          STA MYADRS+1
  914.          LDY #>CODEHOOK+1    ;STORE HI BYTE
  915.          LDA (BASL),Y
  916.          STA MYADRS+2
  917.          JSR MYADRS          ;PERFORM USER'S CODE
  918.          BCS CHKTEMP         ;IF USER DOESN'T WANT BYTE SENT, GET OUT
  919. ;
  920. SENDIT   LDA #SENDMIDI       ;ELSE SEND THE BYTE       
  921.          STA FUNCTION
  922.          LDY #>MIDIBYTE
  923.          LDA (BASL),Y
  924.          STA FLAG
  925.          JSR USRVECT
  926. ;
  927. ;
  928. ;;;;;NEW SUB: TEMPOCHG
  929. ;
  930. CHKTEMP  LDY #>TEMPREQ
  931.          LDA (BASL),Y
  932.          BEQ ESCAPE          ; PROCESS REQUESTS TO CHANGE TEMPO
  933.          LDA #$0
  934.          STA (BASL),Y        ;RESET TEMPREQ FLAG TO 0 SO ONLY CALLED ONCE
  935. ;
  936.          LDY #>MIDISLOT
  937.          LDA (BASL),Y
  938.          TAX
  939.          LDA #$04 
  940.          STA $C080,X         ;REGISTER=4
  941.          LDY #>TIMERHI       ;WRITE HI BYTE
  942.          LDA (BASL),Y
  943.          STA $C084,X
  944.          LDA #$05            ;REGISTER=5
  945.          STA $C080,X         
  946.          LDY #>TIMERLO       ;WRITE LO BYTE
  947.          LDA (BASL),Y
  948.          STA $C085,X 
  949. ESCAPE   RTS
  950. ;
  951. ;
  952. ENQEVEN1 NOP
  953. ;
  954. ENQDELT1 NOP
  955. ;
  956. DEQDELT1 NOP
  957. ;
  958. ;
  959. DEQINST1 NOP
  960. ;
  961. NOTEOFF1 NOP
  962. ;
  963. NOTEON1  NOP
  964. ;
  965. AFTERTO1 NOP
  966. ;
  967. CTRLCHG1 NOP
  968. ;
  969. PROGCHG1 NOP
  970. ;
  971. PRESSUR1 NOP
  972. ;
  973. BENDER1  NOP
  974. ;
  975. SYSEXF01 NOP
  976. ;
  977. SYSEXF71 NOP
  978. ;
  979. META1    NOP
  980. ;
  981. CONVDLT1 NOP
  982. ;
  983. PLAYEVN1 NOP
  984. ;
  985. PLAYSON1 NOP
  986. ;
  987. ;
  988. ;
  989. EOF      BRK
  990.