home *** CD-ROM | disk | FTP | other *** search
/ Source Code 1992 March / Source_Code_CD-ROM_Walnut_Creek_March_1992.iso / msdos / asmutl / tsrdemo2.arc / TSRDEMO2.ASM next >
Assembly Source File  |  1987-03-10  |  46KB  |  1,503 lines
  1. page    60,132
  2. ;==============================================================================
  3. ; TSRDEMO2.ASM
  4. ; Thomas Brandenborg
  5. ; 87.02.11
  6. ;
  7. ; Sample demonstration of a safe approach for writing TSR programmes.
  8. ;
  9. ;------------------------------------------------------------------------------
  10. ; Copyright 1987 by Thomas Brandenborg. All Rights Reserved
  11. ; Written for uploading to Compuserve Forums by
  12. ; 
  13. ;    Thomas Brandenborg
  14. ;    Lundbyesgade 11
  15. ;    DK-8000 Aarhus C
  16. ;    DENMARK
  17. ;
  18. ; This code is intended as a reference to users on Compuserve Forums
  19. ; on how to write Terminate-And-Stay resident programmes for Personal
  20. ; Cumputers running under DOS versions 2.00 and newer.
  21. ;
  22. ; The code is not part of any proprietary product, but is rather a
  23. ; demonstration of such techniques that may be used to write safe TSR
  24. ; programmes.
  25. ;
  26. ; All or part of it may, however, be used in other software products
  27. ; or otherwise distributed assuming the copyright holders Name & Address
  28. ; as listed above are included clearly and visibly in the documentation
  29. ; for such product.
  30. ;
  31. ; The copyright holder offers no warranty with this code whatsoever,
  32. ; including its fitness for any particular purpose. Neither shall he
  33. ; be liable for damages of any kind that may arise from its use.
  34. ;
  35. ;
  36. ; IF YOU THINK THIS CODE IS USEFUL:
  37. ;
  38. ; If you think this code has had some value to you, and in particular
  39. ; if you consider using all or parts of it in your own product, you
  40. ; may want to consider a smaller or larger donation to the author
  41. ; (Name & Address above) who spend his late night hours putting
  42. ; it together.
  43. ;
  44. ; As to the size of a such donation this is entirely up to your own
  45. ; judgement. It is suggested that you simply consider the value this
  46. ; code has had to you, the time you saved not having to write it your
  47. ; self... that should help you determine the right amount.
  48. ;
  49. ; Please notice that such donations are an entirely voluntary contribution.
  50. ; This holds true whatever your purpose is for using this code, and whatever
  51. ; the type of product and distribution you work with. The author has nothing
  52. ; against commercial software distribution and does not have any reason
  53. ; to restrict developers of commercial products in their use of this code.
  54. ;------------------------------------------------------------------------------
  55. ; COMPILING:    masm tsrdemo2;
  56. ; LINKING:    link tsrdemo2;
  57. ;         exe2bin tsrdemo2 tsrdemo2.com
  58. ;------------------------------------------------------------------------------
  59. ; Revisions
  60. ; Brandenborg 87.02.14    Added copyright notice & checked comments
  61. ; Brandenborg 87.02.17    Added full AX value in Set Ext Err call
  62. ; Brandenborg 87.02.25    Went through to optimize things
  63. ; Brandenborg 87.02.28    Added auto INT28 invocation in INT16 handler
  64. ; Brandenborg 87.03.01    Added INT21 filter for recursion onto console stack
  65. ; Brandenborg 87.03.02    Final cleanup of comments etc.
  66. ; Brandenborg 87.03.10    INT28 handler chains AFTER popup actions
  67. ;            InitPopup: INT21.33 (AL=2) not allowed for DOS 2.x
  68. ;            InitPopup: Set ext err info uses all regs
  69. ;==============================================================================
  70.  
  71. ;==============================================================================
  72. ; DEFINE BIOS DATA SEGMENT OFFSETS
  73. ;==============================================================================
  74.  
  75. BiosData    segment at 40h
  76.         org    17h
  77. KbFlag        label    byte        ;current shift status bits
  78.         org    18h
  79. KbFlag1        label    byte        ;current key status of toggle keys
  80. BiosData    ends
  81.  
  82. ;==============================================================================
  83. ; DEFINE OFFSETS WITHIN BIOS EXTRA DATA SEGMENT
  84. ;==============================================================================
  85.  
  86. BiosXX        segment at 50h
  87.         org    0
  88. StatusByte    label    byte        ;PrtSc status
  89. BiosXX        ends
  90.  
  91. ErrPrtSc    equ    -1        ;err during last PrtSc
  92. InPrtSc        equ    1        ;PrtSc in progress
  93.  
  94. ;==============================================================================
  95. ; DEFINE OFFSETS WITHIN OUR PSP
  96. ;==============================================================================
  97.  
  98. Cseg        segment byte public
  99.         org    2
  100. TopSeg        label    word        ;last seg in alloc block
  101.         org    2ch
  102. EnvSeg        label    word        ;seg of our environment copy
  103. Cseg        ends
  104.  
  105. ;==============================================================================
  106. ; DOS COM-FILE ENTRY POINT
  107. ;==============================================================================
  108.  
  109. Cseg        segment public byte
  110.         assume    cs:Cseg, ds:nothing, es:nothing, ss:nothing
  111.         org    100h
  112. ComEntry:    jmp    Init        ;JMP to init at bottom of seg
  113.  
  114. ;==============================================================================
  115. ; IDENTIFICATION CODES FOR THIS TSR (MUST BE UNIQUE FOR EACH CO-EXISTING TSR)
  116. ; HIGH BYTE OF GetId MUST NOT MATCH ANY AH REQUEST CODES FOR INT16H.
  117. ;==============================================================================
  118.  
  119. GetId        equ    'tc'            ;INT16h AX val to get MyId
  120. MyId        equ    'TC'            ;ID of this TSR
  121.  
  122. ;==============================================================================
  123. ; FLAGS AND PTRS FOR RESIDENT HANDLING
  124. ;==============================================================================
  125.  
  126. TsrMode        db    0            ;bits for various modes
  127. InInt08        equ    1 SHL 0            ;timer0 tick handler
  128. InInt09        equ    1 SHL 1            ;keyboard handler
  129. InInt13        equ    1 SHL 2            ;BIOS disk I/O
  130. InInt28        equ    1 SHL 3            ;INT28 handler
  131. In28Call    equ    1 SHL 4            ;we have issued INT28
  132. InPopup        equ    1 SHL 5            ;popup routine activated
  133. NewDos        equ    1 SHL 6            ;DOS 2.x in use
  134. InDosClr    equ    1 SHL 7            ;InDos=0 at popup time
  135.  
  136. KeyMode        db    0            ;bits for hotkey status
  137. HotIsShift    equ    1 SHL 0            ;hotkey is shift state
  138. InHotMatch    equ    1 SHL 1            ;so far keys match hotkey seq
  139. HotKeyOn    equ    1 SHL 2            ;full hotkey pressed
  140.  
  141. InDosPtr    label    dword            ;seg:off of InDos flag
  142. InDosOff    dw    0
  143. InDosSeg    dw    0
  144.  
  145. CritErrPtr    label    dword            ;seg:off of CritErr flag
  146. CritErrOff    dw    0
  147. CritErrSeg    dw    0
  148.  
  149. ;==============================================================================
  150. ; DATA FOR INT09H HANDLER TO CHECK FOR HOTKEY COMBINATION
  151. ;==============================================================================
  152.  
  153. ; ------------    EQU'S FOR BIT SHIFTS WITHIN KEYBOARD FLAGS
  154.  
  155. InsState    equ    80h
  156. CapsState    equ    40h
  157. NumState    equ    20h
  158. ScrollState    equ    10h
  159. AltShift    equ    08h
  160. CtlShift    equ    04h
  161. LeftShift    equ    02h
  162. RightShift    equ    01h
  163.  
  164. InsShift    equ    80h
  165. CapsShift    equ    40h
  166. NumShift    equ    20h
  167. ScrollShift    equ    10h
  168. HoldState    equ    08h
  169.  
  170. ; ------------    SCAN CODES FOR VARIOUS SHIFT KEYS
  171.  
  172. LeftDown    equ    42            ;scan code of left shift key
  173. LeftUp        equ    LeftDown OR 80h
  174. RightDown    equ    54            ;scan code of right shift key
  175. RightUp        equ    RightDown OR 80h
  176. AltDown        equ    56            ;scan code of alt key
  177. AltUp        equ    AltDown OR 80h
  178. CtlDown        equ    29            ;scan code of ctrl key
  179. CtlUp        equ    CtlDown OR 80h
  180.  
  181. ; ------------    MISC KEYBOARD DATA
  182.  
  183. KbData        equ    60h            ;keyboard data input
  184.  
  185. ;==============================================================================
  186. ; TO USE A SHIFT KEY COMBINATION AS HOT KEY:
  187. ;  -    SET THE FLAG HotIsShift IN KeyMode
  188. ;  -    DEFINE THE SHIFT STATUS BITS IN THE VARIABLE HotKeyShift
  189. ;
  190. ; TO USE A SERIES OF SCAN CODES AS HOT KEY:
  191. ;    CLEAR THE FLAG HotIsShift IN KeyMode
  192. ;  -    INSERT THE MAKE AND BREAK SCAN CODES IN THE HotKeySeq STRING
  193. ;    NOTE:    WITH THIS DEMO IMPLEMENTATION YOU SHOULD NOT USE A HOT KEY
  194. ;        SEQUENCE WHICH PRODUCES A KEY IN THE BIOS KEYBOARD QUEUE,
  195. ;        SINCE THE KEY IS NOT REMOVED BEFORE CALLING THE POPUP ROUTINE.
  196. ;
  197. ; NOTE:    HOTKEY TYPE AND CONTENTS OF HOTKEY VARIABLES MAY BE CHANGED AT RUN TIME
  198. ;==============================================================================
  199.  
  200. HotKeyShift    db    LeftShift OR RightShift    ;shift state IF HotIsShift=FF
  201.  
  202. HotKeySeq    db    LeftDown,LeftUp,LeftDown,LeftUp
  203. HotKeyLen    equ    $-HotKeySeq
  204. HotIndex    db    0            ;# key in seq to compare next
  205. BetweenKeys    db    0            ;timeout count between keys
  206. KeyTimeOut    equ    10            ;more ticks means not a hotkey
  207.  
  208. ;==============================================================================
  209. ; DATA FOR INT08H HANDLER TO CHECK FOR POPUP
  210. ;==============================================================================
  211.  
  212. SafeWait    db    0            ;count-down for safe popup
  213. MaxWait        equ    8            ;wait no more 8/18 sec
  214.  
  215. ;==============================================================================
  216. ; PROCESS & SYSTEM DATA
  217. ;==============================================================================
  218.  
  219. OurSS        dw    0            ;stack for popup routine
  220. OurSP        dw    0
  221. StackSize    equ    512            ;bytes to reserve for stack
  222.  
  223. OldSS        dw    0            ;old stack seg
  224. OldSP        dw    0            ;old stack off
  225.  
  226. OurPSP        dw    0            ;our PSP seg
  227. OldPSP        dw    0            ;old PSP seg
  228.  
  229. OldDTA        label    dword            ;seg:off of old DTA area
  230. OldDTAOff    dw    0
  231. OldDTASeg    dw    0
  232.  
  233. OurDTA        label    dword            ;seg:off of our DTA
  234. OurDTAOff    dw    0
  235. OurDTASeg    dw    0
  236.  
  237. OldBreak    db    0            ;old ctrl-break state
  238. OldExtErr    dw    8 dup (0)        ;all regs of ext err info
  239.  
  240. ;==============================================================================
  241. ; LOCATIONS FOR SAVED INTERRUPT VECTORS
  242. ;==============================================================================
  243.  
  244. OldInt08    label    dword            ;Timer0 loaded before this
  245. OldInt08Off    dw    0
  246. OldInt08Seg    dw    0
  247.  
  248. OldInt09    label    dword            ;Kb handler loadde before this
  249. OldInt09Off    dw    0
  250. OldInt09Seg    dw    0
  251.  
  252. OldInt13    label    dword            ;BIOS diskette I/O
  253. OldInt13Off    dw    0
  254. OldInt13Seg    dw    0
  255.  
  256. OldInt16    label    dword            ;BIOS kb Q-handler
  257. OldInt16Off    dw    0
  258. OldInt16Seg    dw    0
  259.  
  260. OldInt1B    label    dword            ;^break of process we steal
  261. OldInt1BOff    dw    0
  262. OldInt1BSeg    dw    0
  263.  
  264. OldInt1C    label    dword            ;timer tick of process we steal
  265. OldInt1COff    dw    0
  266. OldInt1CSeg    dw    0
  267.  
  268. OldInt21    label    dword            ;DOS function dispatcher
  269. OldInt21Off    dw    0
  270. OldInt21Seg    dw    0
  271.  
  272. OldInt23    label    dword            ;^C of process we steal
  273. OldInt23Off    dw    0
  274. OldInt23Seg    dw    0
  275.  
  276. OldInt24    label    dword            ;crit err of process we steal
  277. OldInt24Off    dw    0
  278. OldInt24Seg    dw    0
  279.  
  280. OldInt28    label    dword            ;DOS idles loaded before this
  281. OldInt28Off    dw    0
  282. OldInt28Seg    dw    0
  283.  
  284. ;==============================================================================
  285. ; SPEAKER/TONE GENERATION DATA
  286. ;==============================================================================
  287.  
  288. PB0port        equ    61h            ;port for speaker bit
  289. ErrLen1        equ    10            ;# outer err beep cycles
  290. ErrLen2        equ    80            ;# inner err beep cycles
  291. ErrLow        equ    100            ;low tone wait in err beep
  292. ErrHi        equ    40            ;hi tone wait in err beep
  293.  
  294. ;==============================================================================
  295. ; ErrBeep - PRODUCE ERROR-INDICATING SOUND ON SPEAKER
  296. ;==============================================================================
  297.  
  298. ErrBeep        proc    near
  299.         assume    ds:nothing, es:nothing, ss:nothing
  300.  
  301.         push    ax            ;save regs used
  302.         push    bx
  303.         push    cx
  304.         push    dx
  305.  
  306.         mov    cx,ErrLen1        ;# mix-cycles for beep
  307.  
  308. ErrBeep1:    mov    dx,ErrLow        ;wait time for half-cycle
  309.         mov    bx,ErrLen2        ;len of one tone
  310.         call    DoTone            ;output low err tone
  311.         mov    dx,ErrHi        ;wait time for half-cycle
  312.         mov    bx,ErrLen2        ;len of one tone
  313.         call    DoTone            ;output low err tone
  314.  
  315.         loop    ErrBeep1        ;loop for some time
  316.  
  317.         pop    dx
  318.         pop    cx            ;restore regs
  319.         pop    bx
  320.         pop    ax
  321.         ret
  322. ErrBeep        endp
  323.  
  324. ;==============================================================================
  325. ; DoTone - OUTPUT ONE TONE ON THE SPEAKER
  326. ;
  327. ; INPUT:    DX:    LOOP WAIT TIME FOR HALF CYCLE IN TONE
  328. ;        BX:    NUMBER OF CYCLES FOR TONE DURATION
  329. ; OUTPUT:    NONE
  330. ; REGS:        ALL PRESERVED
  331. ;==============================================================================
  332.  
  333. DoTone        proc    near
  334.         assume    ds:nothing, es:nothing, ss:nothing
  335.  
  336.         push    ax            ;save regs used
  337.         push    bx
  338.         push    cx
  339.         in    al,PB0port        ;get PB0 reg pattern
  340.         mov    ah,al            ;save it
  341.  
  342. DoTone1:    and    al,0fch            ;mask off speaker bit
  343.         out    PB0port,al        ;pull!
  344.         mov    cx,dx            ;half cycle in counter
  345. DoTone2:    loop    DoTone2            ;leave there for half a cycle
  346.         or    al,2            ;turn on speaker bit
  347.         out    PB0port,al        ;push!
  348.         mov    cx,dx            ;half cycle in counter
  349. DoTone3:    loop    DoTone3            ;leave there for half a cycle
  350.  
  351.         dec    bx            ;count down tone duration
  352.         jnz    DoTone1            ;go through full tone
  353.  
  354.         mov    al,ah            ;AL=original PB0 reg value
  355.         out    PB0port,al        ;restore
  356.  
  357.         pop    cx            ;restore regs
  358.         pop    bx
  359.         pop    ax
  360.         ret
  361. DoTone        endp
  362.  
  363. ;==============================================================================
  364. ; TestSafe - CHECK IF THIS IS A SAFE TIME TO DO A POP UP
  365. ; 
  366. ; RETURN CLC IF SAFE TO POP UP, CY IF NOT SAFE.
  367. ;
  368. ; CHECK IF ANY INTs ARE IN CRITICAL AREAS (InInt09 & InInt13)
  369. ; CHECK IF WE ARE IN AN OUR OWN INT28 CALL (In28Call)
  370. ; CHECK 8259A PIC ISR REGISTER FOR MISSING EOIs
  371. ; CHECK IF DOS IS STABLE FOR POP UP
  372. ; CHECK IF A PRINT SCREEN IS IN PROGRESS
  373. ;==============================================================================
  374.  
  375. TestSafe    proc    near
  376.         assume    ds:nothing, es:nothing
  377.  
  378.         push    ax            ;save regs used
  379.         push    bx
  380.         push    ds
  381.  
  382. ; ------------    CHECK INTs TO SEE IF THEY WERE INTERRUPTED AT BAD TIMES
  383.  
  384.         test    TsrMode,InInt09 OR InInt13 OR In28Call
  385.         jnz    NotSafe            ;jump if any INTs are chopped
  386.  
  387. ; ------------    CHECK THE 8259A PIC ISR REGISTER FOR NON-EOIed HW INTs
  388.  
  389.         mov    al,00001011b        ;tell 8259A we want the ISR
  390.         out    20h,al            ;8259A command reg
  391.         nop
  392.         nop
  393.         nop                ;now, ISR should be ready
  394.         in    al,20h            ;AL=mask of active INTs
  395.         or    al,al            ;test all (IRQ0 *did* EOI)
  396.         jnz    NotSafe            ;jump if active INTs
  397.  
  398. ; ------------    NOW, ENSURE THAT DOS WAS NOT INTERRUPTED
  399.  
  400.         assume    ds:nothing
  401.  
  402.         lds    bx,InDosPtr        ;now, DS:BX=InDos
  403.         mov    al,byte ptr [bx]    ;get InDos to AL
  404.         lds    bx,CritErrPtr        ;now, DS:BX=CritErr
  405.         or    al,byte ptr [bx]    ;both flags zero?
  406.         jz    DosSafe            ;YES - DOS is really idle
  407.         test    TsrMode,InInt28        ;is this an INT28h
  408.         jz    NotSafe            ;NO - not safe, should be idle
  409.         cmp    al,1            ;YES - one InDos entry only?
  410.         ja    NotSafe            ;NO - jump if more than one
  411. DosSafe:
  412.  
  413. ; ------------    CHECK TO SEE IF A PRINT SCREEN IS IN PROGRESS
  414.  
  415.         mov    ax,BiosXX
  416.         mov    ds,ax            ;move DS to BIOS extra data seg
  417.         assume    ds:BiosXX
  418.  
  419.         cmp    StatusByte,InPrtSc    ;print screen in progress?
  420.         je    NotSafe            ;YES - jump if prtsc
  421.  
  422. ; ------------    SEEMS TO BE A SAFE TIME FOR POPUP
  423.  
  424. IsSafe:        clc                ;CLC=safe to popup
  425.         jmp    short ExitSafe        ;end this then
  426.  
  427. ; ------------    APPARENTLY THIS IS JUST NOT THE TIME TO DO A POPUP
  428.  
  429. NotSafe:    stc                ;CY=don't popup now
  430.  
  431. ; ------------    RETURN TO CALLER WITH CARRY SET/CLEAR
  432.  
  433. ExitSafe:    pop    ds            ;restore regs
  434.         pop    bx
  435.         pop    ax
  436.         ret
  437. TestSafe    endp
  438.  
  439. ;==============================================================================
  440. ; OurInt08 - TSR INT08H HANDLER TO WATCH FOR HOTKEY AND SAFE POPUP TIMES
  441. ;
  442. ; CALL OldInt08
  443. ; CHECK FOR RE-ENTRANCE INTO CRITICAL INT08 CODE
  444. ; SET InInt08 FLAG
  445. ; CHECK FOR TIMEOUT BETWEEN KEYS IN HOTKEY SEQUENCE
  446. ; CHECK IF HOTKEY WAS PRESSED
  447. ; CHECK IF ALREADY InPopup OR InInt28
  448. ; CHECK IF SAFE TIME FOR SYSTEM TO POPUP
  449. ; UPDATE FLAGS AND CALL POPUP IF SAFE
  450. ; GIVE ERROR BEEP IF POPUP WAS UNSAFE FOR A LONG TIME
  451. ; RESET InInt08 FLAG
  452. ; DO IRET
  453. ;==============================================================================
  454.  
  455. ; ------------    NEAR JUMP DESTINATION FOR FAST IRET'S
  456.  
  457. Exit08:        iret                ;IRET (!)
  458.  
  459. ; ------------    ACTUAL INT08 ENTRY POINT
  460.  
  461. OurInt08    proc    far
  462.         assume    ds:nothing, es:nothing, ss:nothing
  463.  
  464.         pushf                ;simulate INT08
  465.         cli                ;in case others forgot it
  466.         call    OldInt08        ;call TSRs loaded before us
  467.  
  468. ; ------------    ENSURE NO RECURSION INTO CRITICAL INT08 CODE
  469.  
  470.         sti                ;we'll manage INTs
  471.  
  472.         test    TsrMode,InInt08        ;already in here somewhere?
  473.         jnz    Exit08            ;YES - don't re-enter
  474.         or    TsrMode,InInt08        ;tell people we are here
  475.  
  476.         push    ax            ;need a few regs in this code
  477.  
  478. ; ------------    COUNT DOWN TIME-OUT BETWEEN KEYS IN HOTKEY SEQUENCE
  479.  
  480.         test    KeyMode,InHotMatch    ;are we in a key match?
  481.         jz    TestHot08        ;NO - don't care then
  482.         dec    BetweenKeys        ;count down timeout val
  483.         jnz    TestHot08        ;jump if no timeout yet
  484.         mov    HotIndex,0        ;start match from beginning
  485.         and    KeyMode,not InHotMatch    ;just so we know it next time
  486.  
  487. ; ------------    CHECK FOR POSSIBLE POPUP ACTIONS
  488.  
  489. TestHot08:    test    KeyMode,HotKeyOn    ;has hotkey been pressed?
  490.         jz    ExitInt08        ;NO - jump if no fun here
  491.  
  492.         test    TsrMode,InInt28 OR InPopup
  493.         jnz    ExitInt08        ;jmp if not alr in business
  494.  
  495. ; ------------    HOTKEY PRESSED, CHECK TO SEE IF IT IS SAFE TO POPUP
  496.  
  497.         cmp    SafeWait,0        ;first time we find hotkey?
  498.         ja    TestSafe08        ;NO - wait has alr been set
  499.         mov    SafeWait,MaxWait    ;# ticks to wait at most
  500.  
  501. TestSafe08:    call    TestSafe        ;now, CY clear if popup is safe
  502.         jc    NotSafe08        ;jump if popup is bad idea
  503.  
  504. ; ------------    SEEMS SAFE TO POPUP AT THIS TIME, SO DO!
  505.  
  506.         xor    al,al            ;fast zero
  507.         mov    SafeWait,al        ;don't count any more
  508.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  509.         or    TsrMode,InPopup        ;tell'em we enter popup routine
  510.         and    TsrMode,not InInt08    ;OK to enter critical INT08
  511.         call    InitPopup        ;do actual popup
  512.         or    TsrMode,InInt08        ;back in INT08 code here
  513.         and    TsrMode,not InPopup    ;not in popup code any more
  514.         mov    SafeWait,al        ;in case of hotkey during popup
  515.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  516.  
  517.         jmp    short ExitInt08        ;finally done
  518.  
  519. ; ------------    UNSAFE POPUP TIME, COUNT DOWN SafeWait
  520.  
  521. NotSafe08:    dec    SafeWait        ;count down waiter
  522.         jnz    ExitInt08         ;jump if still no timeout
  523.  
  524. ; ------------    NO SAFE TIMES FOUND FOR QUITE SOME TIME, ERROR
  525.  
  526.         and    KeyMode,not HotKeyOn    ;might as well clear hotkey
  527.         call    ErrBeep            ;do an error beep
  528.  
  529. ; ------------    NORMAL INT08H EXIT, RESET InInt08
  530.  
  531. ExitInt08:    pop    ax            ;restore regs used
  532.         and    TsrMode,not InInt08    ;clear that flag
  533.         iret                ;straight back
  534. OurInt08    endp
  535.  
  536. ;==============================================================================
  537. ; OurInt09 - TSR INT09H HANDLER TO WATCH FOR HOTKEY
  538. ;
  539. ; SAVE SCAN CODE
  540. ; CALL OldInt09
  541. ; CHECK FOR RECURSION INTO CRITICAL INT09 CODE
  542. ; SET InInt09 FLAG
  543. ; CHECK IF HOTKEY ALREADY SET
  544. ; DETERMINE HOTKEY TYPE (SHIFT STATE OR KEY SEQENCE)
  545. ; CHECK SHIFT STATE IF HotIsShift
  546. ; COMPARE FOR KEY MATCH IF (NOT HotIsShift)
  547. ; SET HotKeyOn IF HOTKEY PRESSED
  548. ; RESET InInt09 FLAG
  549. ; DO IRET
  550. ;==============================================================================
  551.  
  552. ; ------------    NEAR JUMP DESTINATION FOR EARLY EXITS
  553.  
  554. Exit09:        pop    bx            ;restore regs
  555.         pop    ax
  556.         iret                ;flags restored from stack
  557.  
  558. ; ------------    ACTUAL INT09 ENTRY POINT
  559.  
  560. OurInt09    proc    far
  561.         assume    ds:nothing, es:nothing, ss:nothing
  562.  
  563.         push    ax            ;save regs used
  564.         push    bx
  565.  
  566. ; ------------    READ SCAN CODE, IN CASE SEQUENCE MATCHING SELECTED
  567.  
  568.         in    al,KbData        ;Al=key, preserved by BIOS
  569.  
  570. ; ------------    CALL BIOS TO PERFORM IT'S DUTIES
  571.  
  572.         pushf                ;simulate INT (CLI alr set)
  573.         cli                ;in case others forgot it
  574.         call    OldInt09        ;call BIOS/earlier TSRs
  575.  
  576. ; ------------    ENSURE NO RECURSION INTO CRITICAL INT09 CODE
  577.  
  578.         sti                ;we'll manage INTs
  579.  
  580.         test    TsrMode,InInt09        ;alr in business?
  581.         jnz    Exit09            ;YES - skip test till clear
  582.         or    TsrMode,InInt09        ;tell them we arrived here
  583.  
  584. ; ------------    DETERMINE HOT KEY TYPE SELECTED
  585.  
  586.         test    KeyMode,HotKeyOn    ;already hotkey there?
  587.         jnz    ExitInt09        ;YES - no double hotkeys here
  588.  
  589.         test    KeyMode,HotIsShift    ;shift state type hotkey?
  590.         jz    CompSeq09        ;NO - go compare sequence
  591.  
  592. ; ------------    COMPARE CURRENT SHIFT STATUS AGAINST HOTKEY
  593.  
  594.         push    ds            ;save current ds
  595.         mov    ax,BiosData        ;move DS to BIOS data seg
  596.         mov    ds,ax            ;DS can now access keyb vars
  597.         assume    ds:BiosData        ;tell MASM about our DS
  598.         mov    al,KbFlag        ;get BIOS shift state bits
  599.         pop    ds            ;restore
  600.         assume    ds:nothing        ;last thing we know about him
  601.  
  602.         and    al,HotKeyShift        ;isolate relevant bits
  603.         cmp    al,HotKeyShift        ;our shift state in effect?
  604.         jne    ExitInt09        ;NO - not that shift state
  605.         or    KeyMode,HotKeyOn    ;YES - flag hotkey
  606.         jmp    short ExitInt09        ;now we can be proud to leave
  607.  
  608. ; ------------    MATCH KEY IN SCAN CODE SEQUENCE
  609.  
  610. CompSeq09:    mov    bl,HotIndex        ;next scan code to match
  611.         xor    bh,bh            ;must be word
  612.         cmp    al,HotKeySeq[bx]    ;does key match?
  613.         je    HotMatch09        ;YES - jump if match
  614.         mov    HotIndex,bh        ;search from start next time
  615.         and    KeyMode,not InHotMatch    ;current no match
  616.         jmp    short ExitInt09        ;now end this
  617.  
  618. ; ------------    KEY MACTHED NEXT SCAN CODE IN HotKeySeq
  619.  
  620. HotMatch09:    inc    bl            ;new code at next pass
  621.         cmp    bl,HotKeyLen        ;did we match whole sequence?
  622.         jae    HotHit09         ;YES - jump if full sequence
  623.         mov    HotIndex,bl        ;NO - save new count
  624.         mov    BetweenKeys,KeyTimeOut    ;reset counter between keys
  625.         or    KeyMode,InHotMatch    ;we are in a match now
  626.         jmp    short ExitInt09        ;time to end this
  627.  
  628. ; ------------    KEY MATCHED ALL SCAN CODES IN HOTKEY SEQUENCE
  629.  
  630. HotHit09:    or    KeyMode,HotKeyOn    ;say hotkey was pressed
  631.         mov    HotIndex,bh        ;match 1st code next time
  632.         and    KeyMode,not InHotMatch    ;that's the end of a match
  633.  
  634. ; ------------    EXIT FROM INT09H, RESET InInt09 FLAG
  635.  
  636. ExitInt09:    and    TsrMode,not InInt09    ;tell'em we left this code
  637.         pop    bx            ;restore regs
  638.         pop    ax
  639.         iret                ;flags restored from stack
  640. OurInt09    endp
  641.  
  642. ;==============================================================================
  643. ; OurInt13 - SET InInt13 FLAG TO SAY THAT WE ARE IN AN INT13H
  644. ;==============================================================================
  645.  
  646. OurInt13    proc    far
  647.         assume    ds:nothing, es:nothing, ss:nothing
  648.  
  649.         pushf                ;save flags we use
  650.         or    TsrMode,InInt13        ;remember we are in BIOS now
  651.         popf                ;restore flags
  652.  
  653.         pushf                ;simulate INT13
  654.         cli                ;just in case others forgot
  655.         call    OldInt13        ;let BIOS handle it all
  656.  
  657.         pushf                ;BIOS uses flag return
  658.         and    TsrMode, not InInt13    ;tell people we left INT13h
  659.         popf
  660.  
  661.         ret    2            ;throw flags off stack
  662. OurInt13    endp
  663.  
  664. ;==============================================================================
  665. ; OurInt16 - TSR INT16H HANDLER, INT28 CHAIN INTERFACE
  666. ;
  667. ; INPUT:    AX = GetId
  668. ; OUTPUT:    AX = MyId
  669. ; REGS:        AX LOST, ALL OTHERS PRESERVED
  670. ; DESCRIPTION:    DETERMINE IF TSR WITH THIS ID IS ALREADY IN MEMORY
  671. ;
  672. ; INPUT:    AH = 00
  673. ; OUTPUT:    AX = NEXT KEY FROM BUFFER
  674. ; REGS;        AX LOST, ALL OTHERS PRESERVED
  675. ; DESCRIPTION:    RETURN A KEY FROM KEYBOARD BUFFER, WAIT TILL KEY IS PRESSED
  676. ;
  677. ; INPUT:    AH = 01
  678. ; OUTPUT:    AX = KEY FROM BUFFER IN ANY
  679. ;        ZF = NO KEYS IN BUFFER (AX PRESERVED)
  680. ;        NZ = KEY IN BUFFER (RETURNED IN AX, KEY STILL IN BUFFER)
  681. ; DESCRIPTION:    CHECK BUFFER FOR ANY PENDING KEYS, RETURN KEY IF ANY
  682. ;
  683. ; NOTE:    ALL OTHER AX REQUEST CODES ARE PASSED ON TO BIOS INT16H HANDLER.
  684. ;
  685. ; NOTE:    DURING INT28 POPUP (InPopup AND NOT InDosClr) FUNCTIONS AH=0 AND
  686. ;    AH=1 WILL ISSUE INT28, UNLESS InDos HAS FROM VALUE AT POPUP OR
  687. ;    CritErr HAS BEEN SET.
  688. ;==============================================================================
  689.  
  690. OurInt16    proc    far
  691.         assume    ds:nothing, es:nothing, ss:nothing
  692.  
  693.         sti                ;we'll manage INTs
  694.         pushf                ;save callers flags
  695.         cmp    ax,GetId        ;return ID request?
  696.         jne    NotId16            ;NO - jump if not
  697.  
  698. ; ------------    TSR DIAGNOSTIC REQUEST, RETURN SPECIAL VALUE TO SAY WE ARE HERE
  699.  
  700.         mov    ax,MyId            ;ID val returned in AX
  701.         popf                ;restore flags
  702.         iret                ;return to caller
  703.  
  704. ; ------------    PASS CONTROL TO BIOS, FLAGS ON STACK
  705.  
  706. GoBios16:    popf                ;restore flags at INT time
  707.         jmp    OldInt16        ;continue in the woods
  708.  
  709. ; ------------    REGULAR BIOS INT16 REQUEST, CHECK FOR ANY FANCY ACTIONS
  710.  
  711. NotId16:    test    TsrMode,InPopup        ;are we in a popup?
  712.         jz    GoBios16        ;NO - leave rest with BIOS
  713.         test    TsrMode,InDosClr    ;InDos clear at popup?
  714.         jnz    GoBios16        ;YES - no need to signal INT28
  715.  
  716.         popf                ;restore original flags
  717.         push    bx            ;we need a few regs here
  718.         push    cx
  719.         push    si
  720.         push    ds
  721.         pushf                ;original flags back on stack
  722.  
  723. ; ------------    GET REQUEST CODE TO BH ENHANCED BIT TO BL
  724.  
  725.         mov    bh,ah            ;BH=function request code
  726.         and    bh,not 10h        ;zap enhanced kybd bit
  727.         cmp    bh,1            ;any function above 1?
  728.         ja    ExitBios16        ;YES - leave rest with BIOS
  729.  
  730.         mov    bl,ah            ;BL used for enhanced bit
  731.         and    bl,10h            ;BL=value of enhanced bit
  732.  
  733. ; ------------    GET InDos To CL, CritErr to CH, SETUP REGS
  734.  
  735.         assume    ds:nothing
  736.  
  737.         lds    si,InDosPtr        ;DS:[SI]=InDos
  738.         mov    cl,byte ptr [si]    ;CL=InDos value
  739.         lds    si,CritErrPtr        ;ES:[SI]=CritErr
  740.         mov    ch,byte ptr [si]    ;CH=CritErr value
  741.  
  742.         mov    si,ax            ;save AX call value
  743.  
  744.         mov    ax,cs            ;move DS here, now we got it
  745.         mov    ds,ax
  746.         assume    ds:Cseg            ;everybody should know
  747.  
  748. ; ------------    CHECK KEYBOARD BUFFER, ORIGINAL FLAGS ON STACK
  749.  
  750. Wait16:        mov    ah,1            ;AH=1=test buffer status
  751.         or    ah,bl            ;maintain enhanced bit value
  752.  
  753.         popf                ;restore original flags
  754.         pushf                ;simulate INT
  755.         cli                ;in case others forgot
  756.         call    OldInt16        ;now, ZF set if no keys
  757.         pushf                ;save result flags
  758.         jnz    TestSkip16        ;jump if a key was found
  759.  
  760. ; ------------    NO KEY FOUND, CALL INT28 IF DOS InDos ALLOWS
  761.  
  762.         cmp    cx,0001h        ;CritErr=0, InDos=1 ?
  763.         jne    NextKey16        ;NO - wait for next key
  764.         or    TsrMode,In28Call    ;tell people we called this INT
  765.         int    28h            ;now take your chance
  766.         and    TsrMode,not In28Call    ;end of that call
  767.  
  768. ; ------------    TEST BUFFER AGAIN IF INT16.00, IRET IF INT16.01
  769.  
  770. NextKey16:    or    bh,bh            ;is this a wait for key?
  771.         jz    Wait16            ;YES - then go wait for it!
  772.         mov    ax,si            ;restore original AX contents
  773.         jmp    short Exit16        ;NO - exit with status we got
  774.  
  775. ; ------------    KEY IN BUFFER, IF CTRL-C WE MAY HAVE TO SKIP IT, FLAGS ON STACK
  776.  
  777. TestSkip16:    cmp    al,3            ;is this Ctrl-C?
  778.         jne    TestExit16        ;NO - determine exit method
  779.         test    cx,not 0001h        ;anything but InDos=1?
  780.         jz    TestExit16        ;NO - determine exit method
  781.  
  782. ; ------------    SKIP CTRL-C IN KEYBOARD BUFFER
  783.  
  784.         mov    ah,bl            ;AH=0 + enhanced bit
  785.         popf                ;restore original INTs
  786.         pushf                ;save again
  787.         pushf                ;simulate INT
  788.         cli                ;simulate properly!
  789.         call    OldInt16        ;now, key should be gone
  790.         jmp    short Wait16        ;do as if nothing had happened
  791.  
  792. ; ------------    KEY IN AX, IRET IF INT16.01, LEAVE WITH BIOS IF INT16.00
  793.  
  794. TestExit16:    or    bh,bh            ;is this a wait for key?
  795.         jnz    Exit16            ;NO - do fast return
  796.         mov    ax,si            ;YES - restore AX code
  797.  
  798. ; ------------    PASS CONTROL TO BIOS, FLAGS & REGS ON STACK
  799.  
  800.         assume    ds:nothing
  801.  
  802. ExitBios16:    popf                ;restore work flags
  803.         pop    ds            ;restore regs
  804.         pop    si
  805.         pop    cx
  806.         pop    bx
  807.         cli                ;should look like an INT
  808.         jmp    OldInt16        ;leave rest with BIOS
  809.  
  810. ; ------------    RETURN FROM INT16, FLAGS & REGS ON STACK
  811.  
  812.         assume    ds:nothing
  813.  
  814. Exit16:        popf                ;restore proper flags
  815.         pop    ds            ;restore regs
  816.         pop    si
  817.         pop    cx
  818.         pop    bx
  819.         ret    2            ;IRET, without flags restore
  820.  
  821. OurInt16    endp
  822.  
  823. ;==============================================================================
  824. ; OurInt21 - INT21 FILTER TO THROW DANGEROUS DOS CALLS ON CRITICAL STACK
  825. ;
  826. ; CHECK IF InPopup AND InDosClr
  827. ; CHECK FUNCTION USES CONSOLE STACK
  828. ; SET CritErr IN DOS IF CONSOLE STACK USED
  829. ; CALL OldInt21
  830. ; RESTORE CritErr IF CRITICAL STACK USED
  831. ;==============================================================================
  832.  
  833. OurInt21    proc    far
  834.         assume    ds:nothing, es:nothing
  835.  
  836.         pushf                ;save calling flags
  837.         sti
  838.  
  839.         test    TsrMode,InPopup        ;are we in a popup?
  840.         jz    GoDos21            ;NO - don't worry then
  841.         test    TsrMode,InDosClr    ;console stack idle?
  842.         jnz    GoDos21            ;YES - nothing fancy then
  843.  
  844. ; ------------    THIS IS 2ND CALL INTO DOS, SEE IF USING CONSOLE STACK
  845.  
  846.         cmp    ah,0ch            ;any function 00-0C?
  847.         jbe    UseCrit21        ;YES - use critical stack
  848.         test    TsrMode,NewDos        ;NO - is this DOS 3.x?
  849.         jnz    GoDos21            ;YES - no other to worry about
  850.         cmp    ah,50h            ;set PSP function?
  851.         je    UseCrit21        ;YES - use critical stack
  852.         cmp    ah,51h            ;get PSP function?
  853.         jne    GoDos21            ;NO - leave it with DOS
  854.  
  855. ; ------------    FORCE USE OF CRITICAL STACK FOR THIS CALL
  856.  
  857. UseCrit21:    assume    ds:nothing        ;nothing to say about DS
  858.  
  859.         push    si            ;save regs
  860.         push    ds
  861.         lds    si,CritErrPtr        ;now, DS:[SI]=InDos
  862.         mov    byte ptr [si],-1    ;FF=use crit stack now
  863.         pop    ds            ;restore regs
  864.         pop    si
  865.  
  866.         popf                ;retsore flags setting
  867.         pushf                ;simulate INT
  868.         cli                ;in case others forgot
  869.         call    OldInt21        ;flags already on stack
  870.  
  871.         push    si            ;save regs
  872.         push    ds
  873.         lds    si,CritErrPtr        ;now, DS:[SI]=InDos
  874.         mov    byte ptr [si],0        ;0=back to default stack
  875.         pop    ds            ;restore regs
  876.         pop    si
  877.  
  878.         ret    2            ;IRET throw old flags
  879.  
  880. ; ------------    PASS CONTROL TO DOS, FLAGS ON STACK
  881.  
  882. GoDos21:    popf                ;restore original flags
  883.         cli                ;just in case someone forgot
  884.         jmp    OldInt21        ;let DOS handle the rest
  885. OurInt21    endp
  886.  
  887. ;==============================================================================
  888. ; OurInt24 - SAFE DOS CRITICAL ERROR HANDLER
  889. ; 
  890. ; IF DOS 3.X, FAIL THE SYSTEM CALL
  891. ; IF NOT DOS 3.X, IGNORE ERROR
  892. ;==============================================================================
  893.  
  894. OurInt24    proc    far
  895.         assume    ds:nothing, es:nothing, ss:nothing
  896.         mov    al,3            ;AL=3=fail system call
  897.         test    TsrMode,NewDos        ;are we using DOS 3.x?
  898.         jnz    Exit24            ;YES - OK to use AL=3
  899.         xor    al,al            ;NO - have to ignore err then
  900. Exit24:        iret                ;return to DOS
  901. OurInt24    endp
  902.  
  903. ;==============================================================================
  904. ; OurInt28 - TSR INT28H HANDLER, ALLOWS POPUP DURING DOS IDLE CALLS
  905. ;
  906. ; CALL OldInt28
  907. ; CHECK FOR RECURSION INTO CRITICAL INT28 CODE (& OTHER INTs AS WELL)
  908. ; SET InInt28 FLAG
  909. ; CHECK FOR HOTKEY
  910. ; CHECK IF SAFE TO POPUP
  911. ; DO POPUP IF SAFE AT THIS TIME
  912. ; RESET InInt28 FLAG
  913. ; DO IRET
  914. ;==============================================================================
  915.  
  916. OurInt28    proc    far
  917.         assume    ds:nothing, es:nothing, ss:nothing
  918.  
  919. ; ------------    ENSURE NO RECURSION ON CRITICAL INT28 CODE
  920.  
  921.         pushf                ;save original flags
  922.         sti                ;we'll manage INT's after this
  923.         test    TsrMode,InInt08 OR InInt28 OR In28Call OR InPopup
  924.         jz    NowIn28            ;continue if not recursion
  925.  
  926. ; ------------    PASS CONTROL TO OLD BIOS28, ORIGINAL FLAGS ON STACK
  927.  
  928. GoOld28:    popf                ;restore original flags
  929.         cli                ;in case others forgot
  930.         jmp    OldInt28        ;call TSRs loaded before this
  931.  
  932. ; ------------    ENTER CRITICAL INT28 CODE, ORIGINAL FLAGS ON STACK
  933.  
  934. NowIn28:    or    TsrMode,InInt28        ;tell'em we are here
  935.  
  936. ; ------------    CHECK FOR POSSIBLE POPUP ACTIONS
  937.  
  938.         test    KeyMode,HotKeyOn    ;any hotkeys pressed?
  939.         jz    ExitInt28        ;NO - don't check any more then
  940.  
  941. ; ------------    HOTKEY WAS PRESSED, ENSURE IT'S SAFE TO DO POPUP
  942.  
  943.         call    TestSafe        ;now, CY clear if popup is OK
  944.         jc    ExitInt28        ;jump if not to popup
  945.  
  946. ; ------------    SEEMS OK TO DO POPUP, SO DO!
  947.  
  948.         and    KeyMode,not HotKeyOn    ;clear hotkey status
  949.         or    TsrMode,InPopup        ;tell'em we enter popup routine
  950.         and    TsrMode,not InInt28    ;OK to enter critical INT28
  951.         call    InitPopup        ;then do popup
  952.         or    TsrMode,InInt28        ;back in INT28 code here
  953.         and    TsrMode,not InPopup    ;not in popup code any more
  954.         and    KeyMode,not HotKeyOn    ;clear hotkeys during popup
  955.  
  956. ; ------------    NORMAL INT28H EXIT, RESET InInt28 FLAG
  957.  
  958. ExitInt28:    and    TsrMode,not InInt28    ;tell'em we left this code
  959.         jmp    short GoOld28        ;we have nothing more to say
  960. OurInt28    endp
  961.  
  962. ;==============================================================================
  963. ; NopInt - DUMMY IRET INSTRUCTION USED BY EMPTY INT HANDLERS
  964. ;==============================================================================
  965.  
  966. NopInt:        iret                ;immediate return
  967.  
  968. ;==============================================================================
  969. ; InitPopup - PREPARES SYSTEM FOR POPUP, THEN CALLS Popup, THEN RESTORES
  970. ;
  971. ; ESTABLISH INTERNAL WORK STACK
  972. ; SAVE CPU REGS
  973. ; UPDATE InDosClr FLAG WITH CURRENT VALUE OF InDos
  974. ; SAVE PROCESS RELATED SYSTEM INFO
  975. ; SAVE USER INTERRUPT VECTORS
  976. ; INSERT SAFE USER INTERRUPT VECTORS
  977. ; CALL POPUP ROUTINE
  978. ; RESTORE USER INTERRUPT VECTORS
  979. ; RESTORE PROCESS AND SYSTEM INFO
  980. ; CLEAR InDosClr FLAG TO PREVENT UNSAFE INT28 CALLs
  981. ; RESTORE CPU REGS
  982. ;==============================================================================
  983.  
  984. InitPopup    proc    near
  985.         assume    ds:nothing, es:nothing, ss:nothing
  986.  
  987. ; ------------    SWITCH TO PSP INTERNAL STACK
  988.  
  989.         mov    OldSS,ss        ;save current stack frame
  990.         mov    OldSP,sp
  991.  
  992.         cli                ;always CLI for the old chips
  993.         mov    ss,OurSS        ;move SS here
  994.         mov    sp,OurSP        ;move SP into position
  995.         sti                ;OK guys
  996.  
  997. ; ------------    SAVE ALL REGS
  998.  
  999.         push    ax
  1000.         push    bx
  1001.         push    cx
  1002.         push    dx
  1003.         push    bp
  1004.         push    si
  1005.         push    di
  1006.         push    ds
  1007.         push    es
  1008.  
  1009.         mov    ax,cs
  1010.         mov    ds,ax            ;mov DS here
  1011.         assume    ds:Cseg            ;tell MASM that
  1012.  
  1013. ; ------------    TAG VALUE OF InDos FLAG AT TIME OF POPUP
  1014.  
  1015.         or    TsrMode,InDosClr    ;assume InDos=0
  1016.         les    si,InDosPtr        ;now, ES:[SI]=InDos
  1017.         cmp    byte ptr es:[si],1    ;InDos set? (>2 impossible)
  1018.         jb    InDosSaved        ;NO - jump if all clear DOS
  1019.         and    TsrMode,not InDosClr    ;clear flag for popup InDos
  1020. InDosSaved:
  1021.  
  1022. ; ------------    SAVE DOS 3.X EXTENDED ERROR INFO
  1023.  
  1024.         test    TsrMode,NewDos        ;really DOS 3.x?
  1025.         jz    Dos3Saved        ;NO - jump if not 3.x
  1026.  
  1027.         mov    ah,59h            ;to get err info from DOS
  1028.         xor    bx,bx            ;BX must be zero
  1029.         push    ds            ;save DS (killed by DOS)
  1030.         int    21h            ;ext err info in AX,BX,CX
  1031.         pop    ds            ;restore
  1032.         mov    OldExtErr[0],ax        ;save
  1033.         mov    OldExtErr[2],bx
  1034.         mov    OldExtErr[4],cx
  1035.         mov    OldExtErr[6],dx
  1036.         mov    OldExtErr[8],si
  1037.         mov    OldExtErr[10],di
  1038.         mov    OldExtErr[12],ds
  1039.         mov    OldExtErr[14],es
  1040. Dos3Saved:
  1041.  
  1042. ; ------------    SAVE CURRENT BREAK STATE, RELAX BREAK CHECKING
  1043.  
  1044.         mov    ax,3300h        ;to get current BREAK value
  1045.         int    21h            ;now, DL=current BREAK
  1046.         mov    OldBreak,dl        ;save current level
  1047.         mov    ax,3301h        ;to set BREAK from DL
  1048.         xor    dl,dl            ;DL=0=relax checking
  1049.         int    21h            ;current level in DL
  1050.  
  1051. ; ------------    SAVE CURRENT USER INT VECTORS
  1052.  
  1053.         mov    ax,351bh        ;BIOS ctrl-break int
  1054.         int    21h            ;ES:BX=vector
  1055.         mov    OldInt1BOff,bx        ;save it
  1056.         mov    OldInt1BSeg,es
  1057.  
  1058.         mov    ax,351ch        ;BIOS timer tick
  1059.         int    21h            ;ES:BX=vector
  1060.         mov    OldInt1COff,bx        ;save it
  1061.         mov    OldInt1CSeg,es
  1062.  
  1063.         mov    ax,3523h        ;DOS ctrl-C
  1064.         int    21h            ;ES:BX=vector
  1065.         mov    OldInt23Off,bx        ;save it
  1066.         mov    OldInt23Seg,es
  1067.  
  1068.         mov    ax,3524h        ;DOS crit err handler
  1069.         int    21h            ;ES:BX=vector
  1070.         mov    OldInt24Off,bx        ;save it
  1071.         mov    OldInt24Seg,es
  1072.  
  1073. ; ------------    INSERT DUMMY IRET INTO DANGEROUS VECTORS
  1074.  
  1075.         mov    dx,offset NopInt    ;now, DS:DX=dunny iret
  1076.         mov    ax,251bh        ;BIOS ctrlk-break handler
  1077.         int    21h            ;set to IRET
  1078.         mov    ax,251ch        ;BIOS timer tick
  1079.         int    21h            ;set to IRET
  1080.         mov    ax,2523h        ;DOS ctrl-C handler
  1081.         int    21h            ;set to IRET
  1082.  
  1083. ; ------------    ESTABLISH SAFE CRITICAL ERROR HANDLER
  1084.  
  1085.         mov    dx,offset OurInt24    ;now, DS:DX=safe crit err
  1086.         mov    ax,2524h        ;to set crit err handler
  1087.         int    21h
  1088.  
  1089. ; ------------    SAVE CURRENT DTA AREA, SET OUR DEFAULT DTA
  1090.  
  1091.         mov    ah,2fh            ;to obtain current DTA from DOS
  1092.         int    21h            ;DTA addr now in ES:BX
  1093.         mov    OldDTAOff,bx        ;save it
  1094.         mov    OldDTASeg,es
  1095.  
  1096.         push    ds            ;save DS for a while
  1097.         lds    dx,OurDTA        ;DS:DX=our DTA addr
  1098.         mov    ah,1ah            ;to set DTA via DOS
  1099.         int    21h            ;set that addr
  1100.         pop    ds            ;restore DS
  1101.  
  1102. ; ------------    SAVE CURRENT PSP, ESTABLISH OURS INSTEAD
  1103.  
  1104.         mov    ax,5100h        ;to get PSP from DOS
  1105.         int    21h            ;current PSP now in BX
  1106.         mov    OldPSP,bx        ;save it
  1107.         mov    bx,OurPSP        ;het our PSP instead
  1108.         mov    ax,5000h        ;to set our PSP
  1109.         int    21h
  1110.  
  1111. ; ------------    CALL USER POPUP ROUTINE
  1112.  
  1113.         call    Popup            ;finally!
  1114.  
  1115. ; ------------    RESTORE TO SAVED CURRENT PROCESS
  1116.  
  1117.         mov    bx,OldPSP        ;new current process in BX
  1118.         mov    ax,5000h        ;to set PSP via DOS
  1119.         int    21h            ;restore original PSP
  1120.  
  1121. ; ------------    RESTORE SAVED DTA
  1122.  
  1123.         push    ds            ;save DS for a while
  1124.         lds    dx,OldDTA        ;DS:DX=our DTA addr
  1125.         mov    ah,1ah            ;to set DTA via DOS
  1126.         int    21h            ;set that addr
  1127.         pop    ds            ;restore DS
  1128.  
  1129. ; ------------    RESTORE SAVED INTERRUPT VECTORS
  1130.  
  1131.         push    ds            ;save for a while
  1132.         assume    ds:nothing        ;be careful about MASM
  1133.  
  1134.         lds    dx,OldInt1B        ;BIOS ctrl-break handler
  1135.         mov    ax,251bh
  1136.         int    21h
  1137.  
  1138.         lds    dx,OldInt1C        ;BIOS timer tick
  1139.         mov    ax,251ch
  1140.         int    21h
  1141.  
  1142.         lds    dx,OldInt23        ;DOS ctrl-C
  1143.         mov    ax,2523h
  1144.         int    21h
  1145.  
  1146.         lds    dx,OldInt24        ;DOS crit err handler
  1147.         mov    ax,2524h
  1148.         int    21h
  1149.  
  1150.         pop    ds            ;restore data seg DS
  1151.         assume    ds:Cseg
  1152.  
  1153. ; ------------    RESTORE SAVED BREAK CHECKING LEVEL
  1154.  
  1155.         mov    ax,3301h        ;to set break check level
  1156.         mov    dl,OldBreak        ;get saved break state
  1157.         int    21h
  1158.  
  1159. ; ------------    RESTORE DOS 3.X SPECIFIC SYSTEM INFO
  1160.  
  1161.         test    TsrMode,NewDos        ;using DOS 3.x
  1162.         jz    Dos3Restored        ;NO - jump if old DOS 2
  1163.         mov    dx,offset OldExtErr    ;DS:DX=3 words of ext err
  1164.         mov    ax,5d0ah        ;to set ext err info
  1165.         int    21h
  1166. Dos3Restored:
  1167.  
  1168. ; ------------    RESET InDosSet FLAG VALUE TO PREVENT UNSAFE INT28
  1169.  
  1170.         or    TsrMode,InDosClr    ;now we only care that InDos=0
  1171.  
  1172. ; ------------    RESTORE USER REGS
  1173.  
  1174.         pop    es
  1175.         pop    ds
  1176.         pop    di
  1177.         pop    si
  1178.         pop    bp
  1179.         pop    dx
  1180.         pop    cx
  1181.         pop    bx
  1182.         pop    ax
  1183.         assume    ds:nothing
  1184.  
  1185. ; ------------    RETURN TO USER STACK
  1186.  
  1187.         cli                ;always CLI for the old chips
  1188.         mov    ss,OldSS        ;restore SS
  1189.         mov    sp,OldSP        ;restore SP
  1190.         sti                ;OK guys
  1191.  
  1192.         ret
  1193. InitPopup    endp
  1194.  
  1195. ;==============================================================================
  1196. ; DATA FOR POPUP ROUTINE
  1197. ;==============================================================================
  1198.  
  1199. DosReadMsg    db    13,10,'Reading DOS CON (press <Enter> to terminate)',13,10
  1200. DosReadLen    equ    $-DosReadMsg
  1201.  
  1202. BiosReadMsg    db    'Reading BIOS keyboard (press any key... )',8,8
  1203. BiosReadLen    equ    $-BiosReadMsg
  1204.  
  1205. DoneMsg        db    ' key pressed, exit from TSR DEMO)',13,10
  1206. DoneLen        equ    $-DoneMsg
  1207.  
  1208. Scratch        db    80 dup (?)
  1209.  
  1210. ;==============================================================================
  1211. ; Popup - POPUP USER ROUTINE
  1212. ;
  1213. ; ALL REGISTERS EXCEPT SS:SP AND DS MAY BE CHANGED.
  1214. ; DS IS PRESET TO THE TSR DATA SEGMENT.
  1215. ;
  1216. ; NOTE:    UPON ENTRY TO THIS ROUTINE ALL DOS FUNCTIONS MAY BE CALLED.
  1217. ;    IF POPUP WAS DONE ON INT28, WITH CritErr==1, ALL DOS FUNCTIONS
  1218. ;    THAT WOULD NORMALLY USE THE CONSOLE STACK, WILL GO TO THE CRITICAL
  1219. ;    STACK, HENCE PREVENTING FURTHER POPUP DURING THE DOS CALL.
  1220. ;    (HOWEVER, MOST TSRs WOULD NOT POPUP ANYWAY, SINCE InDos==2).
  1221. ;
  1222. ;    ADDRESSES OF THE InDos AND CritErr ARE STORED IN THE DOUBLE WORDS
  1223. ;    InDosPtr AND CritErrPtr.
  1224. ;
  1225. ;    AT ENTRY CritErr FLAG IS 0 (ZERO), InDos NO GREATER THAN 1 (ONE).
  1226. ;==============================================================================
  1227.  
  1228. Popup        proc    near
  1229.         assume    ds:Cseg, es:nothing, ss:nothing
  1230.  
  1231.         mov    ah,40h            ;DOS write handle
  1232.         mov    bx,1            ;standard output handle
  1233.         mov    dx,offset DosReadMsg    ;DS:DX=str to write
  1234.         mov    cx,DosReadLen        ;CX=# chars to write
  1235.         int    21h            ;output that string
  1236.  
  1237.         mov    ah,3fh            ;DOS read handle
  1238.         xor    bx,bx            ;standard input handle
  1239.         mov    dx,offset Scratch    ;scratch buf for key
  1240.         mov    cx,80            ;read till CR hit
  1241.         int    21h
  1242.  
  1243.         mov    ah,40h            ;read from BIOS msg
  1244.         mov    bx,1
  1245.         mov    dx,offset BiosReadMsg
  1246.         mov    cx,BiosReadLen
  1247.         int    21h
  1248.  
  1249.         xor    ah,ah            ;to let BIOS wait for key
  1250.         int    16h            ;now, key was pressed
  1251.  
  1252.         mov    ah,40h            ;write confirm msg
  1253.         mov    bx,1
  1254.         mov    dx,offset DoneMsg
  1255.         mov    cx,DoneLen
  1256.         int    21h
  1257.  
  1258.         ret
  1259. Popup        endp
  1260.  
  1261. ;==============================================================================
  1262. ; TSR IRON CURTAIN - HE WHO CROSSES THIS CURTAIN WILL BE GONE AFTER TSR!
  1263. ;==============================================================================
  1264.  
  1265. TsrCurtain:                    ;TSR memory break
  1266.  
  1267. ;==============================================================================
  1268. ; NON-RESIDENT MESSAGES FOR INIT
  1269. ;==============================================================================
  1270.  
  1271. BannerMsg    label    byte
  1272. db    13,10
  1273. db    '<<<<<<  TSR DEMO  >>>>>>',13,10
  1274. db    '   Thomas Brandenborg',13,10
  1275. db    '      Version 2.01',13,10,10
  1276. db    '$'
  1277.  
  1278. FirstMsg    label    byte
  1279. db    'Pop up routine installed resident.',13,10
  1280. db    '$'
  1281.  
  1282. SecondMsg    label    byte
  1283. db    'TSR DEMO already loaded.',13,10
  1284. db    '$'
  1285.  
  1286. HotKeyMsg    label    byte
  1287. db    'Hit <Left Shift> twice to pop up!',13,10,10
  1288. db    '$'
  1289.  
  1290. Dos1Msg    label    byte
  1291. db    'OOPS!',7,13,10
  1292. db    'Must use DOS release 2.00 or later!',13,10,10
  1293. db    '$'
  1294.  
  1295. BadDosMsg    label    byte
  1296. db    'OOPS!',7,13,10
  1297. db    'Did not recognize DOS version!',13,10,10
  1298. db    '$'
  1299.  
  1300. ; ------------    DOS ERROR LEVEL EXIT CODES
  1301.  
  1302. xOk        equ    0            ;normal, OK exit
  1303. xSecond        equ    1            ;TSR already loaded
  1304. xBadDos        equ    2            ;CritErr flag not found
  1305.  
  1306. ;==============================================================================
  1307. ; Init - INITIALIZE TSR APPLICATION, ENTERED UPON DOS LOAD
  1308. ; 
  1309. ; DISPLAY BANNER, INITIALIZE SYSTEM DATA, CHECK IF ALREADY LOADED,
  1310. ; HOOK INTO INTERRUPT CHAIN, TERMINATE, BUT STAY RESIDENT.
  1311. ;==============================================================================
  1312.  
  1313. Init        proc    near
  1314.         assume    ds:Cseg, es:nothing, ss:nothing
  1315.  
  1316.         mov    dx,offset BannerMsg
  1317.         mov    ah,9
  1318.         int    21h            ;display programme banner
  1319.  
  1320. ; ------------    USE INT16H DIAGNOSTIC TO SEE IF TSR ALREADY INSTALLED
  1321.  
  1322.         mov    ax,GetId        ;INT16h diagnostic request
  1323.         int    16h            ;now, AX=MyId if installed
  1324.         cmp    ax,MyId            ;TSR already installed?
  1325.         jne    CheckDos        ;NO - jump if not installed
  1326.  
  1327. ; ------------    TSR ALREADY INSTALLED, DISPLAY MSG, EXIT
  1328.  
  1329.         mov    dx,offset SecondMsg
  1330.         mov    ah,9
  1331.         int    21h                ;display alr installed msg
  1332.         mov    dx,offset HotKeyMsg
  1333.         mov    ah,9
  1334.         int    21h            ;be kind & disp hot key
  1335.         mov    ax,4c00h + xSecond    ;error level in AL
  1336.         int    21h            ;abot now
  1337.  
  1338. ; ------------    IDIOT IS RUNNING DOS 1, LEAVE THE OLD FASHION WAY!
  1339.  
  1340. Dos1:        mov    dx,offset Dos1Msg
  1341.         mov    ah,9
  1342.         int    21h            ;display msg about DOS 1
  1343.         int    20h            ;no err level for DOS 1
  1344.  
  1345. ; ------------    ENSURE DOS VERSION IS NEWER THAN 2.00
  1346.  
  1347. CheckDos:    or    TsrMode,NewDos        ;assume suing DOS 3.x
  1348.         mov    ah,30h            ;to get DOS version number
  1349.         int    21h            ;version is AL.AH
  1350.         cmp    al,2            ;release 2 or newer?
  1351.         jb    Dos1            ;NO - jump if DOS 1 in use
  1352.         ja    DosFlags        ;jump if DOS 3.x
  1353.         and    TsrMode,not NewDos    ;now, say we use DOS 2.x
  1354.  
  1355. ; ------------    INITIALIZE PTRS TO DOS FLAGS - 1ST InDos
  1356.  
  1357. DosFlags:    mov    ax,3400h        ;to get InDos ptr
  1358.         int    21h            ;ES:BX=seg:off of InDos
  1359.         mov    InDosOff,bx        ;save ptr
  1360.         mov    InDosSeg,es
  1361.  
  1362. ; ------------    WE NEED CritErr TO USE PSP FUNCTIONS IN DOS 2.X (CHIPs WAY)
  1363.  
  1364.         xor    dl,dl            ;DL=0=this is 1st scan
  1365.         mov    CritErrSeg,es        ;DOS seg still in ES
  1366. CritScan:    mov    di,bx            ;start search at InDos
  1367.         mov    cx,2000h        ;search max 1000h words
  1368.         mov    ax,3e80h        ;opcode CMP BYTE PTR [CritErr]
  1369.         cld                ;better serach forward
  1370.  
  1371. CritScan2:    repne    scasw            ;search till found or end
  1372.         jne    NoCritFound        ;jump if CMP not found
  1373.                         ;ES:[DI-2] at:
  1374.                         ;    CMP BYTE PTR [CritErr]
  1375.                         ;    JNZ ...
  1376.                         ;    MOV SP,stack addr
  1377.         cmp    byte ptr es:[di][5],0bch ;really CMP SP there?
  1378.         jne    CritScan2        ;NO - scan again if not
  1379.         mov    ax,word ptr es:[di]    ;now, AX=CritErr offset
  1380.         mov    CritErrOff,ax        ;save it
  1381.         jmp    short InitData        ;OK to end this now
  1382.  
  1383. NoCritFound:    or    dl,dl            ;was this1 st scan?
  1384.         jnz    BadDos            ;NO - CritErr not founbd at all
  1385.         inc    dl            ;DL=1=this is 2nd scan
  1386.         inc    bx            ;try scan at odd/even offset
  1387.         jmp    CritScan        ;scan again
  1388.         
  1389. ; ------------    COULD NOT LOCATE DOS CritErr FLAG - THAT'S AN ERROR
  1390.  
  1391. BadDos:        mov    dx,offset BadDosMsg
  1392.         mov    ah,9
  1393.         int    21h            ;display msg about that
  1394.         mov    ax,4c00h + xBadDos    ;err level in AL
  1395.         int    21h            ;OK to use 4C (DOS >= 2)
  1396.  
  1397. ; ------------    INITIALIZE SYSTEM DATA VARIABLES
  1398.  
  1399. InitData:                    ;store position for stack
  1400.         mov    OurSP,TsrCurtain - ComEntry + 100h + StackSize
  1401.         mov    OurSS,cs        ;stack seg is code seg
  1402.  
  1403.         mov    ax,5100h        ;to get current PSP from DOS
  1404.         int    21h            ;PSP now in BX
  1405.         mov    OurPSP,bx        ;save our PSP
  1406.  
  1407.         mov    ah,2fh            ;to get current DTA from DOS
  1408.         int    21h            ;now, ES:BX=current DTA
  1409.         mov    OurDTAOff,bx        ;save it
  1410.         mov    OurDTASeg,es
  1411.  
  1412.         and    KeyMode,not HotIsShift    ;hotkey is not shift state
  1413.         or    TsrMode,InDosClr    ;will prevent unsafe INT28s
  1414.  
  1415. ; ------------    SAVE VECTORS FOR OUR MONITOR INTERRUPTS
  1416.  
  1417.         mov    ax,3508h        ;BIOS timer0 tick handler
  1418.         int    21h            ;ES:BX=vector
  1419.         mov    OldInt08Off,bx
  1420.         mov    OldInt08Seg,es
  1421.  
  1422.         mov    ax,3509h        ;BIOS kb HW handler
  1423.         int    21h            ;ES:BX=vector
  1424.         mov    OldInt09Off,bx
  1425.         mov    OldInt09Seg,es
  1426.  
  1427.         mov    ax,3513h        ;BIOS disk I/O service
  1428.         int    21h            ;ES:BX=vector
  1429.         mov    OldInt13Off,bx
  1430.         mov    OldInt13Seg,es
  1431.  
  1432.         mov    ax,3516h        ;BIOS kb read
  1433.         int    21h            ;ES:BX=vector
  1434.         mov    OldInt16Off,bx
  1435.         mov    OldInt16Seg,es
  1436.  
  1437.         mov    ax,3521h        ;DOS functions dispatcher
  1438.         int    21h            ;ES:BX=vector
  1439.         mov    OldInt21Off,bx
  1440.         mov    OldInt21Seg,es
  1441.  
  1442.         mov    ax,3528h        ;DOS idle hook
  1443.         int    21h            ;ES:BX=vector
  1444.         mov    OldInt28Off,bx
  1445.         mov    OldInt28Seg,es
  1446.  
  1447. ; ------------    ESTABLISH IRET INT23 TO PREVENT BREAK DURING VECTOR FIX
  1448.  
  1449.         mov    dx,offset NopInt    ;DS:DX=dummy vector to set
  1450.         mov    ax,2523h        ;to set ^C handler through DOS
  1451.         int    21h            ;now, no break will occur
  1452.  
  1453. ; ------------    SAVE VECTORS FOR OUR MONITOR INTERRUPTS
  1454.  
  1455.         mov    ax,2508h        ;to set our INT08h handler
  1456.         mov    dx,offset OurInt08    ;DS:DX=new vector
  1457.         int    21h            ;let DOS set vector
  1458.  
  1459.         mov    ax,2509h        ;to set our INT09h handler
  1460.         mov    dx,offset OurInt09    ;DS:DX=new vector
  1461.         int    21h            ;let DOS set vector
  1462.  
  1463.         mov    ax,2513h        ;to set our INT13h handler
  1464.         mov    dx,offset OurInt13    ;DS:DX=new vector
  1465.         int    21h            ;let DOS set vector
  1466.  
  1467.         mov    ax,2516h        ;to set our INT16h handler
  1468.         mov    dx,offset OurInt16    ;DS:DX=new vector
  1469.         int    21h            ;let DOS set vector
  1470.  
  1471.         mov    ax,2521h        ;to set our INT21h handler
  1472.         mov    dx,offset OurInt21    ;DS:DX=new vector
  1473.         int    21h            ;let DOS set vector
  1474.  
  1475.         mov    ax,2528h        ;to set our INT28h handler
  1476.         mov    dx,offset OurInt28    ;DS:DX=new vector
  1477.         int    21h            ;let DOS set vector
  1478.  
  1479. ; ------------    DISLAY MSG ABOUT HOW WELL THIS IS ALL RUNNING
  1480.  
  1481.         mov    dx,offset FirstMsg
  1482.         mov    ah,9
  1483.         int    21h            ; display confirm msg
  1484.         mov    dx,offset HotKeyMsg
  1485.         mov    ah,9
  1486.         int    21h            ;disp hot key
  1487.  
  1488. ; ------------    EXIT, SAY GOOD BYE TO FRIENDS BEHIND CURTAIN!
  1489.  
  1490.         mov    es,EnvSeg        ;ES=our environment copy
  1491.         mov    ah,49h            ;to let DOS free block
  1492.         int    21h            ;environment copy freed
  1493.  
  1494.         mov    dx,(TsrCurtain-ComEntry+100h+StackSize+15) SHR 4
  1495.         mov    ax,3100h + xOk        ;TSR, AL=err level
  1496.         int    21h
  1497. Init        endp
  1498.  
  1499. ;==============================================================================
  1500.  
  1501. Cseg        ends
  1502.         end    ComEntry
  1503.