home *** CD-ROM | disk | FTP | other *** search
/ Sunny 1,000 Collection / SUNNY1000.iso / Files / Dos / infoco3 / TAD2EX.ZIP / STD.T < prev    next >
Text File  |  1994-02-06  |  13KB  |  354 lines
  1. /* Copyright (c) 1989, 1991 by Michael J. Roberts.  All Rights Reserved. */
  2. /*
  3. Name
  4.   std.t   - standard default adventure definitions
  5.   Version 1.2
  6.   
  7.   This file is part of TADS:  The Text Adventure Development System.
  8.   Please see the file LICENSE.DOC (which should be part of the TADS
  9.   distribution) for information on using this file, and for information
  10.   on reaching High Energy Software, the developers of TADS.
  11.  
  12.   This file provides some simple definitions for objects and functions
  13.   that are required by TADS, but not defined in the file "adv.t".
  14.   The definitions in std.t are suitable for use while a game is
  15.   being written, but you will probably find that you will want to
  16.   customize the definitions in this file for your game when the
  17.   game is nearing completion.  This file is intended to help you
  18.   get started more quickly by providing basic definitions for these
  19.   functions and objects.
  20.  
  21.   When you decide to customize these functions and objects for
  22.   your game, be sure to remove the inclusion of std.t to avoid
  23.   duplicate definitions.
  24. */
  25.  
  26. /*
  27.  *   Pre-declare all functions, so the compiler knows they are functions.
  28.  *   (This is only really necessary when a function will be referenced
  29.  *   as a daemon or fuse before it is defined; however, it doesn't hurt
  30.  *   anything to pre-declare all of them.)
  31.  */
  32. die: function;
  33. scoreRank: function;
  34. init: function;
  35. terminate: function;
  36. pardon: function;
  37. sleepDaemon: function;
  38. eatDaemon: function;
  39. darkTravel: function;
  40.  
  41. /*
  42.  *   The die() function is called when the player dies.  It tells the
  43.  *   player how well he has done (with his score), and asks if he'd
  44.  *   like to start over (the alternative being quitting the game).
  45.  */
  46. die: function
  47. {
  48.     "\b*** You have died ***\b";
  49.     scoreRank();
  50.     "\bYou may restore a saved game, start over, quit, or undo
  51.     the current command.\n";
  52.     while ( 1 )
  53.     {
  54.         local resp;
  55.  
  56.     "\nPlease enter RESTORE, RESTART, QUIT, or UNDO: >";
  57.         resp := upper(input());
  58.         if ( resp = 'RESTORE' )
  59.     {
  60.         resp := askfile( 'File to restore' );
  61.         if ( resp = nil ) "Restore failed. ";
  62.         else if ( restore( resp )) "Restore failed. ";
  63.         else
  64.         {
  65.             Me.location.lookAround(true);
  66.             setscore( global.score, global.turnsofar );
  67.         abort;
  68.         }
  69.     }
  70.         else if ( resp = 'RESTART' )
  71.     {
  72.         setscore( 0, 0 );
  73.             restart();
  74.     }
  75.     else if ( resp = 'QUIT' )
  76.         {
  77.         terminate();
  78.             quit();
  79.         abort;
  80.         }
  81.     else if (resp = 'UNDO')
  82.     {
  83.         if (undo())
  84.         {
  85.         "(Undoing one command)\b";
  86.         Me.location.lookAround(true);
  87.             setscore(global.score, global.turnsofar);
  88.         abort;
  89.         }
  90.         else
  91.         "Sorry, no undo information is available. ";
  92.     }
  93.     }
  94. }
  95.  
  96. /*
  97.  *   The scoreRank() function displays how well the player is doing.
  98.  *   This default definition doesn't do anything aside from displaying
  99.  *   the current and maximum scores.  Some game designers like to
  100.  *   provide a ranking that goes with various scores ("Novice Adventurer,"
  101.  *   "Expert," and so forth); this is the place to do so if desired.
  102.  *
  103.  *   Note that "global.maxscore" defines the maximum number of points
  104.  *   possible in the game; change the property in the "global" object
  105.  *   if necessary.
  106.  */
  107. scoreRank: function
  108. {
  109.     "In a total of "; say( global.turnsofar );
  110.     " turns, you have achieved a score of ";
  111.     say( global.score ); " points out of a possible ";
  112.     say( global.maxscore ); ".\n";
  113. }
  114.  
  115. /*
  116.  *   The init() function is run at the very beginning of the game.
  117.  *   It should display the introductory text for the game, start
  118.  *   any needed daemons and fuses, and move the player's actor ("Me")
  119.  *   to the initial room, which defaults here to "startroom".
  120.  */
  121. init: function
  122. {
  123.     // put introductory text here
  124.     
  125.     version.sdesc;                // display the game's name and version number
  126.  
  127.     setdaemon( turncount, nil );               // start the turn counter daemon
  128.     setdaemon( sleepDaemon, nil );                    // start the sleep daemon
  129.     setdaemon( eatDaemon, nil );                     // start the hunger daemon
  130.     Me.location := startroom;                // move player to initial location
  131.     startroom.lookAround( true );                    // show player where he is
  132.     startroom.isseen := true;                  // note that we've seen the room
  133. }
  134.  
  135. /*
  136.  *   preinit() is called after compiling the game, before it is written
  137.  *   to the binary game file.  It performs all the initialization that can
  138.  *   be done statically before storing the game in the file, which speeds
  139.  *   loading the game, since all this work has been done ahead of time.
  140.  *
  141.  *   This routine puts all lamp objects (those objects with islamp = true) into
  142.  *   the list global.lamplist.  This list is consulted when determining whether
  143.  *   a dark room contains any light sources.
  144.  */
  145. preinit: function
  146. {
  147.     local o;
  148.     
  149.     global.lamplist := [];
  150.     o := firstobj();
  151.     while( o <> nil )
  152.     {
  153.         if ( o.islamp ) global.lamplist := global.lamplist + o;
  154.         o := nextobj( o );
  155.     }
  156.     initSearch();
  157. }
  158.  
  159. /*
  160.  *   The terminate() function is called just before the game ends.  It
  161.  *   generally displays a good-bye message.  The default version does
  162.  *   nothing.  Note that this function is called only when the game is
  163.  *   about to exit, NOT after dying, before a restart, or anywhere else.
  164.  */
  165. terminate: function
  166. {
  167. }
  168.  
  169. /*
  170.  *   The pardon() function is called any time the player enters a blank
  171.  *   line.  The function generally just prints a message ("Speak up" or
  172.  *   some such).  This default version just says "I beg your pardon?"
  173.  */
  174. pardon: function
  175. {
  176.     "I beg your pardon? ";
  177. }
  178.  
  179. /*
  180.  *   This function is a daemon, started by init(), that monitors how long
  181.  *   it has been since the player slept.  It provides warnings for a while
  182.  *   before the player gets completely exhausted, and causes the player
  183.  *   to pass out and sleep when it has been too long.  The only penalty
  184.  *   exacted if the player passes out is that he drops all his possessions.
  185.  *   Some games might also wish to consider the effects of several hours
  186.  *   having passed; for example, the time-without-food count might be
  187.  *   increased accordingly.
  188.  */
  189. sleepDaemon: function( parm )
  190. {
  191.     local a, s;
  192.  
  193.     global.awakeTime := global.awakeTime + 1;
  194.     a := global.awakeTime;
  195.     s := global.sleepTime;
  196.  
  197.     if ( a = s or a = s+10 or a = s+20 )
  198.         "\bYou're feeling a bit drowsy; you should find a
  199.         comfortable place to sleep. ";
  200.     else if ( a = s+25 or a = s+30 )
  201.         "\bYou really should find someplace to sleep soon, or
  202.         you'll probably pass out from exhaustion. ";
  203.     else if ( a >= s+35 )
  204.     {
  205.       global.awakeTime := 0;
  206.       if ( Me.location.isbed or Me.location.ischair )
  207.       {
  208.         "\bYou find yourself unable to stay awake any longer.
  209.         Fortunately, you are ";
  210.         if ( Me.location.isbed ) "on "; else "in ";
  211.         Me.location.adesc; ", so you gently slip off into
  212.         unconsciousness.
  213.         \b* * * * *
  214.         \bYou awake some time later, feeling refreshed. ";
  215.       }
  216.       else
  217.       {
  218.         local itemRem, thisItem;
  219.  
  220.         "\bYou find yourself unable to stay awake any longer.
  221.         You pass out, falling to the ground.
  222.         \b* * * * *
  223.         \bYou awaken, feeling somewhat the worse for wear.
  224.         You get up and dust yourself off. ";
  225.         itemRem := Me.contents;
  226.         while (car( itemRem ))
  227.         {
  228.             thisItem := car( itemRem );
  229.             if ( not thisItem.isworn )
  230.             thisItem.moveInto( Me.location );
  231.             itemRem := cdr( itemRem );
  232.         }
  233.       }
  234.     }
  235. }
  236.  
  237. /*
  238.  *   This function is a daemon, set running by init(), which monitors how
  239.  *   long it has been since the player has had anything to eat.  It will
  240.  *   provide warnings for some time prior to the player's expiring from
  241.  *   hunger, and will kill the player if he should go too long without
  242.  *   heeding these warnings.
  243.  */
  244. eatDaemon: function( parm )
  245. {
  246.     local e, l;
  247.  
  248.     global.lastMealTime := global.lastMealTime + 1;
  249.     e := global.eatTime;
  250.     l := global.lastMealTime;
  251.  
  252.     if ( l = e or l = e+5 or l = e+10 )
  253.         "\bYou're feeling a bit peckish. Perhaps it would be a good
  254.         time to find something to eat. ";
  255.     else if ( l = e+15 or l = e+20 or l = e+25 )
  256.         "\bYou're feeling really hungry. You should find some food
  257.         soon or you'll pass out from lack of nutrition. ";
  258.     else if ( l=e+30 or l = e+35 )
  259.         "\bYou can't go much longer without food. ";
  260.     else if ( l >= e+40 )
  261.     {
  262.         "\bYou simply can't go on any longer without food. You perish from
  263.         lack of nutrition. ";
  264.         die();
  265.     }
  266. }
  267.  
  268. /*
  269.  *   The numObj object is used to convey a number to the game whenever
  270.  *   the player uses a number in his command.  For example, "turn dial
  271.  *   to 621" results in an indirect object of numObj, with its "value"
  272.  *   property set to 621.
  273.  */
  274. numObj: basicNumObj  // use default definition from adv.t
  275. ;
  276.  
  277. /*
  278.  *   strObj works like numObj, but for strings.  So, a player command of
  279.  *     type "hello" on the keyboard
  280.  *   will result in a direct object of strObj, with its "value" property
  281.  *   set to the string 'hello'.
  282.  *
  283.  *   Note that, because a string direct object is used in the save, restore,
  284.  *   and script commands, this object must handle those commands.
  285.  */
  286. strObj: basicStrObj     // use default definition from adv.t
  287. ;
  288.  
  289. /*
  290.  *   The "global" object is the dumping ground for any data items that
  291.  *   don't fit very well into any other objects.  The properties of this
  292.  *   object that are particularly important to the objects and functions
  293.  *   are defined here; if you replace this object, but keep other parts
  294.  *   of this file, be sure to include the properties defined here.
  295.  *
  296.  *   Note that awakeTime is set to zero; if you wish the player to start
  297.  *   out tired, just move it up around the sleepTime value (which specifies
  298.  *   the interval between sleeping).  The same goes for lastMealTime; move
  299.  *   it up to around eatTime if you want the player to start out hungry.
  300.  *   With both of these values, the player only starts getting warnings
  301.  *   when the elapsed time (awakeTime, lastMealTime) reaches the interval
  302.  *   (sleepTime, eatTime); the player isn't actually required to eat or
  303.  *   sleep until several warnings have been issued.  Look at the eatDaemon
  304.  *   and sleepDaemon functions for details of the timing.
  305.  */
  306. global: object
  307.     turnsofar = 0                            // no turns have transpired so far
  308.     score = 0                            // no points have been accumulated yet
  309.     maxscore = 100                                    // maximum possible score
  310.     verbose = nil                             // we are currently in TERSE mode
  311.     awakeTime = 0               // time that has elapsed since the player slept
  312.     sleepTime = 400     // interval between sleeping times (longest time awake)
  313.     lastMealTime = 0              // time that has elapsed since the player ate
  314.     eatTime = 200         // interval between meals (longest time without food)
  315.     lamplist = []              // list of all known light providers in the game
  316. ;
  317.  
  318. /*
  319.  *   The "version" object defines, via its "sdesc" property, the name and
  320.  *   version number of the game.  Change this to a suitable name for your
  321.  *   game.
  322.  */
  323. version: object
  324.     sdesc = "A TADS Adventure
  325.       \n Developed with TADS, the Text Adventure Development System.\n"
  326. ;
  327.  
  328. /*
  329.  *   "Me" is the player's actor.  Pick up the default definition, basicMe,
  330.  *   from "adv.t".
  331.  */
  332. Me: basicMe
  333. ;
  334.  
  335. /*
  336.  *   darkTravel() is called whenever the player attempts to move from a dark
  337.  *   location into another dark location.  By default, it just says "You
  338.  *   stumble around in the dark," but it could certainly cast the player into
  339.  *   the jaws of a grue, whatever that is...
  340.  */
  341. darkTravel: function
  342. {
  343.     "You stumble around in the dark, and don't get anywhere. ";
  344. }
  345.  
  346. /*
  347.  *   goToSleep - carries out the task of falling asleep.  We just display
  348.  *   a message to this effect.
  349.  */
  350. goToSleep: function
  351. {
  352.     "***\bYou wake up some time later, feeling refreshed. ";
  353. }
  354.